chiark - git - mdw - disorder/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #
   3 # This file is part of DisOrder.
   4 # Copyright (C) 2004-2013 Richard Kettlewell
   5 # Portions copyright (C) 2007 Ross Younger
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20
  21 AC_INIT([disorder], [5.1.1], [richard+disorder@sfere.greenend.org.uk])
  22 AC_CONFIG_AUX_DIR([config.aux])
  23 AM_INIT_AUTOMAKE([foreign])
  24 AC_CONFIG_SRCDIR([server/disorderd.c])
  25 AM_CONFIG_HEADER([config.h])
  26 AC_CONFIG_MACRO_DIR([m4])
  27
  28 # Find host type
  29 AC_CANONICAL_HOST
  30
  31 # What we want to build
  32 want_gtk=yes
  33 want_python=yes
  34 want_tests=yes
  35 want_server=yes
  36 want_cgi=yes
  37
  38 # APIs we want
  39 want_alsa=yes
  40 want_oss=yes
  41 want_coreaudio=yes
  42
  43 # By default we don't want gtk-osx.  But if you ask for --with-gtk-osx...
  44 #
  45 # Disobedience can be built to a native OS X application.  There are some
  46 # caveats:
  47 #  - you will still need Fink (or something) for other libraries
  48 #  - if you wanted an application bundle you are out of luck
  49 #  - the menu bar is still in the main window (not at the top of the screen)
  50 #  - drag and drop doesn't work
  51 #
  52 # So it's still rather rough and ready.  But it does work...
  53 #
  54 # See:
  55 #   http://www.gtk-osx.org/
  56 #   http://live.gnome.org/GTK%2B/OSX/Framework
  57 want_gtkosx=no
  58
  59 # Checks for programs.
  60 AC_PROG_CC
  61 AM_PROG_CC_C_O
  62 AC_PROG_AWK
  63 AC_SET_MAKE
  64 if test "x$GCC" = xyes; then
  65   gcc_werror=-Werror
  66   case "$CC" in
  67   *-std=* )
  68     ;;
  69   * )
  70     CC="${CC} -std=gnu99"
  71     ;;
  72   esac
  73 else
  74   AC_MSG_ERROR([GNU C is required to build this program])
  75   gcc_werror=""
  76 fi
  77
  78 AC_ARG_WITH([alsa],
  79             [AS_HELP_STRING([--without-alsa],
  80                             [do not build with ALSA support])],
  81             [want_alsa=$withval])
  82 AC_ARG_WITH([oss],
  83             [AS_HELP_STRING([--without-oss],
  84                             [do not build with OSS support])],
  85             [want_oss=$withval])
  86 AC_ARG_WITH([coreaudio],
  87             [AS_HELP_STRING([--without-coreaudio],
  88                             [do not build with Core Audio support])],
  89             [want_coreaudio=$withval])
  90 AC_ARG_WITH([tests],
  91             [AS_HELP_STRING([--without-tests],
  92                             [do not build test suit])],
  93             [want_tests=$withval])
  94 AC_ARG_WITH([gtk-osx],
  95             [AS_HELP_STRING([--with-gtk-osx],
  96                             [use native GTK+ (OS X only)])],
  97             [want_gtkosx=$withval])
  98
  99 AC_MSG_CHECKING([for a known target platform])
 100 case "$host" in
 101 *empeg* )
 102   AC_MSG_RESULT([empeg car stereo])
 103   AC_DEFINE([EMPEG_HOST],[1],[define if host is an empeg car stereo])
 104   # work around broken toolchain
 105   AC_CHECK_LIB([gpg-error], [gpg_strerror])
 106   AC_CHECK_LIB([pthread], [pthread_create])
 107   want_server=no
 108   want_cgi=no
 109  ;;
 110 *linux* | *Linux* )
 111   AC_MSG_RESULT([Linux])
 112   AC_DEFINE_UNQUOTED([PATH_PROC_MOUNTS],["/proc/mounts"],[path to kernel mount list])
 113   ;;
 114 *-apple-darwin* )
 115   AC_MSG_RESULT([Mac OS X])
 116   # AudioHardwareGetProperty is deprecated in 10.6, but it's still _there_,
 117   # so we'll just turn off the warning.
 118   CC="$CC -Wno-deprecated-declarations"
 119   if test $want_coreaudio = yes; then
 120     COREAUDIO="-framework CoreFoundation -framework CoreServices -framework CoreAudio"
 121   fi
 122   browser=open
 123   AC_MSG_CHECKING([Mac OS X target version])
 124   # We honor MACOSX_DEPLOYMENT_TARGET in the environment, emulating gcc's
 125   # behaviour.  But we provide a command line option to override it and
 126   # we default to wide support instead of supporting only the build platform.
 127   #
 128   # Currently if you ask for 10.5 you will get a deprecation warning
 129   # when building the CoreAudio support code.  For the time being the
 130   # answer to this is "don't do that then".  If a good reason to ask
 131   # for a 10.5 deployment target emerges then this will be fixed.
 132   if test -z "$MACOSX_DEPLOYMENT_TARGET"; then
 133     MACOSX_DEPLOYMENT_TARGET=10.0
 134   fi
 135   AC_ARG_WITH([deployment-target],
 136               [AS_HELP_STRING([--with-deployment-target=TARGET],
 137                               [set target OS X version])],
 138               [MACOSX_DEPLOYMENT_TARGET=$withval])
 139   # Convert to desired format
 140   underscored=`echo $MACOSX_DEPLOYMENT_TARGET|sed 's/\./_/'`
 141   minver="MAC_OS_X_VERSION_$underscored"
 142   AC_MSG_RESULT([$minver])
 143   AC_DEFINE_UNQUOTED([MAC_OS_X_VERSION_MIN_REQUIRED], [$minver],
 144                      [define to minimum version of Mac OS X to support])
 145
 146   if test $want_gtkosx = no; then
 147     # Fink's GTK+ is hopelessly broken
 148     PKG_CONFIG_PATH=${PKG_CONFIG_PATH:-/sw/lib/pango-ft219/lib/pkgconfig}
 149     export PKG_CONFIG_PATH
 150   fi
 151
 152   ;;
 153 *-freebsd* )
 154   AC_MSG_RESULT([FreeBSD])
 155   # Ports install to /usr/local but the compiler stupidly doesn't look
 156   # there by default
 157   LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 158   CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include"
 159   # Look for a suitable version of libdb among the versions found in FreeBSD 7.0
 160   AC_CACHE_CHECK([looking for a libdb install],[rjk_cv_libdb],[
 161     rjk_cv_libdb="none"
 162     for db in db43 db44 db45 db47; do
 163       if test -e /usr/local/lib/$db; then
 164         rjk_cv_libdb=$db
 165         break
 166       fi
 167     done
 168   ])
 169   if test $rjk_cv_libdb != none; then
 170     LDFLAGS="${LDFLAGS} -L/usr/local/lib/$rjk_cv_libdb"
 171     CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include/$rjk_cv_libdb"
 172   fi
 173   ;;
 174 * )
 175   AC_MSG_RESULT([unknown, winging it])
 176   ;;
 177 esac
 178 AC_SUBST([COREAUDIO])
 179
 180 AC_ARG_WITH([browser],
 181             [AS_HELP_STRING([--with-browser=BROWSER],
 182                             [use BROWSER to display HTML])],
 183             [browser=$withval])
 184
 185 AC_CACHE_CHECK([default HTML viewer],[rjk_cv_browser],[
 186   rjk_cv_browser=UNKNOWN
 187   for candidate in x-www-browser sensible-browser firefox mozilla konqueror netscape; do
 188     if type $candidate >/dev/null 2>&1; then
 189       rjk_cv_browser="$candidate"
 190       break
 191     fi
 192   done
 193 ])
 194 if test -z "$browser"; then
 195   browser="$rjk_cv_browser"
 196 fi
 197 AC_DEFINE_UNQUOTED([BROWSER],["$browser"],[HTML viewer])
 198
 199 # Figure out what version of sox is installed
 200 AC_CACHE_CHECK([sox version],[rjk_cv_soxver],[
 201   rjk_cv_soxver=UNKNOWN
 202   if sox --version > /dev/null 2>&1; then
 203     rjk_cv_soxver=`sox --version|$AWK '{ if(match($0, /[[0-9\.]]+/)) print substr($0,RSTART,RLENGTH)}'`
 204   else
 205     rjk_cv_soxver=`sox -h 2>&1|$AWK '/Version/ { if(match($0, /[[0-9\.]]+/)) print substr($0,RSTART,RLENGTH)}'`
 206   fi
 207 ])
 208
 209 # Decide what command line options to use
 210 #
 211 # sox version   endian     bits       deployed
 212 # 12.17.9       -x         -[bwld]    debian etch, ubuntu dapper
 213 # 14.0.0        -x/-[BL]   -[bwld]    ubuntu hardy
 214 # 14.0.1        -x/-[BL]   -[1248]    debian lenny
 215 # 14.2.0        -x/-[BL]   -[1248]    debian sid (at 2008-12)
 216
 217 AC_CACHE_CHECK([default sox generation],[rjk_cv_soxgen],[
 218   case $rjk_cv_soxver in
 219   [[0-9]].* | 1[[0123]].* )
 220     rjk_cv_soxgen=0
 221     ;;
 222   * )
 223     rjk_cv_soxgen=1
 224     ;;
 225   esac
 226 ])
 227 AC_DEFINE_UNQUOTED([DEFAULT_SOX_GENERATION],[$rjk_cv_soxgen],
 228                    [default sox generation])
 229
 230 AC_ARG_WITH([server],
 231             [AS_HELP_STRING([--without-server],
 232                             [do not build server])],
 233             [want_server=$withval])
 234 AC_ARG_WITH([cgi],
 235             [AS_HELP_STRING([--without-cgi],
 236                             [do not build CGI])],
 237             [want_cgi=$withval])
 238 AC_ARG_WITH([gtk],
 239             [AS_HELP_STRING([--without-gtk],
 240                             [do not build GTK+ client])],
 241             [want_gtk=$withval])
 242 AC_ARG_WITH([python],
 243             [AS_HELP_STRING([--without-python],
 244                             [do not build Python support])],
 245             [want_python=$withval])
 246
 247 if test $want_server = no; then
 248   want_cgi=no
 249 fi
 250
 251 #
 252 # OS          Document Root                  CGI directory
 253 # ==          =============                  =============
 254 # Debian      /var/www                       /usr/lib/cgi-bin
 255 # Ubuntu      /var/www                       /usr/lib/cgi-bin
 256 # Red Hat     /var/www/html                  /var/www/cgi-bin
 257 #      or:    /home/httpd/html/              /home/httpd/cgi-bin
 258 # Slackware   /var/www/htdocs                (unknown)
 259 # SuSE        /srv/www/html                  /srv/www/cgi-bin
 260 # Gentoo      /var/www/localhost/htdocs      /var/www/localhost/cgi-bin/
 261 # FreeBSD     /usr/local/www/data            /usr/local/www/cgi-bin
 262 #      or:    /usr/local/www/???/data        /usr/local/www/???/cgi-bin
 263 # OS X        /Library/WebServer/Documents   /Library/WebServer/CGI-Executables
 264 # Apache      /usr/local/apache/htdocs       (none)
 265 #
 266 # Sources:
 267 #   http://wiki.linuxquestions.org/wiki/Apache
 268 #   http://mapserver.gis.umn.edu/docs/howto/suse-linux
 269 #   http://www.yolinux.com/TUTORIALS/LinuxTutorialWebSiteConfig.html
 270 #   http://sources.gentoo.org/viewcvs.py/apache/trunk/dist/2.2/conf/vhosts.d/default_vhost.include?rev=198&view=log
 271 #   http://httpd.apache.org/docs/
 272 #
 273 if test $want_cgi = yes; then
 274   if test -z "$httpdir"; then
 275     AC_CACHE_CHECK([for httpd document root],[rjk_cv_httpdir],[
 276       rjk_cv_httpdir="not found"
 277       for dir in /var/www/html \
 278                  /var/www/htdocs \
 279                  /var/www/localhost/htdocs \
 280                  /var/www \
 281                  /home/httpd/html \
 282                  /srv/www/html \
 283                  /usr/local/www/data \
 284                  /usr/local/www/*/data \
 285                  /Library/WebServer/Documents \
 286                  /usr/local/apache/htdocs; do
 287         if test -d "$dir"; then
 288           rjk_cv_httpdir="$dir"
 289         fi
 290       done
 291     ])
 292     if test "$rjk_cv_httpdir" = "not found"; then
 293       AC_MSG_ERROR([cannot identify httpd documentroot.  Set httpdir on configure command line])
 294     fi
 295     httpdir="$rjk_cv_httpdir"
 296   fi
 297   if test ! -z "$cgidir"; then
 298     # This is a bit harsh but should stop any disasters
 299     AC_MSG_ERROR([cgidir has been renamed to cgiexecdir])
 300   fi
 301   if test -z "$cgiexecdir"; then
 302     AC_CACHE_CHECK([for CGI directory],[rjk_cv_cgiexecdir],[
 303       rjk_cv_cgiexecdir="not found"
 304       for dir in /usr/lib/cgi-bin \
 305                  /Library/WebServer/CGI-Executables \
 306                  /srv/www/cgi-bin \
 307                  /var/www/cgi-bin \
 308                  /home/httpd/cgi-bin \
 309                  /var/www/localhost/cgi-bin \
 310                  /usr/local/lib/cgi-bin \
 311                  /usr/local/www/cgi-bin \
 312                  /usr/local/www/*/cgi-bin; do
 313         if test -d "$dir"; then
 314           rjk_cv_cgiexecdir="$dir"
 315           break
 316         fi
 317       done
 318     ])
 319     if test "$rjk_cv_cgiexecdir" = "not found"; then
 320       AC_MSG_ERROR([cannot identify CGI install directory.  Set cgiexecdir on configure command line])
 321     fi
 322     cgiexecdir="$rjk_cv_cgiexecdir"
 323   fi
 324 fi
 325 AC_ARG_VAR([cgiexecdir], [location of cgi-bin directory, e.g. /usr/lib/cgi-bin])
 326 AC_ARG_VAR([httpdir], [location of http document root, e.g. /var/www/htdocs])
 327 if test -z "$pkghttpdir"; then
 328   pkghttpdir='$(httpdir)/disorder'
 329 fi
 330 AC_SUBST([pkghttpdir])
 331
 332 if test -z "$dochtmldir"; then
 333   dochtmldir='$(docdir)/html'
 334 fi
 335 AC_SUBST([dochtmldir])
 336
 337 subdirs="scripts lib"
 338 if test $want_tests = yes; then
 339   subdirs="${subdirs} libtests"
 340 fi
 341 subdirs="${subdirs} clients doc examples debian"
 342
 343 if test $want_server = yes; then
 344   subdirs="${subdirs} server plugins sounds"
 345 fi
 346 if test $want_cgi = yes; then
 347   subdirs="${subdirs} cgi templates images"
 348 fi
 349 if test $want_gtk = yes; then
 350   subdirs="${subdirs} disobedience"
 351   if test $want_server = no; then
 352     subdirs="${subdirs} images"
 353   fi
 354 fi
 355 if test $want_tests = yes && test $want_python = yes; then
 356   AM_PATH_PYTHON([2.5])
 357   subdirs="${subdirs} python tests"
 358 fi
 359 AC_SUBST([subdirs])
 360
 361 # libtool config
 362 AC_LIBTOOL_DLOPEN
 363 AC_DISABLE_STATIC
 364
 365 AC_PROG_LIBTOOL
 366
 367 AC_CACHE_CHECK([for GNU sed],[rjk_cv_gnused],[
 368   rjk_cv_gnused="not found"
 369   for candidate in sed gsed; do
 370     if $candidate --version >/dev/null 2>&1; then
 371       rjk_cv_gnused=$candidate
 372     fi
 373   done
 374 ])
 375 GNUSED="${GNUSED:-$rjk_cv_gnused}"
 376 if test "$GNUSED" = "not found"; then
 377   AC_MSG_ERROR([GNU sed is required to build this program])
 378 fi
 379 AC_SUBST([GNUSED])
 380
 381 AC_CHECK_PROGS([GROG],[grog])
 382 AM_CONDITIONAL([GROG],[test "x$GROG" != xnone])
 383
 384 missing_libraries=""
 385 missing_headers=""
 386 missing_functions=""
 387
 388 AC_DEFINE(_GNU_SOURCE, 1, [required for e.g. strsignal])
 389
 390 AC_PATH_PROG([SENDMAIL],[sendmail],[none],[$PATH:/usr/sbin:/usr/lib])
 391
 392 # Macs might have libraries under fink's root
 393 AC_PATH_PROG([FINK],[fink],[none],[$PATH:/sw/bin])
 394 if test "x$FINK" != xnone; then
 395   # Find Fink prefix
 396   AC_CACHE_CHECK([fink install directory],[rjk_cv_finkprefix],[
 397     rjk_cv_finkprefix="`echo "$FINK" | sed 's,/bin/fink$,,'`"
 398   ])
 399   # Add include and link paths
 400   finkdir="${rjk_cv_finkprefix}"
 401   finkbindir="${rjk_cv_finkprefix}/bin"
 402   CPPFLAGS="${CPPFLAGS} -isystem ${rjk_cv_finkprefix}/include/gc -isystem ${rjk_cv_finkprefix}/include"
 403   if test $want_server = yes; then
 404     CPPFLAGS="${CPPFLAGS} -isystem ${rjk_cv_finkprefix}/include/db4"
 405   fi
 406   LDFLAGS="${LDFLAGS} -L${rjk_cv_finkprefix}/lib"
 407   # Distinguish 32- and 64-bit fink
 408   AC_CACHE_CHECK([whether Fink is 32-bit or 64-bit],[rjk_cv_finkbits],[
 409     odata=`otool -v -h $finkbindir/dpkg`
 410     case "$odata" in
 411     *X86_64* )
 412       rjk_cv_finkbits=64
 413       ;;
 414     *I386* )
 415       rjk_cv_finkbits=32
 416       ;;
 417     * )
 418       rjk_cv_finkbits=unknown
 419       ;;
 420     esac
 421   ])
 422   # Match Fink so we can use its libraries
 423   case $rjk_cv_finkbits in
 424   32 | 64 )
 425     CC="$CC -m$rjk_cv_finkbits"
 426     ;;
 427   esac
 428 else
 429   finkbindir=""
 430 fi
 431 AC_SUBST([finkdir])
 432 AC_SUBST([finkbindir])
 433
 434 # Checks for libraries.
 435 # We save up a list of missing libraries that we can't do without
 436 # and report them all at once.
 437 AC_CHECK_LIB(gc, GC_malloc,            [AC_SUBST(LIBGC,[-lgc])],
 438             [missing_libraries="$missing_libraries libgc"])
 439 AC_CHECK_LIB(gcrypt, gcry_md_open,
 440              [AC_SUBST(LIBGCRYPT,[-lgcrypt])],
 441             [missing_libraries="$missing_libraries libgcrypt"])
 442 AC_CHECK_LIB(pcre, pcre_compile,
 443              [AC_SUBST(LIBPCRE,[-lpcre])],
 444              [missing_libraries="$missing_libraries libpcre"])
 445 if test $want_alsa = yes; then
 446   AC_CHECK_LIB([asound], [snd_pcm_open],
 447                [AC_SUBST(LIBASOUND,[-lasound])])
 448 fi
 449 AC_CHECK_LIB([samplerate],[src_new],
 450              [AC_SUBST([LIBSAMPLERATE],[-lsamplerate])])
 451 if test $want_server = yes; then
 452   RJK_CHECK_LIB(db, db_create, [#include <db.h>],
 453                [AC_SUBST(LIBDB,[-ldb])],
 454                [missing_libraries="$missing_libraries libdb"])
 455   AC_CHECK_LIB(vorbis, vorbis_info_clear,
 456                [:],
 457                [missing_libraries="$missing_libraries libvorbis"])
 458   AC_CHECK_LIB(vorbisfile, ov_open,
 459                [AC_SUBST(LIBVORBISFILE,["-lvorbisfile -lvorbis"])],
 460                [missing_libraries="$missing_libraries libvorbisfile"],
 461                [-lvorbis])
 462   AC_CHECK_LIB(mad, mad_stream_init,
 463                [AC_SUBST(LIBMAD,[-lmad])],
 464                [missing_libraries="$missing_libraries libmad"])
 465   AC_CHECK_LIB([FLAC], [FLAC__stream_decoder_new],
 466                [AC_SUBST(LIBFLAC,[-lFLAC])],
 467                [missing_libraries="$missing_libraries libFLAC"])
 468 fi
 469 AC_CHECK_LIB([pthread], [pthread_create],
 470              [AC_SUBST(LIBPTHREAD,[-lpthread])],
 471              [missing_libraries="$missing_libraries libpthread"])
 472
 473 if test $want_gtk = yes; then
 474   if test $want_gtkosx = yes; then
 475     GTK_CFLAGS="-isystem /Library/Frameworks/Gtk.framework/Headers -isystem /Library/Frameworks/Cairo.framework/Headers"
 476     GLIB_CFLAGS="-isystem /Library/Frameworks/GLib.framework/Headers"
 477     GTK_LIBS="-framework Gtk -framework GLib"
 478   else
 479     AM_PATH_GLIB_2_0([],[],[missing_libraries="$missing_libraries libglib"])
 480     AM_PATH_GTK_2_0([],[],[missing_libraries="$missing_libraries libgtk"])
 481   fi
 482 fi
 483
 484 # Some platforms have iconv already
 485 AC_CHECK_FUNC(iconv_open, [:],
 486               [RJK_CHECK_LIB(iconv, iconv_open, [#include <iconv.h>],
 487                             [AC_SUBST(LIBICONV,[-liconv])],
 488                             [missing_functions="$missing_functions iconv_open"])])
 489 AC_CHECK_FUNC([gethostbyname],[:],[
 490   AC_CHECK_LIB(nsl,gethostbyname,
 491                [AC_SUBST(LIBNSL,[-lnsl])],
 492                [missing_functions="$missing_functions gethostbyname"])])
 493 AC_CHECK_FUNC([socket],[:],[
 494   AC_CHECK_LIB(socket,socket,
 495                [AC_SUBST(LIBSOCKET,[-lsocket])],
 496                [missing_functions="$missing_functions socket"])])
 497 AC_CHECK_FUNC([dlopen],[:],[
 498   AC_CHECK_LIB(dl,dlopen,
 499                [AC_SUBST(LIBDL,[-ldl])],
 500                [missing_functions="$missing_functions dlopen"])])
 501
 502 if test ! -z "$missing_libraries"; then
 503   AC_MSG_ERROR([missing libraries:$missing_libraries])
 504 fi
 505
 506 # Checks for header files.
 507 RJK_FIND_GC_H
 508 if test $want_oss = yes; then
 509   AC_CHECK_HEADERS([sys/soundcard.h])
 510 fi
 511 if test $want_alsa = yes; then
 512   AC_CHECK_HEADERS([alsa/asoundlib.h])
 513 fi
 514 if test $want_coreaudio = yes; then
 515   AC_CHECK_HEADERS([CoreAudio/AudioHardware.h])
 516 fi
 517 AC_CHECK_HEADERS([inttypes.h])
 518 # We don't bother checking very standard stuff
 519 # Compilation will fail if any of these headers are missing, so we
 520 # check for them here and fail early.
 521 if test $want_server = yes; then
 522   AC_CHECK_HEADERS([db.h],[:],[
 523     missing_headers="$missing_headers $ac_header"
 524   ])
 525 fi
 526 AC_CHECK_HEADERS([dlfcn.h gcrypt.h \
 527                  getopt.h iconv.h langinfo.h \
 528                  pcre.h sys/ioctl.h \
 529                  syslog.h unistd.h],[:],[
 530   missing_headers="$missing_headers $ac_header"
 531 ])
 532 AC_CHECK_HEADERS([samplerate.h])
 533
 534 if test ! -z "$missing_headers"; then
 535   AC_MSG_ERROR([missing headers:$missing_headers])
 536 fi
 537
 538 # We require that libpcre support UTF-8
 539 RJK_REQUIRE_PCRE_UTF8([-lpcre])
 540
 541 # Checks for typedefs, structures, and compiler characteristics.
 542 AC_C_CONST
 543 AC_TYPE_SIZE_T
 544 AC_C_INLINE
 545 AC_C_BIGENDIAN
 546 AC_CHECK_TYPES([struct sockaddr_in6],,,[AC_INCLUDES_DEFAULT
 547 #include <netinet/in.h>])
 548
 549 # Figure out how we'll check for devices being mounted and unmounted
 550 AC_CACHE_CHECK([for list of mounted filesystems],[rjk_cv_mtab],[
 551   if test -e /etc/mtab; then
 552     rjk_cv_mtab=/etc/mtab
 553   else
 554     rjk_cv_mtab=none
 555   fi
 556 ])
 557 if test $rjk_cv_mtab != none; then
 558   AC_DEFINE_UNQUOTED([PATH_MTAB],["$rjk_cv_mtab"],[path to file containing mount list])
 559 fi
 560
 561 # enable -Werror when we check for certain characteristics:
 562
 563 old_CFLAGS="${CFLAGS}"
 564 CFLAGS="${CFLAGS} $gcc_werror"
 565 AC_CHECK_TYPES([long long,uint32_t,uint8_t,intmax_t,uintmax_t])
 566
 567 # Some GCC invocations warn for converting function pointers to void *.
 568 # This is fair enough, as it's technically forbidden, but we use dlsym()
 569 # which can pretty much only exist if object and function pointers are
 570 # interconvertable.  So we disable -Werror if need be.
 571 if test ! -z "$gcc_werror"; then
 572   AC_CACHE_CHECK([whether function pointers can be converted to void * without a warning],
 573                  [rjk_cv_function_pointer_cast],[
 574     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 575   void somefunction(void);],
 576                       [(void *)somefunction])],
 577                       [rjk_cv_function_pointer_cast=yes],
 578                       [rjk_cv_function_pointer_cast=no])])
 579   if test $rjk_cv_function_pointer_cast = no; then
 580     gcc_werror=""
 581   fi
 582 fi
 583
 584 CFLAGS="${old_CFLAGS}"
 585
 586 # gcrypt maintainers keep changing everything.  Design your interface
 587 # first, then implement it once, rather than getting it wrong three or
 588 # four times and shipping between each attempt.
 589 AC_CACHE_CHECK([for hash handle type in <grypt.h>],
 590                [rjk_cv_gcrypt_hash_handle],[
 591   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 592 #include <gcrypt.h>
 593 ],
 594                [gcry_md_hd_t h;])],
 595                [rjk_cv_gcrypt_hash_handle=gcry_md_hd_t],[
 596     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 597 #include <gcrypt.h>
 598 ],
 599                  [GcryMDHd h;])],
 600                  [rjk_cv_gcrypt_hash_handle=GcryMDHd],
 601                  [rjk_cv_gcrypt_hash_handle=GCRY_MD_HD])])])
 602 AC_DEFINE_UNQUOTED([gcrypt_hash_handle],[$rjk_cv_gcrypt_hash_handle],
 603                    [libgcrypt hash handle type])
 604
 605 AC_CACHE_CHECK([for gcry_error_t in <grypt.h>],
 606                [rjk_cv_have_gcry_error_t],[
 607   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 608 #include <gcrypt.h>
 609 ],
 610                  [gcry_error_t e;])],
 611                  [rjk_cv_have_gcry_error_t=yes],
 612                  [rjk_cv_have_gcry_error_t=no])])
 613 if test $rjk_cv_have_gcry_error_t = yes; then
 614   AC_DEFINE([HAVE_GCRY_ERROR_T],1,[define if <gcrypt.h> defines gcry_error_t])
 615 fi
 616
 617 # Checks for functions
 618 if test $ac_cv_type_long_long = yes; then
 619   AC_CHECK_FUNCS([atoll strtoll],[:],[
 620     missing_functions="$missing_functions $ac_func"
 621   ])
 622   # Darwin sometimes fails to declare strtoll (e.g. if you ask for -std=c99)
 623   AC_CACHE_CHECK([whether strtoll is declared in <stdlib.h>],
 624                  [rjk_cv_strtoll_declared],[
 625     AC_EGREP_HEADER([strtoll], [stdlib.h],
 626                     [rjk_cv_strtoll_declared=yes],
 627                     [rjk_cv_strtoll_declared=no])])
 628   if test $rjk_cv_strtoll_declared = yes; then
 629     AC_DEFINE([DECLARES_STRTOLL],[1],[define if <stdlib.h> declares strtoll])
 630   fi
 631   AC_CACHE_CHECK([whether atoll is declared in <stdlib.h>],
 632                  [rjk_cv_atoll_declared],[
 633     AC_EGREP_HEADER([atoll], [stdlib.h],
 634                     [rjk_cv_atoll_declared=yes],
 635                     [rjk_cv_atoll_declared=no])])
 636   if test $rjk_cv_atoll_declared = yes; then
 637     AC_DEFINE([DECLARES_ATOLL],[1],[define if <stdlib.h> declares atoll])
 638   fi
 639 fi
 640 AC_CHECK_FUNCS([ioctl nl_langinfo strsignal setenv unsetenv],[:],[
 641   missing_functions="$missing_functions $ac_func"
 642 ])
 643 # fsync will do if fdatasync not available
 644 AC_CHECK_FUNCS([fdatasync],[:],[
 645   AC_CHECK_FUNCS([fsync],
 646                  [AC_DEFINE([fdatasync],[fsync],[define fdatasync to fsync if not available])],
 647                  [missing_functions="$missing_functions fdatasync"])])
 648 if test ! -z "$missing_functions"; then
 649   AC_MSG_ERROR([missing functions:$missing_functions])
 650 fi
 651
 652 # Functions we can take or leave
 653 AC_CHECK_FUNCS([fls getfsstat])
 654
 655 if test $want_server = yes; then
 656   # <db.h> had better be version 3 or later
 657   AC_CACHE_CHECK([db.h version],[rjk_cv_db_version],[
 658     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
 659                        #include <db.h>
 660                        #ifndef DB_VERSION_MAJOR
 661                        # error cannot determine db version
 662                        #endif
 663                        #if DB_VERSION_MAJOR < 4
 664                        # error inadequate db version
 665                        #endif
 666                        #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR <= 2
 667                        # error inadequate db version
 668                        #endif
 669                       ],[])],
 670                       [rjk_cv_db_version=ok],
 671                       [rjk_cv_db_version=inadequate])
 672     if test $rjk_cv_db_version = ok; then
 673       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
 674                          #include <db.h>
 675                          #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR == 6
 676                          # error http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=510270
 677                          #endif
 678                         ],[])],
 679                         [rjk_cv_db_version=ok],
 680                         [rjk_cv_db_version=toxic])
 681     fi
 682   ])
 683   case $rjk_cv_db_version in
 684   ok )
 685     ;;
 686   inadequate )
 687     AC_MSG_ERROR([need db version at least 4.3 (but not 4.6)])
 688     ;;
 689   toxic )
 690     AC_MSG_ERROR([db version 4.6.x does not work - see debian bug 510270])
 691     ;;
 692   esac
 693 fi
 694
 695 AM_CONDITIONAL([SERVER], [test x$want_server = xyes])
 696 if test $want_gtk = yes; then
 697   AC_DEFINE([WITH_GTK], [1], [define if using GTK+])
 698 fi
 699 AM_CONDITIONAL([GTK], [test x$want_gtk = xyes])
 700
 701 if test "x$GCC" = xyes; then
 702   # We need LLONG_MAX and annoyingly GCC doesn't always give it to us
 703   # by default.
 704   AC_CACHE_CHECK([what C version to ask for],[rjk_cv_cstd],[
 705     AC_TRY_COMPILE([#include <limits.h>],[
 706       long long n = LLONG_MAX;
 707     ],[rjk_cv_cstd=default],[
 708       old_CC="$CC"
 709       CC="${CC} -std=gnu99"
 710       AC_TRY_COMPILE([#include <limits.h>],[
 711         long long n = LLONG_MAX;
 712       ],[rjk_cv_cstd=gnu99],[rjk_cv_cstd=unknown])
 713       CC="$old_CC"
 714     ])
 715   ])
 716   case $rjk_cv_cstd in
 717   default | unknown )
 718     ;;
 719   * )
 720     CC="${CC} -std=${rjk_cv_cstd}"
 721     ;;
 722   esac
 723
 724   # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=29478
 725   AC_CACHE_CHECK([checking for GCC bug 29478],[rjk_cv_pr29478],[
 726     old_CC="$CC"
 727     if test $GCC = yes; then
 728       CC="$CC -Wall -Werror"
 729     fi
 730     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 731       static int x(char *f) {
 732        return *f;
 733       }
 734       int z(const char *g) {
 735         return x((char *)g);
 736       }],[])],
 737       [rjk_cv_pr29478=no],
 738       [rjk_cv_pr29478=yes]
 739     )
 740     CC="$old_CC"
 741   ])
 742   if test $rjk_cv_pr29478 = yes; then
 743     gcc_werror=''
 744   fi
 745
 746   AC_CACHE_CHECK([checking for excessively strict -Wreturn-type],
 747                  [rjk_cv_gcc44_stupidity],[
 748     old_CC="$CC"
 749     if test $GCC = yes; then
 750       CC="$CC -Wreturn-type -Werror"
 751     fi
 752     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[
 753       static void *threadfn(void) {
 754         for(;;)
 755           ;
 756       }],[])],
 757       [rjk_cv_gcc44_stupidity=no],
 758       [rjk_cv_gcc44_stupidity=yes])
 759     CC="$old_CC"
 760   ])
 761   if test $rjk_cv_gcc44_stupidity = yes; then
 762     AC_DEFINE([HAVE_STUPID_GCC44],[1],[Define if your compiler has excessively strict -Wreturn-type])
 763   fi
 764
 765   # a reasonable default set of warnings
 766   CC="${CC} -Wall -W -Wpointer-arith \
 767         -Wwrite-strings -Wmissing-prototypes \
 768         -Wmissing-declarations -Wnested-externs"
 769
 770   # Fix up GTK+ and GLib compiler flags
 771   GTK_CFLAGS="`echo \"$GTK_CFLAGS\"|sed 's/-I/-isystem /g'`"
 772   GLIB_CFLAGS="`echo \"$GLIB_CFLAGS\"|sed 's/-I/-isystem /g'`"
 773
 774   if test "$gcc_werror" != ''; then
 775     # GCC 2.95 doesn't know to ignore warnings from system headers
 776     AC_CACHE_CHECK([whether -Werror is usable],
 777                     rjk_cv_werror, [
 778       save_CFLAGS="${CFLAGS}"
 779       CFLAGS="${CFLAGS} ${GTK_CFLAGS} -Werror"
 780       AC_TRY_COMPILE([#if WITH_GTK
 781  #include <gtk/gtk.h>
 782 #endif
 783
 784 struct s { int a, b; };
 785 const struct s sv = { .a = 1 };],
 786                      [],
 787                      [rjk_cv_werror=yes],
 788                      [rjk_cv_werror=no])
 789       CFLAGS="${save_CFLAGS}"
 790     ])
 791     if test $rjk_cv_werror = no; then
 792       gcc_werror=''
 793     fi
 794   fi
 795   CC="${CC} $gcc_werror"
 796
 797   # for older GCCs that don't know %ju (etc)
 798   AC_CACHE_CHECK([whether -Wno-format is required],
 799                  rjk_cv_noformat,
 800                  AC_TRY_COMPILE([#include <stdio.h>
 801 #include <stdint.h>
 802 ],
 803                                 [printf("%ju", (uintmax_t)0);],
 804                                 [rjk_cv_noformat=no],
 805                                 [rjk_cv_noformat=yes]))
 806   if test $rjk_cv_noformat = yes; then
 807     CC="${CC} -Wno-format"
 808   fi
 809
 810   AC_CACHE_CHECK([whether -Wshadow is OK],
 811                  rjk_cv_shadow,
 812                  oldCC="${CC}"
 813                  CC="${CC} -Wshadow"
 814                  [AC_TRY_COMPILE([
 815 #include <unistd.h>
 816 #include <vorbis/vorbisfile.h>
 817 ],
 818                                 [],
 819                                 [rjk_cv_shadow=yes],
 820                                 [rjk_cv_shadow=no])
 821                  CC="${oldCC}"])
 822   if test $rjk_cv_shadow = yes; then
 823     CC="${CC} -Wshadow"
 824   fi
 825 fi
 826
 827 RJK_GCOV
 828
 829 AH_BOTTOM([#ifdef __GNUC__
 830 # define attribute(x) __attribute__(x)
 831 #else
 832 # define attribute(x)
 833 #endif])
 834
 835 AC_CONFIG_FILES([Makefile
 836                  images/Makefile
 837                  scripts/Makefile
 838                  lib/Makefile
 839                  server/Makefile
 840                  cgi/Makefile
 841                  clients/Makefile
 842                  disobedience/Makefile
 843                  disobedience/manual/Makefile
 844                  doc/Makefile
 845                  templates/Makefile
 846                  plugins/Makefile
 847                  debian/Makefile
 848                  sounds/Makefile
 849                  python/Makefile
 850                  examples/Makefile
 851                  libtests/Makefile
 852                  tests/Makefile])
 853 AC_OUTPUT
 854
 855 if test $GCC = yes && test "$gcc_werror" = ''; then
 856   AC_MSG_WARN([building without -Werror])
 857 fi
 858 if test $want_python = no; then
 859   AC_MSG_WARN([cannot run the test suit without Python])
 860 fi
 861 if test $want_server = yes && test "$ac_cv_lib_samplerate_src_new" != yes; then
 862   AC_MSG_WARN([libsamplerate will be required in a future version])
 863 fi
 864
 865 # Local Variables:
 866 # indent-tabs-mode:nil
 867 # End: