chiark - git - mdw - catacomb/blob - Makefile.m4

   1 ## -*-makefile-*-
   2 ##
   3 ## $Id: Makefile.m4,v 1.33 2000/07/09 21:34:15 mdw Exp $
   4 ##
   5 ## Makefile for Catacomb
   6 ##
   7 ## (c) 1999 Straylight/Edgeware
   8 ##
   9
  10 ##----- Licensing notice ----------------------------------------------------
  11 ##
  12 ## This file is part of Catacomb.
  13 ##
  14 ## Catacomb is free software; you can redistribute it and/or modify
  15 ## it under the terms of the GNU Library General Public License as
  16 ## published by the Free Software Foundation; either version 2 of the
  17 ## License, or (at your option) any later version.
  18 ##
  19 ## Catacomb is distributed in the hope that it will be useful,
  20 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ## GNU Library General Public License for more details.
  23 ##
  24 ## You should have received a copy of the GNU Library General Public
  25 ## License along with Catacomb; if not, write to the Free
  26 ## Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  27 ## MA 02111-1307, USA.
  28
  29 ##----- Revision history ----------------------------------------------------
  30 ##
  31 ## $Log: Makefile.m4,v $
  32 ## Revision 1.33  2000/07/09 21:34:15  mdw
  33 ## New hash functions and other stuff.
  34 ##
  35 ## Revision 1.32  2000/07/01 11:27:32  mdw
  36 ## Name changes and new files.
  37 ##
  38 ## Revision 1.31  2000/06/25 13:02:07  mdw
  39 ## Fix cleaning of generated files.
  40 ##
  41 ## Revision 1.30  2000/06/22 19:10:33  mdw
  42 ## Fix Makefile to test mp-sqrt.c.
  43 ##
  44 ## Revision 1.29  2000/06/22 19:04:19  mdw
  45 ## More new functions to be added.
  46 ##
  47 ## Revision 1.28  2000/06/18 23:31:18  mdw
  48 ## Rearrange build order to ensure that `mptypes.h' exists by the time it's
  49 ## needed.
  50 ##
  51 ## Revision 1.27  2000/06/17 13:28:50  mdw
  52 ## Minor tidying and fixing.
  53 ##
  54 ## Revision 1.26  2000/06/17 10:33:43  mdw
  55 ## Lots of new ciphers and other files.
  56 ##
  57 ## Revision 1.25  2000/02/12 18:55:40  mdw
  58 ## Make it all compile properly.
  59 ##
  60 ## Revision 1.24  2000/02/12 18:22:26  mdw
  61 ## Missed a file.  Whoops.
  62 ##
  63 ## Revision 1.23  2000/02/12 18:21:01  mdw
  64 ## Overhaul of key management (again).
  65 ##
  66 ## Revision 1.22  1999/12/22 16:04:06  mdw
  67 ## Lots of new files.
  68 ##
  69 ## Revision 1.21  1999/12/13 15:47:58  mdw
  70 ## Fix a couple of minor bugs in the distribution set.
  71 ##
  72 ## Revision 1.19  1999/12/11 10:58:24  mdw
  73 ## Fix bug in test rig link flags.  Add Karatsuba squaring.
  74 ##
  75 ## Revision 1.18  1999/12/10 23:30:01  mdw
  76 ## Lots of new files.
  77 ##
  78 ## Revision 1.17  1999/11/25 11:38:31  mdw
  79 ## Support for conversions between MPs and C integers.
  80 ##
  81 ## Revision 1.16  1999/11/22 20:51:33  mdw
  82 ## Add yet more source files.
  83 ##
  84 ## Revision 1.15  1999/11/22 14:08:30  mdw
  85 ## Improve dependencies for test programs.
  86 ##
  87 ## Revision 1.14  1999/11/22 00:17:09  mdw
  88 ## Create object files for test programs so that rebuilding doesn't take so
  89 ## long.
  90 ##
  91 ## Revision 1.12  1999/11/20 22:36:26  mdw
  92 ## Improve dependencies.  Move mpx testing into mpx.c.
  93 ##
  94 ## Revision 1.11  1999/11/20 22:24:53  mdw
  95 ## Add Diffie-Hellman support.
  96 ##
  97 ## Revision 1.10  1999/11/19 19:28:24  mdw
  98 ## Add DSA files and tests.
  99 ##
 100 ## Revision 1.9  1999/11/17 18:05:35  mdw
 101 ## Many new files and test cases for multiprecision arithmetic.
 102 ##
 103 ## Revision 1.8  1999/11/13 01:56:07  mdw
 104 ## Include multiprecision maths stuff.
 105 ##
 106 ## Revision 1.7  1999/11/11 19:01:02  mdw
 107 ## Use `libtool' to generate a shared library.
 108 ##
 109 ## Revision 1.6  1999/11/11 17:47:34  mdw
 110 ## Updates for new configuration system, and `mptypes' generator.
 111 ##
 112 ## Revision 1.5  1999/11/11 00:59:17  mdw
 113 ## Minor reformatting.
 114 ##
 115 ## Revision 1.4  1999/10/24 10:20:36  mdw
 116 ## Modify for standalone distribution.  The library's getting far too large
 117 ## to be sensibly embedded in other programs.
 118 ##
 119 ## Revision 1.3  1999/10/24 10:04:26  mdw
 120 ## Install headers in the right directory.
 121 ##
 122 ## Revision 1.2  1999/10/23 12:55:35  mdw
 123 ## The `CVS' directory can't be hardlinked.  Don't worry about this
 124 ## overmuch.
 125 ##
 126 ## Revision 1.1  1999/09/03 08:41:11  mdw
 127 ## Initial import.
 128 ##
 129
 130 AUTOMAKE_OPTIONS = foreign
 131
 132 SUBDIRS = tests
 133
 134 archincludedir = $(libdir)/catacomb/include
 135
 136 ## --- List handling macros ---
 137 ##
 138 ## List handling is nice, usually.  Unfortunately, I based this design on
 139 ## TeX list macros rather than anything sensible...
 140
 141 define(`_', `define(`_item', $1)define(`_item_2', $2)emit`'')
 142 define(`adorn', `pushdef(`emit', `$1`'_item`'$3')$2`'popdef(`emit')')
 143 define(`join',
 144 `pushdef(`emit', `adorn(``_(''_item`$2', `$3', ``)'')`'')$1`'popdef(`emit')')
 145 define(`addsuffix', `adorn(`', `$1', `$2')')
 146 define(`lit', `adorn(`', `$1', `')')
 147 define(`nl', `
 148 ')
 149
 150 define(`allwithsuffix',
 151 `addsuffix(`$1', `$3') addsuffix(`$2', `$3') dnl
 152 addsuffix(join(`$1', `-', `$2'), `$3')')
 153
 154 ## --- Autogenerated source files ---
 155
 156 define(`ciphers', `dnl
 157 _(des) _(des3) dnl
 158 _(idea) dnl
 159 _(blowfish) _(twofish) dnl
 160 _(rc2) _(rc5) dnl
 161 _(cast128) _(cast256) dnl
 162 _(rijndael) dnl
 163 _(serpent)')
 164 define(`cipher_modes', `_(ecb) _(cbc) _(cfb) _(ofb) _(counter)')
 165
 166 define(`hashes', `dnl
 167 _(md5) _(md4) _(sha) dnl
 168 _(rmd128) _(rmd160) _(rmd256) _(rmd320)')
 169 define(`hash_modes', `_(mgf) _(hmac)')
 170
 171 MODES = \
 172         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.c') \
 173         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.h') \
 174         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.c') \
 175         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.h')
 176
 177 $(MODES):
 178         cd $(srcdir); ./genmodes "lit(`ciphers')" "lit(`cipher_modes')"
 179         cd $(srcdir); ./genmodes "lit(`hashes')" "lit(`hash_modes')"
 180
 181 des-tab.h: des-mktab
 182         ./des-mktab >des-tab.h
 183
 184 blowfish-tab.h: blowfish-mktab
 185         ./blowfish-mktab >blowfish-tab.h
 186
 187 twofish-tab.h: twofish-mktab
 188         ./twofish-mktab >twofish-tab.h
 189
 190 rijndael-tab.h: rijndael-mktab
 191         ./rijndael-mktab >rijndael-tab.h
 192
 193 primetab.c primetab.h: genprimes
 194         ./genprimes -h primetab.h -c primetab.c -m 255 \
 195                 -t "unsigned char" -i primetab
 196
 197 gfshare-tab.h: gfshare-mktab
 198         ./gfshare-mktab >gfshare-tab.h
 199
 200 archinclude_HEADERS = mptypes.h
 201
 202 mptypes.h: mptypes
 203         ./mptypes >mptypes.h
 204
 205 BUILT_SOURCES = \
 206         getdate.c \
 207         des-tab.h blowfish-tab.h twofish-tab.h rijndael-tab.h \
 208         gfshare-tab.h \
 209         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 210         addsuffix(join(`ciphers', `-', `cipher_modes'), `.h') \
 211         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 212         addsuffix(join(`hashes', `-', `hash_modes'), `.h')
 213
 214 ## --- Building the main library ---
 215
 216 lib_LTLIBRARIES = libcatacomb.la
 217
 218 libcatacomb_la_LDFLAGS = -version-info 2:0:0
 219 ## Middle number is the patchlevel.  Final number is the minor version.  The
 220 ## difference between the first and last numbers is major version.
 221
 222 pkginclude_HEADERS = \
 223         arena.h paranoia.h \
 224         blkc.h hash.h \
 225         gcipher.h ghash.h gmac.h grand.h \
 226         ghash-def.h \
 227         rc4.h seal.h \
 228         rand.h noise.h fipstest.h maurer.h \
 229         key.h key-data.h passphrase.h pixie.h lmem.h \
 230         lcrand.h fibrand.h \
 231         mpx.h mpw.h mpscan.h mparena.h mp.h mptext.h mpint.h \
 232         mpbarrett.h mpmont.h mpcrt.h \
 233         mprand.h mpmul.h \
 234         primetab.h pfilt.h primorial.h rabin.h \
 235         pgen.h prim.h strongprime.h limlee.h \
 236         bbs.h rsa.h dh.h dsarand.h dsa.h \
 237         oaep.h pkcs1.h \
 238         gfshare.h share.h \
 239         rho.h \
 240         allwithsuffix(`ciphers', `cipher_modes', `.h') \
 241         allwithsuffix(`hashes', `hash_modes', `.h') \
 242         addsuffix(`cipher_modes', `-def.h') \
 243         addsuffix(`hash_modes', `-def.h')
 244
 245 libcatacomb_la_SOURCES = \
 246         grand.c keysz.c \
 247         des-base.c des-base.h \
 248         cast-s.c cast-sk.c cast-base.h cast-tab.h \
 249         serpent-sbox.h \
 250         daftstory.h \
 251         rc4.c seal.c \
 252         rand.c noise.c fipstest.c maurer.c \
 253         arena.c \
 254         passphrase.c pixie-client.c pixie-common.c lmem.c \
 255         lcrand.c fibrand.c \
 256         mpx.c mpx-kmul.c mpx-ksqr.c mpx-kmac.h mpscan.c mparena.c \
 257         mp-misc.c mp-mem.c mp-const.c mp-io.c mp-arith.c mp-test.c \
 258         mp-sqrt.c mp-gcd.c mp-jacobi.c mp-modsqrt.c \
 259         mpint.c \
 260         mptext.c mptext-file.c mptext-string.c mptext-dstr.c \
 261         mpbarrett.c mpmont.c mpmont-mexp.c \
 262         mpcrt.c mpmul.c \
 263         mprand.c \
 264         primetab.c pfilt.c rabin.c primorial.c \
 265         pgen.c pgen-stdev.c pgen-safe.c pgen-gcd.c prim.c strongprime.c \
 266         limlee.c \
 267         bbs-rand.c bbs-gen.c bbs-jump.c bbs-fetch.c \
 268         rsa-priv.c rsa-pub.c rsa-gen.c rsa-recover.c rsa-fetch.c \
 269         oaep.c pkcs1.c \
 270         dh-gen.c dh-fetch.c \
 271         dsarand.c dsa-sign.c dsa-verify.c dsa-gen.c dsa-fetch.c \
 272         gfshare.c share.c \
 273         rho.c \
 274         key-data.c key-flags.c key-text.c key-binary.c key-pass.c \
 275                 key-pack.c \
 276         key-misc.c key-file.c key-attr.c key-io.c key-moan.c key-error.c \
 277                 key-fetch.c \
 278         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 279         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 280         addsuffix(`ciphers', `.c') addsuffix(`hashes', `.c')
 281
 282 des-base.lo: des-tab.h
 283 blowfish.lo: blowfish-tab.h
 284 twofish.lo: twofish-tab.h
 285 rijndael.lo: rijndael-tab.h
 286 mpx.lo: mptypes.h
 287
 288 ## --- Utility programs ---
 289
 290 bin_PROGRAMS = dsig key pixie rspit factorial
 291 bin_SCRIPTS = catacomb-config xpixie
 292 noinst_PROGRAMS = \
 293         genprimes mptypes \
 294         des-mktab blowfish-mktab twofish-mktab rijndael-mktab serpent-check \
 295         gfshare-mktab
 296 LDADD = libcatacomb.la
 297
 298 dsig_SOURCES = dsig.c getdate.y getdate.h
 299
 300 key_SOURCES = keyutil.c getdate.y getdate.h
 301
 302 pixie_SOURCES = pixie.c pixie-common.c lmem.c arena.c
 303 pixie_LDADD =
 304
 305 rspit_SOURCES = rspit.c
 306
 307 factorial_SOURCES = factorial.c
 308
 309 des_mktab_SOURCES = des-mktab.c
 310 des_mktab_LDADD =
 311
 312 blowfish_mktab_SOURCES = blowfish-mktab.c
 313 blowfish_mktab_LDADD =
 314
 315 twofish_mktab_SOURCES = twofish-mktab.c
 316 twofish_mktab_LDADD =
 317
 318 rijndael_mktab_SOURCES = rijndael-mktab.c
 319 rijndael_mktab_LDADD =
 320
 321 serpent_check_SOURCES = serpent-check.c
 322 serpent_check_LDADD =
 323
 324 gfshare_mktab_SOURCES = gfshare-mktab.c
 325 gfshare_mktab_LDADD =
 326
 327 genprimes_SOURCES = genprimes.c
 328 genprimes_LDADD =
 329
 330 mptypes_SOURCES = mptypes.c
 331 mptypes_LDADD =
 332
 333 ## --- Install the pixie setuid-root if we can ---
 334
 335 changequote(<, >)
 336 install-exec-hook:
 337         @pixie="$(bindir)/`echo pixie|sed $(transform)`"; \
 338         if chown root $$pixie && chmod 4755 $$pixie; then \
 339           echo "chown root $$pixie"; \
 340           echo "chmod 4755 $$pixie"; \
 341         else \
 342           echo "***"; \
 343           echo "*** You should probably install $$pixie setuid-root."; \
 344           echo "***"; \
 345         fi
 346 changequote(`, ')
 347
 348 ## --- Documentation ---
 349
 350 man_MANS = key.1 keyring.5
 351
 352 ## --- Other handy definitions ---
 353
 354 EXTRA_DIST = \
 355         Makefile.m4 genmodes $(man_MANS) xpixie \
 356         README.cipher README.hash README.random README.mp
 357
 358 dist-hook:
 359         @ln getdate.c $(distdir) || ln $(srcdir)/getdate.c $(distdir) || true
 360         @mkdir $(distdir)/tests || true
 361         @ln $(srcdir)/tests/* $(distdir)/tests || true
 362         @rm -f $(distdir)/tests/*~
 363 #       kr=$$HOME/.catacomb/dsig-keyring; \
 364 #       if [ -r $$kr ]; then \
 365 #         cd $(distdir); \
 366 #         ../key -k $$kr extract -f -secret KEYRING; \
 367 #         find . -type f -print0 | ../dsig -k $$kr sign -0 -oMANIFEST; \
 368 #       fi
 369
 370 ## --- Testing ---
 371
 372 define(`testprogs', `')
 373
 374 define(`CTESTRIG',
 375 `define(`testprogs', testprogs \
 376         $1.t)dnl
 377 $1.to: $1.c
 378         $(COMPILE) -c -DTEST_RIG -DSRCDIR=\"$(srcdir)\" $(srcdir)/$1.c -o $1.to
 379 $1.t: $1.to $1.o libcatacomb.la
 380         $(CC) $(CFLAGS) $(LDFLAGS) $1.to .libs/libcatacomb.a $(LIBS) -o $1.t')
 381
 382 CTESTRIG(rc4)
 383 CTESTRIG(seal)
 384 adorn(`nl`'CTESTRIG(', `ciphers', `)')
 385 adorn(`nl`'CTESTRIG(', `hashes', `)')
 386 adorn(`nl`'CTESTRIG(', join(`ciphers', `-', `cipher_modes'), `)')
 387 adorn(`nl`'CTESTRIG(', join(`hashes', `-', `hash_modes'), `)')
 388 CTESTRIG(lcrand)
 389 CTESTRIG(mpx)
 390 CTESTRIG(mpx-kmul)
 391 CTESTRIG(mpx-ksqr)
 392 CTESTRIG(mp-arith)
 393 CTESTRIG(mp-modsqrt)
 394 CTESTRIG(mp-gcd)
 395 CTESTRIG(mp-jacobi)
 396 CTESTRIG(mp-sqrt)
 397 CTESTRIG(mptext)
 398 CTESTRIG(mpint)
 399 CTESTRIG(mpbarrett)
 400 CTESTRIG(mpmont)
 401 CTESTRIG(mpmont-mexp)
 402 CTESTRIG(mpcrt)
 403 CTESTRIG(mpmul)
 404 CTESTRIG(pgen)
 405 CTESTRIG(dsa-gen)
 406 CTESTRIG(dsa-sign)
 407 CTESTRIG(dsa-verify)
 408 CTESTRIG(bbs-rand)
 409 CTESTRIG(bbs-jump)
 410 CTESTRIG(gfshare)
 411 CTESTRIG(share)
 412 CTESTRIG(rho)
 413
 414 TESTS = testprogs
 415
 416 CLEANFILES = \
 417         *.t *.to \
 418         mptypes.h primetab.c primetab.h \
 419         des-tab.h twofish-tab.h blowfish-tab.h gfshare-tab.h rijndael-tab.h
 420
 421 ## --- Makefile building (haha!) ---
 422
 423 $(srcdir)/Makefile.am: $(srcdir)/Makefile.m4
 424         m4 $(srcdir)/Makefile.m4 >$(srcdir)/Makefile.am
 425
 426 MAINTAINERCLEANFILES = \
 427         $(srcdir)/Makefile.am \
 428         $(srcdir)/getdate.c getdate.c \
 429         $(MODES)
 430
 431 ##----- That's all, folks ---------------------------------------------------