chiark - git - mdw - profile/blob - dot/zshrc

   1 ### -*-sh-*-
   2 ###
   3 ### Zsh session things.
   4
   5 __mdw_shell=zsh
   6 case ${INSIDE_EMACS+t},$TERM in t,dumb) unsetopt zle ;; esac
   7
   8 . "$HOME/.shell-rc"
   9
  10 ###--------------------------------------------------------------------------
  11 ### Prompt hacking.
  12
  13 __mdw_set_prompt_hacks () {
  14   case $TERM in
  15     linux*|screen*|xterm*|vt100*|eterm*)
  16       bold=%B unbold=%b
  17       gitcolour=%F{cyan} rccolour=%F{red} uncolour=%f
  18       ;;
  19   esac
  20   host=%m dir=" %(6~!%-1~/.../%5~!%~)"
  21 }
  22
  23 if [ -t 0 ]; then
  24   __mdw_source_if_exists /usr/lib/git-core/git-sh-prompt
  25   __mdw_set_prompt_pieces
  26   precmd_functions+=(__mdw_precmd)
  27   preexec_functions+=(__mdw_preexec)
  28 fi
  29
  30 ###--------------------------------------------------------------------------
  31 ### Line editing.
  32
  33 bindkey -e
  34
  35 for w in \
  36   forward-word backward-word kill-word backward-kill-word \
  37   transpose-words capitalize-word up-case-word down-case-word \
  38   delete-whole-word select-word
  39 do
  40   autoload -U $w-match
  41   zle -N $w-bash $w-match
  42   zle -N $w-shell $w-match
  43   zstyle ':zle:*-bash' word-style standard
  44   zstyle ':zle:*-bash' skip-whitespace-first true
  45   zstyle ':zle:*-bash' word-chars ""
  46   zstyle ':zle:*-shell' word-style shell
  47   zstyle ':zle:*-shell' skip-whitespace-first false
  48 done
  49
  50 bindkey "\eb" backward-word-bash
  51 bindkey "\e^b" backward-word-shell
  52 bindkey "\ef" forward-word-bash
  53 bindkey "\e^f" forward-word-shell
  54 bindkey "\e^?" backward-kill-word-bash
  55 bindkey "^w" backward-kill-word-shell
  56 bindkey "\ed" kill-word-bash
  57 bindkey "\e^d" kill-word-shell
  58 bindkey "\et" transpose-words-bash
  59 bindkey "\e^t" transpose-words-shell
  60 bindkey "\eu" up-case-word-bash
  61 bindkey "\e^u" up-case-word-shell
  62 bindkey "\el" up-case-word-bash
  63 bindkey "\e^l" up-case-word-shell
  64 bindkey "\ec" capitalize-word-bash
  65 bindkey "\e^c" capitalize-word-shell
  66
  67 bindkey "\ep" history-beginning-search-backward
  68 bindkey "\en" history-beginning-search-forward
  69
  70 setopt interactive_comments
  71 bindkey "\e#" pound-insert
  72
  73 __mdw_delete_horizontal_space () {
  74   LBUFFER=${LBUFFER%%[[:space:]]##}
  75   RBUFFER=${RBUFFER##[[:space:]]##}
  76 }
  77 zle -N delete-horizontal-space __mdw_delete_horizontal_space
  78 bindkey "\e\\" delete-horizontal-space
  79
  80 __mdw_just_one_space () {
  81   LBUFFER="${LBUFFER%%[[:space:]]##} "
  82   RBUFFER=${RBUFFER##[[:space:]]##}
  83 }
  84 zle -N just-one-space __mdw_just_one_space
  85 bindkey "\e " just-one-space
  86
  87
  88 ###--------------------------------------------------------------------------
  89 ### Completion.
  90
  91 ## Initialize the fancy completion machinery.
  92 autoload -Uz compinit
  93 compinit
  94
  95 ## Contexts: :completion:FUNCTION:COMPLETER:COMMAND:ARGUMENT:TAG
  96 zstyle ':completion:*' completer _expand _complete _ignored _approximate
  97 zstyle ':completion:*' insert-unambiguous false
  98 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
  99 zstyle ':completion:*' list-prompt %SAt %p: Hit TAB for more, or the character to insert%s
 100 zstyle ':completion:*' matcher-list '' '+m:{[:lower:]}={[:upper:]} r:|[._-]=** r:|=**' '+l:|=* r:|=*'
 101 zstyle ':completion:*' max-errors 0 numeric
 102 zstyle ':completion:*' original true
 103 zstyle ':completion:*' verbose false
 104 zstyle ':completion:*:*:git*:*' verbose true
 105
 106 _r () { words[1]=sudo; _normal; }
 107 compdef _r rootly
 108 compdef _ssh @
 109
 110 ###--------------------------------------------------------------------------
 111 ### Other shell tweaking.
 112
 113 HISTFILE=~/.zsh-history
 114 HISTSIZE=1000
 115 SAVEHIST=1000
 116
 117 unsetopt auto_cd
 118 unsetopt auto_menu
 119 unsetopt bash_auto_list
 120 unsetopt beep
 121 setopt extendedglob
 122 unsetopt flow_control
 123 setopt hist_ignore_all_dups
 124 setopt ksh_glob
 125 setopt list_ambiguous
 126 setopt list_packed
 127 unsetopt nomatch
 128 unsetopt menu_complete
 129 setopt notify
 130 setopt share_history
 131
 132 zshaddhistory () {
 133   case "$1" in
 134     " "*) return 2 ;;
 135     *) return 0 ;;
 136   esac
 137 }
 138
 139 ###--------------------------------------------------------------------------
 140 ### Finishing touches.
 141
 142 __mdw_source_if_exists "$HOME/.zshrc-local"
 143
 144 ###----- That's all, folks --------------------------------------------------