chiark - git - mdw - catacomb/blob - Makefile.m4

   1 ## -*-m4-*-
   2 ##
   3 ## $Id$
   4 ##
   5 ## Makefile for Catacomb
   6 ##
   7 ## (c) 1999 Straylight/Edgeware
   8 ##
   9
  10 ##----- Licensing notice ----------------------------------------------------
  11 ##
  12 ## This file is part of Catacomb.
  13 ##
  14 ## Catacomb is free software; you can redistribute it and/or modify
  15 ## it under the terms of the GNU Library General Public License as
  16 ## published by the Free Software Foundation; either version 2 of the
  17 ## License, or (at your option) any later version.
  18 ##
  19 ## Catacomb is distributed in the hope that it will be useful,
  20 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ## GNU Library General Public License for more details.
  23 ##
  24 ## You should have received a copy of the GNU Library General Public
  25 ## License along with Catacomb; if not, write to the Free
  26 ## Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  27 ## MA 02111-1307, USA.
  28
  29 AUTOMAKE_OPTIONS = foreign
  30
  31 SUBDIRS = tests
  32
  33 archincludedir = $(libdir)/catacomb/include
  34
  35 ## --- List handling macros ---
  36 ##
  37 ## List handling is nice, usually.  Unfortunately, I based this design on
  38 ## TeX list macros rather than anything sensible...
  39
  40 define(`_', `define(`_item', $1)define(`_item_2', $2)emit`'')
  41 define(`adorn', `pushdef(`emit', `$1`'_item`'$3')$2`'popdef(`emit')')
  42 define(`join',
  43 `pushdef(`emit', `adorn(``_(''_item`$2', `$3', ``)'')`'')$1`'popdef(`emit')')
  44 define(`addsuffix', `adorn(`', `$1', `$2')')
  45 define(`lit', `adorn(`', `$1', `')')
  46 define(`nl', `
  47 ')
  48
  49 define(`allwithsuffix',
  50 `addsuffix(`$1', `$3') addsuffix(`$2', `$3') dnl
  51 addsuffix(join(`$1', `-', `$2'), `$3')')
  52
  53 ## --- Autogenerated source files ---
  54
  55 define(`ciphers', `dnl
  56 _(des) _(desx) _(des3) _(mars) dnl
  57 _(idea) _(safer) _(safersk) dnl
  58 _(blowfish) _(twofish) dnl
  59 _(tea) _(xtea) dnl
  60 _(rc2) _(rc5) dnl
  61 _(skipjack) dnl
  62 _(cast128) _(cast256) dnl
  63 _(square) _(rijndael) _(rijndael192) _(rijndael256) dnl
  64 _(serpent) _(noekeon)')
  65 define(`cipher_modes', `_(ecb) _(cbc) _(cfb) _(ofb) _(counter)')
  66
  67 define(`hashes', `dnl
  68 _(md5) _(md4) _(md2) _(tiger) _(has160) dnl
  69 _(sha) _(sha224) _(sha256) _(sha384) _(sha512) dnl
  70 _(rmd128) _(rmd160) _(rmd256) _(rmd320)')
  71 define(`hash_modes', `_(mgf) _(hmac)')
  72
  73 MODES = \
  74         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.c') \
  75         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.h') \
  76         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.c') \
  77         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.h')
  78
  79 $(MODES): modes-stamp
  80 modes-stamp: genmodes
  81         cd $(srcdir); ./genmodes "lit(`ciphers')" "lit(`cipher_modes')"
  82         cd $(srcdir); ./genmodes "lit(`hashes')" "lit(`hash_modes')"
  83         echo datestamp >modes-stamp
  84
  85 define(`gen_tables', `dnl
  86 _(des) _(blowfish) _(twofish) dnl
  87 _(square) _(rijndael) dnl
  88 _(safer) _(mars) _(tiger) dnl
  89 _(gfshare) _(gfx-sqr)')
  90
  91 autoheaders: addsuffix(`gen_tables', `-tab.h') primetab.h mptypes.h
  92 define(`emit', `
  93 _item`'-tab.h: _item`'-mktab
  94         ./_item`'-mktab >_item`'-tab.h.new
  95         mv _item`'-tab.h.new _item`'-tab.h')dnl
  96 gen_tables
  97
  98 primetab.h: primetab.c
  99 primetab.c: genprimes
 100         ./genprimes -h primetab.h -c primetab.c \
 101                 -s CATACOMB_PRIMETAB_H -n 256 \
 102                 -t "unsigned short" -i primetab
 103 archinclude_HEADERS = mptypes.h
 104 mptypes.h: mptypes
 105         ./mptypes >mptypes.h.new
 106         mv mptypes.h.new mptypes.h
 107
 108 ectab.c: ectab.in ec-gentab.awk mpdump
 109         $(srcdir)/ec-gentab.awk <$(srcdir)/ectab.in >ectab.c.new
 110         mv ectab.c.new ectab.c
 111
 112 ptab.c: ptab.in p-gentab.awk mpdump
 113         $(srcdir)/p-gentab.awk <$(srcdir)/ptab.in >ptab.c.new
 114         mv ptab.c.new ptab.c
 115
 116 gciphertab.c: gengctab
 117         $(srcdir)/gengctab gccipher gcipher >gciphertab.c.new \
 118                 "lit(join(`ciphers', `-', `cipher_modes')) \
 119                 lit(join(`hashes', `-', `_(mgf)')) \
 120                 rc4 seal"
 121         mv gciphertab.c.new gciphertab.c
 122
 123 gmactab.c: gengctab
 124         $(srcdir)/gengctab gcmac gmac >gmactab.c.new \
 125                 "lit(join(`hashes', `-', `_(hmac)'))"
 126         mv gmactab.c.new gmactab.c
 127
 128 ghashtab.c: gengctab
 129         $(srcdir)/gengctab gchash ghash >ghashtab.c.new \
 130                 "lit(`hashes') \
 131                 crc32=gcrc32"
 132         mv ghashtab.c.new ghashtab.c
 133
 134 BUILT_SOURCES = \
 135         getdate.c modes-stamp gciphertab.c gmactab.c ghashtab.c \
 136         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 137         addsuffix(join(`ciphers', `-', `cipher_modes'), `.h') \
 138         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 139         addsuffix(join(`hashes', `-', `hash_modes'), `.h')
 140
 141 ## --- Building the main library ---
 142
 143 lib_LTLIBRARIES = libcatacomb.la
 144
 145 libcatacomb_la_LDFLAGS = -version-info 3:0:1
 146 ## Middle number is the patchlevel.  Final number is the minor version.  The
 147 ## difference between the first and last numbers is major version.
 148
 149 pkginclude_HEADERS = \
 150         arena.h paranoia.h buf.h qdparse.h \
 151         blkc.h hash.h gcipher.h ghash.h gmac.h grand.h ghash-def.h \
 152         lcrand.h fibrand.h rc4.h seal.h rand.h noise.h fipstest.h maurer.h \
 153         key.h key-data.h passphrase.h pixie.h lmem.h \
 154         mpx.h bitops.h mpw.h mpscan.h mparena.h mp.h mptext.h mpint.h \
 155         exp.h mpbarrett.h mpmont.h mpreduce.h \
 156         mpcrt.h mprand.h mpmul.h \
 157         gfx.h gf.h gfreduce.h gfn.h \
 158         primetab.h pfilt.h rabin.h \
 159         pgen.h prim.h strongprime.h limlee.h keycheck.h \
 160         bbs.h rsa.h dh.h dsarand.h dsa.h gdsa.h gkcdsa.h \
 161         tlsprf.h sslprf.h \
 162         gfshare.h share.h \
 163         rho.h \
 164         field.h field-guts.h \
 165         ec.h ec-guts.h ec-exp.h ec-test.h ectab.h ec-keys.h ec-raw.h \
 166         ptab.h group.h group-guts.h \
 167         allwithsuffix(`ciphers', `cipher_modes', `.h') \
 168         allwithsuffix(`hashes', `hash_modes', `.h') \
 169         addsuffix(`cipher_modes', `-def.h') \
 170         addsuffix(`hash_modes', `-def.h') crc32.h
 171
 172 define(`MP_SOURCES',
 173         `mpx.c mpx-kmul.c mpx-ksqr.c mpscan.c mparena.c qdparse.c \
 174         mp-misc.c mp-mem.c mp-const.c mp-io.c mp-arith.c mp-test.c \
 175         mp-sqrt.c mp-gcd.c mp-jacobi.c mp-modsqrt.c \
 176         mpint.c mptext.c mptext-file.c mptext-string.c mptext-dstr.c \
 177         mptext-len.c \
 178         exp.c mpcrt.c mpmul.c mprand.c \
 179         mpbarrett.c mpbarrett-exp.c mpbarrett-mexp.c mpbarrett-exp.h \
 180         mpmont.c mpmont-exp.c mpmont-mexp.c mpmont-exp.h \
 181         mpreduce.c mpreduce-exp.h \
 182         group-stdops.c group-exp.c group-exp.h g-prime.c group-parse.c \
 183         group-string.c group-file.c group-dstr.c \
 184         rho.c buf.c ptab.c \
 185         GF_SOURCES PGEN_SOURCES EC_SOURCES')
 186
 187 define(`GF_SOURCES',
 188         `gfx.c gfx-kmul.c gfx-sqr.c gf-arith.c gf-gcd.c \
 189         gfreduce.c gfreduce-exp.h gfn.c')
 190
 191 define(`EC_SOURCES',
 192         `field.c field-parse.c f-prime.c f-niceprime.c f-binpoly.c \
 193         ec.c ec-exp.c ec-prime.c ec-bin.c ec-test.c ec-info.c ectab.c \
 194         ec-fetch.c ec-raw.c g-ec.c')
 195
 196 define(`PGEN_SOURCES',
 197         `pfilt.c rabin.c \
 198         pgen.c pgen-stdev.c pgen-safe.c pgen-gcd.c prim.c strongprime.c \
 199         limlee.c \
 200         keycheck.c keycheck-mp.c keycheck-report.c \
 201         bbs-rand.c bbs-gen.c bbs-jump.c bbs-fetch.c \
 202         rsa-priv.c rsa-pub.c rsa-gen.c rsa-recover.c rsa-fetch.c \
 203         oaep.c pkcs1.c pss.c \
 204         dh-gen.c dh-limlee.c dh-check.c dh-fetch.c dh-param.c \
 205         dsarand.c dsa-sign.c dsa-verify.c dsa-gen.c dsa-check.c \
 206         gdsa.c gkcdsa.c \
 207         key-data.c key-flags.c key-text.c key-binary.c key-pass.c \
 208         key-pack.c key-misc.c key-file.c key-attr.c key-io.c key-moan.c \
 209         key-error.c key-fetch.c \
 210         primetab.c share.c')
 211
 212 libcatacomb_la_SOURCES = \
 213         grand.c keysz.c \
 214         lcrand.c fibrand.c rc4.c seal.c rand.c noise.c fipstest.c maurer.c \
 215         arena.c \
 216         passphrase.c pixie-client.c pixie-common.c lmem.c \
 217         tlsprf.c sslprf.c \
 218         gfshare.c \
 219         MP_SOURCES karatsuba.h \
 220         gciphertab.c ghashtab.c gmactab.c \
 221         des-base.c des-base.h \
 222         desx-tab.h \
 223         rc2-tab.h \
 224         skipjack-tab.h \
 225         cast-s.c cast-sk.c cast-base.h cast-tab.h \
 226         rijndael-base.c rijndael-base.h \
 227         md2-tab.h \
 228         serpent-sbox.h skipjack-tab.h tiger-base.h \
 229         daftstory.h \
 230         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 231         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 232         addsuffix(`ciphers', `.c') addsuffix(`hashes', `.c') crc32.c
 233
 234 des-base.lo: des-tab.h
 235 blowfish.lo: blowfish-tab.h
 236 twofish.lo: twofish-tab.h
 237 square.lo: square-tab.h
 238 rijndael-base.lo: rijndael-tab.h
 239 safer.lo: safer-tab.h
 240 mars.lo: mars-tab.h
 241 tiger.lo: tiger-tab.h
 242 gfshare.lo: gfshare-tab.h
 243 gfx-sqr.lo: gfx-sqr-tab.h
 244 patsubst(MP_SOURCES, `\.c\>', `.lo') dsig.o keyutil.o rspit.o: \
 245         mptypes.h primetab.h
 246
 247 ## --- Utility programs ---
 248
 249 bin_PROGRAMS = \
 250         dsig key pixie cookie rspit factorial hashsum mkphrase catcrypt
 251 noinst_LIBRARIES = libcatcrypt.a
 252 bin_SCRIPTS = catacomb-config xpixie
 253 noinst_PROGRAMS = \
 254         genprimes mptypes serpent-check bittest mpdump \
 255         perftest \
 256         addsuffix(`gen_tables', `-mktab')
 257 LDADD = libcatacomb.la libcatcrypt.a
 258
 259 libcatcrypt_a_SOURCES = \
 260         cc.h getdate.h \
 261         cc-sig.c cc-subcmd.c cc-enc.c cc-kem.c cc-list.c \
 262         getdate.y
 263
 264 dsig_SOURCES = dsig.c
 265 cookie_SOURCES = cookie.c
 266 catcrypt_SOURCES = catcrypt.c
 267 key_SOURCES = keyutil.c
 268 hashsum_SOURCES = hashsum.c
 269 rspit_SOURCES = rspit.c
 270 factorial_SOURCES = factorial.c
 271 perftest_SOURCES = perftest.c
 272 pixie_SOURCES = pixie.c pixie-common.c lmem.c arena.c
 273 pixie_LDADD =
 274 mkphrase_SOURCES = mkphrase.c
 275 bittest_SOURCES = bittest.c
 276 bittest_LDADD =
 277
 278 define(`emit', `
 279 patsubst(_item, `[^a-zA-Z0-9]', `_')_mktab_SOURCES = _item`'-mktab.c
 280 patsubst(_item, `[^a-zA-Z0-9]', `_')_mktab_LDADD =')dnl
 281 gen_tables
 282
 283 serpent_check_SOURCES = serpent-check.c
 284 serpent_check_LDADD =
 285
 286 genprimes_SOURCES = genprimes.c
 287 genprimes_LDADD =
 288
 289 mptypes_SOURCES = mptypes.c
 290 mptypes_LDADD =
 291
 292 mpdump_SOURCES = \
 293         mpdump.c \
 294         mpx.c mpx-kmul.c mpx-ksqr.c mpscan.c mparena.c \
 295         mp-misc.c mp-mem.c mp-const.c mp-arith.c mp-io.c \
 296         mptext.c mptext-string.c
 297 mpdump_LDADD =
 298
 299 ## --- Install the pixie setuid-root if we can ---
 300 ##
 301 ## Bodge around a bug in Automake: it doesn't call `install-exec-hook' from
 302 ## `install' if there are subdirectories.
 303
 304 changequote(<, >)
 305 install: install-exec-hook
 306 install-exec-hook:
 307         @pixie="$(DESTDIR)$(bindir)/`echo pixie|sed $(transform)`"; \
 308         if chown root $$pixie && chmod 4755 $$pixie; then \
 309           echo "chown root $$pixie"; \
 310           echo "chmod 4755 $$pixie"; \
 311         else \
 312           echo "***"; \
 313           echo "*** You should probably install $$pixie setuid-root."; \
 314           echo "***"; \
 315         fi
 316 changequote(`, ')
 317
 318 ## --- Documentation ---
 319
 320 man_MANS = key.1 dsig.1 cookie.1 catcrypt.1 hashsum.1 keyring.5 pixie.1
 321
 322 ## --- Other handy definitions ---
 323
 324 EXTRA_DIST = \
 325         Makefile.m4 genmodes gengctab $(man_MANS) xpixie \
 326         group-test.c rsa-test.c \
 327         ectab.in ec-gentab.awk ptab.in p-gentab.awk \
 328         README.cipher README.hash README.random README.mp \
 329         debian/rules debian/copyright debian/control debian/changelog \
 330         debian/catacomb-bin.postinst debian/catacomb-bin.config \
 331         debian/catacomb-bin.prerm debian/catacomb-bin.templates
 332
 333 dist-hook:
 334         @for i in getdate.c gciphertab.c ghashtab.c gmactab.c; do \
 335           ln $$i $(distdir) || ln $(srcdir)/$$i $(distdir) || true; \
 336         done
 337         @echo datestamp >$(distdir)/modes-stamp || true
 338         @for i in calc tests; do \
 339           mkdir $(distdir)/$$i; \
 340           ln $(srcdir)/$$i/*[!~] $(distdir)/$$i; \
 341         done || true
 342 #       kr=$$HOME/.catacomb/dsig-keyring; \
 343 #       if [ -r $$kr ]; then \
 344 #         cd $(distdir); \
 345 #         ../key -k $$kr extract -f -secret KEYRING; \
 346 #         find . -type f -print0 | ../dsig -k $$kr sign -0 -oMANIFEST; \
 347 #       fi
 348
 349 ## --- Testing ---
 350
 351 define(`testprogs', `')
 352
 353 define(`CTESTRIG',
 354 `define(`testprogs', testprogs \
 355         $1.t)dnl
 356 $1.to: $1.c
 357         $(COMPILE) -c -DTEST_RIG -DSRCDIR=\"$(srcdir)\" $(srcdir)/$1.c -o $1.to
 358 $1.t: $1.to libcatacomb.la
 359         $(CC) $(CFLAGS) $(LDFLAGS) $1.to .libs/libcatacomb.a $(LIBS) -o $1.t')
 360
 361 CTESTRIG(rc4)
 362 CTESTRIG(seal)
 363 adorn(`nl`'CTESTRIG(', `ciphers', `)')
 364 adorn(`nl`'CTESTRIG(', `hashes', `)')
 365 adorn(`nl`'CTESTRIG(', join(`ciphers', `-', `cipher_modes'), `)')
 366 adorn(`nl`'CTESTRIG(', join(`hashes', `-', `hash_modes'), `)')
 367 CTESTRIG(lcrand)
 368 CTESTRIG(tlsprf)
 369 CTESTRIG(sslprf)
 370 CTESTRIG(mpx)
 371 CTESTRIG(mpx-kmul)
 372 CTESTRIG(mpx-ksqr)
 373 CTESTRIG(mp-arith)
 374 CTESTRIG(mp-modsqrt)
 375 CTESTRIG(mp-gcd)
 376 CTESTRIG(mp-jacobi)
 377 CTESTRIG(mp-sqrt)
 378 CTESTRIG(mptext)
 379 CTESTRIG(mpint)
 380 CTESTRIG(mpbarrett)
 381 CTESTRIG(mpbarrett-exp)
 382 CTESTRIG(mpbarrett-mexp)
 383 CTESTRIG(mpmont)
 384 CTESTRIG(mpmont-exp)
 385 CTESTRIG(mpmont-mexp)
 386 CTESTRIG(mpreduce)
 387 CTESTRIG(mpcrt)
 388 CTESTRIG(mpmul)
 389 CTESTRIG(rsa-test)
 390 CTESTRIG(gfx)
 391 CTESTRIG(gfx-sqr)
 392 CTESTRIG(gfx-kmul)
 393 CTESTRIG(gf-arith)
 394 CTESTRIG(gf-gcd)
 395 CTESTRIG(gfreduce)
 396 CTESTRIG(gfn)
 397 CTESTRIG(ec-prime)
 398 CTESTRIG(ec-bin)
 399 CTESTRIG(ec-test)
 400 CTESTRIG(ec-info)
 401 CTESTRIG(dh-param)
 402 CTESTRIG(group-test)
 403 CTESTRIG(gdsa)
 404 CTESTRIG(gkcdsa)
 405 CTESTRIG(pgen)
 406 CTESTRIG(dsa-gen)
 407 CTESTRIG(dsa-sign)
 408 CTESTRIG(dsa-verify)
 409 CTESTRIG(bbs-rand)
 410 CTESTRIG(bbs-jump)
 411 CTESTRIG(gfshare)
 412 CTESTRIG(share)
 413 CTESTRIG(rho)
 414
 415 TESTS = serpent-check bittest testprogs
 416
 417 CLEANFILES = \
 418         *.t *.to \
 419         mptypes.h primetab.c primetab.h ectab.c \
 420         addsuffix(`gen_tables', `-tab.h')
 421
 422 ## --- Makefile building (haha!) ---
 423
 424 $(srcdir)/Makefile.am: $(srcdir)/Makefile.m4
 425         m4 $(srcdir)/Makefile.m4 >$(srcdir)/Makefile.am.new
 426         mv $(srcdir)/Makefile.am.new $(srcdir)/Makefile.am
 427
 428 DISTCLEANFILES = libtool
 429
 430 MAINTAINERCLEANFILES = \
 431         $(srcdir)/Makefile.am \
 432         $(srcdir)/getdate.c getdate.c \
 433         $(MODES) modes-stamp $(srcdir)/modes-stamp
 434
 435 ##----- That's all, folks ---------------------------------------------------