chiark - git - mdw - misc/blob - configure.ac

   1 dnl -*-autoconf-*-
   2 dnl
   3 dnl Configuration script for nsict-utils
   4 dnl
   5 dnl (c) 2008 Mark Wooding
   6 dnl
   7
   8 dnl ----- Licensing notice --------------------------------------------------
   9 dnl
  10 dnl This program is free software; you can redistribute it and/or modify
  11 dnl it under the terms of the GNU General Public License as published by
  12 dnl the Free Software Foundation; either version 2 of the License, or
  13 dnl (at your option) any later version.
  14 dnl
  15 dnl This program is distributed in the hope that it will be useful,
  16 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 dnl GNU General Public License for more details.
  19 dnl
  20 dnl You should have received a copy of the GNU General Public License
  21 dnl along with this program; if not, write to the Free Software Foundation,
  22 dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23
  24 dnl--------------------------------------------------------------------------
  25 dnl Initialization.
  26
  27 mdw_AUTO_VERSION
  28 AC_INIT([nsict-utils], AUTO_VERSION, [mdw@distorted.org.uk])
  29 AC_CONFIG_SRCDIR([shadowfix.in])
  30 AC_CONFIG_AUX_DIR([config])
  31 AM_INIT_AUTOMAKE([foreign])
  32 mdw_SILENT_RULES
  33
  34 AC_CANONICAL_HOST
  35
  36 dnl--------------------------------------------------------------------------
  37 dnl C programming environment.
  38
  39 ## Compiler.
  40 AC_PROG_CC
  41 AX_CFLAGS_WARN_ALL
  42
  43 ## Libraries.
  44 OLIBS=$LIBS
  45 AC_SEARCH_LIBS([floor], [m])
  46 AC_SUBST([MATH_LIBS], [$LIBS])
  47 LIBS=$OLIBS
  48
  49 AC_CHECK_LIB([cdb], [cdb_seek], [have_cdb=yes], [have_cdb=no])
  50 AM_CONDITIONAL([HAVE_LIBCDB], [test $have_cdb = yes])
  51
  52 AC_CHECK_LIB([spamc], [message_filter], [have_spamc=yes], [have_spamc=no])
  53 AM_CONDITIONAL([HAVE_LIBSPAMC], [test $have_spamc = yes])
  54
  55 ## Packages.
  56 PKG_CHECK_MODULES([mLib], [mLib >= 2.0.4], [have_mLib=yes], [have_mLib=no])
  57 AM_CONDITIONAL([HAVE_MLIB], [test $have_mLib = yes])
  58
  59 PKG_CHECK_MODULES([catacomb], [catacomb >= 2.1.1],
  60                   [have_catacomb=yes], [have_catacomb=no])
  61 AM_CONDITIONAL([HAVE_CATACOMB], [test $have_catacomb = yes])
  62
  63 ## Functions.
  64 AC_CHECK_FUNC([prlimit], [have_prlimit=yes], [have_prlimit=no])
  65 AM_CONDITIONAL([HAVE_PRLIMIT], [test $have_prlimit = yes])
  66
  67 ## Processor type.
  68 case "$host_cpu" in i?86) x86=yes;; *) x86=no;; esac
  69 AM_CONDITIONAL([X86], [test $x86 = yes -a $GCC = yes])
  70
  71 dnl--------------------------------------------------------------------------
  72 dnl Python, Perl and other scripting languages.
  73
  74 ## Python.
  75 AM_PATH_PYTHON([2.4], [have_python=yes], [have_python=no])
  76 AM_CONDITIONAL([HAVE_PYTHON], [test $have_python = yes])
  77
  78 AC_PYTHON_MODULE([cdb])
  79 AM_CONDITIONAL([HAVE_PYMOD_CDB], [test $HAVE_PYMOD_CDB = yes])
  80
  81 ## Perl.
  82 AC_ARG_VAR([PERL], [Path to your favourite Perl binary.])
  83 AC_PATH_PROGS([PERL], [perl perl5], [false])
  84 AX_PROG_PERL_VERSION([5.004], [have_perl=yes], [have_perl=no])
  85 AM_CONDITIONAL([HAVE_PERL], [test $have_perl = yes])
  86
  87 AC_ARG_WITH(
  88         [perlmoddir],
  89         AS_HELP_STRING([--perlmoddir=DIR],
  90                        [Install Perl modules here.]),
  91         [perlmoddir=$withval],
  92         [perlmoddir='${libdir}/site_perl'])
  93 AC_SUBST([perlmoddir])
  94
  95 ## Tcl.
  96 have_tcl=yes
  97 AC_ARG_VAR([TCLSH], [Path to your favourite tclsh binary.])
  98 AC_PATH_PROG([TCLSH], [tclsh], [false])
  99
 100 AC_MSG_CHECKING([Tcl version])
 101 case "$TCLSH" in false) have_tcl=no ;; esac
 102 case "$have_tcl" in
 103   yes)
 104     tclver=$(echo "puts \$tcl_version" | tclsh -)
 105     tclver_hack=$(echo "$tclver" | sed 's/\.//')
 106     if test "$tclver_hack" -ge 83; then
 107       AC_MSG_RESULT([$tclver])
 108     else
 109       have_tcl=no
 110       AC_MSG_RESULT([too old ($tclver)])
 111     fi
 112 esac
 113 AM_CONDITIONAL([HAVE_TCLSH], [test $have_tcl = yes])
 114
 115 ## Bash.
 116 case "$BASH" in /bin/sh) unset BASH ;; esac
 117 AC_ARG_VAR([BASH], [Path to the Bourne Again Shell.])
 118 AC_PATH_PROG([BASH], [bash], [false])
 119 AC_MSG_CHECKING([bash version])
 120 bashver=$("$BASH" -c 'echo $BASH_VERSION')
 121 if "$BASH" 2>/dev/null -c '[[[ ${BASH_VERSINFO[0]} -ge 3 ]]]'; then
 122   have_bash=yes
 123   AC_MSG_RESULT([$bashver])
 124 else
 125   have_bash=no
 126   AC_MSG_RESULT([too old ($bashver)])
 127 fi
 128 AM_CONDITIONAL([HAVE_BASH], [test $have_bash = yes])
 129
 130 dnl--------------------------------------------------------------------------
 131 dnl Output.
 132
 133 AC_CONFIG_FILES([Makefile])
 134 AC_OUTPUT
 135
 136 dnl ----- That's all, folks -------------------------------------------------