chiark - git - mdw - catacomb/blob - Makefile.m4

   1 ## -*-makefile-*-
   2 ##
   3 ## $Id: Makefile.m4,v 1.37 2000/07/29 10:02:36 mdw Exp $
   4 ##
   5 ## Makefile for Catacomb
   6 ##
   7 ## (c) 1999 Straylight/Edgeware
   8 ##
   9
  10 ##----- Licensing notice ----------------------------------------------------
  11 ##
  12 ## This file is part of Catacomb.
  13 ##
  14 ## Catacomb is free software; you can redistribute it and/or modify
  15 ## it under the terms of the GNU Library General Public License as
  16 ## published by the Free Software Foundation; either version 2 of the
  17 ## License, or (at your option) any later version.
  18 ##
  19 ## Catacomb is distributed in the hope that it will be useful,
  20 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ## GNU Library General Public License for more details.
  23 ##
  24 ## You should have received a copy of the GNU Library General Public
  25 ## License along with Catacomb; if not, write to the Free
  26 ## Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  27 ## MA 02111-1307, USA.
  28
  29 ##----- Revision history ----------------------------------------------------
  30 ##
  31 ## $Log: Makefile.m4,v $
  32 ## Revision 1.37  2000/07/29 10:02:36  mdw
  33 ## Lots of fixing to support `make -j' building.
  34 ##
  35 ## Revision 1.36  2000/07/20 20:13:38  mdw
  36 ## Added Bellare and Rogaway's PSS encoding for RSA signatures.
  37 ##
  38 ## Revision 1.35  2000/07/16 20:00:46  mdw
  39 ## Bug fixes to distribution.
  40 ##
  41 ## Revision 1.34  2000/07/15 20:55:32  mdw
  42 ## More hashes and ciphers.  An extra tool.
  43 ##
  44 ## Revision 1.33  2000/07/09 21:34:15  mdw
  45 ## New hash functions and other stuff.
  46 ##
  47 ## Revision 1.32  2000/07/01 11:27:32  mdw
  48 ## Name changes and new files.
  49 ##
  50 ## Revision 1.31  2000/06/25 13:02:07  mdw
  51 ## Fix cleaning of generated files.
  52 ##
  53 ## Revision 1.30  2000/06/22 19:10:33  mdw
  54 ## Fix Makefile to test mp-sqrt.c.
  55 ##
  56 ## Revision 1.29  2000/06/22 19:04:19  mdw
  57 ## More new functions to be added.
  58 ##
  59 ## Revision 1.28  2000/06/18 23:31:18  mdw
  60 ## Rearrange build order to ensure that `mptypes.h' exists by the time it's
  61 ## needed.
  62 ##
  63 ## Revision 1.27  2000/06/17 13:28:50  mdw
  64 ## Minor tidying and fixing.
  65 ##
  66 ## Revision 1.26  2000/06/17 10:33:43  mdw
  67 ## Lots of new ciphers and other files.
  68 ##
  69 ## Revision 1.25  2000/02/12 18:55:40  mdw
  70 ## Make it all compile properly.
  71 ##
  72 ## Revision 1.24  2000/02/12 18:22:26  mdw
  73 ## Missed a file.  Whoops.
  74 ##
  75 ## Revision 1.23  2000/02/12 18:21:01  mdw
  76 ## Overhaul of key management (again).
  77 ##
  78 ## Revision 1.22  1999/12/22 16:04:06  mdw
  79 ## Lots of new files.
  80 ##
  81 ## Revision 1.21  1999/12/13 15:47:58  mdw
  82 ## Fix a couple of minor bugs in the distribution set.
  83 ##
  84 ## Revision 1.19  1999/12/11 10:58:24  mdw
  85 ## Fix bug in test rig link flags.  Add Karatsuba squaring.
  86 ##
  87 ## Revision 1.18  1999/12/10 23:30:01  mdw
  88 ## Lots of new files.
  89 ##
  90 ## Revision 1.17  1999/11/25 11:38:31  mdw
  91 ## Support for conversions between MPs and C integers.
  92 ##
  93 ## Revision 1.16  1999/11/22 20:51:33  mdw
  94 ## Add yet more source files.
  95 ##
  96 ## Revision 1.15  1999/11/22 14:08:30  mdw
  97 ## Improve dependencies for test programs.
  98 ##
  99 ## Revision 1.14  1999/11/22 00:17:09  mdw
 100 ## Create object files for test programs so that rebuilding doesn't take so
 101 ## long.
 102 ##
 103 ## Revision 1.12  1999/11/20 22:36:26  mdw
 104 ## Improve dependencies.  Move mpx testing into mpx.c.
 105 ##
 106 ## Revision 1.11  1999/11/20 22:24:53  mdw
 107 ## Add Diffie-Hellman support.
 108 ##
 109 ## Revision 1.10  1999/11/19 19:28:24  mdw
 110 ## Add DSA files and tests.
 111 ##
 112 ## Revision 1.9  1999/11/17 18:05:35  mdw
 113 ## Many new files and test cases for multiprecision arithmetic.
 114 ##
 115 ## Revision 1.8  1999/11/13 01:56:07  mdw
 116 ## Include multiprecision maths stuff.
 117 ##
 118 ## Revision 1.7  1999/11/11 19:01:02  mdw
 119 ## Use `libtool' to generate a shared library.
 120 ##
 121 ## Revision 1.6  1999/11/11 17:47:34  mdw
 122 ## Updates for new configuration system, and `mptypes' generator.
 123 ##
 124 ## Revision 1.5  1999/11/11 00:59:17  mdw
 125 ## Minor reformatting.
 126 ##
 127 ## Revision 1.4  1999/10/24 10:20:36  mdw
 128 ## Modify for standalone distribution.  The library's getting far too large
 129 ## to be sensibly embedded in other programs.
 130 ##
 131 ## Revision 1.3  1999/10/24 10:04:26  mdw
 132 ## Install headers in the right directory.
 133 ##
 134 ## Revision 1.2  1999/10/23 12:55:35  mdw
 135 ## The `CVS' directory can't be hardlinked.  Don't worry about this
 136 ## overmuch.
 137 ##
 138 ## Revision 1.1  1999/09/03 08:41:11  mdw
 139 ## Initial import.
 140 ##
 141
 142 AUTOMAKE_OPTIONS = foreign
 143
 144 SUBDIRS = tests
 145
 146 archincludedir = $(libdir)/catacomb/include
 147
 148 ## --- List handling macros ---
 149 ##
 150 ## List handling is nice, usually.  Unfortunately, I based this design on
 151 ## TeX list macros rather than anything sensible...
 152
 153 define(`_', `define(`_item', $1)define(`_item_2', $2)emit`'')
 154 define(`adorn', `pushdef(`emit', `$1`'_item`'$3')$2`'popdef(`emit')')
 155 define(`join',
 156 `pushdef(`emit', `adorn(``_(''_item`$2', `$3', ``)'')`'')$1`'popdef(`emit')')
 157 define(`addsuffix', `adorn(`', `$1', `$2')')
 158 define(`lit', `adorn(`', `$1', `')')
 159 define(`nl', `
 160 ')
 161
 162 define(`allwithsuffix',
 163 `addsuffix(`$1', `$3') addsuffix(`$2', `$3') dnl
 164 addsuffix(join(`$1', `-', `$2'), `$3')')
 165
 166 ## --- Autogenerated source files ---
 167
 168 define(`ciphers', `dnl
 169 _(des) _(des3) dnl
 170 _(idea) dnl
 171 _(blowfish) _(twofish) dnl
 172 _(tea) _(xtea) dnl
 173 _(rc2) _(rc5) dnl
 174 _(skipjack) dnl
 175 _(cast128) _(cast256) dnl
 176 _(square) _(rijndael) dnl
 177 _(serpent)')
 178 define(`cipher_modes', `_(ecb) _(cbc) _(cfb) _(ofb) _(counter)')
 179
 180 define(`hashes', `dnl
 181 _(md5) _(md4) _(sha) _(tiger) dnl
 182 _(rmd128) _(rmd160) _(rmd256) _(rmd320)')
 183 define(`hash_modes', `_(mgf) _(hmac)')
 184
 185 MODES = \
 186         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.c') \
 187         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.h') \
 188         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.c') \
 189         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.h')
 190
 191 $(MODES): modes-stamp
 192 modes-stamp: genmodes
 193         cd $(srcdir); ./genmodes "lit(`ciphers')" "lit(`cipher_modes')"
 194         cd $(srcdir); ./genmodes "lit(`hashes')" "lit(`hash_modes')"
 195         echo datestamp >modes-stamp
 196
 197 define(`tables', `dnl
 198 _(des) _(blowfish) _(twofish) _(square) _(rijndael) _(tiger) dnl
 199 _(gfshare)')
 200
 201 autoheaders: addsuffix(tables, `-tab.h') primetab.h mptypes.h
 202 define(`emit', `
 203 _item`'-tab.h: _item`'-mktab
 204         ./_item`'-mktab >_item`'-tab.h')dnl
 205 tables
 206
 207 primetab.h: primetab.c
 208 primetab.c: genprimes
 209         ./genprimes -h primetab.h -c primetab.c -m 255 \
 210                 -t "unsigned char" -i primetab
 211 archinclude_HEADERS = mptypes.h
 212 mptypes.h: mptypes
 213         ./mptypes >mptypes.h
 214
 215 BUILT_SOURCES = \
 216         getdate.c \
 217         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 218         addsuffix(join(`ciphers', `-', `cipher_modes'), `.h') \
 219         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 220         addsuffix(join(`hashes', `-', `hash_modes'), `.h')
 221
 222 ## --- Building the main library ---
 223
 224 lib_LTLIBRARIES = libcatacomb.la
 225
 226 libcatacomb_la_LDFLAGS = -version-info 2:0:0
 227 ## Middle number is the patchlevel.  Final number is the minor version.  The
 228 ## difference between the first and last numbers is major version.
 229
 230 pkginclude_HEADERS = \
 231         arena.h paranoia.h \
 232         blkc.h hash.h gcipher.h ghash.h gmac.h grand.h ghash-def.h \
 233         lcrand.h fibrand.h rc4.h seal.h rand.h noise.h fipstest.h maurer.h \
 234         key.h key-data.h passphrase.h pixie.h lmem.h \
 235         mpx.h mpw.h mpscan.h mparena.h mp.h mptext.h mpint.h \
 236         mpbarrett.h mpmont.h mpcrt.h mprand.h mpmul.h \
 237         primetab.h pfilt.h primorial.h rabin.h \
 238         pgen.h prim.h strongprime.h limlee.h \
 239         bbs.h rsa.h dh.h dsarand.h dsa.h \
 240         oaep.h pkcs1.h pss.h \
 241         gfshare.h share.h \
 242         rho.h \
 243         allwithsuffix(`ciphers', `cipher_modes', `.h') \
 244         allwithsuffix(`hashes', `hash_modes', `.h') \
 245         addsuffix(`cipher_modes', `-def.h') \
 246         addsuffix(`hash_modes', `-def.h')
 247
 248 define(`lib_sources', `\
 249         grand.c keysz.c \
 250         des-base.c des-base.h \
 251         cast-s.c cast-sk.c cast-base.h cast-tab.h \
 252         serpent-sbox.h skipjack-tab.h tiger-base.h \
 253         daftstory.h \
 254         lcrand.c fibrand.c rc4.c seal.c rand.c noise.c fipstest.c maurer.c \
 255         arena.c \
 256         passphrase.c pixie-client.c pixie-common.c lmem.c \
 257         mpx.c mpx-kmul.c mpx-ksqr.c mpx-kmac.h mpscan.c mparena.c \
 258         mp-misc.c mp-mem.c mp-const.c mp-io.c mp-arith.c mp-test.c \
 259         mp-sqrt.c mp-gcd.c mp-jacobi.c mp-modsqrt.c \
 260         mpint.c mptext.c mptext-file.c mptext-string.c mptext-dstr.c \
 261         mpbarrett.c mpmont.c mpmont-mexp.c mpcrt.c mpmul.c mprand.c \
 262         pfilt.c rabin.c primorial.c \
 263         pgen.c pgen-stdev.c pgen-safe.c pgen-gcd.c prim.c strongprime.c \
 264         limlee.c \
 265         bbs-rand.c bbs-gen.c bbs-jump.c bbs-fetch.c \
 266         rsa-priv.c rsa-pub.c rsa-gen.c rsa-recover.c rsa-fetch.c \
 267         oaep.c pkcs1.c pss.c \
 268         dh-gen.c dh-limlee.c dh-fetch.c \
 269         dsarand.c dsa-sign.c dsa-verify.c dsa-gen.c \
 270         gfshare.c share.c \
 271         rho.c \
 272         key-data.c key-flags.c key-text.c key-binary.c key-pass.c \
 273         key-pack.c key-misc.c key-file.c key-attr.c key-io.c key-moan.c \
 274         key-error.c key-fetch.c')
 275 LIBSRC = lib_sources
 276 libcatacomb_la_SOURCES = \
 277         lib_sources \
 278         primetab.c \
 279         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 280         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 281         addsuffix(`ciphers', `.c') addsuffix(`hashes', `.c')
 282
 283 des-base.lo: des-tab.h
 284 blowfish.lo: blowfish-tab.h
 285 twofish.lo: twofish-tab.h
 286 square.lo: square-tab.h
 287 rijndael.lo: rijndael-tab.h
 288 tiger.lo: tiger-tab.h
 289 gfshare.lo: gfshare-tab.h
 290 $(LIBSRC) dsig.o keyutil.o rspit.o: mptypes.h primetab.h
 291
 292 ## --- Utility programs ---
 293
 294 bin_PROGRAMS = dsig key pixie rspit factorial hashsum
 295 bin_SCRIPTS = catacomb-config xpixie
 296 noinst_PROGRAMS = \
 297         genprimes mptypes \
 298         des-mktab blowfish-mktab twofish-mktab square-mktab rijndael-mktab \
 299         tiger-mktab serpent-check \
 300         gfshare-mktab
 301 LDADD = libcatacomb.la
 302
 303 dsig_SOURCES = dsig.c getdate.y getdate.h
 304 key_SOURCES = keyutil.c getdate.y getdate.h
 305 hashsum_SOURCES = hashsum.c
 306 rspit_SOURCES = rspit.c
 307 factorial_SOURCES = factorial.c
 308 pixie_SOURCES = pixie.c pixie-common.c lmem.c arena.c
 309 pixie_LDADD =
 310
 311 des_mktab_SOURCES = des-mktab.c
 312 des_mktab_LDADD =
 313 blowfish_mktab_SOURCES = blowfish-mktab.c
 314 blowfish_mktab_LDADD =
 315 twofish_mktab_SOURCES = twofish-mktab.c
 316 twofish_mktab_LDADD =
 317 square_mktab_SOURCES = square-mktab.c
 318 square_mktab_LDADD =
 319 rijndael_mktab_SOURCES = rijndael-mktab.c
 320 rijndael_mktab_LDADD =
 321 serpent_check_SOURCES = serpent-check.c
 322 serpent_check_LDADD =
 323 gfshare_mktab_SOURCES = gfshare-mktab.c
 324 gfshare_mktab_LDADD =
 325 tiger_mktab_SOURCES = tiger-mktab.c
 326 tiger_mktab_LDADD =
 327
 328 genprimes_SOURCES = genprimes.c
 329 genprimes_LDADD =
 330
 331 mptypes_SOURCES = mptypes.c
 332 mptypes_LDADD =
 333
 334 ## --- Install the pixie setuid-root if we can ---
 335
 336 changequote(<, >)
 337 install-exec-hook:
 338         @pixie="$(bindir)/`echo pixie|sed $(transform)`"; \
 339         if chown root $$pixie && chmod 4755 $$pixie; then \
 340           echo "chown root $$pixie"; \
 341           echo "chmod 4755 $$pixie"; \
 342         else \
 343           echo "***"; \
 344           echo "*** You should probably install $$pixie setuid-root."; \
 345           echo "***"; \
 346         fi
 347 changequote(`, ')
 348
 349 ## --- Documentation ---
 350
 351 man_MANS = key.1 keyring.5
 352
 353 ## --- Other handy definitions ---
 354
 355 EXTRA_DIST = \
 356         Makefile.m4 genmodes $(man_MANS) xpixie \
 357         README.cipher README.hash README.random README.mp
 358
 359 dist-hook:
 360         @ln getdate.c $(distdir) || ln $(srcdir)/getdate.c $(distdir) || true
 361         @echo datestamp >$(distdir)/modes-stamp || true
 362         @mkdir $(distdir)/tests || true
 363         @ln $(srcdir)/tests/* $(distdir)/tests || true
 364         @rm -f $(distdir)/tests/*~
 365 #       kr=$$HOME/.catacomb/dsig-keyring; \
 366 #       if [ -r $$kr ]; then \
 367 #         cd $(distdir); \
 368 #         ../key -k $$kr extract -f -secret KEYRING; \
 369 #         find . -type f -print0 | ../dsig -k $$kr sign -0 -oMANIFEST; \
 370 #       fi
 371
 372 ## --- Testing ---
 373
 374 define(`testprogs', `')
 375
 376 define(`CTESTRIG',
 377 `define(`testprogs', testprogs \
 378         $1.t)dnl
 379 $1.to: $1.c
 380         $(COMPILE) -c -DTEST_RIG -DSRCDIR=\"$(srcdir)\" $(srcdir)/$1.c -o $1.to
 381 $1.t: $1.to $1.o libcatacomb.la
 382         $(CC) $(CFLAGS) $(LDFLAGS) $1.to .libs/libcatacomb.a $(LIBS) -o $1.t')
 383
 384 CTESTRIG(rc4)
 385 CTESTRIG(seal)
 386 adorn(`nl`'CTESTRIG(', `ciphers', `)')
 387 adorn(`nl`'CTESTRIG(', `hashes', `)')
 388 adorn(`nl`'CTESTRIG(', join(`ciphers', `-', `cipher_modes'), `)')
 389 adorn(`nl`'CTESTRIG(', join(`hashes', `-', `hash_modes'), `)')
 390 CTESTRIG(lcrand)
 391 CTESTRIG(oaep)
 392 CTESTRIG(mpx)
 393 CTESTRIG(mpx-kmul)
 394 CTESTRIG(mpx-ksqr)
 395 CTESTRIG(mp-arith)
 396 CTESTRIG(mp-modsqrt)
 397 CTESTRIG(mp-gcd)
 398 CTESTRIG(mp-jacobi)
 399 CTESTRIG(mp-sqrt)
 400 CTESTRIG(mptext)
 401 CTESTRIG(mpint)
 402 CTESTRIG(mpbarrett)
 403 CTESTRIG(mpmont)
 404 CTESTRIG(mpmont-mexp)
 405 CTESTRIG(mpcrt)
 406 CTESTRIG(mpmul)
 407 CTESTRIG(pgen)
 408 CTESTRIG(dsa-gen)
 409 CTESTRIG(dsa-sign)
 410 CTESTRIG(dsa-verify)
 411 CTESTRIG(bbs-rand)
 412 CTESTRIG(bbs-jump)
 413 CTESTRIG(gfshare)
 414 CTESTRIG(share)
 415 CTESTRIG(rho)
 416
 417 TESTS = serpent-check testprogs
 418
 419 CLEANFILES = \
 420         *.t *.to \
 421         mptypes.h primetab.c primetab.h \
 422         des-tab.h twofish-tab.h blowfish-tab.h gfshare-tab.h rijndael-tab.h
 423
 424 ## --- Makefile building (haha!) ---
 425
 426 $(srcdir)/Makefile.am: $(srcdir)/Makefile.m4
 427         m4 $(srcdir)/Makefile.m4 >$(srcdir)/Makefile.am
 428
 429 MAINTAINERCLEANFILES = \
 430         $(srcdir)/Makefile.am \
 431         $(srcdir)/getdate.c getdate.c \
 432         $(MODES) modes-stamp $(srcdir)/modes-stamp
 433
 434 ##----- That's all, folks ---------------------------------------------------