chiark - git - mdw - profile/blob - dot/zshrc

   1 ### -*-sh-*-
   2 ###
   3 ### Zsh session things.
   4
   5 __mdw_shell=zsh
   6 case ${INSIDE_EMACS+t},$TERM in t,dumb) unsetopt zle ;; esac
   7
   8 . "$HOME/.shell-rc"
   9
  10 ###--------------------------------------------------------------------------
  11 ### Prompt hacking.
  12
  13 __mdw_set_prompt_hacks () {
  14   case $TERM in
  15     linux*|screen*|xterm*|putty*|vt100*|eterm*)
  16       bold=%B unbold=%b
  17       gitcolour=%F{cyan} rccolour=%F{red} uncolour=%f
  18       ;;
  19   esac
  20   host=%m dir=" %(6~!%-1~/.../%4~!%~)"
  21   more=%F{green}%_%f
  22 }
  23
  24 if [ -t 0 ]; then
  25   __mdw_source_if_exists /usr/lib/git-core/git-sh-prompt
  26   __mdw_set_prompt_pieces
  27   precmd_functions+=(__mdw_precmd)
  28   preexec_functions+=(__mdw_preexec)
  29 fi
  30
  31 ###--------------------------------------------------------------------------
  32 ### Line editing.
  33
  34 case $TERM in dumb) unsetopt zle ;; esac
  35
  36 bindkey -e
  37
  38 for w in \
  39   forward-word backward-word kill-word backward-kill-word \
  40   transpose-words capitalize-word up-case-word down-case-word \
  41   delete-whole-word select-word
  42 do
  43   autoload -U $w-match
  44   zle -N $w-bash $w-match
  45   zle -N $w-shell $w-match
  46   zstyle ':zle:*-bash' word-style standard
  47   zstyle ':zle:*-bash' skip-whitespace-first true
  48   zstyle ':zle:*-bash' word-chars ""
  49   zstyle ':zle:*-shell' word-style shell
  50   zstyle ':zle:*-shell' skip-whitespace-first false
  51 done
  52
  53 bindkey "\eb" backward-word-bash
  54 bindkey "\e^b" backward-word-shell
  55 bindkey "\ef" forward-word-bash
  56 bindkey "\e^f" forward-word-shell
  57 bindkey "\e^?" backward-kill-word-bash
  58 bindkey "^w" backward-kill-word-shell
  59 bindkey "\ed" kill-word-bash
  60 bindkey "\e^d" kill-word-shell
  61 bindkey "\et" transpose-words-bash
  62 bindkey "\e^t" transpose-words-shell
  63 bindkey "\eu" up-case-word-bash
  64 bindkey "\e^u" up-case-word-shell
  65 bindkey "\el" down-case-word-bash
  66 bindkey "\e^l" down-case-word-shell
  67 bindkey "\ec" capitalize-word-bash
  68 bindkey "\e^c" capitalize-word-shell
  69
  70 bindkey "\e[1~" beginning-of-line "\e[4~" end-of-line
  71
  72 bindkey -s            "\eOQ" "/" "\eOR" "*" "\eOS" "-"
  73 bindkey -s "\eOw" "7" "\eOx" "8" "\eOy" "9"
  74 bindkey -s "\eOt" "4" "\eOu" "5" "\eOv" "6" "\eOk" "+"
  75 bindkey -s "\eOq" "1" "\eOr" "2" "\eOs" "3"
  76 bindkey -s "\eOp" "0"            "\eOn" "."; bindkey "\eOM" accept-line
  77
  78 bindkey -s            "\eOQ" "/" "\eOR" "*" "\eOS" "-"
  79 bindkey -s "\eOw" "7" "\eOx" "8" "\eOy" "9"
  80 bindkey -s "\eOt" "4" "\eOu" "5" "\eOv" "6" "\eOk" "+"
  81 bindkey -s "\eOq" "1" "\eOr" "2" "\eOs" "3"
  82 bindkey -s "\eOp" "0"            "\eOn" "."; bindkey "\eOM" accept-line
  83
  84 bindkey "\ep" history-beginning-search-backward
  85 bindkey "\en" history-beginning-search-forward
  86 bindkey "\e," _history-complete-older
  87
  88 for i in '!' '$' '@' '/' '~'; do
  89   bindkey "\e$i" _bash_complete-word
  90   bindkey "^X$i" _bash_list-choices
  91 done
  92
  93 setopt interactive_comments
  94 bindkey "\e#" pound-insert
  95
  96 __mdw_delete_horizontal_space () {
  97   LBUFFER=${LBUFFER%%[[:space:]]##}
  98   RBUFFER=${RBUFFER##[[:space:]]##}
  99 }
 100 zle -N delete-horizontal-space __mdw_delete_horizontal_space
 101 bindkey "\e\\" delete-horizontal-space
 102
 103 __mdw_just_one_space () {
 104   LBUFFER="${LBUFFER%%[[:space:]]##} "
 105   RBUFFER=${RBUFFER##[[:space:]]##}
 106 }
 107 zle -N just-one-space __mdw_just_one_space
 108 bindkey "\e " just-one-space
 109
 110 ###--------------------------------------------------------------------------
 111 ### Completion.
 112
 113 ## Contexts: :completion:FUNCTION:COMPLETER:COMMAND:ARGUMENT:TAG
 114 zstyle ':completion:*' completer _expand _complete _ignored _approximate
 115 zstyle ':completion:*' insert-unambiguous false
 116 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 117 zstyle ':completion:*' list-prompt %SAt %p: Hit TAB for more, or the character to insert%s
 118 zstyle ':completion:*' matcher-list '' '+m:{[:lower:]}={[:upper:]} r:|[._-]=** r:|=**' '+l:|=* r:|=*'
 119 zstyle ':completion:*' max-errors 0 numeric
 120 zstyle ':completion:*' original true
 121 zstyle ':completion:*' verbose false
 122 zstyle ':completion:*:*:git*:*' verbose true
 123
 124 ## Initialize the fancy completion machinery.
 125 autoload -Uz compinit
 126 compinit
 127
 128 _r () { words[1]=sudo; _normal; }
 129 compdef _r rootly
 130 compdef _ssh @
 131
 132 ###--------------------------------------------------------------------------
 133 ### Other shell tweaking.
 134
 135 HISTFILE=~/.zsh-history
 136 HISTSIZE=1000
 137 SAVEHIST=1000
 138
 139 unsetopt auto_cd
 140 unsetopt auto_menu
 141 setopt bang_hist
 142 unsetopt bash_auto_list
 143 unsetopt beep
 144 setopt extendedglob
 145 unsetopt flow_control
 146 unsetopt global_export
 147 setopt glob_star_short
 148 setopt hist_ignore_all_dups
 149 setopt hist_ignore_space
 150 unsetopt ksh_glob
 151 setopt list_ambiguous
 152 setopt list_packed
 153 setopt multios
 154 unsetopt nomatch
 155 unsetopt menu_complete
 156 setopt notify
 157 setopt rc_expand_param
 158 setopt share_history
 159
 160 hash -d t=$TMPDIR
 161
 162 ###--------------------------------------------------------------------------
 163 ### Finishing touches.
 164
 165 ## Local tweaks.
 166 __mdw_source_if_exists "$HOME/.zshrc-local"
 167
 168 ###----- That's all, folks --------------------------------------------------