chiark - git - mdw - sod/blob - src/builtin.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Builtin module provides the root of the class graph
   4 ;;;
   5 ;;; (c) 2009 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This file is part of the Sensible Object Design, an object system for C.
  11 ;;;
  12 ;;; SOD is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; SOD is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with SOD; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 (cl:in-package #:sod)
  27
  28 ;;;--------------------------------------------------------------------------
  29 ;;; Infrastructure.
  30
  31 (defvar *class-slot-alist* nil)
  32
  33 (defun add-class-slot-function (name function)
  34   "Attach a slot function to the `*class-slot-alist*'.
  35
  36    The FUNCTION is invoked with one argument, which is a `sod-class' object
  37    to which it should add a slot.  If a function with the same NAME is
  38    already defined then that function is replaced; otherwise a new name/
  39    function pair is defined.
  40
  41    Functions are are invoked in the order in which their names were first
  42    added."
  43
  44   (aif (assoc name *class-slot-alist* :test #'string=)
  45        (setf (cdr it) function)
  46        (asetf *class-slot-alist* (append it (list (cons name function))))))
  47
  48 (defmacro define-class-slot
  49     (name (class &optional stream) type init &body prepare)
  50   "Define a new class slot.
  51
  52    The slot will be called NAME (a string) and will be of TYPE (which should
  53    be a type S-expression).  The slot's (static) initializer will be
  54    constructed by printing the value of INIT, which is evaluated with CLASS
  55    bound to the class object being constructed.  If any PREPARE forms are
  56    provided, then they are evaluated as a progn, with CLASS bound to the
  57    class object, and STREAM bound to the output stream it should write on."
  58
  59   (with-gensyms (classvar)
  60     `(add-class-slot-function
  61       ',name
  62       (lambda (,classvar)
  63         (make-sod-slot ,classvar ,name (c-type ,type)
  64                        (make-property-set :slot-class 'sod-class-slot
  65                                           :initializer-function
  66                                           (lambda (,class)
  67                                             ,init)
  68                                           ,@(and prepare
  69                                                  `(:prepare-function
  70                                                    (lambda (,class ,stream)
  71                                                      ,@prepare)))))))))
  72
  73 ;;;--------------------------------------------------------------------------
  74 ;;; Basic information.
  75
  76 (define-class-slot "name" (class) const-string
  77   (prin1-to-string (sod-class-name class)))
  78
  79 (define-class-slot "nick" (class) const-string
  80   (prin1-to-string (sod-class-nickname class)))
  81
  82 ;;;--------------------------------------------------------------------------
  83 ;;; Instance allocation and initialization.
  84
  85 (define-class-slot "initsz" (class) size-t
  86   (format nil "sizeof(struct ~A)" (ilayout-struct-tag class)))
  87
  88 (define-class-slot "align" (class) size-t
  89   (format nil "SOD__ALIGNOF(struct ~A)" (ilayout-struct-tag class)))
  90
  91 (define-class-slot "imprint" (class stream)
  92     (* (fun (* void) ("/*p*/" (* void))))
  93   (format nil "~A__imprint" class)
  94   (let ((ilayout (sod-class-ilayout class)))
  95     (format stream "~&~:
  96 /* Imprint raw memory with class `~A' instance structure. */
  97 static void *~:*~A__imprint(void *p)
  98 {
  99   struct ~A *sod__obj = p;
 100
 101   ~:{sod__obj->~A.~A._vt = &~A.~A;~:^~%  ~}
 102   return (p);
 103 }~2%"
 104             class
 105             (ilayout-struct-tag class)
 106             (mapcar (lambda (ichain)
 107                       (let* ((head (ichain-head ichain))
 108                              (tail (ichain-tail ichain)))
 109                         (list (sod-class-nickname head)
 110                               (sod-class-nickname tail)
 111                               (vtable-name class head)
 112                               (sod-class-nickname tail))))
 113                     (ilayout-ichains ilayout)))))
 114
 115 ;;;--------------------------------------------------------------------------
 116 ;;; Superclass structure.
 117
 118 (define-class-slot "n_supers" (class) size-t
 119   (length (sod-class-direct-superclasses class)))
 120
 121 (define-class-slot "supers" (class stream)
 122     (* (* (class "SodClass" :const) :const))
 123   (if (null (sod-class-direct-superclasses class)) 0
 124       (format nil "~A__supers" class))
 125   (let ((supers (sod-class-direct-superclasses class)))
 126     (when supers
 127       (format stream "~&~:
 128 /* Direct superclasses. */
 129 static const SodClass *const ~A__supers[] = {
 130   ~{~A__class~^,~%  ~}
 131 };~2%"
 132               class supers))))
 133
 134 (define-class-slot "n_cpl" (class) size-t
 135   (length (sod-class-precedence-list class)))
 136
 137 (define-class-slot "cpl" (class stream)
 138     (* (* (class "SodClass" :const) :const))
 139   (format nil "~A__cpl" class)
 140   (format stream "~&~:
 141 /* Class precedence list. */
 142 static const SodClass *const ~A__cpl[] = {
 143   ~{~A__class~^,~%  ~}
 144 };~2%"
 145           class (sod-class-precedence-list class)))
 146
 147 ;;;--------------------------------------------------------------------------
 148 ;;; Chain structure.
 149
 150 (define-class-slot "link" (class) (* (class "SodClass" :const))
 151   (aif (sod-class-chain-link class)
 152        (format nil "~A__class" it)
 153        0))
 154
 155 (define-class-slot "head" (class) (* (class "SodClass" :const))
 156   (format nil "~A__class" (sod-class-chain-head class)))
 157
 158 (define-class-slot "level" (class) size-t
 159   (position class (reverse (sod-class-chain class))))
 160
 161 (define-class-slot "n_chains" (class) size-t
 162   (length (sod-class-chains class)))
 163
 164 (define-class-slot "chains" (class stream) (* (struct "sod_chain" :const))
 165   (format nil "~A__chains" class)
 166   (let ((chains (sod-class-chains class)))
 167     (format stream "~&~:
 168 /* Chain structure. */
 169 ~1@*~:{static const SodClass *const ~A__chain_~A[] = {
 170   ~{~A__class~^,~%  ~}
 171 };~:^~2%~}
 172
 173 ~0@*static const struct sod_chain ~A__chains[] = {
 174 ~:{  { ~
 175     /*           n_classes = */ ~3@*~A,
 176     /*             classes = */ ~0@*~A__chain_~A,
 177     /*          off_ichain = */ ~4@*offsetof(struct ~A, ~A),
 178     /*                  vt = */ (const struct sod_vtable *)&~A,
 179     /*            ichainsz = */ sizeof(struct ~A) }~:^,~%~}
 180 };~2%"
 181             class                       ;0
 182             (mapcar (lambda (chain)     ;1
 183                       (let* ((head (sod-class-chain-head (car chain)))
 184                              (chain-nick (sod-class-nickname head)))
 185                         (list class chain-nick                        ;0 1
 186                               (reverse chain)                         ;2
 187                               (length chain)                          ;3
 188                               (ilayout-struct-tag class) chain-nick   ;4 5
 189                               (vtable-name class head)                ;6
 190                               (ichain-struct-tag (car chain) head)))) ;7
 191                     chains))))
 192
 193 ;;;--------------------------------------------------------------------------
 194 ;;; Class-specific layout.
 195
 196 (define-class-slot "off_islots" (class) size-t
 197   (if (sod-class-slots class)
 198       (format nil "offsetof(struct ~A, ~A)"
 199               (ichain-struct-tag class (sod-class-chain-head class))
 200               (sod-class-nickname class))
 201       "0"))
 202
 203 (define-class-slot "islotsz" (class) size-t
 204   (if (sod-class-slots class)
 205       (format nil "sizeof(struct ~A)"
 206               (islots-struct-tag class))
 207       "0"))
 208
 209 ;;;--------------------------------------------------------------------------
 210 ;;; Built-in methods.
 211
 212 ;; Common protocol.
 213
 214 (defclass lifecycle-message (standard-message)
 215   ())
 216
 217 (defclass lifecycle-effective-method (standard-effective-method)
 218   ())
 219
 220 (defmethod effective-method-live-p ((method lifecycle-effective-method))
 221   t)
 222
 223 (defgeneric lifecycle-method-kernel (method codegen target)
 224   (:documentation
 225    "Compute (into CODEGEN) the class-specific part of the METHOD.
 226
 227    The result, if any, needs to find its way to the TARGET, as usual."))
 228
 229 (defmethod simple-method-body
 230     ((method lifecycle-effective-method) codegen target)
 231   (invoke-delegation-chain codegen target
 232                            (effective-method-basic-argument-names method)
 233                            (effective-method-primary-methods method)
 234                            (lambda (target)
 235                              (lifecycle-method-kernel method
 236                                                       codegen
 237                                                       target))))
 238
 239 ;; Utilities.
 240
 241 (defun declare-me (codegen class)
 242   "Emit, to CODEGEN, a declaration of `me' as a pointer to CLASS.
 243
 244    The pointer refers to a part of the prevailing `sod__obj' object, which is
 245    assumed to be a pointer to an appropriate `ilayout' structure."
 246   (emit-decl codegen (make-var-inst "me" (c-type (* (class class)))
 247                                     (format nil "&sod__obj->~A.~A"
 248                                             (sod-class-nickname
 249                                              (sod-class-chain-head class))
 250                                             (sod-class-nickname class)))))
 251
 252 (defun collect-initarg-keywords (class)
 253   "Return a list of keyword arguments corresponding to CLASS's initargs.
 254
 255    For each distinct name among the initargs defined on CLASS and its
 256    superclasses, return a single `argument' object containing the (agreed
 257    common) type, and the (unique, if present) default value from the most
 258    specific defining superclass.
 259
 260    The arguments are not returned in any especially meaningful order."
 261
 262   (let ((map (make-hash-table :test #'equal))
 263         (default-map (make-hash-table :test #'equal))
 264         (list nil))
 265     (dolist (super (sod-class-precedence-list class))
 266       (dolist (initarg (sod-class-initargs super))
 267         (let ((name (sod-initarg-name initarg))
 268               (default (sod-initarg-default initarg)))
 269           (unless (gethash name default-map)
 270             (when (or default (not (gethash name map)))
 271               (setf (gethash name map) (sod-initarg-argument initarg)))
 272             (when default
 273               (setf (gethash name default-map) t))))))
 274     (maphash (lambda (key value)
 275                (declare (ignore key))
 276                (push value list))
 277              map)
 278     list))
 279
 280 (definst suppliedp-struct (stream) (flags var)
 281   (format stream
 282           "~@<struct { ~2I~_~{unsigned ~A : 1;~^ ~_~} ~I~_} ~A;~:>"
 283           flags var))
 284
 285 ;; Initialization.
 286
 287 (defclass initialization-message (lifecycle-message)
 288   ())
 289
 290 (defclass initialization-effective-method (lifecycle-effective-method)
 291   ())
 292
 293 (defmethod sod-message-effective-method-class
 294     ((message initialization-message))
 295   'initialization-effective-method)
 296
 297 (defmethod method-keyword-argument-lists
 298     ((method initialization-effective-method) direct-methods)
 299   (append (call-next-method)
 300           (mapcan (lambda (class)
 301                     (let ((initargs (sod-class-initargs class)))
 302                       (and initargs
 303                            (list (cons (mapcar #'sod-initarg-argument
 304                                                initargs)
 305                                        (format nil "initargs for ~A"
 306                                                class))))))
 307                   (sod-class-precedence-list
 308                    (effective-method-class method)))))
 309
 310 (defmethod lifecycle-method-kernel
 311     ((method initialization-effective-method) codegen target)
 312   (let* ((class (effective-method-class method))
 313          (keywords (collect-initarg-keywords class))
 314          (ilayout (sod-class-ilayout class))
 315          (obj-tag (ilayout-struct-tag class))
 316          (kw-tag (effective-method-keyword-struct-tag method))
 317          (kw-tail (and keywords
 318                        (list (make-argument
 319                               "sod__kw"
 320                               (c-type (* (struct kw-tag :const)))))))
 321          (func-type (c-type (fun void
 322                                  ("sod__obj" (* (struct obj-tag)))
 323                                  . kw-tail)))
 324          (func-name (format nil "~A__init" class))
 325          (done-setup-p nil))
 326
 327     ;; Start building the initialization function.
 328     (codegen-push codegen)
 329
 330     (labels ((set-from-initializer (var type init)
 331                ;; Store the value of INIT, which has the given TYPE, in VAR.
 332                ;; INIT has the syntax of an initializer: declare and
 333                ;; initialize a temporary, and then copy the result.
 334                ;; Compilers seem to optimize this properly.  Return the
 335                ;; resulting code as an instruction.
 336                (codegen-push codegen)
 337                (emit-decl codegen (make-var-inst *sod-tmp-val* type init))
 338                (deliver-expr codegen var *sod-tmp-val*)
 339                (codegen-pop-block codegen))
 340              (setup ()
 341                ;; Do any necessary one-time initialization required to set up
 342                ;; the environment for the initialization code.
 343                (unless done-setup-p
 344
 345                  ;; Extract the keyword arguments into local variables.
 346                  (when keywords
 347                    (emit-decl codegen
 348                               (make-suppliedp-struct-inst
 349                                (mapcar #'argument-name keywords)
 350                                "suppliedp"))
 351                    (emit-banner codegen "Collect the keyword arguments.")
 352                    (dolist (arg keywords)
 353                      (let* ((name (argument-name arg))
 354                             (type (argument-type arg))
 355                             (default (argument-default arg))
 356                             (kwvar (format nil "sod__kw->~A" name))
 357                             (kwset (make-set-inst name kwvar))
 358                             (suppliedp (format nil "suppliedp.~A" name)))
 359                        (emit-decl codegen (make-var-inst name type))
 360                        (deliver-expr codegen suppliedp
 361                                      (format nil "sod__kw->~A__suppliedp"
 362                                              name))
 363                        (emit-inst
 364                         codegen
 365                         (if default
 366                             (make-if-inst suppliedp kwset
 367                                           (set-from-initializer name
 368                                                                 type
 369                                                                 default))
 370                             kwset))))
 371
 372                    (deliver-call codegen :void
 373                                  "SOD__IGNORE" "suppliedp")
 374                    (dolist (arg keywords)
 375                      (deliver-call codegen :void
 376                                    "SOD__IGNORE" (argument-name arg))))
 377
 378                  (setf done-setup-p t))))
 379
 380       ;; Initialize the structure defined by the various superclasses, in
 381       ;; reverse precedence order.
 382       (dolist (super (reverse (sod-class-precedence-list class)))
 383         (let* ((ichain (find (sod-class-chain-head super)
 384                              (ilayout-ichains ilayout)
 385                              :key #'ichain-head))
 386                (islots (find super (ichain-body ichain)
 387                              :test (lambda (class item)
 388                                      (and (typep item 'islots)
 389                                           (eq (islots-class item) class)))))
 390                (frags (sod-class-initfrags super))
 391                (this-class-focussed-p nil)
 392                (isl (format nil "me->~A" (sod-class-nickname super))))
 393
 394           (flet ((focus-this-class ()
 395                    ;; Delayed initial preparation.  Don't bother defining the
 396                    ;; `me' pointer if there's actually nothing to do.
 397                    (setup)
 398                    (unless this-class-focussed-p
 399                      (emit-banner codegen
 400                                   "Initialization for class `~A'." super)
 401                      (codegen-push codegen)
 402                      (declare-me codegen super)
 403                      (setf this-class-focussed-p t))))
 404
 405             ;; Work through each slot in turn.
 406             (dolist (slot (and islots (islots-slots islots)))
 407               (let ((dslot (effective-slot-direct-slot slot))
 408                     (init (effective-slot-initializer slot))
 409                     (initargs (effective-slot-initargs slot)))
 410                 (when (or init initargs)
 411                   (focus-this-class)
 412                   (let* ((slot-type (sod-slot-type dslot))
 413                          (slot-default (sod-initializer-value init))
 414                          (target (format nil "~A.~A"
 415                                          isl (sod-slot-name dslot)))
 416                          (initinst (set-from-initializer target
 417                                                          slot-type
 418                                                          slot-default)))
 419
 420                     ;; If there are applicable initialization arguments,
 421                     ;; check to see whether they were supplied.
 422                     (dolist (initarg (reverse (remove-duplicates
 423                                                initargs
 424                                                :key #'sod-initarg-name
 425                                                :test #'string=)))
 426                       (let ((arg-name (sod-initarg-name initarg)))
 427                         (setf initinst (make-if-inst
 428                                         (format nil "suppliedp.~A" arg-name)
 429                                         (make-set-inst target arg-name)
 430                                         initinst))))
 431
 432                     (emit-inst codegen initinst)))))
 433
 434             ;; Emit the class's initialization fragments.
 435             (when frags
 436               (let ((used-me-p this-class-focussed-p))
 437                 (focus-this-class)
 438                 (unless used-me-p
 439                   (deliver-call codegen :void "SOD__IGNORE" "me")))
 440               (dolist (frag frags)
 441                 (codegen-push codegen)
 442                 (emit-inst codegen frag)
 443                 (emit-inst codegen (codegen-pop-block codegen))))
 444
 445             ;; If we opened a block to initialize this class then close it
 446             ;; again.
 447             (when this-class-focussed-p
 448               (emit-inst codegen (codegen-pop-block codegen)))))))
 449
 450     ;; Done making the initialization function.
 451     (codegen-pop-function codegen func-name func-type
 452                           "Instance initialization function ~:_~
 453                            for class `~A'."
 454                           class)
 455
 456     (apply #'deliver-call codegen :void func-name
 457            "sod__obj" (and keywords (list (keyword-struct-pointer))))))
 458
 459 ;; Teardown.
 460
 461 (defclass teardown-message (lifecycle-message)
 462   ())
 463
 464 (defclass teardown-effective-method (lifecycle-effective-method)
 465   ())
 466
 467 (defmethod sod-message-effective-method-class ((message teardown-message))
 468   'teardown-effective-method)
 469
 470 (defmethod lifecycle-method-kernel
 471     ((method teardown-effective-method) codegen target)
 472   (let* ((class (effective-method-class method))
 473          (obj-tag (ilayout-struct-tag class))
 474          (func-type (c-type (fun void ("sod__obj" (* (struct obj-tag))))))
 475          (func-name (format nil "~A__teardown" class)))
 476     (codegen-push codegen)
 477     (dolist (super (sod-class-precedence-list class))
 478       (let ((frags (sod-class-tearfrags super)))
 479         (when frags
 480           (emit-banner codegen "Teardown for class `~A'." super)
 481           (codegen-push codegen)
 482           (declare-me codegen super)
 483           (deliver-call codegen :void "SOD__IGNORE" "me")
 484           (dolist (frag frags)
 485             (codegen-push codegen)
 486             (emit-inst codegen frag)
 487             (emit-inst codegen (codegen-pop-block codegen)))
 488           (emit-inst codegen (codegen-pop-block codegen)))))
 489     (codegen-pop-function codegen func-name func-type
 490                           "Instance teardown function ~:_~
 491                            for class `~A'."
 492                           class)
 493     (deliver-call codegen :void
 494                   (format nil "~A__teardown" class) "sod__obj")
 495     (deliver-expr codegen target 0)))
 496
 497 ;;;--------------------------------------------------------------------------
 498 ;;; Bootstrapping the class graph.
 499
 500 (defun bootstrap-classes (module)
 501   "Bootstrap the braid in MODULE.
 502
 503    This builds the fundamental recursive braid, where `SodObject' is an
 504    instance of `SodClass', and `SodClass' is a subclass of `SodObject' (and
 505    an instance of itself)."
 506   (let* ((sod-object (make-sod-class "SodObject" nil
 507                                      (make-property-set :nick 'obj)))
 508          (sod-class (make-sod-class "SodClass" (list sod-object)
 509                                     (make-property-set :nick 'cls)))
 510          (classes (list sod-object sod-class)))
 511
 512     ;; Attach the built-in messages.
 513     (make-sod-message sod-object "init"
 514                       (c-type (fun void :keys))
 515                       (make-property-set
 516                        :message-class 'initialization-message))
 517     (make-sod-message sod-object "teardown" (c-type (fun int))
 518                       (make-property-set :message-class 'teardown-message))
 519
 520     ;; Sort out the recursion.
 521     (setf (slot-value sod-class 'chain-link) sod-object)
 522     (dolist (class classes)
 523       (setf (slot-value class 'metaclass) sod-class))
 524
 525     ;; Predeclare the class types.
 526     (dolist (class classes)
 527       (make-class-type (sod-class-name class)))
 528
 529     ;; Attach the class slots.
 530     (dolist (slot *class-slot-alist*)
 531       (funcall (cdr slot) sod-class))
 532
 533     ;; These classes are too closely intertwined.  We must partially finalize
 534     ;; them together by hand.  This is cloned from `finalize-sod-class'.
 535     (dolist (class classes)
 536       (with-slots (class-precedence-list chain-head chain chains) class
 537         (setf class-precedence-list (compute-cpl class))
 538         (setf (values chain-head chain chains) (compute-chains class))))
 539
 540     ;; Done.
 541     (dolist (class classes)
 542       (finalize-sod-class class)
 543       (add-to-module module class))))
 544
 545 (export '*builtin-module*)
 546 (defvar-unbound *builtin-module*
 547   "The builtin module.")
 548
 549 (export 'make-builtin-module)
 550 (defun make-builtin-module ()
 551   "Construct the builtin module.
 552
 553    This involves constructing the braid (which is done in
 554    `bootstrap-classes') and defining a few obvious type names which users
 555    will find handy.
 556
 557    Returns the newly constructed module, and stores it in the variable
 558    `*builtin-module*'."
 559   (let ((module (make-instance 'module
 560                                :name (make-pathname :name "SOD-BASE"
 561                                                     :type "SOD"
 562                                                     :case :common)
 563                                :state nil)))
 564     (with-module-environment (module)
 565       (flet ((header-name (name)
 566                (concatenate 'string "\"" (string-downcase name) ".h\""))
 567              (add-includes (reason &rest names)
 568                (let ((text (with-output-to-string (out)
 569                              (dolist (name names)
 570                                (format out "#include ~A~%" name)))))
 571                  (add-to-module module
 572                                 (make-instance 'code-fragment-item
 573                                                :reason reason
 574                                                :constraints nil
 575                                                :name :includes
 576                                                :fragment text)))))
 577         (add-includes :c (header-name "sod"))
 578         (add-includes :h "<stddef.h>"))
 579       (bootstrap-classes module))
 580     (setf *builtin-module* module)))
 581
 582 (define-clear-the-decks builtin-module
 583   (unless (boundp '*builtin-module*) (make-builtin-module)))
 584
 585 ;;;----- That's all, folks --------------------------------------------------