chiark - git - mdw - odin-cgi/blob - lib/Odin.pm

   1 ### -*-perl-*-
   2
   3 package Odin;
   4
   5 use DBI;
   6 use Date::Parse;
   7 use Digest::SHA qw(sha256_hex);
   8 use MIME::Base64;
   9 use POSIX;
  10
  11 ###--------------------------------------------------------------------------
  12 ### Early utilities.
  13
  14 sub merge_hash (\%%) {
  15   my ($hashref, %defaults) = @_;
  16   for my $k (keys %defaults)
  17     { $hashref->{$k} = $defaults{$k} unless exists $hashref->{$k}; }
  18 }
  19
  20 ###--------------------------------------------------------------------------
  21 ### Configuration.
  22
  23 our $DSN = "dbi:Pg(pg_enable_utf8=>1):host=db";
  24 our $RETRY = 10;
  25 our @BACKOFF = (0.1, 10, 1.5, 0.5, 2.0);
  26
  27 our $BASEURL = "http://odin.gg/";
  28 our $STATIC = "http://odin.gg/";
  29
  30 our $SHORTURL_PATH = "u";
  31 our $PASTEBIN_PATH = "p";
  32
  33 our $URLMAXLEN = 1024;
  34 our @URLPAT = (
  35   qr{^https?://}
  36 );
  37
  38 our $PASTEMAXLEN = 1024*1024;
  39
  40 our %COOKIE_DEFAULTS = (
  41   -httponly => undef,
  42   -max_age => 3600
  43 );
  44
  45 our $ALPHA = "abcdefghijklmnopqrstuvwxyz";
  46 our $NUM = "0123456789";
  47 our $SAFECH = qr/^[-\w_.+]*$/;
  48
  49 our %GENPARAM = ();
  50 our %GENMAP = ();
  51 our %MAILDOM_POLICY = ();
  52 our $MAIL_QUALDOM;
  53
  54 our @MAIL_DEFGEN = "chars";
  55 our $MAIL_MAXGENTRY = 32;
  56
  57 our $MAIL_DEFDOMAIN = "odin.gg";
  58 our $MAIL_ADDRMAX_LIVE = 16384;
  59 our $MAIL_ADDRMAX_RESV = 32;
  60 our $MAIL_AGEMAX_RESV = 3600;
  61
  62 our ($SCHEME, $DOMAIN, $BASEPATH);
  63 our ($SHORTURL, $PASTEBIN);
  64
  65 ###--------------------------------------------------------------------------
  66 ### Miscellaneous utilities.
  67
  68 our $NOW;
  69 sub update_now () { $NOW = time; }
  70 update_now;
  71
  72 (our $PROG = $0) =~ s:^.*/::;
  73
  74 sub fail_cmdline ($$%) {
  75   my ($msg, $label, %args) = @_;
  76   print STDERR "$PROG: $msg\n";
  77   exit 1;
  78 }
  79
  80 our $FAILPROC = \&fail_cmdline;
  81
  82 sub fail ($;$%) {
  83   my ($msg, $label, %args) = @_;
  84   $FAILPROC->($msg, $label, %args);
  85 }
  86
  87 sub set_mason_failproc ($) {
  88   my ($m) = @_;
  89   $FAILPROC = sub {
  90     my ($msg, $label, %args) = @_;
  91     $m->clear_buffer;
  92     $m->comp($label, %args);
  93     $m->abort;
  94   };
  95 }
  96
  97 sub nice_name ($) {
  98   my ($s) = @_;
  99   $s =~ s/\W+//g;
 100   return lc $s;
 101 }
 102
 103 my %TIMEUNIT = (
 104   "" => 1,
 105   "s" => 1, "m" => 60, "h" => 3600,
 106   "d" => 86400, "w" => 604800
 107 );
 108 sub parse_time ($) {
 109   my ($date) = @_;
 110   return undef unless defined $date;
 111   if ($date =~ /^\+\s*(\d+)\s*([smhdw]?)\s*$/)
 112     { return $NOW + $1 * $TIMEUNIT{$2}; }
 113   my $t = str2time($date);
 114   defined $t or Odin::fail "invalid time `$date'";
 115   return $t;
 116 }
 117
 118 sub print_columns (@) {
 119   my @col = reverse @_;
 120   my @fmt = ();
 121   my @val = ();
 122   while (@col && $col[1] eq "") { splice @col, 0, 2; }
 123   my ($wd, $v) = splice @col, 0, 2;
 124   push @fmt, "%s"; push @val, $v;
 125   while (@col) {
 126     my ($wd, $v) = splice @col, 0, 2;
 127     push @fmt, "%-${wd}s";
 128     push @val, $v;
 129   }
 130   printf join("  ", reverse @fmt) . "\n", reverse @val;
 131 }
 132
 133 sub fmt_time ($) {
 134   my ($t) = @_;
 135   return $t == -1 ? "--" : strftime "%Y-%m-%d %H:%M:%S %z", localtime $t;
 136 }
 137
 138 ###--------------------------------------------------------------------------
 139 ### Database utilities.
 140
 141 sub open_db (@) {
 142   my @attr = @_;
 143   my $db = DBI->connect_cached($DSN, undef, undef, {
 144     PrintError => 0,
 145     RaiseError => 1,
 146     @attr
 147   });
 148
 149   my $drv = $db->{Driver}{Name};
 150   if ($drv eq "Pg") {
 151     $db->{private_odin_retry_p} = sub { $db->state =~ /^40[0P]01$/ };
 152   } elsif ($drv eq "SQLite") {
 153     $db->{private_odin_retry_p} = sub { $db->err == 5 };
 154   } else {
 155     $db->{private_odin_retry_p} = sub { 0 };
 156   }
 157
 158   return $db;
 159 }
 160
 161 sub xact (&$) {
 162   my ($body, $db) = @_;
 163   my @rv;
 164   my $exc;
 165
 166   my ($sleep, $maxsleep, $mult, $minvar, $maxvar) = @BACKOFF;
 167   for (my $i = 0; $i < $RETRY; $i++) {
 168     $db->begin_work;
 169     eval { @rv = $body->(); $db->commit; };
 170     $exc = $@;
 171     return @rv unless $exc;
 172     my $retryp = $db->{private_odin_retry_p}();
 173     eval { $db->rollback; };
 174     die $exc unless $retryp;
 175     my $t = $sleep * ($minvar + rand($maxvar - $minvar));
 176     $sleep *= $mult; $sleep = $max if $sleep > $max;
 177     select undef, undef, undef, $t;
 178   }
 179   die $exc;
 180 }
 181
 182 sub insert_record ($$%) {
 183   my ($db, $table, %fields) = @_;
 184   my @var = ();
 185   my @val = ();
 186
 187   for my $v (keys %fields) {
 188     push @var, $v;
 189     push @val, $fields{$v};
 190   }
 191   $db->do("INSERT INTO $table (" . join(", ", @var) . ")
 192            VALUES (" . join(", ", map { "?" } @var) . ")", undef, @val);
 193 }
 194
 195 ###--------------------------------------------------------------------------
 196 ### Sequence numbers and tagging.
 197
 198 sub next_seq ($$) {
 199   my ($db, $table) = @_;
 200   my ($seq) = $db->selectrow_array("SELECT seq FROM $table");
 201   die "no sequence number in $table" unless defined $seq;
 202   $db->do("UPDATE $table SET seq = ?", undef, $seq + 1);
 203   return $seq;
 204 }
 205
 206 my $ALPHABET =
 207   "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789";
 208 my $NALPHA = length $ALPHABET;
 209
 210 sub encode_tag ($) {
 211   my ($seq) = @_;
 212   my $tag = "";
 213   while ($seq) {
 214     $tag .= substr($ALPHABET, $seq % $NALPHA, 1);
 215     $seq = int $seq/$NALPHA;
 216   }
 217   return $tag;
 218 }
 219
 220 ###--------------------------------------------------------------------------
 221 ### HTTP utilities.
 222
 223 our %COOKIE;
 224 sub fetch_cookies ($) {
 225   my ($r) = @_;
 226
 227   %COOKIE = ();
 228   my $cookies = $r->header_in("Cookie");
 229   if (defined $cookies) {
 230     for my $kv (split /;/, $cookies) {
 231       my ($k, $v) = split /=/, $kv, 2;
 232       $k =~ s/^\s*(|\S|\S.*\S)\s*$/$1/;
 233       $v =~ s/^\s*(|\S|\S.*\S)\s*$/$1/;
 234       $v =~ s/\+/ /g;
 235       $v =~ s/\%([0-9a-f][0-9a-f])/chr hex $1/eg;
 236       $COOKIE{$k} = $v;
 237     }
 238   }
 239 }
 240
 241 sub bake_cookie ($$%) {
 242   my ($r, $cookie, %attr) = @_;
 243   merge_hash %attr, %COOKIE_DEFAULTS;
 244   my @attr = map {
 245     my $v = $attr{$_}; tr/_-/-/d;
 246     defined $v ? "$_=$v" : $_
 247   } keys %attr;
 248   $r->headers_out->add("Set-Cookie", join "; ", $cookie, @attr);
 249 }
 250
 251 sub path_info ($) {
 252   my ($r) = @_;
 253   return $ENV{PATH_INFO} // $r->path_info;
 254 }
 255
 256 ###--------------------------------------------------------------------------
 257 ### HTML utilities.
 258
 259 sub escapify ($$;$) {
 260   my ($m, $s, $mode) = @_;
 261   return $m->interp->apply_escapes($s, $mode // "h");
 262 }
 263
 264 ###--------------------------------------------------------------------------
 265 ### Access control.
 266
 267 our ($WHO, $WHOSURE);
 268 our ($WHOMATCH, $WHOCMP, $WHOPAT);
 269
 270 sub cgi_who ($) {
 271   my ($r) = @_;
 272   my $raddr = $ENV{REMOTE_ADDR} // $r->connection->remote_ip;
 273   $WHO = ":NET-$raddr"; $WHOSURE = 0;
 274   $WHOMATCH = "LIKE"; $WHOCMP = ":NET-\%"; $WHOPAT = qr/^:NET-/;
 275 }
 276
 277 sub cmdline_who () {
 278   $WHO = $ENV{USERV_USER}
 279     // ($< == $> && $ENV{USER})
 280     // @{[getpwuid $<]}[0]
 281     // die "nameless user";
 282   $WHOMATCH = "="; $WHOCMP = $WHO; $WHOPAT = qr/^\Q$WHO\E$/;
 283   $WHOSURE = 1;
 284 }
 285
 286 sub new_editkey () {
 287   open my $fh, "/dev/urandom" or die "open urandom: $!";
 288   sysread $fh, my $rand, 16;
 289   (my $edit = encode_base64 $rand) =~ tr:+/=\n:.-:d;
 290   return $edit, sha256_hex $edit;
 291 }
 292
 293 ###--------------------------------------------------------------------------
 294 ### URL shortening.
 295
 296 sub get_shorturl ($) {
 297   my ($tag) = @_;
 298
 299   my $db = open_db;
 300   my ($url) = $db->selectrow_array
 301     ("SELECT url FROM odin_shorturl WHERE tag = ?", undef, $tag);
 302   fail "tag `$tag' not found", ".notfound", tag => $tag unless defined $url;
 303   return $url;
 304 }
 305
 306 sub valid_url_p ($) {
 307   my ($url) = @_;
 308   return
 309     length $url < $URLMAXLEN &&
 310     scalar grep { $url =~ /$_/ } @URLPAT;
 311 }
 312
 313 sub new_shorturl ($) {
 314   my ($url) = @_;
 315
 316   valid_url_p $url or fail "invalid url", ".badurl", u => $url;
 317
 318   my $db = open_db;
 319   my $tag;
 320   xact {
 321     ($tag) = $db->selectrow_array
 322       ("SELECT tag FROM odin_shorturl WHERE owner $WHOMATCH ? AND url = ?",
 323        undef, $WHOCMP, $url);
 324     unless (defined $tag) {
 325       $tag = encode_tag(next_seq($db, "odin_shorturl_seq"));
 326       insert_record $db, "odin_shorturl",
 327         tag => $tag, stamp => $NOW, owner => $WHO, url => $url;
 328     }
 329   } $db;
 330   return $tag;
 331 }
 332
 333 sub check_shorturl_owner ($$) {
 334   my ($db, $tag) = @_;
 335
 336   my ($owner) = $db->selectrow_array
 337     ("SELECT owner FROM odin_shorturl WHERE tag = ?", undef, $tag);
 338   fail "tag `$tag' not found", ".notfound", tag => $tag
 339     unless defined $owner;
 340   fail "not owner of `$tag'", ".notowner", tag => $tag
 341     unless $owner =~ /$WHOPAT/;
 342 }
 343
 344 sub update_shorturl ($$) {
 345   my ($tag, $url) = @_;
 346
 347   my $db = open_db;
 348   xact {
 349     check_shorturl_owner $db, $tag;
 350     $db->do("UPDATE odin_shorturl SET url = ? WHERE tag = ?",
 351             undef, $url, $tag);
 352   } $db;
 353 }
 354
 355 sub delete_shorturl (@) {
 356   my (@tags) = @_;
 357
 358   my $db = open_db;
 359   xact {
 360     for my $tag (@tags) {
 361       check_shorturl_owner $db, $tag;
 362       $db->do("DELETE FROM odin_shorturl WHERE tag = ?", undef, $tag);
 363     }
 364   } $db;
 365 }
 366
 367 ###--------------------------------------------------------------------------
 368 ### Paste bin.
 369
 370 our %PASTEBIN_DEFAULTS = (
 371   title => "(untitled)",
 372   lang => "txt",
 373   content => ""
 374 );
 375 our @PASTEBIN_PROPS = keys %PASTEBIN_DEFAULTS;
 376 our $PASTEBIN_PROPCOLS = join ", ", @PASTEBIN_PROPS;
 377 our $PASTEBIN_PROPPLACES = join ", ", map "?", @PASTEBIN_PROPS;
 378
 379 sub new_pastebin (\%) {
 380   my ($new) = @_;
 381
 382   my $db = open_db;
 383   my ($editkey, $hash) = new_editkey;
 384   my $tag;
 385
 386   merge_hash %$new, %PASTEBIN_DEFAULTS;
 387   xact {
 388     $tag = encode_tag next_seq $db, "odin_pastebin_seq";
 389     insert_record $db, "odin_pastebin",
 390       tag => $tag, stamp => $NOW, edithash => $hash, owner => $WHO,
 391       %$new;
 392   } $db;
 393   return $tag, $editkey;
 394 }
 395
 396 sub get_pastebin ($$\%) {
 397   my ($db, $tag, $props) = @_;
 398
 399   (my $owner, my $hash, @{$props}{@PASTEBIN_PROPS}) =
 400     $db->selectrow_array("SELECT owner, edithash, $PASTEBIN_PROPCOLS
 401                           FROM odin_pastebin WHERE tag = ?",
 402                          undef, $tag);
 403   fail "tag `$tag' not found", ".notfound", tag => $tag
 404     unless defined $owner;
 405   return $owner, $hash;
 406 }
 407
 408 sub get_pastebin_check_owner ($$\%) {
 409   my ($db, $tag, $props) = @_;
 410
 411   my ($owner, $hash) = get_pastebin $db, $tag, %$props;
 412   fail "not owner of `$tag'", ".notowner", tag => $tag
 413     unless $WHOSURE && $WHO eq $owner;
 414 }
 415
 416 sub get_pastebin_check_editkey_or_owner ($$$\%) {
 417   my ($db, $tag, $editkey, $props) = @_;
 418
 419   if (!defined $editkey) { get_pastebin_check_owner $db, $tag, %$props; }
 420   else {
 421     my ($owner, $hash) = get_pastebin $db, $tag, %$props;
 422     fail "incorrect edit key for `$tag'", ".badhash", tag => $tag
 423       unless $hash eq sha256_hex $editkey;
 424   }
 425 }
 426
 427 sub rekey_pastebin ($) {
 428   my ($tag) = @_;
 429
 430   my $db = open_db;
 431   my $editkey;
 432   xact {
 433     get_pastebin_check_owner $db, $tag, my %hunoz;
 434     ($editkey, my $hash) = new_editkey;
 435     $db->do("UPDATE odin_pastebin SET edithash = ? WHERE tag = ?",
 436             undef, $hash, $tag);
 437   } $db;
 438   return $editkey;
 439 }
 440
 441 sub claim_pastebin ($$) {
 442   my ($tag, $editkey) = @_;
 443
 444   my $db = open_db;
 445   $WHOSURE or fail "you can't claim pastes", ".notsure";
 446   xact {
 447     get_pastebin_check_editkey_or_owner $db, $tag, $editkey, my %hunoz;
 448     $db->do("UPDATE odin_pastebin SET owner = ? WHERE tag = ?",
 449             undef, $WHO, $tag);
 450   } $db;
 451 }
 452
 453 sub update_pastebin ($$\%) {
 454   my ($tag, $editkey, $new) = @_;
 455
 456   my $db = open_db;
 457   my $editp = 0;
 458   xact {
 459     get_pastebin_check_editkey_or_owner $db, $tag, $editkey, my %old;
 460     for my $p (@PASTEBIN_PROPS) {
 461       if (!defined $new->{$p}) { $new->{$p} = $old{$p}; }
 462       else {
 463         $db->do("UPDATE odin_pastebin SET $p = ? WHERE tag = ?",
 464                 undef, $new->{$p}, $tag)
 465           unless $new->{$p} eq $old{$p};
 466         $editp = 1;
 467       }
 468     }
 469   } $db;
 470   return $editp;
 471 }
 472
 473 sub delete_pastebin (@) {
 474   my @a = @_;
 475   my $db = open_db;
 476   xact {
 477     while (@a) {
 478       (my $tag, my $editkey, @a) = @a;
 479       get_pastebin_check_editkey_or_owner $db, $tag, $editkey, my %hunoz;
 480       $db->do("DELETE FROM odin_pastebin WHERE tag = ?", undef, $tag);
 481     }
 482   } $db;
 483 }
 484
 485 sub tidy_pastebin_content ($) {
 486   my ($content) = @_;
 487   return undef unless defined $content;
 488   $content =~ tr/\r//d;
 489   $content =~ s/([^\n])\z/$1\n/;
 490   length $content <= $PASTEMAXLEN or
 491     fail "invalid paste content", ".badpaste";
 492   return $content;
 493 }
 494
 495 ###--------------------------------------------------------------------------
 496 ### Mail redirection utilities.
 497
 498 sub redir_query ($$$;$@) {
 499   my ($db, $dom, $owner, $cond, @args) = @_;
 500   return @{$db->selectall_arrayref
 501              ("SELECT lpart, expire, recip, comment
 502                FROM odin_mailredir WHERE dom = ? AND owner = ?" .
 503                (defined $cond ? " AND $cond" : "") . " " .
 504               "ORDER BY expire, lpart", undef, $dom, $owner, @args)};
 505 }
 506
 507 sub clear_redir_reservations ($) {
 508   my ($db) = @_;
 509   $db->do("DELETE FROM odin_mailredir WHERE
 510            st = 'reserved' AND expire < ?", undef,
 511           $NOW);
 512   $db->do("UPDATE odin_mailredir SET st = 'dormant', expire = -1
 513            WHERE st = 'live' AND expire <> -1 AND expire < ?", undef, $NOW);
 514 }
 515
 516 sub check_redir_limits ($) {
 517   my ($db) = @_;
 518   my %h = map { $_->[0] => $_->[1] }
 519     @{ $db->selectall_arrayref("SELECT st, COUNT(*) FROM odin_mailredir
 520                                 WHERE owner = ? GROUP BY st", undef,
 521                                $Odin::WHO) };
 522   for my $st (qw(live dormant reserved)) { $h{$st} //= 0; }
 523   $h{live} + $h{dormant} + $h{reserved} <= $MAIL_ADDRMAX_LIVE or
 524     Odin::fail "too many addresses claimed (see your sysadmin)";
 525   $h{reserved} <= $MAIL_ADDRMAX_RESV or
 526     Odin::fail "too many addresses reserved (time to release some)";
 527 }
 528
 529 sub gencls ($) {
 530   my ($g) = @_;
 531   return $GENMAP{$g} // die "configuration error: no generator class `$g'";
 532 }
 533
 534 sub default_generator_class ($) {
 535   my ($dom) = @_;
 536
 537   my $g = $MAILDOM_POLICY{$dom}{gen}[0] // $MAIL_DEFGEN[0];
 538   return gencls $g;
 539 }
 540
 541 sub get_generator_class ($$) {
 542   my ($dom, $g) = @_;
 543
 544   grep { $_ eq $g } @{$MAILDOM_POLICY{$dom}{gen} // \@MAIL_DEFGEN}
 545     or fail "domain `$dom' doesn't allow generator `$g'";
 546   return gencls $g;
 547 }
 548
 549 sub gen_redir_name ($$) {
 550   my ($db, $gen) = @_;
 551
 552   for (my $try = 0; $try < $MAIL_MAXGENTRY; $try++) {
 553     my $l = lc $gen->gen;
 554     return $l
 555       unless $db->selectrow_arrayref
 556         ("SELECT 1 FROM odin_mailredir WHERE lpart = ? AND dom = ?",
 557          undef, $l, $DOMAIN);
 558   }
 559   Odin::fail "failed to find unique local part";
 560 }
 561
 562 sub qualify_recip ($) {
 563   my ($r) = @_;
 564
 565   return $r =~ /\@/ || !defined $MAIL_QUALDOM ? $r : "$r\@$MAIL_QUALDOM";
 566 }
 567
 568 sub check_fixup_redir ($) {
 569   my ($r) = @_;
 570
 571   if (exists $r->{recip}) {
 572     $r->{recip} =~ /^[!-~]+$/ or fail "invalid recipient name `$r->{recip}'";
 573     $r->{recip} = qualify_recip $r->{recip};
 574   }
 575 }
 576
 577 sub new_redir ($$\%;$) {
 578   my ($dom, $gen, $r, $n) = @_;
 579   my $db = open_db;
 580   my @l;
 581
 582   $n //= 1;
 583   check_fixup_redir $r;
 584   Odin::xact {
 585     clear_redir_reservations $db;
 586     while (@l < $n) {
 587       my $l = Odin::gen_redir_name $db, $gen;
 588       insert_record $db, "odin_mailredir",
 589         lpart => $l, dom => $dom, st => 'live',
 590         owner => $WHO, creator => $WHO,
 591         recip => $r->{recip} // qualify_recip $Odin::WHO,
 592         expire => $r->{expire} // -1,
 593         comment => $r->{comment} // "";
 594       push @l, $l;
 595     }
 596     check_redir_limits $db;
 597   } $db;
 598   return @l;
 599 }
 600
 601 sub reserve_redir ($$$) {
 602   my ($dom, $gen, $n) = @_;
 603   my $db = open_db;
 604   my @l;
 605
 606   Odin::xact {
 607     clear_redir_reservations $db;
 608     @l = ();
 609     for (my $i = 0; $i < $n; $i++) { push @l, gen_redir_name $db, $gen; }
 610     for my $l (@l) {
 611       insert_record $db, "odin_mailredir",
 612         lpart => $l, dom => $dom, owner => $WHO,
 613         st => 'reserved', expire => $NOW + $MAIL_AGEMAX_RESV;
 614     }
 615     check_redir_limits $db;
 616   } $db;
 617   return @l;
 618 }
 619
 620 sub release_all_redir ($) {
 621   my ($dom) = @_;
 622   my $db = open_db;
 623
 624   my $st = $db->prepare("DELETE FROM odin_mailredir
 625                          WHERE dom = ? AND owner = ? AND st = 'reserved'");
 626   Odin::xact {
 627     $st->execute($dom, $WHO);
 628     $st->rows or Odin::fail "no reserved addresses";
 629   } $db;
 630 }
 631
 632 sub release_redir ($@) {
 633   my ($dom, @l) = @_;
 634   my $db = open_db;
 635
 636   my $st = $db->prepare("DELETE FROM odin_mailredir
 637                          WHERE lpart = ? AND dom = ? AND
 638                                owner = ? AND st = 'reserved'");
 639   Odin::xact {
 640     clear_redir_reservations $db;
 641     for my $l (@l) {
 642       $st->execute($l, $dom, $WHO);
 643       Odin::fail "local part `$l' not reserved" unless $st->rows;
 644     }
 645   } $db;
 646 }
 647
 648 sub disable_redir ($$) {
 649   my ($dom, @l) = @_;
 650   my $db = open_db;
 651
 652   my $st = $db->prepare("UPDATE odin_mailredir
 653                          SET st = 'dormant', expire = -1
 654                          WHERE lpart = ? AND dom = ? AND
 655                                owner = ? AND st = 'live'");
 656   Odin::xact {
 657     clear_redir_reservations $db;
 658     for my $l (@ARGV) {
 659       $st->execute($l, $dom, $WHO);
 660       Odin::fail "local part `$l' not live" unless $st->rows;
 661     }
 662   } $db;
 663 }
 664
 665 sub modify_redir ($\%@) {
 666   my ($dom, $r, @l) = @_;
 667   my $db = open_db;
 668
 669   check_fixup_redir $r;
 670   Odin::xact {
 671     clear_redir_reservations $db;
 672     for my $l (@l) {
 673       my %r = %$r;
 674       my ($recip, $st) = $db->selectrow_array
 675         ("SELECT recip, st FROM odin_mailredir
 676           WHERE lpart = ? AND dom = ? AND owner = ?", undef,
 677          $l, $dom, $WHO);
 678       if (!defined $recip) { Odin::fail "unknown local part `$l'"; }
 679       elsif ($recip eq "") { $r{recip} //= qualify_recip $WHO; }
 680       if ($st ne "live") { $r{st} = "live"; $r{expire} //= -1; }
 681       my @var = ();
 682       my @val = ();
 683       for my $v (keys %r) {
 684         push @var, $v;
 685         push @val, $r{$v};
 686       }
 687       @var or fail "nothing to change";
 688       $db->do("UPDATE odin_mailredir SET " .
 689               join(", ", map { "$_ = ?" } @var) . " " .
 690               "WHERE lpart = ? AND dom = ?", undef,
 691               @val, $l, $dom);
 692     }
 693   } $db;
 694 }
 695
 696 ###--------------------------------------------------------------------------
 697 ### Simple option parser.
 698
 699 package Odin::OptParse;
 700
 701 sub new {
 702   my ($cls, @args) = @_;
 703   return bless {
 704     cur => "",
 705     args => \@args,
 706     opt => undef,
 707     ok => 1
 708   }, $cls;
 709 }
 710
 711 sub get {
 712   my ($me) = @_;
 713   if (!length $me->{cur}) {
 714     my $args = $me->{args};
 715     if (!@$args) { return undef; }
 716     elsif ($args->[0] =~ /^[^-]|^-$/) { return undef; }
 717     elsif ($args->[0] eq "--") { shift @$args; return undef; }
 718     $me->{cur} = substr shift @$args, 1;
 719   }
 720   my $o = $me->{opt} = substr $me->{cur}, 0, 1;
 721   $me->{cur} = substr $me->{cur}, 1;
 722   return $o;
 723 }
 724
 725 sub arg {
 726   my ($me) = @_;
 727   my $a;
 728   if (length $me->{cur}) { $a = $me->{cur}; $me->{cur} = ""; }
 729   elsif (@{$me->{args}}) { $a = shift @{$me->{args}}; }
 730   else { $a = undef; $me->err("option `-$me->{opt}' requires an argument"); }
 731   return $a;
 732 }
 733
 734 sub intarg {
 735   my ($me, $what, $min, $max) = @_;
 736   $what //= "option `-$me->{opt}'";
 737   defined (my $a = $me->arg) or return undef;
 738   if ($a !~ /^[-+]?\d+$/ ||
 739       (defined $min && $a < $min) ||
 740       (defined $max && $a > $max)) {
 741     $me->err("invalid value `$a' for $what");
 742     $a = undef;
 743   }
 744   return $a;
 745 }
 746
 747 sub rest { return @{$_[0]->{args}}; }
 748 sub ok { return $_[0]->{ok}; }
 749 sub bad { $_[0]->{ok} = 0; }
 750 sub err { $_[0]->bad; print STDERR "$PROG: $_[1]\n"; }
 751 sub unk { $_[0]->err("unknown option `-$_[0]->{opt}'"); }
 752
 753 ###--------------------------------------------------------------------------
 754 ### Parameter objects.
 755
 756 package Odin::Param;
 757 sub dflt { return $_[0]->{dflt}; }
 758
 759 package Odin::Param::Int;
 760 @ISA = qw(Odin::Param);
 761
 762 sub new {
 763   my ($cls, $dflt, $min, $max) = @_;
 764   return bless { dflt => $dflt, min => $min, max => $max }, $cls;
 765 }
 766
 767 sub check {
 768   my ($me, $v) = @_;
 769   return undef unless
 770     $v =~ /^[-+]?\d+$/ &&
 771     (!defined $me->{min} || $v >= $me->{min}) &&
 772     (!defined $me->{max} || $v <= $me->{max});
 773   return $v + 0;
 774 }
 775
 776 package Odin::Param::Str;
 777 @ISA = qw(Odin::Param);
 778
 779 sub new {
 780   my ($cls, $dflt, $rx, $minlen, $maxlen) = @_;
 781   return bless {
 782     dflt => $dflt,
 783     rx => defined $rx ? qr/$rx/ : qr//,
 784     minlen => $minlen,
 785     maxlen => $maxlen
 786   }, $cls;
 787 }
 788
 789 sub check {
 790   my ($me, $v) = @_;
 791   return undef unless
 792     $v =~ /$me->{rx}/ &&
 793     (!defined $me->{minlen} || length $v >= $me->{minlen}) &&
 794     (!defined $me->{maxlen} || length $v <= $me->{maxlen});
 795   return $v . "";
 796 }
 797
 798 ###--------------------------------------------------------------------------
 799 ### Name generators.
 800
 801 package Odin::Gen;
 802
 803 use Scalar::Util qw(blessed);
 804
 805 sub random {
 806   my ($me, $lim) = @_;
 807
 808   defined $me->{rand}
 809     or open $me->{rand}, "/dev/urandom"
 810     or die "open random: $!";
 811
 812   my $nb = 1; my $max = 255;
 813   while ($lim > $max) { $nb++; $max = ($max << 8) | 255; }
 814   my $thresh = $max - ($max%$lim);
 815
 816   for (;;) {
 817     sysread $me->{rand}, my $b, $nb
 818       or die "read random: $!";
 819     my $r = 0;
 820     for (my $i = 0; $i < $nb; $i++)
 821       { $r = ($r << 255) | ord substr $b, $i, 1; }
 822     return $r%$lim if $r < $thresh;
 823   }
 824 }
 825
 826 sub new {
 827   my ($cls, $dom, $param) = @_;
 828   my $pkg = \%::;
 829   for my $p (split /::/, $cls) { $pkg = \%{$pkg->{"${p}::"}}; }
 830
 831   my $label = ${$pkg->{LABEL}};
 832   my $plist = \@{$pkg->{PARAM}};
 833   my $gtmpl = $GENPARAM{$label};
 834   my $dtmpl = $MAILDOM_POLICY{$dom}{$label};
 835   my %pp = ();
 836
 837   for my $p (@$plist) {
 838     $pp->{$p} = 1;
 839     my $t = $dtmpl->{$p} // $gtmpl->{$p};
 840     if (blessed $t && $t->isa("Odin::Param")) {
 841       if (!exists $param->{$p}) { $param->{$p} = $t->dflt; }
 842       else {
 843         my $v = $t->check($param->{$p});
 844         Odin::fail "bad value `$param->{$p}' for $label parameter `$p'"
 845           unless defined $v;
 846         $param->{$p} = $v;
 847       }
 848     } else {
 849       if (exists $param->{$p})
 850         { Odin::fail "not allowed to set $label parameter `$p'"; }
 851       else
 852         { $param->{$p} = $t; }
 853     }
 854   }
 855   for my $p (keys %$param) {
 856     if (!$pp->{$p}) { Odin::fail "unknown $label parameter `$p'"; }
 857   }
 858
 859   my $me = bless { %$param }, $cls;
 860   $me->{rand} = undef;
 861   return $me;
 862 }
 863
 864 package Odin::Gen::Chars;
 865 @ISA = qw(Odin::Gen);
 866
 867 $LABEL = 'chars';
 868 @PARAM = qw(ichars mchars echars len);
 869
 870 $GENMAP{chars} = "Odin::Gen::Chars";
 871 $GENPARAM{chars} = {
 872   ichars => Odin::Param::Str->new($ALPHA, $SAFECH, 1, 255),
 873   mchars => Odin::Param::Str->new($ALPHA . $NUM, $SAFECH, 2, 255),
 874   echars => Odin::Param::Str->new($ALPHA . $NUM, $SAFECH, 2, 255),
 875   len => Odin::Param::Int->new(6, 2, 16)
 876 };
 877
 878 sub _pick {
 879   my ($me, $chars) = @_;
 880   return substr $chars, $me->random(length $chars), 1;
 881 }
 882
 883 sub gen {
 884   my ($me) = @_;
 885
 886   my $n = $me->{len};
 887
 888   my $s = "";
 889   if ($n) { $s .= $me->_pick($me->{ichars}); $n--; }
 890   while ($n > 1) { $s .= $me->_pick($me->{mchars}); $n--; }
 891   if ($n) { $s .= $me->_pick($me->{echars}); $n--; }
 892   if ($n) { die "INTERNAL can't count"; }
 893   return $s;
 894 }
 895
 896 package Odin::Gen::Words;
 897 @ISA = qw(Odin::Gen);
 898
 899 $LABEL = 'words';
 900 @PARAM = qw(wordlist delim nwords);
 901
 902 $GENMAP{words} = "Odin::Gen::Words";
 903 $GENPARAM{words} = {
 904   wordlist => "etc/words",
 905   delim => Odin::Param::Str->new(".", qr/^[-_.+]*$/, 1, 1),
 906   nwords => Odin::Param::Int->new(3, 2, 16)
 907 };
 908
 909 sub gen {
 910   my ($me) = @_;
 911   my @w = ();
 912
 913   if (!exists $me->{words}) {
 914     open my $f, $me->{wordlist} or die "open wordlist: $!";
 915     $me->{words} = [grep chomp, <$f>];
 916     close $f or die "close/read wordlist: $!";
 917   }
 918
 919   for (my $i = 0; $i < $me->{nwords}; $i++)
 920     { push @w, $me->{words}[$me->random(scalar @{$me->{words}})]; }
 921   return join $me->{delim}, @w;
 922 }
 923
 924 ###--------------------------------------------------------------------------
 925 ### Final configuration.
 926
 927 package Odin;
 928
 929 require "config.pl";
 930
 931 ($SCHEME, $DOMAIN, $BASEPATH) = $BASEURL =~ m!^([^:]+)://([^/]+)(/.*)$!;
 932 merge_hash %COOKIE_DEFAULTS, -domain => $DOMAIN, -path => $BASEPATH;
 933 merge_hash %COOKIE_DEFAULTS, -secure => undef if $SCHEME eq "https";
 934
 935 $MAIL_QUALDOM //= $MAIL_DEFDOMAIN;
 936
 937 $SHORTURL = "$BASEURL$SHORTURL_PATH";
 938 $PASTEBIN = "$BASEURL$PASTEBIN_PATH";
 939
 940 ###----- That's all, folks --------------------------------------------------
 941
 942 1;