chiark - git - mdw - mLib/blob - configure.ac

   1 dnl -*-autoconf-*-
   2 dnl
   3 dnl Configuration script for mLib
   4 dnl
   5 dnl (c) 2008 Straylight/Edgeware
   6 dnl
   7
   8 dnl ----- Licensing notice --------------------------------------------------
   9 dnl
  10 dnl This file is part of the mLib utilities library.
  11 dnl
  12 dnl mLib is free software; you can redistribute it and/or modify
  13 dnl it under the terms of the GNU Library General Public License as
  14 dnl published by the Free Software Foundation; either version 2 of the
  15 dnl License, or (at your option) any later version.
  16 dnl
  17 dnl mLib is distributed in the hope that it will be useful,
  18 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 dnl GNU Library General Public License for more details.
  21 dnl
  22 dnl You should have received a copy of the GNU Library General Public
  23 dnl License along with mLib; if not, write to the Free
  24 dnl Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  25 dnl MA 02111-1307, USA.
  26
  27 dnl--------------------------------------------------------------------------
  28 dnl Initialization.
  29
  30 mdw_AUTO_VERSION
  31 AC_INIT([mLib], AUTO_VERSION, [mdw@distorted.org.uk], [mLib])
  32 AC_CONFIG_SRCDIR([mLib.pc.in])
  33 AC_CONFIG_AUX_DIR([config])
  34 AM_INIT_AUTOMAKE([foreign])
  35 mdw_SILENT_RULES
  36
  37 AC_PROG_CC
  38 AM_PROG_CC_C_O
  39 AM_PROG_LIBTOOL
  40 AX_CFLAGS_WARN_ALL
  41 mdw_LIBTOOL_VERSION_INFO
  42
  43 AC_CHECK_PROGS([AUTOM4TE], [autom4te])
  44
  45 mdw_MANEXT
  46
  47 AC_DEFINE_UNQUOTED([SRCDIR], ["$(cd $srcdir && pwd)"],
  48                    [absolute pathname for the source directory.])
  49
  50 dnl--------------------------------------------------------------------------
  51 dnl C programming environment.
  52
  53 dnl Headers.
  54 AC_CHECK_HEADERS([float.h])
  55
  56 dnl Libraries.
  57 AC_SEARCH_LIBS([socket], [socket])
  58 AC_SEARCH_LIBS([gethostbyname], [nsl resolv])
  59
  60 dnl Types.
  61 AC_CHECK_TYPE([socklen_t], [int])
  62
  63 dnl Which version of struct msghdr do we have?
  64 AC_CHECK_MEMBERS([struct msgdr.msg_control],,, [
  65 #include <sys/types.h>
  66 #include <sys/socket.h>
  67 ])
  68
  69 dnl Find out whether we're cross-compiling.
  70 AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes ])
  71
  72 dnl--------------------------------------------------------------------------
  73 dnl Name resolution.
  74
  75 AC_ARG_WITH([adns],
  76   AS_HELP_STRING([--with-adns],
  77                  [use ADNS library for background name resolution]),
  78   [want_adns=$withval],
  79   [want_adns=auto])
  80
  81 case $want_adns in
  82   no) ;;
  83   *) AC_SEARCH_LIBS([adns_init], [adns], [have_adns=yes], [have_adns=no]) ;;
  84 esac
  85 case $want_adns,$have_adns in
  86   yes,no)
  87     AC_MSG_ERROR([ADNS library not found but explicitly requested])
  88     ;;
  89   yes,yes | auto,yes)
  90     use_adns=yes
  91     AC_DEFINE([HAVE_ADNS], [1],
  92               [define if you have (and want to use) the ADNS library.])
  93     ;;
  94   no,* | auto,no)
  95     use_adns=no
  96     mdw_DEFINE_PATHS([
  97       AC_DEFINE_UNQUOTED([BRES_SERVER],
  98                          ["mdw_PATH($libexecdir)/$PACKAGE/mdw_PROG(bres)"],
  99                          [pathname to the standalone `bres' binary.'])
 100     ])
 101     ;;
 102 esac
 103 AM_CONDITIONAL([WITH_ADNS], [test "$use_adns" = yes])
 104
 105 dnl--------------------------------------------------------------------------
 106 dnl Python (used for testing).
 107
 108 AM_PATH_PYTHON([2.4],, [:])
 109
 110 dnl--------------------------------------------------------------------------
 111 dnl Output.
 112
 113 AC_CONFIG_HEADER([config/config.h])
 114 AC_CONFIG_TESTDIR([t])
 115
 116 AC_CONFIG_FILES(
 117   [Makefile]
 118   [buf/Makefile]
 119   [codec/Makefile]
 120   [hash/Makefile]
 121   [mem/Makefile]
 122   [sel/Makefile]
 123   [struct/Makefile]
 124   [sys/Makefile]
 125   [test/Makefile]
 126   [trace/Makefile]
 127   [ui/Makefile]
 128   [utils/Makefile]
 129   [t/Makefile t/atlocal])
 130 AC_OUTPUT
 131
 132 dnl ----- That's all, folks -------------------------------------------------