chiark - git - mdw - disorder/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #
   3 # This file is part of DisOrder.
   4 # Copyright (C) 2004-2010 Richard Kettlewell
   5 # Portions copyright (C) 2007 Ross Younger
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20
  21 AC_INIT([disorder], [4.3+], [richard+disorder@sfere.greenend.org.uk])
  22 AC_CONFIG_AUX_DIR([config.aux])
  23 AM_INIT_AUTOMAKE(disorder, [4.3+])
  24 AC_CONFIG_SRCDIR([server/disorderd.c])
  25 AM_CONFIG_HEADER([config.h])
  26
  27 # Find host type
  28 AC_CANONICAL_HOST
  29
  30 # What we want to build
  31 want_gtk=yes
  32 want_python=yes
  33 want_tests=yes
  34 want_server=yes
  35 want_cgi=yes
  36
  37 # APIs we want
  38 want_alsa=yes
  39 want_oss=yes
  40 want_coreaudio=yes
  41
  42 # By default we don't want gtk-osx.  But if you ask for --with-gtk-osx...
  43 #
  44 # Disobedience can be built to a native OS X application.  There are some
  45 # caveats:
  46 #  - you will still need Fink (or something) for other libraries
  47 #  - if you wanted an application bundle you are out of luck
  48 #  - the menu bar is still in the main window (not at the top of the screen)
  49 #
  50 # So it's still rather rough and ready.  But it does work...
  51 #
  52 # See:
  53 #   http://www.gtk-osx.org/
  54 #   http://live.gnome.org/GTK%2B/OSX/Framework
  55 want_gtkosx=no
  56
  57 # Checks for programs.
  58 AC_PROG_CC
  59 AM_PROG_CC_C_O
  60 AC_PROG_AWK
  61 AC_SET_MAKE
  62 if test "x$GCC" = xyes; then
  63   gcc_werror=-Werror
  64   case "$CC" in
  65   *-std=* )
  66     ;;
  67   * )
  68     CC="${CC} -std=gnu99"
  69     ;;
  70   esac
  71 else
  72   AC_MSG_ERROR([GNU C is required to build this program])
  73   gcc_werror=""
  74 fi
  75
  76 AC_ARG_WITH([alsa],
  77             [AS_HELP_STRING([--without-alsa],
  78                             [do not build with ALSA support])],
  79             [want_alsa=$withval])
  80 AC_ARG_WITH([oss],
  81             [AS_HELP_STRING([--without-oss],
  82                             [do not build with OSS support])],
  83             [want_oss=$withval])
  84 AC_ARG_WITH([coreaudio],
  85             [AS_HELP_STRING([--without-coreaudio],
  86                             [do not build with Core Audio support])],
  87             [want_coreaudio=$withval])
  88 AC_ARG_WITH([tests],
  89             [AS_HELP_STRING([--without-tests],
  90                             [do not build test suit])],
  91             [want_tests=$withval])
  92 AC_ARG_WITH([gtk-osx],
  93             [AS_HELP_STRING([--with-gtk-osx],
  94                             [use native GTK+ (OS X only)])],
  95             [want_gtkosx=$withval])
  96
  97 AC_MSG_CHECKING([for a known target platform])
  98 case "$host" in
  99 *empeg* )
 100   AC_MSG_RESULT([empeg car stereo])
 101   AC_DEFINE([EMPEG_HOST],[1],[define if host is an empeg car stereo])
 102   # work around broken toolchain
 103   AC_CHECK_LIB([gpg-error], [gpg_strerror])
 104   AC_CHECK_LIB([pthread], [pthread_create])
 105   want_server=no
 106   want_cgi=no
 107  ;;
 108 *linux* | *Linux* )
 109   AC_MSG_RESULT([Linux])
 110   ;;
 111 *-apple-darwin* )
 112   AC_MSG_RESULT([Mac OS X])
 113   # AudioHardwareGetProperty is deprecated in 10.6, but it's still _there_,
 114   # so we'll just turn off the warning.
 115   CC="$CC -Wno-deprecated-declarations"
 116   if test $want_coreaudio = yes; then
 117     COREAUDIO="-framework CoreFoundation -framework CoreServices -framework CoreAudio"
 118   fi
 119   browser=open
 120   AC_MSG_CHECKING([Mac OS X target version])
 121   # We honor MACOSX_DEPLOYMENT_TARGET in the environment, emulating gcc's
 122   # behaviour.  But we provide a command line option to override it and
 123   # we default to wide support instead of supporting only the build platform.
 124   #
 125   # Currently if you ask for 10.5 you will get a deprecation warning
 126   # when building the CoreAudio support code.  For the time being the
 127   # answer to this is "don't do that then".  If a good reason to ask
 128   # for a 10.5 deployment target emerges then this will be fixed.
 129   if test -z "$MACOSX_DEPLOYMENT_TARGET"; then
 130     MACOSX_DEPLOYMENT_TARGET=10.0
 131   fi
 132   AC_ARG_WITH([deployment-target],
 133               [AS_HELP_STRING([--with-deployment-target=TARGET],
 134                               [set target OS X version])],
 135               [MACOSX_DEPLOYMENT_TARGET=$withval])
 136   # Convert to desired format
 137   underscored=`echo $MACOSX_DEPLOYMENT_TARGET|sed 's/\./_/'`
 138   minver="MAC_OS_X_VERSION_$underscored"
 139   AC_MSG_RESULT([$minver])
 140   AC_DEFINE_UNQUOTED([MAC_OS_X_VERSION_MIN_REQUIRED], [$minver],
 141                      [define to minimum version of Mac OS X to support])
 142
 143   if test $want_gtkosx = no; then
 144     # Fink's GTK+ is hopelessly broken
 145     PKG_CONFIG_PATH=${PKG_CONFIG_PATH:-/sw/lib/pango-ft219/lib/pkgconfig}
 146     export PKG_CONFIG_PATH
 147   fi
 148
 149   ;;
 150 *-freebsd* )
 151   AC_MSG_RESULT([FreeBSD])
 152   # Ports install to /usr/local but the compiler stupidly doesn't look
 153   # there by default
 154   LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 155   CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include"
 156   # Look for a suitable version of libdb among the versions found in FreeBSD 7.0
 157   AC_CACHE_CHECK([looking for a libdb install],[rjk_cv_libdb],[
 158     rjk_cv_libdb="none"
 159     for db in db43 db44 db45 db46; do
 160       if test -e /usr/local/lib/$db; then
 161         rjk_cv_libdb=$db
 162         break
 163       fi
 164     done
 165   ])
 166   if test $rjk_cv_libdb != none; then
 167     LDFLAGS="${LDFLAGS} -L/usr/local/lib/$rjk_cv_libdb"
 168     CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include/$rjk_cv_libdb"
 169   fi
 170   ;;
 171 * )
 172   AC_MSG_RESULT([unknown, winging it])
 173   ;;
 174 esac
 175 AC_SUBST([COREAUDIO])
 176
 177 AC_ARG_WITH([browser],
 178             [AS_HELP_STRING([--with-browser=BROWSER],
 179                             [use BROWSER to display HTML])],
 180             [browser=$withval])
 181
 182 AC_CACHE_CHECK([default HTML viewer],[rjk_cv_browser],[
 183   rjk_cv_browser=UNKNOWN
 184   for candidate in x-www-browser sensible-browser firefox mozilla konqueror netscape; do
 185     if type $candidate >/dev/null 2>&1; then
 186       rjk_cv_browser="$candidate"
 187       break
 188     fi
 189   done
 190 ])
 191 if test -z "$browser"; then
 192   browser="$rjk_cv_browser"
 193 fi
 194 AC_DEFINE_UNQUOTED([BROWSER],["$browser"],[HTML viewer])
 195
 196 # Figure out what version of sox is installed
 197 AC_CACHE_CHECK([sox version],[rjk_cv_soxver],[
 198   rjk_cv_soxver=UNKNOWN
 199   if sox --version > /dev/null 2>&1; then
 200     rjk_cv_soxver=`sox --version|$AWK '{ if(match($0, /[[0-9\.]]+/)) print substr($0,RSTART,RLENGTH)}'`
 201   else
 202     rjk_cv_soxver=`sox -h 2>&1|$AWK '/Version/ { if(match($0, /[[0-9\.]]+/)) print substr($0,RSTART,RLENGTH)}'`
 203   fi
 204 ])
 205
 206 # Decide what command line options to use
 207 #
 208 # sox version   endian     bits       deployed
 209 # 12.17.9       -x         -[bwld]    debian etch, ubuntu dapper
 210 # 14.0.0        -x/-[BL]   -[bwld]    ubuntu hardy
 211 # 14.0.1        -x/-[BL]   -[1248]    debian lenny
 212 # 14.2.0        -x/-[BL]   -[1248]    debian sid (at 2008-12)
 213
 214 AC_CACHE_CHECK([default sox generation],[rjk_cv_soxgen],[
 215   case $rjk_cv_soxver in
 216   [[0-9]].* | 1[[0123]].* )
 217     rjk_cv_soxgen=0
 218     ;;
 219   * )
 220     rjk_cv_soxgen=1
 221     ;;
 222   esac
 223 ])
 224 AC_DEFINE_UNQUOTED([DEFAULT_SOX_GENERATION],[$rjk_cv_soxgen],
 225                    [default sox generation])
 226
 227 AC_ARG_WITH([server],
 228             [AS_HELP_STRING([--without-server],
 229                             [do not build server])],
 230             [want_server=$withval])
 231 AC_ARG_WITH([cgi],
 232             [AS_HELP_STRING([--without-cgi],
 233                             [do not build CGI])],
 234             [want_cgi=$withval])
 235 AC_ARG_WITH([gtk],
 236             [AS_HELP_STRING([--without-gtk],
 237                             [do not build GTK+ client])],
 238             [want_gtk=$withval])
 239 AC_ARG_WITH([python],
 240             [AS_HELP_STRING([--without-python],
 241                             [do not build Python support])],
 242             [want_python=$withval])
 243
 244 if test $want_server = no; then
 245   want_cgi=no
 246 fi
 247
 248 #
 249 # OS          Document Root                  CGI directory
 250 # ==          =============                  =============
 251 # Debian      /var/www                       /usr/lib/cgi-bin
 252 # Ubuntu      /var/www                       /usr/lib/cgi-bin
 253 # Red Hat     /var/www/html                  /var/www/cgi-bin
 254 #      or:    /home/httpd/html/              /home/httpd/cgi-bin
 255 # Slackware   /var/www/htdocs                (unknown)
 256 # SuSE        /srv/www/html                  /srv/www/cgi-bin
 257 # Gentoo      /var/www/localhost/htdocs      /var/www/localhost/cgi-bin/
 258 # FreeBSD     /usr/local/www/data            /usr/local/www/cgi-bin
 259 #      or:    /usr/local/www/???/data        /usr/local/www/???/cgi-bin
 260 # OS X        /Library/WebServer/Documents   /Library/WebServer/CGI-Executables
 261 # Apache      /usr/local/apache/htdocs       (none)
 262 #
 263 # Sources:
 264 #   http://wiki.linuxquestions.org/wiki/Apache
 265 #   http://mapserver.gis.umn.edu/docs/howto/suse-linux
 266 #   http://www.yolinux.com/TUTORIALS/LinuxTutorialWebSiteConfig.html
 267 #   http://sources.gentoo.org/viewcvs.py/apache/trunk/dist/2.2/conf/vhosts.d/default_vhost.include?rev=198&view=log
 268 #   http://httpd.apache.org/docs/
 269 #
 270 if test $want_cgi = yes; then
 271   if test -z "$httpdir"; then
 272     AC_CACHE_CHECK([for httpd document root],[rjk_cv_httpdir],[
 273       rjk_cv_httpdir="not found"
 274       for dir in /var/www/html \
 275                  /var/www/htdocs \
 276                  /var/www/localhost/htdocs \
 277                  /var/www \
 278                  /home/httpd/html \
 279                  /srv/www/html \
 280                  /usr/local/www/data \
 281                  /usr/local/www/*/data \
 282                  /Library/WebServer/Documents \
 283                  /usr/local/apache/htdocs; do
 284         if test -d "$dir"; then
 285           rjk_cv_httpdir="$dir"
 286         fi
 287       done
 288     ])
 289     if test "$rjk_cv_httpdir" = "not found"; then
 290       AC_MSG_ERROR([cannot identify httpd documentroot.  Set httpdir on configure command line])
 291     fi
 292     httpdir="$rjk_cv_httpdir"
 293   fi
 294   if test ! -z "$cgidir"; then
 295     # This is a bit harsh but should stop any disasters
 296     AC_MSG_ERROR([cgidir has been renamed to cgiexecdir])
 297   fi
 298   if test -z "$cgiexecdir"; then
 299     AC_CACHE_CHECK([for CGI directory],[rjk_cv_cgiexecdir],[
 300       rjk_cv_cgiexecdir="not found"
 301       for dir in /usr/lib/cgi-bin \
 302                  /Library/WebServer/CGI-Executables \
 303                  /srv/www/cgi-bin \
 304                  /var/www/cgi-bin \
 305                  /home/httpd/cgi-bin \
 306                  /var/www/localhost/cgi-bin \
 307                  /usr/local/lib/cgi-bin \
 308                  /usr/local/www/cgi-bin \
 309                  /usr/local/www/*/cgi-bin; do
 310         if test -d "$dir"; then
 311           rjk_cv_cgiexecdir="$dir"
 312           break
 313         fi
 314       done
 315     ])
 316     if test "$rjk_cv_cgiexecdir" = "not found"; then
 317       AC_MSG_ERROR([cannot identify CGI install directory.  Set cgiexecdir on configure command line])
 318     fi
 319     cgiexecdir="$rjk_cv_cgiexecdir"
 320   fi
 321 fi
 322 AC_ARG_VAR([cgiexecdir], [location of cgi-bin directory, e.g. /usr/lib/cgi-bin])
 323 AC_ARG_VAR([httpdir], [location of http document root, e.g. /var/www/htdocs])
 324 if test -z "$pkghttpdir"; then
 325   pkghttpdir='$(httpdir)/disorder'
 326 fi
 327 AC_SUBST([pkghttpdir])
 328
 329 if test -z "$dochtmldir"; then
 330   dochtmldir='$(docdir)/html'
 331 fi
 332 AC_SUBST([dochtmldir])
 333
 334 subdirs="scripts lib"
 335 if test $want_tests = yes; then
 336   subdirs="${subdirs} libtests"
 337 fi
 338 subdirs="${subdirs} clients doc examples debian"
 339
 340 if test $want_server = yes; then
 341   subdirs="${subdirs} server plugins sounds"
 342   if test "$rjk_cv_libao_plugin_api_works" = yes; then
 343     subdirs="${subdirs} driver"
 344   fi
 345 fi
 346 if test $want_cgi = yes; then
 347   subdirs="${subdirs} cgi templates images"
 348 fi
 349 if test $want_gtk = yes; then
 350   subdirs="${subdirs} disobedience"
 351   if test $want_server = no; then
 352     subdirs="${subdirs} images"
 353   fi
 354 fi
 355 if test $want_tests = yes && test $want_python = yes; then
 356   AM_PATH_PYTHON([2.5])
 357   subdirs="${subdirs} python tests"
 358 fi
 359 AC_SUBST([subdirs])
 360
 361 # libtool config
 362 AC_LIBTOOL_DLOPEN
 363 AC_DISABLE_STATIC
 364
 365 AC_PROG_LIBTOOL
 366
 367 AC_CACHE_CHECK([for GNU sed],[rjk_cv_gnused],[
 368   rjk_cv_gnused="not found"
 369   for candidate in sed gsed; do
 370     if $candidate --version >/dev/null 2>&1; then
 371       rjk_cv_gnused=$candidate
 372     fi
 373   done
 374 ])
 375 GNUSED="${GNUSED:-$rjk_cv_gnused}"
 376 if test "$GNUSED" = "not found"; then
 377   AC_MSG_ERROR([GNU sed is required to build this program])
 378 fi
 379 AC_SUBST([GNUSED])
 380
 381 AC_CHECK_PROGS([GROG],[grog])
 382 AM_CONDITIONAL([GROG],[test "x$GROG" != xnone])
 383
 384 missing_libraries=""
 385 missing_headers=""
 386 missing_functions=""
 387
 388 AC_DEFINE(_GNU_SOURCE, 1, [required for e.g. strsignal])
 389
 390 AC_PATH_PROG([SENDMAIL],[sendmail],[none],[$PATH:/usr/sbin:/usr/lib])
 391
 392 # Macs might have libraries under fink's root
 393 AC_PATH_PROG([FINK],[fink],[none],[$PATH:/sw/bin])
 394 if test "x$FINK" != xnone; then
 395   # Find Fink prefix
 396   AC_CACHE_CHECK([fink install directory],[rjk_cv_finkprefix],[
 397     rjk_cv_finkprefix="`echo "$FINK" | sed 's,/bin/fink$,,'`"
 398   ])
 399   # Add include and link paths
 400   finkdir="${rjk_cv_finkprefix}"
 401   finkbindir="${rjk_cv_finkprefix}/bin"
 402   CPPFLAGS="${CPPFLAGS} -isystem ${rjk_cv_finkprefix}/include/gc -isystem ${rjk_cv_finkprefix}/include"
 403   if test $want_server = yes; then
 404     CPPFLAGS="${CPPFLAGS} -isystem ${rjk_cv_finkprefix}/include/db4"
 405   fi
 406   LDFLAGS="${LDFLAGS} -L${rjk_cv_finkprefix}/lib"
 407   # Distinguish 32- and 64-bit fink
 408   AC_CACHE_CHECK([whether Fink is 32-bit or 64-bit],[rjk_cv_finkbits],[
 409     odata=`otool -v -h $finkbindir/dpkg`
 410     case "$odata" in
 411     *X86_64* )
 412       rjk_cv_finkbits=64
 413       ;;
 414     *I386* )
 415       rjk_cv_finkbits=32
 416       ;;
 417     * )
 418       rjk_cv_finkbits=unknown
 419       ;;
 420     esac
 421   ])
 422   # Match Fink so we can use its libraries
 423   case $rjk_cv_finkbits in
 424   32 | 64 )
 425     CC="$CC -m$rjk_cv_finkbits"
 426     ;;
 427   esac
 428 else
 429   finkbindir=""
 430 fi
 431 AC_SUBST([finkdir])
 432 AC_SUBST([finkbindir])
 433
 434 # Checks for libraries.
 435 # We save up a list of missing libraries that we can't do without
 436 # and report them all at once.
 437 AC_CHECK_LIB(gc, GC_malloc,            [AC_SUBST(LIBGC,[-lgc])],
 438             [missing_libraries="$missing_libraries libgc"])
 439 AC_CHECK_LIB(gcrypt, gcry_md_open,
 440              [AC_SUBST(LIBGCRYPT,[-lgcrypt])],
 441             [missing_libraries="$missing_libraries libgcrypt"])
 442 AC_CHECK_LIB(pcre, pcre_compile,
 443              [AC_SUBST(LIBPCRE,[-lpcre])],
 444              [missing_libraries="$missing_libraries libpcre"])
 445 if test $want_alsa = yes; then
 446   AC_CHECK_LIB([asound], [snd_pcm_open],
 447                [AC_SUBST(LIBASOUND,[-lasound])])
 448 fi
 449 AC_CHECK_LIB([samplerate],[src_new],
 450              [AC_SUBST([LIBSAMPLERATE],[-lsamplerate])])
 451 if test $want_server = yes; then
 452   RJK_CHECK_LIB(db, db_create, [#include <db.h>],
 453                [AC_SUBST(LIBDB,[-ldb])],
 454                [missing_libraries="$missing_libraries libdb"])
 455   AC_CHECK_LIB(vorbis, vorbis_info_clear,
 456                [:],
 457                [missing_libraries="$missing_libraries libvorbis"])
 458   AC_CHECK_LIB(vorbisfile, ov_open,
 459                [AC_SUBST(LIBVORBISFILE,["-lvorbisfile -lvorbis"])],
 460                [missing_libraries="$missing_libraries libvorbisfile"],
 461                [-lvorbis])
 462   AC_CHECK_LIB(mad, mad_stream_init,
 463                [AC_SUBST(LIBMAD,[-lmad])],
 464                [missing_libraries="$missing_libraries libmad"])
 465   AC_CHECK_LIB([ao], [ao_initialize],
 466                [AC_SUBST(LIBAO,[-lao])],
 467                [missing_libraries="$missing_libraries libao"])
 468   AC_CHECK_LIB([FLAC], [FLAC__stream_decoder_new],
 469                [AC_SUBST(LIBFLAC,[-lFLAC])],
 470                [missing_libraries="$missing_libraries libFLAC"])
 471   if test $ac_cv_lib_ao_ao_initialize = yes; then
 472     # libao 1.0.0 breaks the plugin interface
 473     AC_CACHE_CHECK([whether libao has a working plugin interface],
 474                    [rjk_cv_libao_plugin_api_works],[
 475       AC_COMPILE_IFELSE([#include <ao/ao.h>
 476 #include <ao/plugin.h>
 477
 478 int ao_plugin_device_init(ao_device *d) {
 479   d->internal = 0;
 480 }],[rjk_cv_libao_plugin_api_works=yes],[rjk_cv_libao_plugin_api_works=no])])
 481   else
 482     rjk_cv_libao_plugin_api_works=no
 483   fi
 484 fi
 485 AC_CHECK_LIB([pthread], [pthread_create],
 486              [AC_SUBST(LIBPTHREAD,[-lpthread])],
 487              [missing_libraries="$missing_libraries libpthread"])
 488
 489 if test $want_gtk = yes; then
 490   if test $want_gtkosx = yes; then
 491     GTK_CFLAGS="-isystem /Library/Frameworks/Gtk.framework/Headers -isystem /Library/Frameworks/Cairo.framework/Headers"
 492     GLIB_CFLAGS="-isystem /Library/Frameworks/GLib.framework/Headers"
 493     GTK_LIBS="-framework Gtk -framework GLib"
 494   else
 495     AM_PATH_GLIB_2_0([],[],[missing_libraries="$missing_libraries libglib"])
 496     AM_PATH_GTK_2_0([],[],[missing_libraries="$missing_libraries libgtk"])
 497   fi
 498 fi
 499
 500 # Some platforms have iconv already
 501 AC_CHECK_FUNC(iconv_open, [:],
 502               [RJK_CHECK_LIB(iconv, iconv_open, [#include <iconv.h>],
 503                             [AC_SUBST(LIBICONV,[-liconv])],
 504                             [missing_functions="$missing_functions iconv_open"])])
 505 AC_CHECK_FUNC([gethostbyname],[:],[
 506   AC_CHECK_LIB(nsl,gethostbyname,
 507                [AC_SUBST(LIBNSL,[-lnsl])],
 508                [missing_functions="$missing_functions gethostbyname"])])
 509 AC_CHECK_FUNC([socket],[:],[
 510   AC_CHECK_LIB(socket,socket,
 511                [AC_SUBST(LIBSOCKET,[-lsocket])],
 512                [missing_functions="$missing_functions socket"])])
 513 AC_CHECK_FUNC([dlopen],[:],[
 514   AC_CHECK_LIB(dl,dlopen,
 515                [AC_SUBST(LIBDL,[-ldl])],
 516                [missing_functions="$missing_functions dlopen"])])
 517
 518 if test ! -z "$missing_libraries"; then
 519   AC_MSG_ERROR([missing libraries:$missing_libraries])
 520 fi
 521
 522 # Checks for header files.
 523 RJK_FIND_GC_H
 524 if test $want_oss = yes; then
 525   AC_CHECK_HEADERS([sys/soundcard.h])
 526 fi
 527 if test $want_alsa = yes; then
 528   AC_CHECK_HEADERS([alsa/asoundlib.h])
 529 fi
 530 if test $want_coreaudio = yes; then
 531   AC_CHECK_HEADERS([CoreAudio/AudioHardware.h])
 532 fi
 533 AC_CHECK_HEADERS([inttypes.h])
 534 # We don't bother checking very standard stuff
 535 # Compilation will fail if any of these headers are missing, so we
 536 # check for them here and fail early.
 537 if test $want_server = yes; then
 538   AC_CHECK_HEADERS([db.h],[:],[
 539     missing_headers="$missing_headers $ac_header"
 540   ])
 541   AC_CHECK_HEADERS([FLAC/file_decoder.h])
 542 fi
 543 AC_CHECK_HEADERS([dlfcn.h gcrypt.h \
 544                  getopt.h iconv.h langinfo.h \
 545                  pcre.h sys/ioctl.h \
 546                  syslog.h unistd.h],[:],[
 547   missing_headers="$missing_headers $ac_header"
 548 ])
 549 AC_CHECK_HEADERS([samplerate.h])
 550
 551 if test ! -z "$missing_headers"; then
 552   AC_MSG_ERROR([missing headers:$missing_headers])
 553 fi
 554
 555 # We require that libpcre support UTF-8
 556 RJK_REQUIRE_PCRE_UTF8([-lpcre])
 557
 558 # Checks for typedefs, structures, and compiler characteristics.
 559 AC_C_CONST
 560 AC_TYPE_SIZE_T
 561 AC_C_INLINE
 562 AC_C_BIGENDIAN
 563 AC_CHECK_TYPES([struct sockaddr_in6],,,[AC_INCLUDES_DEFAULT
 564 #include <netinet/in.h>])
 565
 566 # enable -Werror when we check for certain characteristics:
 567
 568 old_CFLAGS="${CFLAGS}"
 569 CFLAGS="${CFLAGS} $gcc_werror"
 570 AC_CHECK_TYPES([long long,uint32_t,uint8_t,intmax_t,uintmax_t])
 571
 572 # Some GCC invocations warn for converting function pointers to void *.
 573 # This is fair enough, as it's technically forbidden, but we use dlsym()
 574 # which can pretty much only exist if object and function pointers are
 575 # interconvertable.  So we disable -Werror if need be.
 576 if test ! -z "$gcc_werror"; then
 577   AC_CACHE_CHECK([whether function pointers can be converted to void * without a warning],
 578                  [rjk_cv_function_pointer_cast],[
 579     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 580   void somefunction(void);],
 581                       [(void *)somefunction])],
 582                       [rjk_cv_function_pointer_cast=yes],
 583                       [rjk_cv_function_pointer_cast=no])])
 584   if test $rjk_cv_function_pointer_cast = no; then
 585     gcc_werror=""
 586   fi
 587 fi
 588
 589 CFLAGS="${old_CFLAGS}"
 590
 591 # gcrypt maintainers keep changing everything.  Design your interface
 592 # first, then implement it once, rather than getting it wrong three or
 593 # four times and shipping between each attempt.
 594 AC_CACHE_CHECK([for hash handle type in <grypt.h>],
 595                [rjk_cv_gcrypt_hash_handle],[
 596   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 597 #include <gcrypt.h>
 598 ],
 599                [gcry_md_hd_t h;])],
 600                [rjk_cv_gcrypt_hash_handle=gcry_md_hd_t],[
 601     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 602 #include <gcrypt.h>
 603 ],
 604                  [GcryMDHd h;])],
 605                  [rjk_cv_gcrypt_hash_handle=GcryMDHd],
 606                  [rjk_cv_gcrypt_hash_handle=GCRY_MD_HD])])])
 607 AC_DEFINE_UNQUOTED([gcrypt_hash_handle],[$rjk_cv_gcrypt_hash_handle],
 608                    [libgcrypt hash handle type])
 609
 610 AC_CACHE_CHECK([for gcry_error_t in <grypt.h>],
 611                [rjk_cv_have_gcry_error_t],[
 612   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 613 #include <gcrypt.h>
 614 ],
 615                  [gcry_error_t e;])],
 616                  [rjk_cv_have_gcry_error_t=yes],
 617                  [rjk_cv_have_gcry_error_t=no])])
 618 if test $rjk_cv_have_gcry_error_t = yes; then
 619   AC_DEFINE([HAVE_GCRY_ERROR_T],1,[define if <gcrypt.h> defines gcry_error_t])
 620 fi
 621
 622 # Checks for functions
 623 if test $ac_cv_type_long_long = yes; then
 624   AC_CHECK_FUNCS([atoll strtoll],[:],[
 625     missing_functions="$missing_functions $ac_func"
 626   ])
 627   # Darwin sometimes fails to declare strtoll (e.g. if you ask for -std=c99)
 628   AC_CACHE_CHECK([whether strtoll is declared in <stdlib.h>],
 629                  [rjk_cv_strtoll_declared],[
 630     AC_EGREP_HEADER([strtoll], [stdlib.h],
 631                     [rjk_cv_strtoll_declared=yes],
 632                     [rjk_cv_strtoll_declared=no])])
 633   if test $rjk_cv_strtoll_declared = yes; then
 634     AC_DEFINE([DECLARES_STRTOLL],[1],[define if <stdlib.h> declares strtoll])
 635   fi
 636   AC_CACHE_CHECK([whether atoll is declared in <stdlib.h>],
 637                  [rjk_cv_atoll_declared],[
 638     AC_EGREP_HEADER([atoll], [stdlib.h],
 639                     [rjk_cv_atoll_declared=yes],
 640                     [rjk_cv_atoll_declared=no])])
 641   if test $rjk_cv_atoll_declared = yes; then
 642     AC_DEFINE([DECLARES_ATOLL],[1],[define if <stdlib.h> declares atoll])
 643   fi
 644 fi
 645 AC_CHECK_FUNCS([ioctl nl_langinfo strsignal setenv unsetenv],[:],[
 646   missing_functions="$missing_functions $ac_func"
 647 ])
 648 # fsync will do if fdatasync not available
 649 AC_CHECK_FUNCS([fdatasync],[:],[
 650   AC_CHECK_FUNCS([fsync],
 651                  [AC_DEFINE([fdatasync],[fsync],[define fdatasync to fsync if not available])],
 652                  [missing_functions="$missing_functions fdatasync"])])
 653 if test ! -z "$missing_functions"; then
 654   AC_MSG_ERROR([missing functions:$missing_functions])
 655 fi
 656
 657 # Functions we can take or leave
 658 AC_CHECK_FUNCS([fls])
 659
 660 if test $want_server = yes; then
 661   # <db.h> had better be version 3 or later
 662   AC_CACHE_CHECK([db.h version],[rjk_cv_db_version],[
 663     AC_PREPROC_IFELSE([
 664                        #include <db.h>
 665                        #ifndef DB_VERSION_MAJOR
 666                        # error cannot determine db version
 667                        #endif
 668                        #if DB_VERSION_MAJOR < 4
 669                        # error inadequate db version
 670                        #endif
 671                        #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR <= 2
 672                        # error inadequate db version
 673                        #endif
 674                       ],
 675                       [rjk_cv_db_version=ok],
 676                       [rjk_cv_db_version=inadequate])
 677     if test $rjk_cv_db_version = ok; then
 678       AC_PREPROC_IFELSE([
 679                          #include <db.h>
 680                          #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR == 6
 681                          # error http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=510270
 682                          #endif
 683                         ],
 684                         [rjk_cv_db_version=ok],
 685                         [rjk_cv_db_version=toxic])
 686     fi
 687   ])
 688   case $rjk_cv_db_version in
 689   ok )
 690     ;;
 691   inadequate )
 692     AC_MSG_ERROR([need db version at least 4.3 (but not 4.6)])
 693     ;;
 694   toxic )
 695     AC_MSG_ERROR([db version 4.6.x does not work - see debian bug 510270])
 696     ;;
 697   esac
 698 fi
 699
 700 AM_CONDITIONAL([SERVER], [test x$want_server = xyes])
 701 if test $want_gtk = yes; then
 702   AC_DEFINE([WITH_GTK], [1], [define if using GTK+])
 703 fi
 704 AM_CONDITIONAL([GTK], [test x$want_gtk = xyes])
 705
 706 if test "x$GCC" = xyes; then
 707   # We need LLONG_MAX and annoyingly GCC doesn't always give it to us
 708   # by default.
 709   AC_CACHE_CHECK([what C version to ask for],[rjk_cv_cstd],[
 710     AC_TRY_COMPILE([#include <limits.h>],[
 711       long long n = LLONG_MAX;
 712     ],[rjk_cv_cstd=default],[
 713       old_CC="$CC"
 714       CC="${CC} -std=gnu99"
 715       AC_TRY_COMPILE([#include <limits.h>],[
 716         long long n = LLONG_MAX;
 717       ],[rjk_cv_cstd=gnu99],[rjk_cv_cstd=unknown])
 718       CC="$old_CC"
 719     ])
 720   ])
 721   case $rjk_cv_cstd in
 722   default | unknown )
 723     ;;
 724   * )
 725     CC="${CC} -std=${rjk_cv_cstd}"
 726     ;;
 727   esac
 728
 729   # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=29478
 730   AC_CACHE_CHECK([checking for GCC bug 29478],[rjk_cv_pr29478],[
 731     old_CC="$CC"
 732     if test $GCC = yes; then
 733       CC="$CC -Wall -Werror"
 734     fi
 735     AC_COMPILE_IFELSE([
 736       static int x(char *f) {
 737        return *f;
 738       }
 739       int z(const char *g) {
 740         return x((char *)g);
 741       }],
 742       [rjk_cv_pr29478=no],
 743       [rjk_cv_pr29478=yes]
 744     )
 745     CC="$old_CC"
 746   ])
 747   if test $rjk_cv_pr29478 = yes; then
 748     gcc_werror=''
 749   fi
 750
 751   AC_CACHE_CHECK([checking for excessively strict -Wreturn-type],
 752                  [rjk_cv_gcc44_stupidity],[
 753     old_CC="$CC"
 754     if test $GCC = yes; then
 755       CC="$CC -Wreturn-type -Werror"
 756     fi
 757     AC_COMPILE_IFELSE([
 758       static void *threadfn(void) {
 759         for(;;)
 760           ;
 761       }],
 762       [rjk_cv_gcc44_stupidity=no],
 763       [rjk_cv_gcc44_stupidity=yes])
 764     CC="$old_CC"
 765   ])
 766   if test $rjk_cv_gcc44_stupidity = yes; then
 767     AC_DEFINE([HAVE_STUPID_GCC44],[1],[Define if your compiler has excessively strict -Wreturn-type])
 768   fi
 769
 770   # a reasonable default set of warnings
 771   CC="${CC} -Wall -W -Wpointer-arith -Wbad-function-cast \
 772         -Wwrite-strings -Wmissing-prototypes \
 773         -Wmissing-declarations -Wnested-externs"
 774
 775   # Fix up GTK+ and GLib compiler flags
 776   GTK_CFLAGS="`echo \"$GTK_CFLAGS\"|sed 's/-I/-isystem /g'`"
 777   GLIB_CFLAGS="`echo \"$GLIB_CFLAGS\"|sed 's/-I/-isystem /g'`"
 778
 779   if test "$gcc_werror" != ''; then
 780     # GCC 2.95 doesn't know to ignore warnings from system headers
 781     AC_CACHE_CHECK([whether -Werror is usable],
 782                     rjk_cv_werror, [
 783       save_CFLAGS="${CFLAGS}"
 784       CFLAGS="${CFLAGS} ${GTK_CFLAGS} -Werror"
 785       AC_TRY_COMPILE([#if WITH_GTK
 786  #include <gtk/gtk.h>
 787 #endif
 788
 789 struct s { int a, b; };
 790 const struct s sv = { .a = 1 };],
 791                      [],
 792                      [rjk_cv_werror=yes],
 793                      [rjk_cv_werror=no])
 794       CFLAGS="${save_CFLAGS}"
 795     ])
 796     if test $rjk_cv_werror = no; then
 797       gcc_werror=''
 798     fi
 799   fi
 800   CC="${CC} $gcc_werror"
 801
 802   # for older GCCs that don't know %ju (etc)
 803   AC_CACHE_CHECK([whether -Wno-format is required],
 804                  rjk_cv_noformat,
 805                  AC_TRY_COMPILE([#include <stdio.h>
 806 #include <stdint.h>
 807 ],
 808                                 [printf("%ju", (uintmax_t)0);],
 809                                 [rjk_cv_noformat=no],
 810                                 [rjk_cv_noformat=yes]))
 811   if test $rjk_cv_noformat = yes; then
 812     CC="${CC} -Wno-format"
 813   fi
 814
 815   AC_CACHE_CHECK([whether -Wshadow is OK],
 816                  rjk_cv_shadow,
 817                  oldCC="${CC}"
 818                  CC="${CC} -Wshadow"
 819                  [AC_TRY_COMPILE([
 820 #include <unistd.h>
 821 #include <vorbis/vorbisfile.h>
 822 ],
 823                                 [],
 824                                 [rjk_cv_shadow=yes],
 825                                 [rjk_cv_shadow=no])
 826                  CC="${oldCC}"])
 827   if test $rjk_cv_shadow = yes; then
 828     CC="${CC} -Wshadow"
 829   fi
 830 fi
 831
 832 RJK_GCOV
 833
 834 AH_BOTTOM([#ifdef __GNUC__
 835 # define attribute(x) __attribute__(x)
 836 #else
 837 # define attribute(x)
 838 #endif])
 839
 840 AC_CONFIG_FILES([Makefile
 841                  images/Makefile
 842                  scripts/Makefile
 843                  lib/Makefile
 844                  server/Makefile
 845                  cgi/Makefile
 846                  clients/Makefile
 847                  disobedience/Makefile
 848                  disobedience/manual/Makefile
 849                  doc/Makefile
 850                  templates/Makefile
 851                  plugins/Makefile
 852                  driver/Makefile
 853                  debian/Makefile
 854                  sounds/Makefile
 855                  python/Makefile
 856                  examples/Makefile
 857                  libtests/Makefile
 858                  tests/Makefile])
 859 AC_OUTPUT
 860
 861 if test $GCC = yes && test "$gcc_werror" = ''; then
 862   AC_MSG_WARN([building without -Werror])
 863 fi
 864 if test $want_python = no; then
 865   AC_MSG_WARN([cannot run the test suit without Python])
 866 fi
 867 if test $want_server = yes && test "$ac_cv_lib_samplerate_src_new" != yes; then
 868   AC_MSG_WARN([libsamplerate will be required in a future version])
 869 fi
 870
 871 # Local Variables:
 872 # indent-tabs-mode:nil
 873 # End: