chiark - git - mdw - disorder/blob - scripts/make-unidata

   1 #! /usr/bin/perl -w
   2 #
   3 # This file is part of DisOrder.
   4 # Copyright (C) 2007 Richard Kettlewell
   5 #
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 #
  19 #
  20 # Generate Unicode support tables
  21 #
  22 # This script will download data from unicode.org if the required files
  23 # aren't in the current directory.
  24 #
  25 # After modifying this script you should run:
  26 #  make -C lib rebuild-unicode check
  27 #
  28 # Things not supported yet:
  29 #  - SpecialCasing.txt data for case mapping
  30 #  - Title case offsets
  31 #  - Some kind of hinting for composition
  32 #  - ...
  33 #
  34 # NB the generated files DO NOT offer a stable ABI and so are not immediately
  35 # suitable for use in a general-purpose library.  Things that would need to
  36 # be done:
  37 #  - Hide unidata.h from applications; it will never be ABI- or even API-stable.
  38 #  - Stablized General_Category values
  39 #  - Extend the unicode.h API to general utility rather than just what
  40 #    DisOrder needs.
  41 #  - ...
  42 #
  43 use strict;
  44 use File::Basename;
  45
  46 sub out {
  47     print @_ or die "$!\n";
  48 }
  49
  50 sub key {
  51     my $d = shift;
  52     local $_;
  53
  54     return join("-", map($d->{$_}, sort keys %$d));
  55 }
  56
  57 # Size of a subtable
  58 #
  59 # This can be varied to trade off the number of subtables against their size.
  60 # 16 gave the smallest results last time I checked (on a Mac with a 32-bit
  61 # build).
  62 our $modulus = 16;
  63
  64 if(@ARGV) {
  65     $modulus = shift;
  66 }
  67
  68 # Where to break the table.  There is a huge empty section of the Unicode
  69 # code space and we deal with this by simply leaving it out of the table.
  70 # This complicates the lookup function a little but should not affect
  71 # performance in the cases we care about.
  72 our $break_start = 0x30000;
  73 our $break_end = 0xE0000;
  74
  75 # Similarly we simply omit the very top of the table and sort it out in the
  76 # lookup function.
  77 our $break_top = 0xE0200;
  78
  79 my %cats = ();                  # known general categories
  80 my %data = ();                  # mapping of codepoints to information
  81 my $max = 0;                    # maximum codepoint
  82 my $maxccc = 0;                 # maximum combining class
  83 my $maxud = 0;
  84 my $minud = 0;                  # max/min upper case offset
  85 my $maxld = 0;
  86 my $minld = 0;                  # max/min lower case offset
  87
  88 # Make sure we have our desired input files.  We explicitly specify a
  89 # Unicode standard version to make sure that a given version of DisOrder
  90 # supports a given version of Unicode.
  91 sub input {
  92     my $path = shift;
  93     my $lpath = basename($path);
  94     if(!-e $lpath) {
  95         system("wget http://www.unicode.org/Public/5.0.0/ucd/$path");
  96         chmod(0444, $lpath) or die "$lpath: $!\n";
  97     }
  98     open(STDIN, "<$lpath") or die "$lpath: $!\n";
  99     print STDERR "Reading $lpath...\n";
 100 }
 101
 102
 103 # Read the main data file
 104 input("UnicodeData.txt");
 105 my ($start, $end);
 106 my $maxcompat = 0;
 107 my $maxcanon = 0;
 108 my $hangul_syllable_decomps = 0;
 109 my $hangul_choseong_decomps = 0;
 110 while(<>) {
 111     my @f = split(/;/, $_);
 112     my $c = hex($f[0]);         # codepoint
 113     my $name = $f[1];
 114     die "$f[0] $name is in the break\n"
 115         if $c >= $break_start && $c < $break_end;
 116     my $gc = $f[2];             # General_Category
 117     # Variuos GCs we don't expect to see in UnicodeData.txt
 118     $cats{$gc} = 1;             # always record all GCs
 119     if($name =~ /first>/i) {
 120         $start = $c;
 121         next;
 122     } elsif($name =~ /last>/i) {
 123         $end = $c;
 124     } else {
 125         $start = $end = $c;
 126     }
 127     die "unexpected Cn" if $gc eq 'Cn';
 128     my $ccc = $f[3];            # Canonical_Combining_Class
 129     my $dm = $f[5];             # Decomposition_Type + Decomposition_Mapping
 130     my $sum = hex($f[12]) || $c; # Simple_Uppercase_Mapping
 131     my $slm = hex($f[13]) || $c; # Simple_Lowercase_Mapping
 132     # recalculate the upper/lower case mappings as offsets
 133     my $ud = $sum - $c;
 134     my $ld = $slm - $c;
 135     # update bounds on various values
 136     $maxccc = $ccc if $ccc > $maxccc; # assumed never to be -ve
 137     $minud = $ud if $ud < $minud;
 138     $maxud = $ud if $ud > $maxud;
 139     $minld = $ld if $ld < $minld;
 140     $maxld = $ld if $ld > $maxld;
 141     if($start != $end) {
 142         printf STDERR "> range %04X-%04X is %s\n", $start, $end, $gc;
 143     }
 144     for($c = $start; $c <= $end; ++$c) {
 145         my $d = {
 146             "gc" => $gc,
 147             "ccc" => $ccc,
 148             "ud" => $ud,
 149             "ld" => $ld,
 150         };
 151         if($dm ne '') {
 152             my $maxref;
 153             if($dm =~ /</) {
 154                 # This is a compatibility decomposition
 155                 $dm =~ s/^<.*>\s*//;
 156                 $d->{compat} = 1;
 157                 $maxref = \$maxcompat;
 158             } else {
 159                 $maxref = \$maxcanon;
 160             }
 161             $d->{decomp} = [map(hex($_), split(/\s+/, $dm))];
 162             my $len = scalar @{$d->{decomp}};
 163             $$maxref = $len if $len > $$maxref;
 164             if(!$d->{compat}) {
 165                 if(${$d->{decomp}}[0] >= 0xAC00 && ${$d->{decomp}}[0] <= 0xD7A3) {
 166                     ++$hangul_syllable_decomps;
 167                 }
 168                 if(${$d->{decomp}}[0] >= 0x1100 && ${$d->{decomp}}[0] <= 0x115F) {
 169                     ++$hangul_choseong_decomps;
 170                 }
 171             }
 172         }
 173         $data{$c} = $d;
 174     }
 175     $cats{$gc} = 1;
 176     $max = $end if $end > $max;
 177 }
 178
 179 sub read_prop_with_ranges {
 180     my $path = shift;
 181     my $propkey = shift;
 182     input($path);
 183     while(<>) {
 184         chomp;
 185         s/\s*\#.*//;
 186         next if $_ eq '';
 187         my ($range, $propval) = split(/\s*;\s*/, $_);
 188         if($range =~ /(.*)\.\.(.*)/) {
 189             for my $c (hex($1) .. hex($2)) {
 190                 $data{$c}->{$propkey} = $propval;
 191             }
 192         } else {
 193             my $c = hex($range);
 194             $data{$c}->{$propkey} = $propval;
 195         }
 196     }
 197 }
 198
 199 # Grapheme_Break etc
 200 read_prop_with_ranges("auxiliary/GraphemeBreakProperty.txt", "gbreak");
 201 read_prop_with_ranges("auxiliary/WordBreakProperty.txt", "wbreak");
 202 read_prop_with_ranges("auxiliary/SentenceBreakProperty.txt", "sbreak");
 203
 204 # Compute the full list and fill in the Extend category properly
 205 my %gbreak = ();
 206 my %wbreak = ();
 207 my %sbreak = ();
 208 for my $c (keys %data) {
 209     if(!exists $data{$c}->{gbreak}) {
 210         $data{$c}->{gbreak} = 'Other';
 211     }
 212     $gbreak{$data{$c}->{gbreak}} = 1;
 213
 214     if(!exists $data{$c}->{wbreak}) {
 215         if($data{$c}->{gbreak} eq 'Extend') {
 216             $data{$c}->{wbreak} = 'Extend';
 217         } else {
 218             $data{$c}->{wbreak} = 'Other';
 219         }
 220     }
 221     $wbreak{$data{$c}->{wbreak}} = 1;
 222
 223     if(!exists $data{$c}->{sbreak}) {
 224         if($data{$c}->{gbreak} eq 'Extend') {
 225             $data{$c}->{sbreak} = 'Extend';
 226         } else {
 227             $data{$c}->{sbreak} = 'Other';
 228         }
 229     }
 230     $sbreak{$data{$c}->{sbreak}} = 1;
 231 }
 232
 233 # Various derived properties
 234 input("DerivedNormalizationProps.txt");
 235 while(<>) {
 236     chomp;
 237     s/\s*\#.*//;
 238     next if $_ eq '';
 239     my @f = split(/\s*;\s*/, $_);
 240     if(@f == 2) {
 241         push(@f, 1);
 242     }
 243     my ($range, $propkey, $propval) = @f;
 244     if($range =~ /(.*)\.\.(.*)/) {
 245         for my $c (hex($1) .. hex($2)) {
 246             $data{$c}->{$propkey} = $propval
 247         }
 248     } else {
 249         my $c = hex($range);
 250         $data{$c}->{$propkey} = $propval
 251     }
 252 }
 253
 254 # Round up the maximum value to a whole number of subtables
 255 $max += ($modulus - 1) - ($max % $modulus);
 256
 257 # Private use characters
 258 # We only fill in values below $max, utf32__unidata()
 259 my $Co = {
 260     "gc" => "Co",
 261     "ccc" => 0,
 262     "ud" => 0,
 263     "ld" => 0
 264 };
 265 for(my $c = 0xE000; $c <= 0xF8FF && $c <= $max; ++$c) {
 266     $data{$c} = $Co;
 267 }
 268 for(my $c = 0xF0000; $c <= 0xFFFFD && $c <= $max; ++$c) {
 269     $data{$c} = $Co;
 270 }
 271 for(my $c = 0x100000; $c <= 0x10FFFD && $c <= $max; ++$c) {
 272     $data{$c} = $Co;
 273 }
 274
 275 # Anything left is not assigned
 276 my $Cn = {
 277     "gc" => "Cn",               # not assigned
 278     "ccc" => 0,
 279     "ud" => 0,
 280     "ld" => 0
 281 };
 282 for(my $c = 0; $c <= $max; ++$c) {
 283     if(!exists $data{$c}) {
 284         $data{$c} = $Cn;
 285     }
 286     if(!exists $data{$c}->{wbreak}) {
 287         $data{$c}->{wbreak} = 'Other';
 288     }
 289     if(!exists $data{$c}->{gbreak}) {
 290         $data{$c}->{gbreak} = 'Other';
 291     }
 292     if(!exists $data{$c}->{sbreak}) {
 293         $data{$c}->{sbreak} = 'Other';
 294     }
 295 }
 296 $cats{'Cn'} = 1;
 297
 298 # Read the casefolding data too
 299 input("CaseFolding.txt");
 300 while(<>) {
 301     chomp;
 302     next if /^\#/ or $_ eq '';
 303     my @f = split(/\s*;\s*/, $_);
 304     # Full case folding means use status C and F.
 305     # We discard status T, Turkish users may wish to change this.
 306     if($f[1] eq 'C' or $f[1] eq 'F') {
 307         my $c = hex($f[0]);
 308         $data{$c}->{casefold} = $f[2];
 309         # We are particularly interest in combining characters that
 310         # case-fold to non-combining characters, or characters that
 311         # case-fold to sequences with combining characters in non-initial
 312         # positions, as these required decomposiiton before case-folding
 313         my @d = map(hex($_), split(/\s+/, $data{$c}->{casefold}));
 314         if($data{$c}->{ccc} != 0) {
 315             # This is a combining character
 316             if($data{$d[0]}->{ccc} == 0) {
 317                 # The first character of its case-folded form is NOT
 318                 # a combining character.  The field name is the example
 319                 # explicitly mentioned in the spec.
 320                 $data{$c}->{ypogegrammeni} = 1;
 321             }
 322         } else {
 323             # This is a non-combining character; inspect the non-initial
 324             # code points of the case-folded sequence
 325             shift(@d);
 326             if(grep($data{$_}->{ccc} != 0, @d)) {
 327                 # Some non-initial code point in the case-folded for is NOT a
 328                 # a combining character.
 329                 $data{$c}->{ypogegrammeni} = 1;
 330             }
 331         }
 332     }
 333 }
 334
 335 # Generate the header file
 336 print STDERR "Generating unidata.h...\n";
 337 open(STDOUT, ">unidata.h") or die "unidata.h: $!\n";
 338
 339 out("/* Automatically generated file, see scripts/make-unidata */\n",
 340     "#ifndef UNIDATA_H\n",
 341     "#define UNIDATA_H\n");
 342
 343 # TODO choose stable values for General_Category
 344 out("enum unicode_General_Category {\n",
 345     join(",\n",
 346          map("  unicode_General_Category_$_", sort keys %cats)), "\n};\n");
 347
 348 out("enum unicode_Grapheme_Break {\n",
 349     join(",\n",
 350          map("  unicode_Grapheme_Break_$_", sort keys %gbreak)),
 351     "\n};\n");
 352 out("extern const char *const unicode_Grapheme_Break_names[];\n");
 353
 354 out("enum unicode_Word_Break {\n",
 355     join(",\n",
 356          map("  unicode_Word_Break_$_", sort keys %wbreak)),
 357     "\n};\n");
 358 out("extern const char *const unicode_Word_Break_names[];\n");
 359
 360 out("enum unicode_Sentence_Break {\n",
 361     join(",\n",
 362          map("  unicode_Sentence_Break_$_", sort keys %sbreak)),
 363     "\n};\n");
 364 out("extern const char *const unicode_Sentence_Break_names[];\n");
 365
 366 out("enum unicode_flags {\n",
 367     "  unicode_normalize_before_casefold = 1,\n",
 368     "  unicode_compatibility_decomposition = 2\n",
 369     "};\n",
 370     "\n");
 371
 372 # Choose the narrowest type that will fit the required values
 373 sub choosetype {
 374     my ($min, $max) = @_;
 375     if($min >= 0) {
 376         return "char" if $max <= 127;
 377         return "unsigned char" if $max <= 255;
 378         return "int16_t" if $max < 32767;
 379         return "uint16_t" if $max < 65535;
 380         return "int32_t";
 381     } else {
 382         return "char" if $min >= -127 && $max <= 127;
 383         return "int16_t" if $min >= -32767 && $max <= 32767;
 384         return "int32_t";
 385     }
 386 }
 387
 388 out("struct unidata {\n",
 389     # decomposition (canonical or compatibility;
 390     # unicode_compatibility_decomposition distinguishes) or NULL
 391     "  const uint32_t *decomp;\n",
 392
 393     # case-folded string or NULL
 394     "  const uint32_t *casefold;\n",
 395
 396     # composed characters that start with this code point.  This only
 397     # includes primary composites, i.e. the decomposition mapping is
 398     # canonical and this code point is not in the exclusion table.
 399     "  const uint32_t *composed;\n",
 400
 401 #    "  ".choosetype($minud, $maxud)." upper_offset;\n",
 402 #    "  ".choosetype($minld, $maxld)." lower_offset;\n",
 403
 404     # canonical combining class
 405     "  ".choosetype(0, $maxccc)." ccc;\n",
 406     "  char general_category;\n",
 407
 408     # see unicode_flags enum
 409     "  uint8_t flags;\n",
 410     "  char grapheme_break;\n",
 411     "  char word_break;\n",
 412     "  char sentence_break;\n",
 413     "};\n");
 414 # decomp and  casefold do have have non-BMP characters, so we
 415 # can't use a simple 16-bit table.  We could use UTF-8 or UTF-16
 416 # though, saving a bit of space (probably not that much...) at the
 417 # cost of marginally reduced performance and additional complexity
 418
 419 out("extern const struct unidata *const unidata[];\n");
 420
 421 out("extern const struct unicode_utf8_row {\n",
 422     "  uint8_t count;\n",
 423     "  uint8_t min2, max2;\n",
 424     "} unicode_utf8_valid[];\n");
 425
 426 out("#define UNICODE_NCHARS ", ($max + 1), "\n");
 427 out("#define UNICODE_MODULUS $modulus\n");
 428 out("#define UNICODE_BREAK_START $break_start\n");
 429 out("#define UNICODE_BREAK_END $break_end\n");
 430 out("#define UNICODE_BREAK_TOP $break_top\n");
 431
 432 out("#endif\n");
 433
 434 close STDOUT or die "unidata.h: $!\n";
 435
 436 print STDERR "Generating unidata.c...\n";
 437 open(STDOUT, ">unidata.c") or die "unidata.c: $!\n";
 438
 439 out("/* Automatically generated file, see scripts/make-unidata */\n",
 440     "#include \"common.h\"\n",
 441     "#include \"unidata.h\"\n");
 442
 443 # Short aliases to keep .c file small
 444
 445 out(map(sprintf("#define %s unicode_General_Category_%s\n", $_, $_),
 446         sort keys %cats));
 447 out(map(sprintf("#define GB%s unicode_Grapheme_Break_%s\n", $_, $_),
 448         sort keys %gbreak));
 449 out(map(sprintf("#define WB%s unicode_Word_Break_%s\n", $_, $_),
 450         sort keys %wbreak));
 451 out(map(sprintf("#define SB%s unicode_Sentence_Break_%s\n", $_, $_),
 452         sort keys %sbreak));
 453 out("#define NBC unicode_normalize_before_casefold\n");
 454 out("#define CD unicode_compatibility_decomposition\n");
 455
 456 # Names for *_Break properties
 457 out("const char *const unicode_Grapheme_Break_names[] = {\n",
 458     join(",\n",
 459          map("  \"$_\"", sort keys %gbreak)),
 460     "\n};\n");
 461 out("const char *const unicode_Word_Break_names[] = {\n",
 462     join(",\n",
 463          map("  \"$_\"", sort keys %wbreak)),
 464     "\n};\n");
 465 out("const char *const unicode_Sentence_Break_names[] = {\n",
 466     join(",\n",
 467          map("  \"$_\"", sort keys %sbreak)),
 468     "\n};\n");
 469
 470 our $ddnum = 0;
 471 our $ddsaved = 0;
 472 our %ddnums = ();
 473 my $ddfirst = 1;
 474 out("static const uint32_t ");
 475 sub dedupe {
 476     my $s = join(",", @_);
 477     if(!exists $ddnums{$s}) {
 478         if($ddfirst) {
 479             $ddfirst = 0;
 480         } else {
 481             out(",\n");
 482         }
 483         out("dd$ddnum\[]={$s}");
 484         $ddnums{$s} = $ddnum++;
 485     } else {
 486         ++$ddsaved;
 487     }
 488     return "dd$ddnums{$s}";
 489 }
 490
 491 # Generate the decomposition mapping tables.
 492 print STDERR "> decomposition mappings\n";
 493 for(my $c = 0; $c <= $max; ++$c) {
 494     if(exists $data{$c} && exists $data{$c}->{decomp}) {
 495         $data{$c}->{decompsym} = dedupe(@{$data{$c}->{decomp}}, 0);
 496     }
 497 }
 498
 499 print STDERR "> composition mappings\n";
 500 # First we must generate the mapping of each code point to possible
 501 # compositions.
 502 for(my $c = 0; $c <= $max; ++$c) {
 503     if(exists $data{$c}
 504        && exists $data{$c}->{decomp}
 505        && !exists $data{$c}->{compat}
 506        && !$data{$c}->{Full_Composition_Exclusion}) {
 507         # $c has a non-excluded canonical decomposition, i.e. it is
 508         # a primary composite.  Find the first code point of the decomposition
 509         my $first = ${$data{$c}->{decomp}}[0];
 510         if(!exists $data{$first}->{compose}) {
 511             $data{$first}->{compose} = [$c];
 512         } else {
 513             push(@{$data{$first}->{compose}}, $c);
 514         }
 515     }
 516 }
 517 # Then we can generate the tables.
 518 for(my $c = 0; $c <= $max; ++$c) {
 519     if(exists $data{$c} && exists $data{$c}->{compose}) {
 520         $data{$c}->{compsym} = dedupe(@{$data{$c}->{compose}}, 0);
 521     }
 522 }
 523
 524 # The case folding table.
 525 print STDERR "> case-fold mappings\n";
 526 for(my $c = 0; $c <= $max; ++$c) {
 527     if(exists $data{$c} && exists $data{$c}->{casefold}) {
 528         $data{$c}->{cfsym} = dedupe(map(hex($_), split(/\s+/,
 529                                                        $data{$c}->{casefold})),
 530                                     0);
 531     }
 532 }
 533
 534 # End of de-dupable arrays
 535 out(";\n");
 536
 537 # Visit all the $modulus-character blocks in turn and generate the
 538 # required subtables.  As above we spot duplicates to save space.  In
 539 # Unicode 5.0.0 with $modulus=128 and current table data this saves
 540 # 1372 subtables or at least three and a half megabytes on 32-bit
 541 # platforms.
 542 print STDERR "> subtables\n";
 543 my %subtable = ();              # base->subtable number
 544 my %subtableno = ();            # subtable number -> content
 545 my $subtablecounter = 0;        # counter for subtable numbers
 546 my $subtablessaved = 0;         # number of tables saved
 547 for(my $base = 0; $base <= $max; $base += $modulus) {
 548     next if $base >= $break_start && $base < $break_end;
 549     next if $base >= $break_top;
 550     my @t;
 551     for(my $c = $base; $c < $base + $modulus; ++$c) {
 552         my $d = $data{$c};
 553         my $decompsym = ($data{$c}->{decompsym} or "0");
 554         my $cfsym = ($data{$c}->{cfsym} or "0");
 555         my $compsym = ($data{$c}->{compsym} or "0");
 556         my @flags = ();
 557         if($data{$c}->{ypogegrammeni}) {
 558             push(@flags, "NBC");
 559         }
 560         if($data{$c}->{compat}) {
 561             push(@flags, "CD");
 562         }
 563         my $flags = @flags ? join("|", @flags) : 0;
 564         push(@t, "{".
 565              join(",",
 566                   $decompsym,
 567                   $cfsym,
 568                   $compsym,
 569 #                 $d->{ud},
 570 #                 $d->{ld},
 571                   $d->{ccc},
 572                   $d->{gc},
 573                   $flags,
 574                   "GB$d->{gbreak}",
 575                   "WB$d->{wbreak}",
 576                   "SB$d->{sbreak}",
 577              )."}");
 578     }
 579     my $t = join(",\n", @t);
 580     if(!exists $subtable{$t}) {
 581         out(sprintf("/* %04X-%04X */\n", $base, $base + $modulus - 1));
 582         out("static const struct unidata st$subtablecounter\[] = {\n",
 583             "$t\n",
 584             "};\n");
 585         $subtable{$t} = $subtablecounter++;
 586     } else {
 587         ++$subtablessaved;
 588     }
 589     $subtableno{$base} = $subtable{$t};
 590 }
 591
 592 print STDERR "> main table\n";
 593 out("const struct unidata *const unidata[]={\n");
 594 for(my $base = 0; $base <= $max; $base += $modulus) {
 595     next if $base >= $break_start && $base < $break_end;
 596     next if $base >= $break_top;
 597     #out("st$subtableno{$base} /* ".sprintf("%04x", $base)." */,\n");
 598     out("st$subtableno{$base},\n");
 599 }
 600 out("};\n");
 601
 602 print STDERR "> UTF-8 table\n";
 603 out("const struct unicode_utf8_row unicode_utf8_valid[] = {\n");
 604 for(my $c = 0; $c <= 0x7F; ++$c) {
 605     out(" { 1, 0, 0 }, /* $c */\n");
 606 }
 607 for(my $c = 0x80; $c < 0xC2; ++$c) {
 608     out(" { 0, 0, 0 }, /* $c */\n");
 609 }
 610 for(my $c = 0xC2; $c <= 0xDF; ++$c) {
 611     out(" { 2, 0x80, 0xBF }, /* $c */\n");
 612 }
 613 for(my $c = 0xE0; $c <= 0xE0; ++$c) {
 614     out(" { 3, 0xA0, 0xBF }, /* $c */\n");
 615 }
 616 for(my $c = 0xE1; $c <= 0xEC; ++$c) {
 617     out(" { 3, 0x80, 0xBF }, /* $c */\n");
 618 }
 619 for(my $c = 0xED; $c <= 0xED; ++$c) {
 620     out(" { 3, 0x80, 0x9F }, /* $c */\n");
 621 }
 622 for(my $c = 0xEE; $c <= 0xEF; ++$c) {
 623     out(" { 3, 0x80, 0xBF }, /* $c */\n");
 624 }
 625 for(my $c = 0xF0; $c <= 0xF0; ++$c) {
 626     out(" { 4, 0x90, 0xBF }, /* $c */\n");
 627 }
 628 for(my $c = 0xF1; $c <= 0xF3; ++$c) {
 629     out(" { 4, 0x80, 0xBF }, /* $c */\n");
 630 }
 631 for(my $c = 0xF4; $c <= 0xF4; ++$c) {
 632     out(" { 4, 0x80, 0x8F }, /* $c */\n");
 633 }
 634 for(my $c = 0xF5; $c <= 0xFF; ++$c) {
 635     out(" { 0, 0, 0 }, /* $c */\n");
 636 }
 637 out("};\n");
 638
 639 close STDOUT or die "unidata.c: $!\n";
 640
 641 print STDERR "Done.\n\n";
 642 printf STDERR "modulus=%d\n", $modulus;
 643 printf STDERR "max=%04X\n", $max;
 644 print STDERR "subtables=$subtablecounter, subtablessaved=$subtablessaved\n";
 645 print STDERR "ddsaved=$ddsaved\n";
 646 print STDERR "maxcompat=$maxcompat maxcanon=$maxcanon\n";
 647 print STDERR "$hangul_syllable_decomps canonical decompositions to Hangul syllables\n";
 648 print STDERR "$hangul_choseong_decomps canonical decompositions to Hangul Choseong\n";
 649
 650 die "We assumed that canonical decompositions were never more than 2 long!\n"
 651     if $maxcanon > 2;
 652
 653 die "We assumed no canonical decompositions to Hangul syllables/Choseong!\n"
 654     if $hangul_syllable_decomps || $hangul_choseong_decomps;