chiark - git - mdw - disorder/blob - scripts/protocol

   1 #! /usr/bin/perl -w
   2 #
   3 # This file is part of DisOrder.
   4 # Copyright (C) 2010-11 Richard Kettlewell
   5 #
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 #
  19 use strict;
  20
  21 # This file contains the definition of the disorder protocol, plus
  22 # code to generates stubs for it in the various supported languages.
  23 #
  24 # At the time of writing it is a work in progress!
  25
  26 #
  27 # Types:
  28 #
  29 #    string         A (Unicode) string.
  30 #    string-raw     A string that is not subject to de-quoting (return only)
  31 #    integer        An integer.  Decimal on the wire.
  32 #    time           A timestamp.  Decimal on the wire.
  33 #    boolean        True or false.  "yes" or "no" on the wire.
  34 #    list           In commands: a list of strings in the command.
  35 #                   In returns: a list of lines in the response.
  36 #    pair-list      In returns: a list of key-value pairs in a response body.
  37 #    body           In commands: a list of strings as a command body.
  38 #                   In returns: a list of strings as a response body.
  39 #    queue          In returns: a list of queue entries in a response body.
  40 #    queue-one      In returns: a queue entry in the response.
  41 #    literal        Constant string sent in sequence
  42 #
  43
  44 # Variables and utilities -----------------------------------------------------
  45
  46 our @h = ();
  47 our @c = ();
  48
  49 # Write(PATH, LINES)
  50 #
  51 # Write array ref LINES to file PATH.
  52 sub Write {
  53     my $path = shift;
  54     my $lines = shift;
  55
  56     (open(F, ">$path")
  57      and print F @$lines
  58      and close F)
  59         or die "$0: $path: $!\n";
  60 }
  61
  62 # Command classes -------------------------------------------------------------
  63
  64 # c_in_decl([TYPE, NAME])
  65 #
  66 # Return the C declaration for an input parameter of type TYPE with
  67 # name NAME.
  68 sub c_in_decl {
  69     my $arg = shift;
  70
  71     my $type = $arg->[0];
  72     my $name = $arg->[1];
  73     if($type eq 'string') {
  74         return "const char *$name";
  75     } elsif($type eq 'integer') {
  76         return "long $name";
  77     } elsif($type eq 'time') {
  78         return "time_t $name";
  79     } elsif($type eq 'list' or $type eq 'body') {
  80         return ("char **$name",
  81                 "int n$name");
  82     } elsif($type eq 'literal') {
  83         return ();
  84     } else {
  85         die "$0: c_in_decl: unknown type '$type'\n";
  86     }
  87 }
  88
  89 # c_out_decl([TYPE, NAME])
  90 #
  91 # Return the C declaration for an output (reference) parameter of type
  92 # TYPE with name NAME.
  93 sub c_out_decl {
  94     my $arg = shift;
  95
  96     return () unless defined $arg;
  97     my $type = $arg->[0];
  98     my $name = $arg->[1];
  99     if($type eq 'string' or $type eq 'string-raw') {
 100         return ("char **${name}p");
 101     } elsif($type eq 'integer') {
 102         return ("long *${name}p");
 103     } elsif($type eq 'time') {
 104         return ("time_t *${name}p");
 105     } elsif($type eq 'boolean') {
 106         return ("int *${name}p");
 107     } elsif($type eq 'list' or $type eq 'body') {
 108         return ("char ***${name}p",
 109                 "int *n${name}p");
 110     } elsif($type eq 'pair-list') {
 111         return ("struct kvp **${name}p");
 112     } elsif($type eq 'queue' or $type eq 'queue-one') {
 113         return ("struct queue_entry **${name}p");
 114     } elsif($type eq 'user') {
 115         return ();
 116     } else {
 117         die "$0: c_out_decl: unknown type '$type'\n";
 118     }
 119 }
 120
 121 # c_param_docs([TYPE, NAME})
 122 #
 123 # Return the doc string for a C input parameter.
 124 sub c_param_docs {
 125     my $args = shift;
 126     my @d = ();
 127     for my $arg (@$args) {
 128         my $type = $arg->[0];
 129         my $name = $arg->[1];
 130         my $description = $arg->[2];
 131         if($type eq 'body' or $type eq 'list') {
 132             push(@d,
 133                  " * \@param $name $description\n",
 134                  " * \@param n$name Length of $name\n");
 135         } elsif($type ne 'literal') {
 136             push(@d, " * \@param $name $description\n");
 137         }
 138     }
 139     return @d;
 140 }
 141
 142 # c_param_docs([TYPE, NAME})
 143 #
 144 # Return the doc string for a C output parameter.
 145 sub c_return_docs {
 146     my $returns = shift;
 147     return () unless defined $returns;
 148     for my $return (@$returns) {
 149         my $type = $return->[0];
 150         my $name = $return->[1];
 151         my $descr = $return->[2];
 152         if($type eq 'string'
 153            or $type eq 'string-raw'
 154            or $type eq 'integer'
 155            or $type eq 'time'
 156            or $type eq 'boolean') {
 157             return (" * \@param ${name}p $descr\n");
 158         } elsif($type eq 'list' or $type eq 'body') {
 159             return (" * \@param ${name}p $descr\n",
 160                     " * \@param n${name}p Number of elements in ${name}p\n");
 161         } elsif($type eq 'pair-list') {
 162             return (" * \@param ${name}p $descr\n");
 163         } elsif($type eq 'queue' or $type eq 'queue-one') {
 164             return (" * \@param ${name}p $descr\n");
 165         } elsif($type eq 'user') {
 166             return ();
 167         } else {
 168             die "$0: c_return_docs: unknown type '$type'\n";
 169         }
 170     }
 171 }
 172
 173 # simple(CMD, SUMMARY, DETAIL,
 174 #        [[TYPE,NAME,DESCR], [TYPE,NAME,DESCR], ...],
 175 #        [[RETURN-TYPE, RETURN-NAME, RETURN_DESCR]])
 176 #
 177 # CMD is normally just the name of the command, but can
 178 # be [COMMAND,FUNCTION] if the function name should differ
 179 # from the protocol command.
 180 sub simple {
 181     my $cmd = shift;
 182     my $summary = shift;
 183     my $detail = shift;
 184     my $args = shift;
 185     my $returns = shift;
 186
 187     my $cmdc;
 188     if(ref $cmd eq 'ARRAY') {
 189         $cmdc = $$cmd[1];
 190         $cmd = $$cmd[0];
 191     } else {
 192         $cmdc = $cmd;
 193         $cmdc =~ s/-/_/g;
 194     }
 195     print STDERR "Processing $cmd... ";
 196     # Synchronous C API
 197     print STDERR "H ";
 198     push(@h, "/** \@brief $summary\n",
 199          " *\n",
 200          " * $detail\n",
 201          " *\n",
 202          " * \@param c Client\n",
 203          c_param_docs($args),
 204          c_return_docs($returns),
 205          " * \@return 0 on success, non-0 on error\n",
 206          " */\n",
 207          "int disorder_$cmdc(",
 208          join(", ", "disorder_client *c",
 209                     map(c_in_decl($_), @$args),
 210                     map(c_out_decl($_), @$returns)),
 211          ");\n\n");
 212     print STDERR "C ";
 213     push(@c, "int disorder_$cmdc(",
 214          join(", ", "disorder_client *c",
 215                     map(c_in_decl($_), @$args),
 216                     map(c_out_decl($_), @$returns)),
 217          ") {\n");
 218     my @cargs = ();
 219     for my $arg (@$args) {
 220         if($arg->[0] eq 'body' or $arg->[0] eq 'list') {
 221             push(@cargs, "disorder_$arg->[0]", $arg->[1], "n$arg->[1]");
 222         } elsif($arg->[0] eq 'string') {
 223             push(@cargs, $arg->[1]);
 224         } elsif($arg->[0] eq 'integer') {
 225             push(@cargs, "buf_$arg->[1]");
 226             push(@c, "  char buf_$arg->[1]\[16];\n",
 227                  "  byte_snprintf(buf_$arg->[1], sizeof buf_$arg->[1], \"%ld\", $arg->[1]);\n");
 228         } elsif($arg->[0] eq 'time') {
 229             push(@cargs, "buf_$arg->[1]");
 230             push(@c, "  char buf_$arg->[1]\[16];\n",
 231                  "  byte_snprintf(buf_$arg->[1], sizeof buf_$arg->[1], \"%lld\", (long long)$arg->[1]);\n");
 232         } elsif($arg->[0] eq 'literal') {
 233             push(@cargs, "\"$arg->[1]\"");
 234         } else {
 235             die "$0: unsupported arg type '$arg->[0]' for '$cmd'\n";
 236         }
 237     }
 238     if(!defined $returns or scalar @$returns == 0) {
 239         # Simple case
 240         push(@c, "  return disorder_simple(",
 241              join(", ", "c", "NULL", "\"$cmd\"", @cargs, "(char *)NULL"),
 242              ");\n");
 243     } elsif(scalar @$returns == 1
 244             and $returns->[0]->[0] eq 'queue-one') {
 245         # Special case
 246         my $return = $$returns[0];
 247         push(@c, "  return onequeue(c, \"$cmd\", $return->[1]p);\n");
 248     } elsif(scalar @$returns == 1
 249             and $returns->[0]->[0] eq 'string-raw') {
 250         # Special case
 251         my $return = $$returns[0];
 252         push(@c, "  return disorder_simple(",
 253              join(", ", "c", "$return->[1]p", "\"$cmd\"", @cargs, "(char *)NULL"),
 254              ");\n");
 255     } elsif(scalar @$returns == 1
 256             and $returns->[0]->[0] eq 'pair-list') {
 257         # Special case
 258         my $return = $$returns[0];
 259         push(@c, "  return pairlist(",
 260              join(", ", "c", "$return->[1]p", "\"$cmd\"",
 261                   @cargs,
 262                   "(char *)NULL"),
 263              ");\n");
 264     } else {
 265         my $expected = 0;
 266         for(my $n = 0; $n < scalar @$returns; ++$n) {
 267             my $return = $returns->[$n];
 268             my $type = $return->[0];
 269             my $name = $return->[1];
 270             if($type eq 'string'
 271                or $type eq 'boolean'
 272                or $type eq 'integer'
 273                or $type eq 'time'
 274                or $type eq 'user') {
 275                 ++$expected;
 276             }
 277         }
 278         if($expected) {
 279             push(@c, "  char **v;\n",
 280                  "  int nv, rc = disorder_simple_split(",
 281                  join(", ",
 282                       "c",
 283                       "&v",
 284                       "&nv",
 285                       $expected,
 286                       "\"$cmd\"",
 287                       @cargs,
 288                       "(char *)NULL"),
 289                  ");\n",
 290                  "  if(rc)\n",
 291                  "    return rc;\n");
 292         } else {
 293             push(@c,
 294                  "  int rc = disorder_simple(",
 295                  join(", ",
 296                       "c",
 297                       "NULL",
 298                       "\"$cmd\"",
 299                       @cargs,
 300                       "(char *)NULL"),
 301                  ");\n",
 302                  "  if(rc)\n",
 303                  "    return rc;\n");
 304         }
 305         for(my $n = 0; $n < scalar @$returns; ++$n) {
 306             my $return = $returns->[$n];
 307             my $type = $return->[0];
 308             my $name = $return->[1];
 309             if($type eq 'string') {
 310                 push(@c,
 311                      "  *${name}p = v[$n];\n");
 312             } elsif($type eq 'boolean') {
 313                 push(@c,
 314                      "  if(boolean(\"$cmd\", v[$n], ${name}p))\n",
 315                      "    return -1;\n");
 316             } elsif($type eq 'integer') {
 317                 push(@c,
 318                      "  *${name}p = atol(v[$n]);\n");
 319             } elsif($type eq 'time') {
 320                 push(@c,
 321                      "  *${name}p = atoll(v[$n]);\n");
 322             } elsif($type eq 'user') {
 323                 push(@c,
 324                      "  c->user = v[$n];\n");
 325             } elsif($type eq 'body') {
 326                 push(@c,
 327                      "  if(readlist(c, ${name}p, n${name}p))\n",
 328                      "    return -1;\n");
 329             } elsif($type eq 'queue') {
 330                 push(@c,
 331                      "  if(readqueue(c, ${name}p))\n",
 332                      "    return -1;\n");
 333             } else {
 334                 die "$0: C API: unknown return type '$type' for '$name'\n";
 335             }
 336         }
 337         push(@c, "  return 0;\n");
 338         # TODO xfree unconsumed split output
 339     }
 340     push(@c, "}\n\n");
 341
 342     # Asynchronous C API
 343     # TODO
 344
 345     # Python API
 346     # TODO
 347
 348     # Java API
 349     # TODO
 350     print STDERR "\n";
 351 }
 352
 353 # TODO other command classes
 354
 355 # Front matter ----------------------------------------------------------------
 356
 357 our @generated = ("/*\n",
 358                   " * Automatically generated file, see scripts/protocol\n",
 359                   " *\n",
 360                   " * DO NOT EDIT.\n",
 361                   " */\n");
 362
 363 our @gpl = ("/*\n",
 364             " * This file is part of DisOrder.\n",
 365             " * Copyright (C) 2010-11 Richard Kettlewell\n",
 366             " *\n",
 367             " * This program is free software: you can redistribute it and/or modify\n",
 368             " * it under the terms of the GNU General Public License as published by\n",
 369             " * the Free Software Foundation, either version 3 of the License, or\n",
 370             " * (at your option) any later version.\n",
 371             " *\n",
 372             " * This program is distributed in the hope that it will be useful,\n",
 373             " * but WITHOUT ANY WARRANTY; without even the implied warranty of\n",
 374             " * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the\n",
 375             " * GNU General Public License for more details.\n",
 376             " *\n",
 377             " * You should have received a copy of the GNU General Public License\n",
 378             " * along with this program.  If not, see <http://www.gnu.org/licenses/>.\n",
 379             " */\n");
 380
 381
 382 push(@h, @generated, @gpl,
 383      "#ifndef CLIENT_STUBS_H\n",
 384      "#define CLIENT_STUBS_H\n",
 385      "\n");
 386
 387 push(@c, @generated, @gpl,
 388      "\n");
 389
 390 # The protocol ----------------------------------------------------------------
 391
 392 simple("adopt",
 393        "Adopt a track",
 394        "Makes the calling user owner of a randomly picked track.",
 395        [["string", "id", "Track ID"]]);
 396
 397 simple("adduser",
 398        "Create a user",
 399        "Create a new user.  Requires the 'admin' right.  Email addresses etc must be filled in in separate commands.",
 400        [["string", "user", "New username"],
 401         ["string", "password", "Initial password"],
 402         ["string", "rights", "Initial rights (optional)"]]);
 403
 404 simple("allfiles",
 405        "List files and directories in a directory",
 406        "See 'files' and 'dirs' for more specific lists.",
 407        [["string", "dir", "Directory to list (optional)"],
 408         ["string", "re", "Regexp that results must match (optional)"]],
 409        [["body", "files", "List of matching files and directories"]]);
 410
 411 simple("confirm",
 412        "Confirm registration",
 413        "The confirmation string must have been created with 'register'.  The username is returned so the caller knows who they are.",
 414        [["string", "confirmation", "Confirmation string"]],
 415        [["user"]]);
 416
 417 simple("cookie",
 418        "Log in with a cookie",
 419        "The cookie must have been created with 'make-cookie'.  The username is returned so the caller knows who they are.",
 420        [["string", "cookie", "Cookie string"]],
 421        [["user"]]);
 422
 423 simple("deluser",
 424        "Delete user",
 425        "Requires the 'admin' right.",
 426        [["string", "user", "User to delete"]]);
 427
 428 simple("dirs",
 429        "List directories in a directory",
 430        "",
 431        [["string", "dir", "Directory to list (optional)"],
 432         ["string", "re", "Regexp that results must match (optional)"]],
 433        [["body", "files", "List of matching directories"]]);
 434
 435 simple("disable",
 436        "Disable play",
 437        "Play will stop at the end of the current track, if one is playing.  Requires the 'global prefs' right.",
 438        []);
 439
 440 simple("edituser",
 441        "Set a user property",
 442        "With the 'admin' right you can do anything.  Otherwise you need the 'userinfo' right and can only set 'email' and 'password'.",
 443        [["string", "username", "User to modify"],
 444         ["string", "property", "Property name"],
 445         ["string", "value", "New property value"]]);
 446
 447 simple("enable",
 448        "Enable play",
 449        "Requires the 'global prefs' right.",
 450        []);
 451
 452 simple("enabled",
 453        "Detect whether play is enabled",
 454        "",
 455        [],
 456        [["boolean", "enabled", "1 if play is enabled and 0 otherwise"]]);
 457
 458 simple("exists",
 459        "Test whether a track exists",
 460        "",
 461        [["string", "track", "Track name"]],
 462        [["boolean", "exists", "1 if the track exists and 0 otherwise"]]);
 463
 464 simple("files",
 465        "List files in a directory",
 466        "",
 467        [["string", "dir", "Directory to list (optional)"],
 468         ["string", "re", "Regexp that results must match (optional)"]],
 469        [["body", "files", "List of matching files"]]);
 470
 471 simple("get",
 472        "Get a track preference",
 473        "If the track does not exist that is an error.  If the track exists but the preference does not then a null value is returned.",
 474        [["string", "track", "Track name"],
 475         ["string", "pref", "Preference name"]],
 476        [["string", "value", "Preference value"]]);
 477
 478 simple("get-global",
 479        "Get a global preference",
 480        "If the preference does exist not then a null value is returned.",
 481        [["string", "pref", "Global preference name"]],
 482        [["string", "value", "Preference value"]]);
 483
 484 simple("length",
 485        "Get a track's length",
 486        "If the track does not exist an error is returned.",
 487        [["string", "track", "Track name"]],
 488        [["integer", "length", "Track length in seconds"]]);
 489
 490 # TODO log
 491
 492 simple("make-cookie",
 493        "Create a login cookie for this user",
 494        "The cookie may be redeemed via the 'cookie' command",
 495        [],
 496        [["string", "cookie", "Newly created cookie"]]);
 497
 498 simple("move",
 499        "Move a track",
 500        "Requires one of the 'move mine', 'move random' or 'move any' rights depending on how the track came to be added to the queue.",
 501        [["string", "track", "Track ID or name"],
 502         ["integer", "delta", "How far to move the track towards the head of the queue"]]);
 503
 504 simple("moveafter",
 505        "Move multiple tracks",
 506        "Requires one of the 'move mine', 'move random' or 'move any' rights depending on how the track came to be added to the queue.",
 507        [["string", "target", "Move after this track, or to head if \"\""],
 508         ["list", "ids", "List of tracks to move by ID"]]);
 509
 510 simple(["new", "new_tracks"],
 511        "List recently added tracks",
 512        "",
 513        [["integer", "max", "Maximum tracks to fetch, or 0 for all available"]],
 514        [["body", "tracks", "Recently added tracks"]]);
 515
 516 simple("nop",
 517        "Do nothing",
 518        "Used as a keepalive.  No authentication required.",
 519        []);
 520
 521 simple("part",
 522        "Get a track name part",
 523        "If the name part cannot be constructed an empty string is returned.",
 524        [["string", "track", "Track name"],
 525         ["string", "context", "Context (\"sort\" or \"display\")"],
 526         ["string", "part", "Name part (\"artist\", \"album\" or \"title\")"]],
 527        [["string", "part", "Value of name part"]]);
 528
 529 simple("pause",
 530        "Pause the currently playing track",
 531        "Requires the 'pause' right.",
 532        []);
 533
 534 simple("play",
 535        "Play a track",
 536        "Requires the 'play' right.",
 537        [["string", "track", "Track to play"]],
 538        [["string-raw", "id", "Queue ID of new track"]]);
 539
 540 simple("playafter",
 541        "Play multiple tracks",
 542        "Requires the 'play' right.",
 543        [["string", "target", "Insert into queue after this track, or at head if \"\""],
 544         ["list", "tracks", "List of track names to play"]]);
 545
 546 simple("playing",
 547        "Retrieve the playing track",
 548        "",
 549        [],
 550        [["queue-one", "playing", "Details of the playing track"]]);
 551
 552 simple("playlist-delete",
 553        "Delete a playlist",
 554        "Requires the 'play' right and permission to modify the playlist.",
 555        [["string", "playlist", "Playlist to delete"]]);
 556
 557 simple("playlist-get",
 558        "List the contents of a playlist",
 559        "Requires the 'read' right and oermission to read the playlist.",
 560        [["string", "playlist", "Playlist name"]],
 561        [["body", "tracks", "List of tracks in playlist"]]);
 562
 563 simple("playlist-get-share",
 564        "Get a playlist's sharing status",
 565        "Requires the 'read' right and permission to read the playlist.",
 566        [["string", "playlist", "Playlist to read"]],
 567        [["string-raw", "share", "Sharing status (\"public\", \"private\" or \"shared\")"]]);
 568
 569 simple("playlist-lock",
 570        "Lock a playlist",
 571        "Requires the 'play' right and permission to modify the playlist.  A given connection may lock at most one playlist.",
 572        [["string", "playlist", "Playlist to delete"]]);
 573
 574 simple("playlist-set",
 575        "Set the contents of a playlist",
 576        "Requires the 'play' right and permission to modify the playlist, which must be locked.",
 577        [["string", "playlist", "Playlist to modify"],
 578         ["body", "tracks", "New list of tracks for playlist"]]);
 579
 580 simple("playlist-set-share",
 581        "Set a playlist's sharing status",
 582        "Requires the 'play' right and permission to modify the playlist.",
 583        [["string", "playlist", "Playlist to modify"],
 584         ["string", "share", "New sharing status (\"public\", \"private\" or \"shared\")"]]);
 585
 586 simple("playlist-unlock",
 587        "Unlock the locked playlist playlist",
 588        "The playlist to unlock is implicit in the connection.",
 589        []);
 590
 591 simple("playlists",
 592        "List playlists",
 593        "Requires the 'read' right.  Only playlists that you have permission to read are returned.",
 594        [],
 595        [["body", "playlists", "Playlist names"]]);
 596
 597 simple("prefs",
 598        "Get all the preferences for a track",
 599        "",
 600        [["string", "track", "Track name"]],
 601        [["pair-list", "prefs", "Track preferences"]]);
 602
 603 simple("queue",
 604        "List the queue",
 605        "",
 606        [],
 607        [["queue", "queue", "Current queue contents"]]);
 608
 609 simple("random-disable",
 610        "Disable random play",
 611        "Requires the 'global prefs' right.",
 612        []);
 613
 614 simple("random-enable",
 615        "Enable random play",
 616        "Requires the 'global prefs' right.",
 617        []);
 618
 619 simple("random-enabled",
 620        "Detect whether random play is enabled",
 621        "Random play counts as enabled even if play is disabled.",
 622        [],
 623        [["boolean", "enabled", "1 if random play is enabled and 0 otherwise"]]);
 624
 625 simple("recent",
 626        "List recently played tracks",
 627        "",
 628        [],
 629        [["queue", "recent", "Recently played tracks"]]);
 630
 631 simple("reconfigure",
 632        "Re-read configuraiton file.",
 633        "Requires the 'admin' right.",
 634        []);
 635
 636 simple("register",
 637        "Register a new user",
 638        "Requires the 'register' right which is usually only available to the 'guest' user.  Redeem the confirmation string via 'confirm' to complete registration.",
 639        [["string", "username", "Requested new username"],
 640         ["string", "password", "Requested initial password"],
 641         ["string", "email", "New user's email address"]],
 642        [["string", "confirmation", "Confirmation string"]]);
 643
 644 simple("reminder",
 645        "Send a password reminder.",
 646        "If the user has no valid email address, or no password, or a reminder has been sent too recently, then no reminder will be sent.",
 647        [["string", "username", "User to remind"]]);
 648
 649 simple("remove",
 650        "Remove a track form the queue.",
 651        "Requires one of the 'remove mine', 'remove random' or 'remove any' rights depending on how the track came to be added to the queue.",
 652        [["string", "id", "Track ID"]]);
 653
 654 simple("rescan",
 655        "Rescan all collections for new or obsolete tracks.",
 656        "Requires the 'rescan' right.",
 657        []);     # TODO wait/fresh flags
 658
 659 simple("resolve",
 660        "Resolve a track name",
 661        "Converts aliases to non-alias track names",
 662        [["string", "track", "Track name (might be an alias)"]],
 663        [["string", "resolved", "Resolve track name (definitely not an alias)"]]);
 664
 665 simple("resume",
 666        "Resume the currently playing track",
 667        "Requires the 'pause' right.",
 668        []);
 669
 670 simple("revoke",
 671        "Revoke a cookie.",
 672        "It will not subsequently be possible to log in with the cookie.",
 673        []);
 674
 675 simple("rtp-address",
 676        "Get the server's RTP address information",
 677        "",
 678        [],
 679        [["string", "address", "Where to store hostname or address"],
 680         ["string", "port", "Where to store service name or port number"]]);
 681
 682 simple("scratch",
 683        "Terminate the playing track.",
 684        "Requires one of the 'scratch mine', 'scratch random' or 'scratch any' rights depending on how the track came to be added to the queue.",
 685        [["string", "id", "Track ID (optional)"]]);
 686
 687 simple(["schedule-add", "schedule_add_play"],
 688        "Schedule a track to play in the future",
 689        "",
 690        [["time", "when", "When to play the track"],
 691         ["string", "priority", "Event priority (\"normal\" or \"junk\")"],
 692         ["literal", "play", ""],
 693         ["string", "track", "Track to play"]]);
 694
 695 simple(["schedule-add", "schedule_add_set_global"],
 696        "Schedule a global setting to be changed in the future",
 697        "",
 698        [["time", "when", "When to change the setting"],
 699         ["string", "priority", "Event priority (\"normal\" or \"junk\")"],
 700         ["literal", "set-global", ""],
 701         ["string", "pref", "Global preference to set"],
 702         ["string", "value", "New value of global preference"]]);
 703
 704 simple(["schedule-add", "schedule_add_unset_global"],
 705        "Schedule a global setting to be unset in the future",
 706        "",
 707        [["time", "when", "When to change the setting"],
 708         ["string", "priority", "Event priority (\"normal\" or \"junk\")"],
 709         ["literal", "set-global", ""],
 710         ["string", "pref", "Global preference to set"]]);
 711
 712 simple("schedule-del",
 713        "Delete a scheduled event.",
 714        "Users can always delete their own scheduled events; with the admin right you can delete any event.",
 715        [["string", "event", "ID of event to delete"]]);
 716
 717 simple("schedule-get",
 718        "Get the details of scheduled event",
 719        "",
 720        [["string", "id", "Event ID"]],
 721        [["pair-list", "actiondata", "Details of event"]]);
 722
 723 simple("schedule-list",
 724        "List scheduled events",
 725        "This just lists IDs.  Use 'schedule-get' to retrieve more detail",
 726        [],
 727        [["body", "ids", "List of event IDs"]]);
 728
 729 simple("search",
 730        "Search for tracks",
 731        "Terms are either keywords or tags formatted as 'tag:TAG-NAME'.",
 732        [["string", "terms", "List of search terms"]],
 733        [["body", "tracks", "List of matching tracks"]]);
 734
 735 simple("set",
 736        "Set a track preference",
 737        "Requires the 'prefs' right.",
 738        [["string", "track", "Track name"],
 739         ["string", "pref", "Preference name"],
 740         ["string", "value", "New value"]]);
 741
 742 simple("set-global",
 743        "Set a global preference",
 744        "Requires the 'global prefs' right.",
 745        [["string", "pref", "Preference name"],
 746         ["string", "value", "New value"]]);
 747
 748 simple("shutdown",
 749        "Request server shutdown",
 750        "Requires the 'admin' right.",
 751        []);
 752
 753 simple("stats",
 754        "Get server statistics",
 755        "The details of what the server reports are not really defined.  The returned strings are intended to be printed out one to a line.",
 756        [],
 757        [["body", "stats", "List of server information strings."]]);
 758
 759 simple("tags",
 760        "Get a list of known tags",
 761        "Only tags which apply to at least one track are returned.",
 762        [],
 763        [["body", "tags", "List of tags"]]);
 764
 765 simple("unset",
 766        "Unset a track preference",
 767        "Requires the 'prefs' right.",
 768        [["string", "track", "Track name"],
 769         ["string", "pref", "Preference name"]]);
 770
 771 simple("unset-global",
 772        "Set a global preference",
 773        "Requires the 'global prefs' right.",
 774        [["string", "pref", "Preference name"]]);
 775
 776 # 'user' only used for authentication
 777
 778 simple("userinfo",
 779        "Get a user property.",
 780        "If the user does not exist an error is returned, if the user exists but the property does not then a null value is returned.",
 781        [["string", "username", "User to read"],
 782         ["string", "property", "Property to read"]],
 783        [["string", "value", "Value of property"]]);
 784
 785 simple("users",
 786        "Get a list of users",
 787        "",
 788        [],
 789        [["body", "users", "List of users"]]);
 790
 791 simple("version",
 792        "Get the server version",
 793        "",
 794        [],
 795        [["string", "version", "Server version string"]]);
 796
 797 simple(["volume", "set_volume"],
 798        "Set the volume",
 799        "",
 800        [["integer", "left", "Left channel volume"],
 801         ["integer", "right", "Right channel volume"]]);
 802
 803 simple(["volume", "get_volume"],
 804        "Get the volume",
 805        "",
 806        [],
 807        [["integer", "left", "Left channel volume"],
 808         ["integer", "right", "Right channel volume"]]);
 809
 810 # End matter ------------------------------------------------------------------
 811
 812 push(@h, "#endif\n");
 813
 814 # Write it all out ------------------------------------------------------------
 815
 816 Write("lib/client-stubs.h", \@h);
 817 Write("lib/client-stubs.c", \@c);