chiark - git - mdw - secnet/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl This file is part of secnet.
   4 dnl See README for full list of copyright holders.
   5 dnl
   6 dnl secnet is free software; you can redistribute it and/or modify it
   7 dnl under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version d of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl secnet is distributed in the hope that it will be useful, but
  12 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 dnl General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl version 3 along with secnet; if not, see
  18 dnl https://www.gnu.org/licenses/gpl.html.
  19
  20 sinclude(ac_prog_cc_no_writeable_strings.m4)
  21
  22 AC_INIT(secnet,0.1.18+,secnet@chiark.greenend.org.uk)
  23 AC_CONFIG_SRCDIR(secnet.c)
  24 AC_CONFIG_HEADER(config.h)
  25
  26 AC_PREREQ(2.50)
  27 AC_REVISION($Id: configure.in,v 1.4 2002/09/09 22:05:02 steve Exp $)
  28
  29 AC_LANG_C
  30
  31 # If fink is on the path then it is assumed we should use it.
  32 AC_PATH_PROG([FINK],[fink])
  33 if test "x$FINK" != x; then
  34   finkdir=`echo $FINK|sed 's,/[[^/]]*/[[^/]]*$,,'`
  35   CPPFLAGS="-I$finkdir/include ${CPPFLAGS}"
  36   LDFLAGS="-L$finkdir/lib ${LDFLAGS}"
  37 fi
  38
  39 AC_PROG_MAKE_SET
  40 AC_PROG_CC
  41 AC_PROG_INSTALL
  42 AC_PATH_PROG(RM,rm)
  43 AC_STDC_HEADERS
  44 AC_CHECK_HEADERS([stdint.h inttypes.h])
  45 AC_CHECK_HEADERS([net/if.h net/route.h])
  46 AC_CHECK_HEADERS([sys/socket.h])
  47 AC_CHECK_HEADERS([linux/if_tun.h], [], [],
  48 [#if HAVE_SYS_SOCKET_H
  49 # include <sys/socket.h>
  50 #endif
  51 ])
  52 AC_CHECK_HEADERS([stropts.h sys/sockio.h net/if_tun.h])
  53 AC_C_BIGENDIAN
  54 AC_CHECK_SIZEOF(unsigned long long)
  55 AC_CHECK_SIZEOF(unsigned long)
  56 AC_CHECK_SIZEOF(unsigned int)
  57 AC_CHECK_SIZEOF(unsigned short)
  58 AC_CHECK_SIZEOF(unsigned char)
  59 AC_PROG_CC_NO_WRITEABLE_STRINGS(WRITESTRINGS)
  60
  61 AC_ARG_ENABLE(hacky-parallel,
  62   [AS_HELP_STRING([--enable-hacky-parallel],
  63                   [parallelise slow cryptography (default is no)])], [
  64   case "$enableval" in
  65   n|0|no) ;;
  66   y|1|yes) CFLAGS="$CFLAGS -DHACKY_PARALLEL" ;;
  67   *) ;;
  68   esac
  69 ])
  70
  71 AC_DEFUN([REQUIRE_HEADER],[AC_CHECK_HEADER($1,,[AC_MSG_ERROR($1 not found)])])
  72
  73 dnl the order in which libraries is checked is important
  74 dnl eg. adns on Solaris 2.5.1 depends on -lnsl and -lsocket
  75 AC_CHECK_LIB(gmp,mpz_init_set_str)
  76 AC_CHECK_LIB(gmp2,mpz_init_set_str)
  77 AC_CHECK_LIB(gmp,__gmpz_init_set_str)
  78 REQUIRE_HEADER([gmp.h])
  79 dnl Would love to barf if no gmp was found, but how to test? Requiring the header will do for now.
  80 AC_CHECK_LIB(fl,yywrap)
  81 if test "$ac_cv_lib_fl_yywrap" != yes; then
  82   AC_MSG_ERROR([A compatible libfl is required])
  83 fi
  84 AC_CHECK_LIB(nsl,inet_ntoa)
  85 AC_CHECK_LIB(socket,socket)
  86 ADNS_C_GETFUNC(inet_aton,resolv,[
  87  LIBS="-lresolv $LIBS";
  88  AC_MSG_WARN([inet_aton is in libresolv, urgh.  Must use -lresolv.])
  89 ])
  90 AC_CHECK_LIB(adns,adns_init)
  91 REQUIRE_HEADER([adns.h])
  92
  93 AC_MSG_NOTICE([Checking requirements for IPv6 support...])
  94 enable_ipv6=true
  95 m4_define(NO_IPV6,[enable_ipv6=false])
  96 AC_CHECK_DECL(AF_INET6,        [],[NO_IPV6],[#include <netinet/in.h>])
  97 AC_CHECK_FUNC(adns_addr2text,  [],[NO_IPV6])
  98 if $enable_ipv6; then
  99     AC_MSG_NOTICE([Enabling IPv6 support])
 100     AC_DEFINE(CONFIG_IPV6, 1,
 101               [Define to 1 to use IPv6 support in system and adns])
 102 else
 103     AC_MSG_WARN([Disabling IPv6 support])
 104 fi
 105
 106 AC_OUTPUT(Makefile,echo timestamp >stamp-h)
 107
 108 AH_TOP([
 109 #ifndef _CONFIG_H
 110 #define _CONFIG_H
 111 ])
 112
 113 AH_BOTTOM([
 114 /* -*- c -*- */
 115
 116 /* These used to be in config.h.bot, but are now in configure.in. */
 117
 118 #ifdef HAVE_INTTYPES_H
 119 #include <inttypes.h>
 120 #else
 121 #ifdef HAVE_STDINT_H
 122 #include <stdint.h>
 123 #else
 124 #if SIZEOF_UNSIGNED_LONG_LONG==8
 125 typedef unsigned long long uint64_t;
 126 typedef long long int64_t;
 127 #elif SIZEOF_UNSIGNED_LONG==8
 128 typedef unsigned long uint64_t;
 129 typedef long int64_t;
 130 #else
 131 #error I do not know what to use for a uint64_t.
 132 #endif
 133
 134 /* Give us an unsigned 32-bit data type. */
 135 #if SIZEOF_UNSIGNED_LONG==4
 136 typedef unsigned long uint32_t;
 137 typedef long int32_t;
 138 #elif SIZEOF_UNSIGNED_INT==4
 139 typedef unsigned int uint32_t;
 140 typedef int int32_t;
 141 #else
 142 #error I do not know what to use for a uint32_t.
 143 #endif
 144
 145 /* An unsigned 16-bit data type. */
 146 #if SIZEOF_UNSIGNED_INT==2
 147 typedef unsigned int uint16_t;
 148 typedef int int16_t;
 149 #elif SIZEOF_UNSIGNED_SHORT==2
 150 typedef unsigned short uint16_t;
 151 typedef short int16_t;
 152 #else
 153 #error I do not know what to use for a uint16_t.
 154 #endif
 155
 156 /* An unsigned 8-bit data type */
 157 #if SIZEOF_UNSIGNED_CHAR==1
 158 typedef unsigned char uint8_t;
 159 #else
 160 #error I do not know what to use for a uint8_t.
 161 #endif
 162 #endif
 163 #endif
 164
 165 #ifdef __GNUC__
 166 #define NORETURN(_x) void _x __attribute__ ((noreturn))
 167 #define FORMAT(_a,_b,_c) __attribute__ ((format (_a,_b,_c)))
 168 #else
 169 #define NORETURN(_x) _x
 170 #define FORMAT(_a,_b,_c)
 171 #endif
 172
 173 #endif /* _CONFIG_H */
 174 ])