chiark - git - mdw - ircbot/blob - irccore.tcl

   1 proc defset {varname val} {
   2     upvar 1 $varname var
   3     if {![info exists var]} { set var $val }
   4 }
   5
   6 # must set host
   7 defset port 6667
   8
   9 defset nick testbot
  10 defset ident blight
  11 defset ownfullname "testing bot"
  12 defset ownmailaddr test-irc-bot@example.com
  13
  14 defset muststartby_ms 10000
  15 defset out_maxburst 6
  16 defset out_interval 2100
  17 defset out_lag_lag 5000
  18 defset out_lag_very 25000
  19 defset ownping_every 300000
  20
  21 proc manyset {list args} {
  22     foreach val $list var $args {
  23         upvar 1 $var my
  24         set my $val
  25     }
  26 }
  27
  28 proc try_except_finally {try except finally} {
  29     global errorInfo errorCode
  30     set er [catch { uplevel 1 $try } emsg]
  31     if {$er} {
  32         set ei $errorInfo
  33         set ec $errorCode
  34         if {[catch { uplevel 1 $except } emsg3]} {
  35             append ei "\nALSO ERROR HANDLING ERROR:\n$emsg3"
  36         }
  37     }
  38     set er2 [catch { uplevel 1 $finally } emsg2]
  39     if {$er} {
  40         if {$er2} {
  41             append ei "\nALSO ERROR CLEANING UP:\n$emsg2"
  42         }
  43         return -code $er -errorinfo $ei -errorcode $ec $emsg
  44     } elseif {$er2} {
  45         return -code $er2 -errorinfo $errorInfo -errorcode $errorCode $emsg2
  46     } else {
  47         return $emsg
  48     }
  49 }
  50
  51 proc out__vars {} {
  52     uplevel 1 {
  53         global out_queue out_creditms out_creditat out_interval out_maxburst
  54         global out_lag_lag out_lag_very
  55 #set pr [lindex [info level 0] 0]
  56 #puts $pr>[clock seconds]|$out_creditat|$out_creditms|[llength $out_queue]<
  57     }
  58 }
  59
  60 proc out_lagged {} {
  61     out__vars
  62     if {[llength $out_queue]*$out_interval > $out_lag_very} {
  63         return 2
  64     } elseif {[llength $out_queue]*$out_interval > $out_lag_lag} {
  65         return 1
  66     } else {
  67         return 0
  68     }
  69 }
  70
  71 proc out_restart {} {
  72     out__vars
  73
  74     set now [clock seconds]
  75     incr out_creditms [expr {($now - $out_creditat) * 1000}]
  76     set out_creditat $now
  77     if {$out_creditms > $out_maxburst*$out_interval} {
  78         set out_creditms [expr {$out_maxburst*$out_interval}]
  79     }
  80     out_runqueue $now
  81 }
  82
  83 proc out_runqueue {now} {
  84     global sock
  85     out__vars
  86
  87     while {[llength $out_queue] && $out_creditms >= $out_interval} {
  88 #puts rq>$now|$out_creditat|$out_creditms|[llength $out_queue]<
  89         manyset [lindex $out_queue 0] orgwhen msg
  90         set out_queue [lrange $out_queue 1 end]
  91         if {[llength $out_queue]} {
  92             append orgwhen "+[expr {$now - $orgwhen}]"
  93             append orgwhen "([llength $out_queue])"
  94         }
  95         puts "$orgwhen -> $msg"
  96         puts $sock $msg
  97         incr out_creditms -$out_interval
  98     }
  99     if {[llength $out_queue]} {
 100         after $out_interval out_nextmessage
 101     }
 102 }
 103
 104 proc out_nextmessage {} {
 105     out__vars
 106     set now [clock seconds]
 107     incr out_creditms $out_interval
 108     set out_creditat $now
 109     out_runqueue $now
 110 }
 111
 112 proc sendout_priority {priority command args} {
 113     global sock out_queue
 114     if {[llength $args]} {
 115         set la [lindex $args end]
 116         set args [lreplace $args end end]
 117         foreach i $args {
 118             if {[regexp {[: ]} $i]} {
 119                 error "bad argument in output $i ($command $args)"
 120             }
 121         }
 122         lappend args :$la
 123     }
 124     set args [lreplace $args 0 -1 $command]
 125     set string [join $args { }]
 126     set now [clock seconds]
 127     set newe [list $now $string]
 128     if {$priority} {
 129         set out_queue [concat [list $newe] $out_queue]
 130     } else {
 131         lappend out_queue $newe
 132     }
 133     if {[llength $out_queue] == 1} {
 134         out_restart
 135     }
 136 }
 137
 138 proc sendout {command args} { eval sendout_priority [list 0 $command] $args }
 139
 140 proc log {data} {
 141     puts $data
 142 }
 143
 144 proc logerror {data} {
 145     log $data
 146 }
 147
 148 proc saveeic {} {
 149     global saveei saveec errorInfo errorCode
 150
 151     set saveei $errorInfo
 152     set saveec $errorCode
 153
 154     puts ">$saveec|$saveei<"
 155 }
 156
 157 proc bgerror {msg} {
 158     global save
 159     logerror $msg
 160     saveeic
 161 }
 162
 163 proc onread {args} {
 164     global sock nick calling_nick errorInfo errorCode line_org_endchar
 165
 166     if {[catch { gets $sock line } rv]} { fail "error on input: $rv" }
 167     if {$rv == -1} { fail "EOF on input" }
 168
 169     set line_org_endchar [string range $line end end]
 170     regsub -all "\[^ -\176\240-\376\]" $line ? line
 171     set org $line
 172
 173     new_event
 174
 175     if {[regexp -nocase {^:([^ ]+) (.*)} $line dummy prefix remain]} {
 176         set line $remain
 177         if {[regexp {^([^!]+)!} $prefix dummy maybenick]} {
 178             set calling_nick $maybenick
 179             if {"[irctolower $maybenick]" == "[irctolower $nick]"} return
 180         }
 181     } else {
 182         set prefix {}
 183     }
 184     if {![string length $line]} { return }
 185     if {![regexp -nocase {^([0-9a-z]+) *(.*)} $line dummy command line]} {
 186         log "bad command: $org"
 187         return
 188     }
 189     set command [string toupper $command]
 190     set params {}
 191     while {[regexp {^([^ :]+) *(.*)} $line dummy thisword line]} {
 192         lappend params $thisword
 193     }
 194     if {[regexp {^:(.*)} $line dummy thisword]} {
 195         lappend params $thisword
 196     } elseif {[string length $line]} {
 197         log "junk at end: $org"
 198         return
 199     }
 200     if {"$command" == "PRIVMSG" && \
 201         [privmsg_unlogged $prefix [ischan [lindex $params 0]] $params]} {
 202         return
 203     }
 204     log "[clock seconds] <- $org"
 205     set procname msg_$command
 206     if {[catch { info body $procname }]} { return }
 207     if {[catch {
 208         eval [list $procname $prefix $command] $params
 209     } emsg]} {
 210         logerror "error: $emsg ($prefix $command $params)"
 211         saveeic
 212     }
 213 }
 214
 215 proc sendprivmsg {dest l} {
 216     foreach v [split $l "\n"] {
 217         sendout [expr {[ischan $dest] ? "PRIVMSG" : "NOTICE"}] $dest $v
 218     }
 219 }
 220 proc sendaction_priority {priority dest what} {
 221     sendout_priority $priority PRIVMSG $dest "\001ACTION $what\001"
 222 }
 223 proc msendprivmsg {dest ll} { foreach l $ll { sendprivmsg $dest $l } }
 224 proc msendprivmsg_delayed {delay dest ll} { after $delay [list msendprivmsg $dest $ll] }
 225
 226 proc check_nick {n} {
 227     if {[regexp -nocase {[^][\\`_^{|}a-z0-9-]} $n]} { error "bad char in nick" }
 228     if {[regexp {^[-0-9]} $n]} { error "bad nick start" }
 229 }
 230
 231 proc ischan {dest} {
 232     return [regexp {^[&#+!]} $dest]
 233 }
 234
 235 proc irctolower {v} {
 236     foreach {from to} [list "\\\[" "{" \
 237                           "\\\]" "}" \
 238                           "\\\\" "|" \
 239                           "~"    "^"] {
 240         regsub -all $from $v $to v
 241     }
 242     return [string tolower $v]
 243 }
 244
 245 proc prefix_none {} {
 246     upvar 1 p p
 247     if {[string length $p]} { error "prefix specified" }
 248 }
 249
 250 proc prefix_nick {} {
 251     global nick
 252     upvar 1 p p
 253     upvar 1 n n
 254     if {![regexp {^([^!]+)!} $p dummy n]} { error "not from nick" }
 255     check_nick $n
 256     if {"[irctolower $n]" == "[irctolower $nick]"} {
 257         error "from myself" {} {}
 258     }
 259 }
 260
 261 proc msg_PING {p c s1} {
 262     prefix_none
 263     sendout PONG $s1
 264 }
 265
 266 proc sendownping {} {
 267     global ownping_every nick
 268     sendout ping $nick
 269     after $ownping_every sendownping
 270 }
 271
 272 proc msg_001 {args} {
 273     global muststartby_after
 274     if {[info exists muststartby_after]} {
 275         after cancel $muststartby_after
 276         unset muststartby_after
 277         sendownping
 278         connected
 279     }
 280 }
 281
 282 proc ensure_outqueue {} {
 283     out__vars
 284     if {[info exists out_queue]} return
 285     set out_creditms 0
 286     set out_creditat [clock seconds]
 287     set out_queue {}
 288     set out_lag_reported 0
 289     set out_lag_reportwhen $out_creditat
 290 }
 291
 292 proc fail {msg} {
 293     logerror "failing: $msg"
 294     exit 1
 295 }
 296
 297 proc ensure_connecting {} {
 298     global sock ownfullname host port nick ident socketargs
 299     global muststartby_ms muststartby_after
 300
 301     ensure_outqueue
 302
 303     if {[info exists sock]} return
 304     set sock [eval socket $socketargs [list $host $port]]
 305     fconfigure $sock -buffering line
 306     fconfigure $sock -translation crlf
 307
 308     sendout USER $ident 0 * $ownfullname
 309     sendout NICK $nick
 310     fileevent $sock readable onread
 311
 312     set muststartby_after [after $muststartby_ms \
 313             {fail "no successfuly connect within timeout"}]
 314 }