chiark - git - mdw - disorder/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #
   3 # This file is part of DisOrder.
   4 # Copyright (C) 2004-2014 Richard Kettlewell
   5 # Portions copyright (C) 2007 Ross Younger
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20
  21 AC_INIT([disorder], [5.1.1], [richard+disorder@sfere.greenend.org.uk])
  22 AC_CONFIG_AUX_DIR([config.aux])
  23 AM_INIT_AUTOMAKE([foreign])
  24 AC_CONFIG_SRCDIR([server/disorderd.c])
  25 AM_CONFIG_HEADER([config.h])
  26 AC_CONFIG_MACRO_DIR([m4])
  27
  28 # Find host type
  29 AC_CANONICAL_HOST
  30
  31 # What we want to build
  32 want_gtk=yes
  33 want_python=yes
  34 want_tests=yes
  35 want_server=yes
  36 want_cgi=yes
  37
  38 # APIs we want
  39 want_alsa=yes
  40 want_oss=yes
  41 want_coreaudio=yes
  42 want_pulseaudio=yes
  43
  44 # By default we don't want gtk-osx.  But if you ask for --with-gtk-osx...
  45 #
  46 # Disobedience can be built to a native OS X application.  There are some
  47 # caveats:
  48 #  - you will still need Fink (or something) for other libraries
  49 #  - if you wanted an application bundle you are out of luck
  50 #  - the menu bar is still in the main window (not at the top of the screen)
  51 #  - drag and drop doesn't work
  52 #
  53 # So it's still rather rough and ready.  But it does work...
  54 #
  55 # See:
  56 #   http://www.gtk-osx.org/
  57 #   http://live.gnome.org/GTK%2B/OSX/Framework
  58 want_gtkosx=no
  59
  60 # Checks for programs.
  61 AC_PROG_CC
  62 AM_PROG_CC_C_O
  63 AC_PROG_AWK
  64 AC_SET_MAKE
  65 if test "x$GCC" = xyes; then
  66   gcc_werror=-Werror
  67   case "$CC" in
  68   *-std=* )
  69     ;;
  70   * )
  71     CC="${CC} -std=gnu99"
  72     ;;
  73   esac
  74 else
  75   AC_MSG_ERROR([GNU C is required to build this program])
  76   gcc_werror=""
  77 fi
  78
  79 AC_ARG_WITH([alsa],
  80             [AS_HELP_STRING([--without-alsa],
  81                             [do not build with ALSA support])],
  82             [want_alsa=$withval])
  83 AC_ARG_WITH([pulseaudio],
  84             [AS_HELP_STRING([--without-pulseaudio],
  85                             [do not build with PulseAudio support])],
  86             [want_pulseaudio=$withval])
  87 AC_ARG_WITH([oss],
  88             [AS_HELP_STRING([--without-oss],
  89                             [do not build with OSS support])],
  90             [want_oss=$withval])
  91 AC_ARG_WITH([coreaudio],
  92             [AS_HELP_STRING([--without-coreaudio],
  93                             [do not build with Core Audio support])],
  94             [want_coreaudio=$withval])
  95 AC_ARG_WITH([tests],
  96             [AS_HELP_STRING([--without-tests],
  97                             [do not build test suit])],
  98             [want_tests=$withval])
  99 AC_ARG_WITH([gtk-osx],
 100             [AS_HELP_STRING([--with-gtk-osx],
 101                             [use native GTK+ (OS X only)])],
 102             [want_gtkosx=$withval])
 103
 104 AC_MSG_CHECKING([for a known target platform])
 105 case "$host" in
 106 *empeg* )
 107   AC_MSG_RESULT([empeg car stereo])
 108   AC_DEFINE([EMPEG_HOST],[1],[define if host is an empeg car stereo])
 109   # work around broken toolchain
 110   AC_CHECK_LIB([gpg-error], [gpg_strerror])
 111   AC_CHECK_LIB([pthread], [pthread_create])
 112   want_server=no
 113   want_cgi=no
 114  ;;
 115 *linux* | *Linux* )
 116   AC_MSG_RESULT([Linux])
 117   AC_DEFINE_UNQUOTED([PATH_PROC_MOUNTS],["/proc/mounts"],[path to kernel mount list])
 118   ;;
 119 *-apple-darwin* )
 120   AC_MSG_RESULT([Mac OS X])
 121   # AudioHardwareGetProperty is deprecated in 10.6, but it's still _there_,
 122   # so we'll just turn off the warning.
 123   CC="$CC -Wno-deprecated-declarations"
 124   if test $want_coreaudio = yes; then
 125     COREAUDIO="-framework CoreFoundation -framework CoreServices -framework CoreAudio"
 126   fi
 127   browser=open
 128   AC_MSG_CHECKING([Mac OS X target version])
 129   # We honor MACOSX_DEPLOYMENT_TARGET in the environment, emulating gcc's
 130   # behaviour.  But we provide a command line option to override it and
 131   # we default to wide support instead of supporting only the build platform.
 132   #
 133   # Currently if you ask for 10.5 you will get a deprecation warning
 134   # when building the CoreAudio support code.  For the time being the
 135   # answer to this is "don't do that then".  If a good reason to ask
 136   # for a 10.5 deployment target emerges then this will be fixed.
 137   if test -z "$MACOSX_DEPLOYMENT_TARGET"; then
 138     MACOSX_DEPLOYMENT_TARGET=10.0
 139   fi
 140   AC_ARG_WITH([deployment-target],
 141               [AS_HELP_STRING([--with-deployment-target=TARGET],
 142                               [set target OS X version])],
 143               [MACOSX_DEPLOYMENT_TARGET=$withval])
 144   # Convert to desired format
 145   underscored=`echo $MACOSX_DEPLOYMENT_TARGET|sed 's/\./_/'`
 146   minver="MAC_OS_X_VERSION_$underscored"
 147   AC_MSG_RESULT([$minver])
 148   AC_DEFINE_UNQUOTED([MAC_OS_X_VERSION_MIN_REQUIRED], [$minver],
 149                      [define to minimum version of Mac OS X to support])
 150
 151   if test $want_gtkosx = no; then
 152     # Fink's GTK+ is hopelessly broken
 153     PKG_CONFIG_PATH=${PKG_CONFIG_PATH:-/sw/lib/pango-ft219/lib/pkgconfig}
 154     export PKG_CONFIG_PATH
 155   fi
 156
 157   ;;
 158 *-freebsd* )
 159   AC_MSG_RESULT([FreeBSD])
 160   # Ports install to /usr/local but the compiler stupidly doesn't look
 161   # there by default
 162   LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 163   CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include"
 164   # Look for a suitable version of libdb among the versions found in FreeBSD 7.0
 165   AC_CACHE_CHECK([looking for a libdb install],[rjk_cv_libdb],[
 166     rjk_cv_libdb="none"
 167     for db in db43 db44 db45 db47 db48; do
 168       if test -e /usr/local/lib/$db; then
 169         rjk_cv_libdb=$db
 170         break
 171       fi
 172     done
 173   ])
 174   if test $rjk_cv_libdb != none; then
 175     LDFLAGS="${LDFLAGS} -L/usr/local/lib/$rjk_cv_libdb"
 176     CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include/$rjk_cv_libdb"
 177   fi
 178   # iconv needs bodging
 179   AC_SUBST(LIBICONV,[-liconv])
 180   ;;
 181 * )
 182   AC_MSG_RESULT([unknown, winging it])
 183   ;;
 184 esac
 185 AC_SUBST([COREAUDIO])
 186
 187 AC_ARG_WITH([browser],
 188             [AS_HELP_STRING([--with-browser=BROWSER],
 189                             [use BROWSER to display HTML])],
 190             [browser=$withval])
 191
 192 AC_CACHE_CHECK([default HTML viewer],[rjk_cv_browser],[
 193   rjk_cv_browser=UNKNOWN
 194   for candidate in x-www-browser sensible-browser firefox mozilla konqueror netscape; do
 195     if type $candidate >/dev/null 2>&1; then
 196       rjk_cv_browser="$candidate"
 197       break
 198     fi
 199   done
 200 ])
 201 if test -z "$browser"; then
 202   browser="$rjk_cv_browser"
 203 fi
 204 AC_DEFINE_UNQUOTED([BROWSER],["$browser"],[HTML viewer])
 205
 206 # Figure out what version of sox is installed
 207 AC_CACHE_CHECK([sox version],[rjk_cv_soxver],[
 208   rjk_cv_soxver=UNKNOWN
 209   if sox --version > /dev/null 2>&1; then
 210     rjk_cv_soxver=`sox --version|$AWK '{ if(match($0, /[[0-9\.]]+/)) print substr($0,RSTART,RLENGTH)}'`
 211   else
 212     rjk_cv_soxver=`sox -h 2>&1|$AWK '/Version/ { if(match($0, /[[0-9\.]]+/)) print substr($0,RSTART,RLENGTH)}'`
 213   fi
 214 ])
 215
 216 # Decide what command line options to use
 217 #
 218 # sox version   endian     bits       deployed
 219 # 12.17.9       -x         -[bwld]    debian etch, ubuntu dapper
 220 # 14.0.0        -x/-[BL]   -[bwld]    ubuntu hardy
 221 # 14.0.1        -x/-[BL]   -[1248]    debian lenny
 222 # 14.2.0        -x/-[BL]   -[1248]    debian sid (at 2008-12)
 223
 224 AC_CACHE_CHECK([default sox generation],[rjk_cv_soxgen],[
 225   case $rjk_cv_soxver in
 226   [[0-9]].* | 1[[0123]].* )
 227     rjk_cv_soxgen=0
 228     ;;
 229   * )
 230     rjk_cv_soxgen=1
 231     ;;
 232   esac
 233 ])
 234 AC_DEFINE_UNQUOTED([DEFAULT_SOX_GENERATION],[$rjk_cv_soxgen],
 235                    [default sox generation])
 236
 237 AC_ARG_WITH([server],
 238             [AS_HELP_STRING([--without-server],
 239                             [do not build server])],
 240             [want_server=$withval])
 241 AC_ARG_WITH([cgi],
 242             [AS_HELP_STRING([--without-cgi],
 243                             [do not build CGI])],
 244             [want_cgi=$withval])
 245 AC_ARG_WITH([gtk],
 246             [AS_HELP_STRING([--without-gtk],
 247                             [do not build GTK+ client])],
 248             [want_gtk=$withval])
 249 AC_ARG_WITH([python],
 250             [AS_HELP_STRING([--without-python],
 251                             [do not build Python support])],
 252             [want_python=$withval])
 253
 254 if test $want_server = no; then
 255   want_cgi=no
 256 fi
 257
 258 #
 259 # OS          Document Root                  CGI directory
 260 # ==          =============                  =============
 261 # Debian      /var/www                       /usr/lib/cgi-bin
 262 # Ubuntu      /var/www                       /usr/lib/cgi-bin
 263 # Red Hat     /var/www/html                  /var/www/cgi-bin
 264 #      or:    /home/httpd/html/              /home/httpd/cgi-bin
 265 # Slackware   /var/www/htdocs                (unknown)
 266 # SuSE        /srv/www/html                  /srv/www/cgi-bin
 267 # Gentoo      /var/www/localhost/htdocs      /var/www/localhost/cgi-bin/
 268 # FreeBSD     /usr/local/www/data            /usr/local/www/cgi-bin
 269 #      or:    /usr/local/www/???/data        /usr/local/www/???/cgi-bin
 270 # OS X        /Library/WebServer/Documents   /Library/WebServer/CGI-Executables
 271 # Apache      /usr/local/apache/htdocs       (none)
 272 #
 273 # Sources:
 274 #   http://wiki.linuxquestions.org/wiki/Apache
 275 #   http://mapserver.gis.umn.edu/docs/howto/suse-linux
 276 #   http://www.yolinux.com/TUTORIALS/LinuxTutorialWebSiteConfig.html
 277 #   http://sources.gentoo.org/viewcvs.py/apache/trunk/dist/2.2/conf/vhosts.d/default_vhost.include?rev=198&view=log
 278 #   http://httpd.apache.org/docs/
 279 #
 280 if test $want_cgi = yes; then
 281   if test -z "$httpdir"; then
 282     AC_CACHE_CHECK([for httpd document root],[rjk_cv_httpdir],[
 283       rjk_cv_httpdir="not found"
 284       for dir in /var/www/html \
 285                  /var/www/htdocs \
 286                  /var/www/localhost/htdocs \
 287                  /var/www \
 288                  /home/httpd/html \
 289                  /srv/www/html \
 290                  /usr/local/www/data \
 291                  /usr/local/www/*/data \
 292                  /Library/WebServer/Documents \
 293                  /usr/local/apache/htdocs; do
 294         if test -d "$dir"; then
 295           rjk_cv_httpdir="$dir"
 296         fi
 297       done
 298     ])
 299     if test "$rjk_cv_httpdir" = "not found"; then
 300       AC_MSG_ERROR([cannot identify httpd documentroot.  Set httpdir on configure command line])
 301     fi
 302     httpdir="$rjk_cv_httpdir"
 303   fi
 304   if test ! -z "$cgidir"; then
 305     # This is a bit harsh but should stop any disasters
 306     AC_MSG_ERROR([cgidir has been renamed to cgiexecdir])
 307   fi
 308   if test -z "$cgiexecdir"; then
 309     AC_CACHE_CHECK([for CGI directory],[rjk_cv_cgiexecdir],[
 310       rjk_cv_cgiexecdir="not found"
 311       for dir in /usr/lib/cgi-bin \
 312                  /Library/WebServer/CGI-Executables \
 313                  /srv/www/cgi-bin \
 314                  /var/www/cgi-bin \
 315                  /home/httpd/cgi-bin \
 316                  /var/www/localhost/cgi-bin \
 317                  /usr/local/lib/cgi-bin \
 318                  /usr/local/www/cgi-bin \
 319                  /usr/local/www/*/cgi-bin; do
 320         if test -d "$dir"; then
 321           rjk_cv_cgiexecdir="$dir"
 322           break
 323         fi
 324       done
 325     ])
 326     if test "$rjk_cv_cgiexecdir" = "not found"; then
 327       AC_MSG_ERROR([cannot identify CGI install directory.  Set cgiexecdir on configure command line])
 328     fi
 329     cgiexecdir="$rjk_cv_cgiexecdir"
 330   fi
 331 fi
 332 AC_ARG_VAR([cgiexecdir], [location of cgi-bin directory, e.g. /usr/lib/cgi-bin])
 333 AC_ARG_VAR([httpdir], [location of http document root, e.g. /var/www/htdocs])
 334 if test -z "$pkghttpdir"; then
 335   pkghttpdir='$(httpdir)/disorder'
 336 fi
 337 AC_SUBST([pkghttpdir])
 338
 339 if test -z "$dochtmldir"; then
 340   dochtmldir='$(docdir)/html'
 341 fi
 342 AC_SUBST([dochtmldir])
 343
 344 subdirs="scripts lib"
 345 if test $want_tests = yes; then
 346   subdirs="${subdirs} libtests"
 347 fi
 348 subdirs="${subdirs} clients doc examples debian"
 349
 350 if test $want_server = yes; then
 351   subdirs="${subdirs} server plugins sounds"
 352 fi
 353 if test $want_cgi = yes; then
 354   subdirs="${subdirs} cgi templates images"
 355 fi
 356 if test $want_gtk = yes; then
 357   subdirs="${subdirs} disobedience"
 358   if test $want_server = no; then
 359     subdirs="${subdirs} images"
 360   fi
 361 fi
 362 if test $want_tests = yes && test $want_python = yes; then
 363   AM_PATH_PYTHON([2.5])
 364   subdirs="${subdirs} python tests"
 365 fi
 366 AC_SUBST([subdirs])
 367
 368 # libtool config
 369 AC_LIBTOOL_DLOPEN
 370 AC_DISABLE_STATIC
 371
 372 AC_PROG_LIBTOOL
 373
 374 AC_CACHE_CHECK([for GNU sed],[rjk_cv_gnused],[
 375   rjk_cv_gnused="not found"
 376   for candidate in sed gsed; do
 377     if $candidate --version >/dev/null 2>&1; then
 378       rjk_cv_gnused=$candidate
 379     fi
 380   done
 381 ])
 382 GNUSED="${GNUSED:-$rjk_cv_gnused}"
 383 if test "$GNUSED" = "not found"; then
 384   AC_MSG_ERROR([GNU sed is required to build this program])
 385 fi
 386 AC_SUBST([GNUSED])
 387
 388 AC_CHECK_PROGS([GROG],[grog])
 389 AM_CONDITIONAL([GROG],[test "x$GROG" != xnone])
 390
 391 missing_libraries=""
 392 missing_headers=""
 393 missing_functions=""
 394
 395 AC_DEFINE(_GNU_SOURCE, 1, [required for e.g. strsignal])
 396
 397 AC_PATH_PROG([SENDMAIL],[sendmail],[none],[$PATH:/usr/sbin:/usr/lib])
 398
 399 # Macs might have libraries under fink's root
 400 AC_PATH_PROG([FINK],[fink],[none],[$PATH:/sw/bin])
 401 if test "x$FINK" != xnone; then
 402   # Find Fink prefix
 403   AC_CACHE_CHECK([fink install directory],[rjk_cv_finkprefix],[
 404     rjk_cv_finkprefix="`echo "$FINK" | sed 's,/bin/fink$,,'`"
 405   ])
 406   # Add include and link paths
 407   finkdir="${rjk_cv_finkprefix}"
 408   finkbindir="${rjk_cv_finkprefix}/bin"
 409   CPPFLAGS="${CPPFLAGS} -isystem ${rjk_cv_finkprefix}/include/gc -isystem ${rjk_cv_finkprefix}/include"
 410   if test $want_server = yes; then
 411     CPPFLAGS="${CPPFLAGS} -isystem ${rjk_cv_finkprefix}/include/db4"
 412   fi
 413   LDFLAGS="${LDFLAGS} -L${rjk_cv_finkprefix}/lib"
 414   # Distinguish 32- and 64-bit fink
 415   AC_CACHE_CHECK([whether Fink is 32-bit or 64-bit],[rjk_cv_finkbits],[
 416     odata=`otool -v -h $finkbindir/dpkg`
 417     case "$odata" in
 418     *X86_64* )
 419       rjk_cv_finkbits=64
 420       ;;
 421     *I386* )
 422       rjk_cv_finkbits=32
 423       ;;
 424     * )
 425       rjk_cv_finkbits=unknown
 426       ;;
 427     esac
 428   ])
 429   # Match Fink so we can use its libraries
 430   case $rjk_cv_finkbits in
 431   32 | 64 )
 432     CC="$CC -m$rjk_cv_finkbits"
 433     ;;
 434   esac
 435 else
 436   finkbindir=""
 437 fi
 438 AC_SUBST([finkdir])
 439 AC_SUBST([finkbindir])
 440
 441 # Checks for libraries.
 442 # We save up a list of missing libraries that we can't do without
 443 # and report them all at once.
 444 AC_CHECK_LIB(gc, GC_malloc,            [AC_SUBST(LIBGC,[-lgc])],
 445             [missing_libraries="$missing_libraries libgc"])
 446 AC_CHECK_LIB(gcrypt, gcry_md_open,
 447              [AC_SUBST(LIBGCRYPT,[-lgcrypt])],
 448             [missing_libraries="$missing_libraries libgcrypt"])
 449 AC_CHECK_LIB(pcre, pcre_compile,
 450              [AC_SUBST(LIBPCRE,[-lpcre])],
 451              [missing_libraries="$missing_libraries libpcre"])
 452 if test $want_alsa = yes; then
 453   AC_CHECK_LIB([asound], [snd_pcm_open],
 454                [AC_SUBST(LIBASOUND,[-lasound])])
 455 fi
 456 if test $want_pulseaudio = yes; then
 457   PKG_CHECK_MODULES([PULSEAUDIO],[libpulse],
 458                     [AC_DEFINE([HAVE_PULSEAUDIO],[1],[define to 1 for PulseAudio support])],
 459                     [missing_libraries="$missing_libraries libpulse"])
 460   PKG_CHECK_MODULES([PULSEAUDIO_SIMPLE],[libpulse-simple],,
 461                     [missing_libraries="$missing_libraries libpulse-simple"])
 462 fi
 463 AC_CHECK_LIB([samplerate],[src_new],
 464              [AC_SUBST([LIBSAMPLERATE],[-lsamplerate])])
 465 if test $want_server = yes; then
 466   RJK_CHECK_LIB(db, db_create, [#include <db.h>],
 467                [AC_SUBST(LIBDB,[-ldb])],
 468                [missing_libraries="$missing_libraries libdb"])
 469   AC_CHECK_LIB(vorbis, vorbis_info_clear,
 470                [:],
 471                [missing_libraries="$missing_libraries libvorbis"])
 472   AC_CHECK_LIB(vorbisfile, ov_open,
 473                [AC_SUBST(LIBVORBISFILE,["-lvorbisfile -lvorbis"])],
 474                [missing_libraries="$missing_libraries libvorbisfile"],
 475                [-lvorbis])
 476   AC_CHECK_LIB(mad, mad_stream_init,
 477                [AC_SUBST(LIBMAD,[-lmad])],
 478                [missing_libraries="$missing_libraries libmad"])
 479   AC_CHECK_LIB([FLAC], [FLAC__stream_decoder_new],
 480                [AC_SUBST(LIBFLAC,[-lFLAC])],
 481                [missing_libraries="$missing_libraries libFLAC"])
 482 fi
 483 AC_CHECK_LIB([pthread], [pthread_create],
 484              [AC_SUBST(LIBPTHREAD,[-lpthread])],
 485              [missing_libraries="$missing_libraries libpthread"])
 486
 487 if test $want_gtk = yes; then
 488   if test $want_gtkosx = yes; then
 489     GTK_CFLAGS="-isystem /Library/Frameworks/Gtk.framework/Headers -isystem /Library/Frameworks/Cairo.framework/Headers"
 490     GLIB_CFLAGS="-isystem /Library/Frameworks/GLib.framework/Headers"
 491     GTK_LIBS="-framework Gtk -framework GLib"
 492   else
 493     AM_PATH_GLIB_2_0([],[],[missing_libraries="$missing_libraries libglib"])
 494     AM_PATH_GTK_2_0([],[],[missing_libraries="$missing_libraries libgtk"])
 495   fi
 496 fi
 497
 498 # Some platforms have iconv already
 499 AC_CHECK_FUNC(iconv_open, [:],
 500               [RJK_CHECK_LIB(iconv, iconv_open, [#include <iconv.h>],
 501                             [AC_SUBST(LIBICONV,[-liconv])],
 502                             [missing_functions="$missing_functions iconv_open"])])
 503 AC_CHECK_FUNC([gethostbyname],[:],[
 504   AC_CHECK_LIB(nsl,gethostbyname,
 505                [AC_SUBST(LIBNSL,[-lnsl])],
 506                [missing_functions="$missing_functions gethostbyname"])])
 507 AC_CHECK_FUNC([socket],[:],[
 508   AC_CHECK_LIB(socket,socket,
 509                [AC_SUBST(LIBSOCKET,[-lsocket])],
 510                [missing_functions="$missing_functions socket"])])
 511 AC_CHECK_FUNC([dlopen],[:],[
 512   AC_CHECK_LIB(dl,dlopen,
 513                [AC_SUBST(LIBDL,[-ldl])],
 514                [missing_functions="$missing_functions dlopen"])])
 515
 516 if test ! -z "$missing_libraries"; then
 517   AC_MSG_ERROR([missing libraries:$missing_libraries])
 518 fi
 519
 520 # Checks for header files.
 521 RJK_FIND_GC_H
 522 if test $want_oss = yes; then
 523   AC_CHECK_HEADERS([sys/soundcard.h])
 524 fi
 525 if test $want_alsa = yes; then
 526   AC_CHECK_HEADERS([alsa/asoundlib.h])
 527 fi
 528 if test $want_coreaudio = yes; then
 529   AC_CHECK_HEADERS([CoreAudio/AudioHardware.h])
 530 fi
 531 AC_CHECK_HEADERS([inttypes.h sys/time.h sys/socket.h netinet/in.h \
 532                   arpa/inet.h sys/un.h netdb.h pcre.h pwd.h langinfo.h])
 533 # We don't bother checking very standard stuff
 534 # Compilation will fail if any of these headers are missing, so we
 535 # check for them here and fail early.
 536 if test $want_server = yes; then
 537   AC_CHECK_HEADERS([db.h],[:],[
 538     missing_headers="$missing_headers $ac_header"
 539   ])
 540 fi
 541 AC_CHECK_HEADERS([dlfcn.h gcrypt.h \
 542                  getopt.h iconv.h langinfo.h \
 543                  pcre.h sys/ioctl.h \
 544                  syslog.h unistd.h],[:],[
 545   missing_headers="$missing_headers $ac_header"
 546 ])
 547 AC_CHECK_HEADERS([samplerate.h])
 548
 549 if test ! -z "$missing_headers"; then
 550   AC_MSG_ERROR([missing headers:$missing_headers])
 551 fi
 552
 553 # We require that libpcre support UTF-8
 554 RJK_REQUIRE_PCRE_UTF8([-lpcre])
 555
 556 # Checks for typedefs, structures, and compiler characteristics.
 557 AC_C_CONST
 558 AC_TYPE_SIZE_T
 559 AC_C_INLINE
 560 AC_C_BIGENDIAN
 561 AC_CHECK_TYPES([struct sockaddr_in6],,,[AC_INCLUDES_DEFAULT
 562 #include <netinet/in.h>])
 563
 564 # Figure out how we'll check for devices being mounted and unmounted
 565 AC_CACHE_CHECK([for list of mounted filesystems],[rjk_cv_mtab],[
 566   if test -e /etc/mtab; then
 567     rjk_cv_mtab=/etc/mtab
 568   else
 569     rjk_cv_mtab=none
 570   fi
 571 ])
 572 if test $rjk_cv_mtab != none; then
 573   AC_DEFINE_UNQUOTED([PATH_MTAB],["$rjk_cv_mtab"],[path to file containing mount list])
 574 fi
 575
 576 # enable -Werror when we check for certain characteristics:
 577
 578 old_CFLAGS="${CFLAGS}"
 579 CFLAGS="${CFLAGS} $gcc_werror"
 580 AC_CHECK_TYPES([long long,uint32_t,uint16_t,uint8_t,intmax_t,uintmax_t])
 581
 582 # Some GCC invocations warn for converting function pointers to void *.
 583 # This is fair enough, as it's technically forbidden, but we use dlsym()
 584 # which can pretty much only exist if object and function pointers are
 585 # interconvertable.  So we disable -Werror if need be.
 586 if test ! -z "$gcc_werror"; then
 587   AC_CACHE_CHECK([whether function pointers can be converted to void * without a warning],
 588                  [rjk_cv_function_pointer_cast],[
 589     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 590   void somefunction(void);],
 591                       [(void *)somefunction])],
 592                       [rjk_cv_function_pointer_cast=yes],
 593                       [rjk_cv_function_pointer_cast=no])])
 594   if test $rjk_cv_function_pointer_cast = no; then
 595     gcc_werror=""
 596   fi
 597 fi
 598
 599 CFLAGS="${old_CFLAGS}"
 600
 601 # gcrypt maintainers keep changing everything.  Design your interface
 602 # first, then implement it once, rather than getting it wrong three or
 603 # four times and shipping between each attempt.
 604 AC_CACHE_CHECK([for hash handle type in <grypt.h>],
 605                [rjk_cv_gcrypt_hash_handle],[
 606   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 607 #include <gcrypt.h>
 608 ],
 609                [gcry_md_hd_t h;])],
 610                [rjk_cv_gcrypt_hash_handle=gcry_md_hd_t],[
 611     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 612 #include <gcrypt.h>
 613 ],
 614                  [GcryMDHd h;])],
 615                  [rjk_cv_gcrypt_hash_handle=GcryMDHd],
 616                  [rjk_cv_gcrypt_hash_handle=GCRY_MD_HD])])])
 617 AC_DEFINE_UNQUOTED([gcrypt_hash_handle],[$rjk_cv_gcrypt_hash_handle],
 618                    [libgcrypt hash handle type])
 619
 620 AC_CACHE_CHECK([for gcry_error_t in <grypt.h>],
 621                [rjk_cv_have_gcry_error_t],[
 622   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 623 #include <gcrypt.h>
 624 ],
 625                  [gcry_error_t e;])],
 626                  [rjk_cv_have_gcry_error_t=yes],
 627                  [rjk_cv_have_gcry_error_t=no])])
 628 if test $rjk_cv_have_gcry_error_t = yes; then
 629   AC_DEFINE([HAVE_GCRY_ERROR_T],1,[define if <gcrypt.h> defines gcry_error_t])
 630 fi
 631
 632 # Checks for functions
 633 if test $ac_cv_type_long_long = yes; then
 634   AC_CHECK_FUNCS([atoll strtoll],[:],[
 635     missing_functions="$missing_functions $ac_func"
 636   ])
 637   # Darwin sometimes fails to declare strtoll (e.g. if you ask for -std=c99)
 638   AC_CACHE_CHECK([whether strtoll is declared in <stdlib.h>],
 639                  [rjk_cv_strtoll_declared],[
 640     AC_EGREP_HEADER([strtoll], [stdlib.h],
 641                     [rjk_cv_strtoll_declared=yes],
 642                     [rjk_cv_strtoll_declared=no])])
 643   if test $rjk_cv_strtoll_declared = yes; then
 644     AC_DEFINE([DECLARES_STRTOLL],[1],[define if <stdlib.h> declares strtoll])
 645   fi
 646   AC_CACHE_CHECK([whether atoll is declared in <stdlib.h>],
 647                  [rjk_cv_atoll_declared],[
 648     AC_EGREP_HEADER([atoll], [stdlib.h],
 649                     [rjk_cv_atoll_declared=yes],
 650                     [rjk_cv_atoll_declared=no])])
 651   if test $rjk_cv_atoll_declared = yes; then
 652     AC_DEFINE([DECLARES_ATOLL],[1],[define if <stdlib.h> declares atoll])
 653   fi
 654 fi
 655 AC_CHECK_FUNCS([ioctl nl_langinfo strsignal setenv unsetenv],[:],[
 656   missing_functions="$missing_functions $ac_func"
 657 ])
 658 # fsync will do if fdatasync not available
 659 AC_CHECK_FUNCS([fdatasync],[:],[
 660   AC_CHECK_FUNCS([fsync],
 661                  [AC_DEFINE([fdatasync],[fsync],[define fdatasync to fsync if not available])],
 662                  [missing_functions="$missing_functions fdatasync"])])
 663 if test ! -z "$missing_functions"; then
 664   AC_MSG_ERROR([missing functions:$missing_functions])
 665 fi
 666
 667 # Functions we can take or leave
 668 AC_CHECK_FUNCS([fls getfsstat closesocket])
 669
 670 if test $want_server = yes; then
 671   # <db.h> had better be version 3 or later
 672   AC_CACHE_CHECK([db.h version],[rjk_cv_db_version],[
 673     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
 674                        #include <db.h>
 675                        #ifndef DB_VERSION_MAJOR
 676                        # error cannot determine db version
 677                        #endif
 678                        #if DB_VERSION_MAJOR < 4
 679                        # error inadequate db version
 680                        #endif
 681                        #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR <= 2
 682                        # error inadequate db version
 683                        #endif
 684                       ],[])],
 685                       [rjk_cv_db_version=ok],
 686                       [rjk_cv_db_version=inadequate])
 687     if test $rjk_cv_db_version = ok; then
 688       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
 689                          #include <db.h>
 690                          #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR == 6
 691                          # error http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=510270
 692                          #endif
 693                         ],[])],
 694                         [rjk_cv_db_version=ok],
 695                         [rjk_cv_db_version=toxic])
 696     fi
 697   ])
 698   case $rjk_cv_db_version in
 699   ok )
 700     ;;
 701   inadequate )
 702     AC_MSG_ERROR([need db version at least 4.3 (but not 4.6)])
 703     ;;
 704   toxic )
 705     AC_MSG_ERROR([db version 4.6.x does not work - see debian bug 510270])
 706     ;;
 707   esac
 708 fi
 709
 710 AM_CONDITIONAL([SERVER], [test x$want_server = xyes])
 711 if test $want_gtk = yes; then
 712   AC_DEFINE([WITH_GTK], [1], [define if using GTK+])
 713 fi
 714 AM_CONDITIONAL([GTK], [test x$want_gtk = xyes])
 715
 716 if test "x$GCC" = xyes; then
 717   # We need LLONG_MAX and annoyingly GCC doesn't always give it to us
 718   # by default.
 719   AC_CACHE_CHECK([what C version to ask for],[rjk_cv_cstd],[
 720     AC_TRY_COMPILE([#include <limits.h>],[
 721       long long n = LLONG_MAX;
 722     ],[rjk_cv_cstd=default],[
 723       old_CC="$CC"
 724       CC="${CC} -std=gnu99"
 725       AC_TRY_COMPILE([#include <limits.h>],[
 726         long long n = LLONG_MAX;
 727       ],[rjk_cv_cstd=gnu99],[rjk_cv_cstd=unknown])
 728       CC="$old_CC"
 729     ])
 730   ])
 731   case $rjk_cv_cstd in
 732   default | unknown )
 733     ;;
 734   * )
 735     CC="${CC} -std=${rjk_cv_cstd}"
 736     ;;
 737   esac
 738
 739   # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=29478
 740   AC_CACHE_CHECK([checking for GCC bug 29478],[rjk_cv_pr29478],[
 741     old_CC="$CC"
 742     if test $GCC = yes; then
 743       CC="$CC -Wall -Werror"
 744     fi
 745     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 746       static int x(char *f) {
 747        return *f;
 748       }
 749       int z(const char *g) {
 750         return x((char *)g);
 751       }],[])],
 752       [rjk_cv_pr29478=no],
 753       [rjk_cv_pr29478=yes]
 754     )
 755     CC="$old_CC"
 756   ])
 757   if test $rjk_cv_pr29478 = yes; then
 758     gcc_werror=''
 759   fi
 760
 761   AC_CACHE_CHECK([checking for excessively strict -Wreturn-type],
 762                  [rjk_cv_gcc44_stupidity],[
 763     old_CC="$CC"
 764     if test $GCC = yes; then
 765       CC="$CC -Wreturn-type -Werror"
 766     fi
 767     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[
 768       static void *threadfn(void) {
 769         for(;;)
 770           ;
 771       }],[])],
 772       [rjk_cv_gcc44_stupidity=no],
 773       [rjk_cv_gcc44_stupidity=yes])
 774     CC="$old_CC"
 775   ])
 776   if test $rjk_cv_gcc44_stupidity = yes; then
 777     AC_DEFINE([HAVE_STUPID_GCC44],[1],[Define if your compiler has excessively strict -Wreturn-type])
 778   fi
 779
 780   # a reasonable default set of warnings
 781   CC="${CC} -Wall -W -Wpointer-arith \
 782         -Wwrite-strings -Wmissing-prototypes \
 783         -Wmissing-declarations -Wnested-externs"
 784
 785   # Fix up GTK+ and GLib compiler flags
 786   GTK_CFLAGS="`echo \"$GTK_CFLAGS\"|sed 's/-I/-isystem /g'`"
 787   GLIB_CFLAGS="`echo \"$GLIB_CFLAGS\"|sed 's/-I/-isystem /g'`"
 788
 789   if test "$gcc_werror" != ''; then
 790     # GCC 2.95 doesn't know to ignore warnings from system headers
 791     AC_CACHE_CHECK([whether -Werror is usable],
 792                     rjk_cv_werror, [
 793       save_CFLAGS="${CFLAGS}"
 794       CFLAGS="${CFLAGS} ${GTK_CFLAGS} -Werror"
 795       AC_TRY_COMPILE([#if WITH_GTK
 796  #include <gtk/gtk.h>
 797 #endif
 798
 799 struct s { int a, b; };
 800 const struct s sv = { .a = 1 };],
 801                      [],
 802                      [rjk_cv_werror=yes],
 803                      [rjk_cv_werror=no])
 804       CFLAGS="${save_CFLAGS}"
 805     ])
 806     if test $rjk_cv_werror = no; then
 807       gcc_werror=''
 808     fi
 809   fi
 810   CC="${CC} $gcc_werror"
 811
 812   # for older GCCs that don't know %ju (etc)
 813   AC_CACHE_CHECK([whether -Wno-format is required],
 814                  rjk_cv_noformat,
 815                  AC_TRY_COMPILE([#include <stdio.h>
 816 #include <stdint.h>
 817 ],
 818                                 [printf("%ju", (uintmax_t)0);],
 819                                 [rjk_cv_noformat=no],
 820                                 [rjk_cv_noformat=yes]))
 821   if test $rjk_cv_noformat = yes; then
 822     CC="${CC} -Wno-format"
 823   fi
 824
 825   AC_CACHE_CHECK([whether -Wshadow is OK],
 826                  rjk_cv_shadow,
 827                  oldCC="${CC}"
 828                  CC="${CC} -Wshadow"
 829                  [AC_TRY_COMPILE([
 830 #include <unistd.h>
 831 #include <vorbis/vorbisfile.h>
 832 ],
 833                                 [],
 834                                 [rjk_cv_shadow=yes],
 835                                 [rjk_cv_shadow=no])
 836                  CC="${oldCC}"])
 837   if test $rjk_cv_shadow = yes; then
 838     CC="${CC} -Wshadow"
 839   fi
 840 fi
 841
 842 RJK_GCOV
 843
 844 AH_BOTTOM([#ifdef __GNUC__
 845 # define attribute(x) __attribute__(x)
 846 #else
 847 # define attribute(x)
 848 #endif])
 849
 850 AC_CONFIG_FILES([Makefile
 851                  images/Makefile
 852                  scripts/Makefile
 853                  lib/Makefile
 854                  server/Makefile
 855                  cgi/Makefile
 856                  clients/Makefile
 857                  disobedience/Makefile
 858                  disobedience/manual/Makefile
 859                  doc/Makefile
 860                  templates/Makefile
 861                  plugins/Makefile
 862                  debian/Makefile
 863                  sounds/Makefile
 864                  python/Makefile
 865                  examples/Makefile
 866                  libtests/Makefile
 867                  tests/Makefile])
 868 AC_OUTPUT
 869
 870 if test $GCC = yes && test "$gcc_werror" = ''; then
 871   AC_MSG_WARN([building without -Werror])
 872 fi
 873 if test $want_python = no; then
 874   AC_MSG_WARN([cannot run the test suit without Python])
 875 fi
 876 if test $want_server = yes && test "$ac_cv_lib_samplerate_src_new" != yes; then
 877   AC_MSG_WARN([libsamplerate will be required in a future version])
 878 fi
 879
 880 # Local Variables:
 881 # indent-tabs-mode:nil
 882 # End: