chiark - git - mdw - profile/blob - dot/zshrc

   1 ### -*-sh-*-
   2 ###
   3 ### Zsh session things.
   4
   5 __mdw_shell=zsh
   6 case ${INSIDE_EMACS+t},$TERM in t,dumb) unsetopt zle ;; esac
   7
   8 . "$HOME/.shell-rc"
   9
  10 ###--------------------------------------------------------------------------
  11 ### Prompt hacking.
  12
  13 __mdw_set_prompt_hacks () {
  14   case $TERM in
  15     linux*|screen*|xterm*|vt100*|eterm*)
  16       bold=%B unbold=%b
  17       gitcolour=%F{cyan} rccolour=%F{red} uncolour=%f
  18       ;;
  19   esac
  20   host=%m dir=" %(6~!%-1~/.../%5~!%~)"
  21 }
  22
  23 if [ -t 0 ]; then
  24   __mdw_source_if_exists /usr/lib/git-core/git-sh-prompt
  25   __mdw_set_prompt_pieces
  26   precmd_functions+=(__mdw_precmd)
  27   preexec_functions+=(__mdw_preexec)
  28 fi
  29
  30 ###--------------------------------------------------------------------------
  31 ### Line editing.
  32
  33 bindkey -e
  34
  35 for w in \
  36   forward-word backward-word kill-word backward-kill-word \
  37   transpose-words capitalize-word up-case-word down-case-word \
  38   delete-whole-word select-word
  39 do
  40   autoload -U $w-match
  41   zle -N $w-bash $w-match
  42   zle -N $w-shell $w-match
  43   zstyle ':zle:*-bash' word-style standard
  44   zstyle ':zle:*-bash' skip-whitespace-first true
  45   zstyle ':zle:*-bash' word-chars ""
  46   zstyle ':zle:*-shell' word-style shell
  47   zstyle ':zle:*-shell' skip-whitespace-first false
  48 done
  49
  50 bindkey "\eb" backward-word-bash
  51 bindkey "\e^b" backward-word-shell
  52 bindkey "\ef" forward-word-bash
  53 bindkey "\e^f" forward-word-shell
  54 bindkey "\e^?" backward-kill-word-bash
  55 bindkey "^w" backward-kill-word-shell
  56 bindkey "\ed" kill-word-bash
  57 bindkey "\e^d" kill-word-shell
  58 bindkey "\et" transpose-words-bash
  59 bindkey "\e^t" transpose-words-shell
  60 bindkey "\eu" up-case-word-bash
  61 bindkey "\e^u" up-case-word-shell
  62 bindkey "\el" up-case-word-bash
  63 bindkey "\e^l" up-case-word-shell
  64 bindkey "\ec" capitalize-word-bash
  65 bindkey "\e^c" capitalize-word-shell
  66
  67 ###--------------------------------------------------------------------------
  68 ### Completion.
  69
  70 ## Initialize the fancy completion machinery.
  71 autoload -Uz compinit
  72 compinit
  73
  74 ## Contexts: :completion:FUNCTION:COMPLETER:COMMAND:ARGUMENT:TAG
  75 zstyle ':completion:*' completer _expand _complete _ignored _approximate
  76 zstyle ':completion:*' insert-unambiguous false
  77 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
  78 zstyle ':completion:*' list-prompt %SAt %p: Hit TAB for more, or the character to insert%s
  79 zstyle ':completion:*' matcher-list '' '+m:{[:lower:]}={[:upper:]} r:|[._-]=** r:|=**' '+l:|=* r:|=*'
  80 zstyle ':completion:*' max-errors 0 numeric
  81 zstyle ':completion:*' original true
  82 zstyle ':completion:*' verbose false
  83 zstyle ':completion:*:*:git*:*' verbose true
  84
  85 _r () { words[1]=sudo; _normal; }
  86 compdef _r rootly
  87 compdef _ssh @
  88
  89 ###--------------------------------------------------------------------------
  90 ### Other shell tweaking.
  91
  92 HISTFILE=~/.zsh-history
  93 HISTSIZE=1000
  94 SAVEHIST=1000
  95
  96 setopt appendhistory
  97 unsetopt auto_cd
  98 unsetopt auto_menu
  99 unsetopt bash_auto_list
 100 unsetopt beep
 101 setopt extendedglob
 102 setopt ksh_glob
 103 setopt list_ambiguous
 104 setopt list_packed
 105 unsetopt nomatch
 106 unsetopt menu_complete
 107 setopt notify
 108
 109 zshaddhistory () {
 110   case "$1" in
 111     " "*) return 2 ;;
 112     *) return 0 ;;
 113   esac
 114 }
 115
 116 ###--------------------------------------------------------------------------
 117 ### Finishing touches.
 118
 119 __mdw_source_if_exists "$HOME/.zshrc-local"
 120
 121 ###----- That's all, folks --------------------------------------------------