chiark - git - mdw - disorder/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #
   3 # This file is part of DisOrder.
   4 # Copyright (C) 2004, 2005, 2006, 2007 Richard Kettlewell
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 # General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  19 # USA
  20 #
  21
  22 AC_INIT(disorder, 1.5.99+, richard+disorder@sfere.greenend.org.uk)
  23 AC_CONFIG_AUX_DIR([config.aux])
  24 AM_INIT_AUTOMAKE(disorder, 1.5.99+)
  25 AC_CONFIG_SRCDIR([server/disorderd.c])
  26 AM_CONFIG_HEADER([config.h])
  27
  28 # Find host type
  29 AC_CANONICAL_HOST
  30
  31 # What we want to build
  32 want_server=yes
  33 want_gtk=yes
  34 want_python=yes
  35
  36 case "$host" in
  37 *linux* | *Linux* )
  38   want_alsa=yes
  39   ;;
  40 * )
  41   want_alsa=no
  42   ;;
  43 esac
  44
  45 # Checks for programs.
  46 AC_PROG_CC
  47 AC_SET_MAKE
  48 if test "x$GCC" = xyes; then
  49   gcc_werror=-Werror
  50 else
  51   gcc_werror=""
  52 fi
  53
  54 AC_ARG_WITH([server],
  55             [AS_HELP_STRING([--without-server],
  56                             [do not build server])],
  57             [want_server=$withval])
  58 AC_ARG_WITH([gtk],
  59             [AS_HELP_STRING([--without-gtk],
  60                             [do not build GTK+ client])],
  61             [want_gtk=$withval])
  62 AC_ARG_WITH([python],
  63             [AS_HELP_STRING([--without-python],
  64                             [do not build Python support])],
  65             [want_python=$withval])
  66
  67 subdirs="scripts lib clients doc examples debian"
  68
  69 if test $want_server = yes; then
  70   subdirs="${subdirs} server plugins driver templates sounds images"
  71 fi
  72 if test $want_python = yes; then
  73   AM_PATH_PYTHON
  74   subdirs="${subdirs} python"
  75 fi
  76 if test $want_gtk = yes; then
  77   subdirs="${subdirs} disobedience"
  78   if test $want_server = no; then
  79     subdirs="${subdirs} images"
  80   fi
  81 fi
  82 AC_SUBST([subdirs])
  83
  84 # libtool config
  85 AC_LIBTOOL_DLOPEN
  86 AC_DISABLE_STATIC
  87
  88 AC_PROG_LIBTOOL
  89
  90 missing_libraries=""
  91 missing_headers=""
  92 missing_functions=""
  93
  94 AC_DEFINE(_GNU_SOURCE, 1, [required for e.g. strsignal])
  95
  96 # Macs might have libraries under fink's root
  97 AC_PATH_PROG([FINK],[fink],[none],[$PATH:/sw/bin])
  98 if test "x$FINK" != xnone; then
  99   AC_CACHE_CHECK([fink install directory],[rjk_cv_finkprefix],[
 100     rjk_cv_finkprefix="`echo "$FINK" | sed 's,/bin/fink$,,'`"
 101   ])
 102   CPPFLAGS="${CPPFLAGS} -I${rjk_cv_finkprefix}/include"
 103   if test $want_server = yes; then
 104     CPPFLAGS="${CPPFLAGS} -I${rjk_cv_finkprefix}/include/db4"
 105   fi
 106   LDFLAGS="${LDFLAGS} -L${rjk_cv_finkprefix}/lib"
 107 fi
 108
 109 # Checks for libraries.
 110 # We save up a list of missing libraries that we can't do without
 111 # and report them all at once.
 112 AC_CHECK_LIB(gc, GC_malloc,            [AC_SUBST(LIBGC,[-lgc])],
 113             [missing_libraries="$missing_libraries libgc"])
 114 AC_CHECK_LIB(gcrypt, gcry_md_open,
 115              [AC_SUBST(LIBGCRYPT,[-lgcrypt])],
 116             [missing_libraries="$missing_libraries libgcrypt"])
 117 AC_CHECK_LIB(pcre, pcre_compile,
 118              [AC_SUBST(LIBPCRE,[-lpcre])],
 119              [missing_libraries="$missing_libraries libpcre"])
 120 if test $want_server = yes; then
 121   RJK_CHECK_LIB(db, db_create, [#include <db.h>],
 122                [AC_SUBST(LIBDB,[-ldb])],
 123                [missing_libraries="$missing_libraries libdb"])
 124   AC_CHECK_LIB(vorbis, vorbis_info_clear,
 125                [:],
 126                [missing_libraries="$missing_libraries libvorbis"])
 127   AC_CHECK_LIB(vorbisfile, ov_open,
 128                [AC_SUBST(LIBVORBISFILE,["-lvorbisfile -lvorbis"])],
 129                [missing_libraries="$missing_libraries libvorbisfile"],
 130                [-lvorbis])
 131   AC_CHECK_LIB(mad, mad_stream_init,
 132                [AC_SUBST(LIBMAD,[-lmad])],
 133                [missing_libraries="$missing_libraries libmad"])
 134   AC_CHECK_LIB([ao], [ao_initialize],
 135                [AC_SUBST(LIBAO,[-lao])],
 136                [missing_libraries="$missing_libraries libao"])
 137   if test $want_alsa = yes; then
 138     AC_CHECK_LIB([asound], [snd_pcm_open],
 139                  [AC_SUBST(LIBASOUND,[-lasound])],
 140                  [missing_libraries="$missing_libraries libasound"])
 141     AC_DEFINE([API_ALSA],[1],[define to use the ALSA API])
 142   fi
 143 fi
 144
 145 if test $want_gtk = yes; then
 146   AM_PATH_GLIB_2_0([],[],[missing_libraries="$missing_libraries libglib"])
 147   AM_PATH_GTK_2_0([],[],[missing_libraries="$missing_libraries libgtk"])
 148 fi
 149
 150 # Some platforms have iconv already
 151 AC_CHECK_FUNC(iconv_open, [:],
 152               [RJK_CHECK_LIB(iconv, iconv_open, [#include <iconv.h>],
 153                             [AC_SUBST(LIBICONV,[-liconv])],
 154                             [missing_functions="$missing_functions iconv_open"])])
 155 AC_CHECK_FUNC([gethostbyname],[:],[
 156   AC_CHECK_LIB(nsl,gethostbyname,
 157                [AC_SUBST(LIBNSL,[-lnsl])],
 158                [missing_functions="$missing_functions gethostbyname"])])
 159 AC_CHECK_FUNC([socket],[:],[
 160   AC_CHECK_LIB(socket,socket,
 161                [AC_SUBST(LIBSOCKET,[-lsocket])],
 162                [missing_functions="$missing_functions socket"])])
 163 AC_CHECK_FUNC([dlopen],[:],[
 164   AC_CHECK_LIB(dl,dlopen,
 165                [AC_SUBST(LIBDL,[-ldl])],
 166                [missing_functions="$missing_functions dlopen"])])
 167
 168 if test ! -z "$missing_libraries"; then
 169   AC_MSG_ERROR([missing libraries:$missing_libraries])
 170 fi
 171
 172 # We require that libpcre support UTF-8
 173 RJK_REQUIRE_PCRE_UTF8([-lpcre])
 174
 175 # Checks for header files.
 176 RJK_FIND_GC_H
 177 AC_CHECK_HEADERS([inttypes.h])
 178 # Compilation will fail if any of these headers are missing, so we
 179 # check for them here and fail early.
 180 # We don't bother checking very standard stuff
 181 if test $want_server = yes; then
 182   AC_CHECK_HEADERS([db.h],[:],[
 183     missing_headers="$missing_headers $ac_header"
 184   ])
 185   AC_CHECK_HEADERS([sys/soundcard.h]) dnl can cope without
 186 fi
 187 AC_CHECK_HEADERS([dlfcn.h gcrypt.h \
 188                  getopt.h iconv.h langinfo.h \
 189                  pcre.h sys/ioctl.h \
 190                  syslog.h unistd.h],[:],[
 191   missing_headers="$missing_headers $ac_header"
 192 ])
 193
 194 if test ! -z "$missing_headers"; then
 195   AC_MSG_ERROR([missing headers:$missing_headers])
 196 fi
 197
 198 # Checks for typedefs, structures, and compiler characteristics.
 199 AC_C_CONST
 200 AC_TYPE_SIZE_T
 201 AC_C_INLINE
 202 AC_CHECK_TYPES([struct sockaddr_in6],,,[AC_INCLUDES_DEFAULT
 203 #include <netinet/in.h>])
 204
 205 # enable -Werror when we check for certain characteristics:
 206
 207 old_CFLAGS="${CFLAGS}"
 208 CFLAGS="${CFLAGS} $gcc_werror"
 209 AC_CHECK_TYPES([long long,uint32_t,uint8_t,intmax_t,uintmax_t])
 210
 211 # Some GCC invocations warn for converting function pointers to void *.
 212 # This is fair enough, as it's technically forbidden, but we use dlsym()
 213 # which can pretty much only exist if object and function pointers are
 214 # interconvertable.  So we disable -Werror if need be.
 215 if test ! -z "$gcc_werror"; then
 216   AC_CACHE_CHECK([whether function pointers can be converted to void * without a warning],
 217                  [rjk_cv_function_pointer_cast],[
 218     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 219   void somefunction(void);],
 220                       [(void *)somefunction])],
 221                       [rjk_cv_function_pointer_cast=yes],
 222                       [rjk_cv_function_pointer_cast=no])])
 223   if test $rjk_cv_function_pointer_cast = no; then
 224     gcc_werror=""
 225   fi
 226 fi
 227
 228 CFLAGS="${old_CFLAGS}"
 229
 230 # gcrypt maintainers keep changing everything.  Design your interface
 231 # first, then implement it once, rather than getting it wrong three or
 232 # four times and shipping between each attempt.
 233 AC_CACHE_CHECK([for hash handle type in <grypt.h>],
 234                [rjk_cv_gcrypt_hash_handle],[
 235   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 236 #include <gcrypt.h>
 237 ],
 238                [gcry_md_hd_t h;])],
 239                [rjk_cv_gcrypt_hash_handle=gcry_md_hd_t],[
 240     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 241 #include <gcrypt.h>
 242 ],
 243                  [GcryMDHd h;])],
 244                  [rjk_cv_gcrypt_hash_handle=GcryMDHd],
 245                  [rjk_cv_gcrypt_hash_handle=GCRY_MD_HD])])])
 246 AC_DEFINE_UNQUOTED([gcrypt_hash_handle],[$rjk_cv_gcrypt_hash_handle],
 247                    [libgcrypt hash handle type])
 248
 249 AC_CACHE_CHECK([for gcry_error_t in <grypt.h>],
 250                [rjk_cv_have_gcry_error_t],[
 251   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 252 #include <gcrypt.h>
 253 ],
 254                  [gcry_error_t e;])],
 255                  [rjk_cv_have_gcry_error_t=yes],
 256                  [rjk_cv_have_gcry_error_t=no])])
 257 if test $rjk_cv_have_gcry_error_t = yes; then
 258   AC_DEFINE([HAVE_GCRY_ERROR_T],1,[define if <gcrypt.h> defines gcry_error_t])
 259 fi
 260
 261 # Checks for functions
 262 if test $ac_cv_type_long_long = yes; then
 263   AC_CHECK_FUNCS([atoll strtoll],[:],[
 264     missing_functions="$missing_functions $ac_func"
 265   ])
 266   # Darwin sometimes fails to declare strtoll (e.g. if you ask for -std=c99)
 267   AC_CACHE_CHECK([whether strtoll is declared in <stdlib.h>],
 268                  [rjk_cv_strtoll_declared],[
 269     AC_EGREP_HEADER([strtoll], [stdlib.h],
 270                     [rjk_cv_strtoll_declared=yes],
 271                     [rjk_cv_strtoll_declared=no])])
 272   if test $rjk_cv_strtoll_declared = yes; then
 273     AC_DEFINE([DECLARES_STRTOLL],[1],[define if <stdlib.h> declares strtoll])
 274   fi
 275   AC_CACHE_CHECK([whether atoll is declared in <stdlib.h>],
 276                  [rjk_cv_atoll_declared],[
 277     AC_EGREP_HEADER([atoll], [stdlib.h],
 278                     [rjk_cv_atoll_declared=yes],
 279                     [rjk_cv_atoll_declared=no])])
 280   if test $rjk_cv_atoll_declared = yes; then
 281     AC_DEFINE([DECLARES_ATOLL],[1],[define if <stdlib.h> declares atoll])
 282   fi
 283 fi
 284 AC_CHECK_FUNCS([ioctl nl_langinfo strsignal],[:],[
 285   missing_functions="$missing_functions $ac_func"
 286 ])
 287 # fsync will do if fdatasync not available
 288 AC_CHECK_FUNCS([fdatasync],[:],[
 289   AC_CHECK_FUNCS([fsync],
 290                  [AC_DEFINE([fdatasync],[fsync],[define fdatasync to fsync if not available])],
 291                  [missing_functions="$missing_functions fdatasync"])])
 292 if test ! -z "$missing_functions"; then
 293   AC_MSG_ERROR([missing functions:$missing_functions])
 294 fi
 295 if test $want_server = yes; then
 296   # <db.h> had better be version 3 or later
 297   AC_CACHE_CHECK([db.h version],[rjk_cv_db_version],[
 298     AC_PREPROC_IFELSE([
 299                        #include <db.h>
 300                        #ifndef DB_VERSION_MAJOR
 301                        # error cannot determine db version
 302                        #endif
 303                        #if DB_VERSION_MAJOR < 4
 304                        # error inadequate db version
 305                        #endif
 306                        #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR < 2
 307                        # error inadequate db version
 308                        #endif
 309                       ],
 310                       [rjk_cv_db_version=ok],
 311                       [rjk_cv_db_version=inadequate])
 312   ])
 313   if test $rjk_cv_db_version != ok; then
 314     AC_MSG_ERROR([need db.h version at least 4.2])
 315   fi
 316 fi
 317
 318 if test "x$GCC" = xyes; then
 319   # a reasonable default set of warnings
 320   CC="${CC} -Wall -W -Wpointer-arith -Wbad-function-cast \
 321         -Wwrite-strings -Wmissing-prototypes \
 322         -Wmissing-declarations -Wnested-externs"
 323
 324   # Fix up GTK+ and GLib compiler flags
 325   GTK_CFLAGS="`echo \"$GTK_CFLAGS\"|sed 's/-I/-isystem /g'`"
 326   GLIB_CFLAGS="`echo \"$GLIB_CFLAGS\"|sed 's/-I/-isystem /g'`"
 327
 328   # GCC 2.95 doesn't know to ignore warnings from system headers
 329   AC_CACHE_CHECK([whether -Werror is usable],
 330                   rjk_cv_werror, [
 331     save_CFLAGS="${CFLAGS}"
 332     CFLAGS="${CFLAGS} ${GTK_CFLAGS} -Werror"
 333     AC_TRY_COMPILE([#include <gtk/gtk.h>],
 334                    [],
 335                    [rjk_cv_werror=yes],
 336                    [rjk_cv_werror=no])
 337     CFLAGS="${save_CFLAGS}"
 338   ])
 339   if test $rjk_cv_werror = no; then
 340     gcc_werror=''
 341   fi
 342   CC="${CC} $gcc_werror"
 343
 344   # for older GCCs that don't know %ju (etc)
 345   AC_CACHE_CHECK([whether -Wno-format is required],
 346                  rjk_cv_noformat,
 347                  AC_TRY_COMPILE([#include <stdio.h>
 348 #include <stdint.h>
 349 ],
 350                                 [printf("%ju", (uintmax_t)0);],
 351                                 [rjk_cv_noformat=no],
 352                                 [rjk_cv_noformat=yes]))
 353   if test $rjk_cv_noformat = yes; then
 354     CC="${CC} -Wno-format"
 355   fi
 356
 357   AC_CACHE_CHECK([whether -Wshadow is OK],
 358                  rjk_cv_shadow,
 359                  oldCC="${CC}"
 360                  CC="${CC} -Wshadow"
 361                  [AC_TRY_COMPILE([
 362 #include <unistd.h>
 363 #include <vorbis/vorbisfile.h>
 364 ],
 365                                 [],
 366                                 [rjk_cv_shadow=yes],
 367                                 [rjk_cv_shadow=no])
 368                  CC="${oldCC}"])
 369   if test $rjk_cv_shadow = yes; then
 370     CC="${CC} -Wshadow"
 371   fi
 372
 373
 374 fi
 375
 376 AH_BOTTOM([#ifdef __GNUC__
 377 # define attribute(x) __attribute__(x)
 378 #else
 379 # define attribute(x)
 380 #endif])
 381
 382 AC_CONFIG_FILES([Makefile
 383                  templates/Makefile
 384                  images/Makefile
 385                  scripts/Makefile
 386                  lib/Makefile
 387                  server/Makefile
 388                  clients/Makefile
 389                  disobedience/Makefile
 390                  doc/Makefile
 391                  plugins/Makefile
 392                  driver/Makefile
 393                  debian/Makefile
 394                  sounds/Makefile
 395                  python/Makefile
 396                  examples/Makefile])
 397 AC_OUTPUT