chiark - git - mdw - mLib/blob - configure.ac

   1 dnl -*-autoconf-*-
   2 dnl
   3 dnl Configuration script for mLib
   4 dnl
   5 dnl (c) 2008 Straylight/Edgeware
   6 dnl
   7
   8 dnl ----- Licensing notice --------------------------------------------------
   9 dnl
  10 dnl This file is part of the mLib utilities library.
  11 dnl
  12 dnl mLib is free software; you can redistribute it and/or modify
  13 dnl it under the terms of the GNU Library General Public License as
  14 dnl published by the Free Software Foundation; either version 2 of the
  15 dnl License, or (at your option) any later version.
  16 dnl
  17 dnl mLib is distributed in the hope that it will be useful,
  18 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 dnl GNU Library General Public License for more details.
  21 dnl
  22 dnl You should have received a copy of the GNU Library General Public
  23 dnl License along with mLib; if not, write to the Free
  24 dnl Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  25 dnl MA 02111-1307, USA.
  26
  27 dnl--------------------------------------------------------------------------
  28 dnl Initialization.
  29
  30 mdw_AUTO_VERSION
  31 AC_INIT([mLib], AUTO_VERSION, [mdw@distorted.org.uk], [mLib])
  32 AC_CONFIG_SRCDIR([mLib.pc.in])
  33 AC_CONFIG_AUX_DIR([config])
  34 AM_INIT_AUTOMAKE([foreign])
  35 mdw_SILENT_RULES
  36
  37 AC_PROG_CC
  38 AM_PROG_CC_C_O
  39 AM_PROG_LIBTOOL
  40 AX_CFLAGS_WARN_ALL
  41 mdw_LIBTOOL_VERSION_INFO
  42
  43 AC_CHECK_PROGS([AUTOM4TE], [autom4te])
  44
  45 mdw_MANEXT
  46
  47 AC_DEFINE_UNQUOTED([SRCDIR], ["$(cd $srcdir && pwd)"],
  48                    [absolute pathname for the source directory.])
  49
  50 dnl--------------------------------------------------------------------------
  51 dnl C programming environment.
  52
  53 dnl Headers.
  54 AC_CHECK_HEADERS([float.h])
  55
  56 dnl Libraries.
  57 AC_SEARCH_LIBS([socket], [socket])
  58 AC_SEARCH_LIBS([gethostbyname], [nsl resolv])
  59
  60 dnl Which version of struct msghdr do we have?
  61 AC_CHECK_MEMBERS([struct msgdr.msg_control],,, [
  62 #include <sys/types.h>
  63 #include <sys/socket.h>
  64 ])
  65
  66 dnl Find out whether we're cross-compiling.
  67 AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes ])
  68
  69 dnl--------------------------------------------------------------------------
  70 dnl Name resolution.
  71
  72 AC_ARG_WITH([adns],
  73   AS_HELP_STRING([--with-adns],
  74                  [use ADNS library for background name resolution]),
  75   [want_adns=$withval],
  76   [want_adns=auto])
  77
  78 case $want_adns in
  79   no) ;;
  80   *) AC_SEARCH_LIBS([adns_init], [adns], [have_adns=yes], [have_adns=no]) ;;
  81 esac
  82 case $want_adns,$have_adns in
  83   yes,no)
  84     AC_MSG_ERROR([ADNS library not found but explicitly requested])
  85     ;;
  86   yes,yes | auto,yes)
  87     use_adns=yes
  88     AC_DEFINE([HAVE_ADNS], [1],
  89               [define if you have (and want to use) the ADNS library.])
  90     ;;
  91   no,* | auto,no)
  92     use_adns=no
  93     mdw_DEFINE_PATHS([
  94       AC_DEFINE_UNQUOTED([BRES_SERVER],
  95                          ["mdw_PATH($libexecdir)/$PACKAGE/mdw_PROG(bres)"],
  96                          [pathname to the standalone `bres' binary.'])
  97     ])
  98     ;;
  99 esac
 100 AM_CONDITIONAL([WITH_ADNS], [test "$use_adns" = yes])
 101
 102 dnl--------------------------------------------------------------------------
 103 dnl Python (used for testing).
 104
 105 AM_PATH_PYTHON([2.4],, [:])
 106
 107 dnl--------------------------------------------------------------------------
 108 dnl Output.
 109
 110 AC_CONFIG_HEADER([config/config.h])
 111 AC_CONFIG_TESTDIR([t])
 112
 113 AC_CONFIG_FILES(
 114   [Makefile]
 115   [buf/Makefile]
 116   [codec/Makefile]
 117   [hash/Makefile]
 118   [mem/Makefile]
 119   [sel/Makefile]
 120   [struct/Makefile]
 121   [sys/Makefile]
 122   [test/Makefile]
 123   [trace/Makefile]
 124   [ui/Makefile]
 125   [utils/Makefile]
 126   [t/Makefile t/atlocal])
 127 AC_OUTPUT
 128
 129 dnl ----- That's all, folks -------------------------------------------------