chiark - git - mdw - mLib/blob - configure.ac

   1 dnl -*-autoconf-*-
   2 dnl
   3 dnl Configuration script for mLib
   4 dnl
   5 dnl (c) 2008 Straylight/Edgeware
   6 dnl
   7
   8 dnl----- Licensing notice ---------------------------------------------------
   9 dnl
  10 dnl This file is part of the mLib utilities library.
  11 dnl
  12 dnl mLib is free software; you can redistribute it and/or modify
  13 dnl it under the terms of the GNU Library General Public License as
  14 dnl published by the Free Software Foundation; either version 2 of the
  15 dnl License, or (at your option) any later version.
  16 dnl
  17 dnl mLib is distributed in the hope that it will be useful,
  18 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 dnl GNU Library General Public License for more details.
  21 dnl
  22 dnl You should have received a copy of the GNU Library General Public
  23 dnl License along with mLib; if not, write to the Free
  24 dnl Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  25 dnl MA 02111-1307, USA.
  26
  27 dnl--------------------------------------------------------------------------
  28 dnl Initialization.
  29
  30 mdw_AUTO_VERSION
  31 AC_INIT([mLib], AUTO_VERSION, [mdw@distorted.org.uk], [mLib])
  32 AC_CONFIG_SRCDIR([mLib.pc.in])
  33 AC_CONFIG_AUX_DIR([config])
  34 AM_INIT_AUTOMAKE([foreign])
  35 mdw_SILENT_RULES
  36
  37 AC_PROG_CC
  38 AM_PROG_CC_C_O
  39 AM_PROG_LIBTOOL
  40 AX_CFLAGS_WARN_ALL
  41 mdw_LIBTOOL_VERSION_INFO
  42
  43 AC_CHECK_PROGS([AUTOM4TE], [autom4te])
  44
  45 mdw_MANEXT
  46
  47 AC_DEFINE_UNQUOTED([SRCDIR], ["$(cd $srcdir && pwd)"],
  48                    [absolute pathname for the source directory.])
  49
  50 dnl--------------------------------------------------------------------------
  51 dnl C programming environment.
  52
  53 dnl Headers.
  54 AC_CHECK_HEADERS([float.h])
  55
  56 dnl Libraries.
  57 AC_SEARCH_LIBS([socket], [socket])
  58 AC_SEARCH_LIBS([gethostbyname], [nsl resolv])
  59
  60 dnl Functions.
  61 AC_CHECK_FUNCS([snprintf])
  62
  63 dnl Types.
  64 AC_CHECK_TYPE([socklen_t], [int])
  65
  66 dnl Which version of struct msghdr do we have?
  67 AC_CHECK_MEMBERS([struct msgdr.msg_control],,, [
  68 #include <sys/types.h>
  69 #include <sys/socket.h>
  70 ])
  71
  72 dnl Find out whether we're cross-compiling.
  73 AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes])
  74
  75 dnl--------------------------------------------------------------------------
  76 dnl Name resolution.
  77
  78 AC_ARG_WITH([adns],
  79   AS_HELP_STRING([--with-adns],
  80                  [use ADNS library for background name resolution]),
  81   [want_adns=$withval],
  82   [want_adns=auto])
  83
  84 case $want_adns in
  85   no) ;;
  86   *) AC_SEARCH_LIBS([adns_init], [adns], [have_adns=yes], [have_adns=no]) ;;
  87 esac
  88 case $want_adns,$have_adns in
  89   yes,no)
  90     AC_MSG_ERROR([ADNS library not found but explicitly requested])
  91     ;;
  92   yes,yes | auto,yes)
  93     use_adns=yes
  94     AC_DEFINE([HAVE_ADNS], [1],
  95               [define if you have (and want to use) the ADNS library.])
  96     ;;
  97   no,* | auto,no)
  98     use_adns=no
  99     mdw_DEFINE_PATHS([
 100       AC_DEFINE_UNQUOTED([BRES_SERVER],
 101                          ["mdw_PATH($libexecdir)/$PACKAGE/mdw_PROG(bres)"],
 102                          [pathname to the standalone `bres' binary.'])
 103     ])
 104     ;;
 105 esac
 106 AM_CONDITIONAL([WITH_ADNS], [test "$use_adns" = yes])
 107
 108 dnl--------------------------------------------------------------------------
 109 dnl Python (used for testing).
 110
 111 AM_PATH_PYTHON([2.4],, [:])
 112
 113 dnl--------------------------------------------------------------------------
 114 dnl Output.
 115
 116 AC_CONFIG_HEADER([config/config.h])
 117 AC_CONFIG_TESTDIR([t])
 118
 119 AC_CONFIG_FILES(
 120   [Makefile]
 121   [buf/Makefile]
 122   [codec/Makefile]
 123   [hash/Makefile]
 124   [mem/Makefile]
 125   [sel/Makefile]
 126   [struct/Makefile]
 127   [sys/Makefile]
 128   [test/Makefile]
 129   [trace/Makefile]
 130   [ui/Makefile]
 131   [utils/Makefile]
 132   [t/Makefile t/atlocal])
 133 AC_OUTPUT
 134
 135 dnl------ That's all, folks -------------------------------------------------