chiark - git - mdw - become/blob - configure.in

   1 dnl -*-fundamental-*-
   2 dnl
   3 dnl $Id: configure.in,v 1.16 1998/06/18 15:15:45 mdw Exp $
   4 dnl
   5 dnl Source for auto configuration for `become'
   6 dnl
   7 dnl (c) 1998 Mark Wooding
   8 dnl
   9
  10 dnl----- Licensing notice ---------------------------------------------------
  11 dnl
  12 dnl This file is part of `become'
  13 dnl
  14 dnl `Become' is free software; you can redistribute it and/or modify
  15 dnl it under the terms of the GNU General Public License as published by
  16 dnl the Free Software Foundation; either version 2 of the License, or
  17 dnl (at your option) any later version.
  18 dnl
  19 dnl `Become' is distributed in the hope that it will be useful,
  20 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 dnl GNU General Public License for more details.
  23 dnl
  24 dnl You should have received a copy of the GNU General Public License
  25 dnl along with `become'; if not, write to the Free Software Foundation,
  26 dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  27
  28 dnl----- Revision history ---------------------------------------------------
  29 dnl
  30 dnl $Log: configure.in,v $
  31 dnl Revision 1.16  1998/06/18 15:15:45  mdw
  32 dnl Set version number properly.  D'oh.
  33 dnl
  34 dnl Revision 1.15  1998/06/18 15:11:36  mdw
  35 dnl Change patchlevel.  Check for @sigprocmask@, for improved @noise__shell@
  36 dnl function.
  37 dnl
  38 dnl Revision 1.14  1998/06/08 11:22:16  mdw
  39 dnl Step version number and date.
  40 dnl
  41 dnl Revision 1.13  1998/04/23 13:34:10  mdw
  42 dnl Release version.
  43 dnl
  44 dnl Revision 1.12  1998/04/23 13:09:24  mdw
  45 dnl Add new option to disable networking.
  46 dnl
  47 dnl Revision 1.11  1998/02/20 17:55:56  mdw
  48 dnl Fix default HTML directory.
  49 dnl
  50 dnl Revision 1.10  1998/01/12 16:45:21  mdw
  51 dnl Fix copyright date.
  52 dnl
  53 dnl Revision 1.9  1997/09/18  11:24:27  mdw
  54 dnl Add `conf' directory.  Add an `htmldir' installation directory too.
  55 dnl
  56 dnl Revision 1.8  1997/09/17  10:36:30  mdw
  57 dnl Remove `set.c'.  No longer necessary.
  58 dnl
  59 dnl Revision 1.7  1997/09/09 18:18:41  mdw
  60 dnl Check for setgroups(2), to see whether subsidiary group lists need to be
  61 dnl fiddled with.
  62 dnl
  63 dnl Revision 1.6  1997/09/08  13:41:14  mdw
  64 dnl Check for `setreuid' for changing permissions.
  65 dnl
  66 dnl Revision 1.5  1997/09/05  11:45:18  mdw
  67 dnl Add support for different login styles, and environment variable
  68 dnl manipulation in a safe and useful way.
  69 dnl
  70 dnl Revision 1.4  1997/08/20  16:10:56  mdw
  71 dnl Lowercase `mdw_' prefixes to macros.  Add a `--with-etcdir=PATH'
  72 dnl option.  Update `stamp-h' as required by the Automake docs (silly
  73 dnl me).
  74 dnl
  75 dnl Revision 1.3  1997/08/07 09:34:32  mdw
  76 dnl Added `ElectricFence' support, and support for the `deep' package
  77 dnl structure.
  78 dnl
  79 dnl Revision 1.2  1997/08/04 10:24:21  mdw
  80 dnl Sources placed under CVS control.
  81 dnl
  82 dnl Revision 1.1  1997/07/21  13:47:51  mdw
  83 dnl Initial revision
  84 dnl
  85
  86 AC_INIT(src/icrypt.c)
  87 AC_CONFIG_HEADER(config.h)
  88 PACKAGE=become
  89 VERSION=1.3.2
  90 AC_DEFINE(VERSION, "1.3.2 (18 June 1998)")
  91 AC_SUBST(PACKAGE)
  92 AC_SUBST(VERSION)
  93
  94 dnl --- Check for compilers and things ---
  95
  96 AC_PROG_CC
  97 AC_PROG_INSTALL
  98 AC_PROG_LEX
  99 AC_CHECK_PROG(AR, ar, ar)
 100 AC_PROG_RANLIB
 101 AC_PROG_MAKE_SET
 102 AC_PROG_YACC
 103 AC_ARG_PROGRAM
 104 if test "$GCC" = "yes"; then
 105   CFLAGS="$CFLAGS -pedantic -Wall"
 106 fi
 107
 108 dnl --- Set default become style ---
 109
 110 AC_ARG_ENABLE([style],
 111 [  --enable-style=STYLE   set default style to preserve, setuser, or login],
 112 [case "$enableval" in
 113   preserve) style="l_preserve" ;;
 114   su|setuser) style="l_setuser" ;;
 115   login) style="l_login" ;;
 116   *) AC_MSG_ERROR([unknown login style: choose preserve, setuser, or login])
 117      ;;
 118 esac],
 119 [style="l_preserve"])
 120 AC_DEFINE_UNQUOTED(DEFAULT_LOGIN_STYLE, $style)
 121
 122 dnl --- Choose networking options ---
 123
 124 AC_ARG_ENABLE([network],
 125 [  --disable-network      disable the client-server bits of the program],
 126   [if test "$enableval" = "no"; then
 127     AC_DEFINE(NONETWORK)
 128   fi])
 129
 130 dnl --- Set configuration directory ---
 131
 132 AC_ARG_WITH([etcdir],
 133 [  --with-etcdir=PATH     set directory for configuration and key files
 134                           [default is /etc/become]],
 135 [etcdir="$withval"], [etcdir="/etc/become"])
 136 AC_SUBST(etcdir)
 137 AC_DEFINE_UNQUOTED(ETCDIR, "$etcdir")
 138
 139 AC_ARG_WITH([htmldir],
 140 [  --with-htmldir=PATH    set directory for HTML documentation
 141                           [default is PREFIX/html/become]],
 142 [htmldir="$withval"], [htmldir='${prefix}/html/become'])
 143 AC_SUBST(htmldir)
 144
 145 dnl --- Debugging stuff ---
 146
 147 AC_ARG_WITH(electric-fence,
 148 [  --with-electric-fence          link programs with Electric Fence],
 149   [if test "$withval" = "yes"; then
 150     AC_CHECK_LIB(efence, malloc)
 151   fi])
 152
 153 AC_ARG_ENABLE(debugging,
 154 [  --enable-debugging     spews vast swathes of useless information],
 155   [if test "$enableval" = "no"; then
 156     AC_DEFINE(NDEBUG, 1)
 157   fi],
 158   AC_DEFINE(NDEBUG, 1))
 159
 160 AC_ARG_ENABLE(tracing,
 161 [  --enable-tracing       enable output of tracing information],
 162   [if test "$enableval" = "yes"; then
 163     AC_DEFINE(TRACING)
 164   fi],
 165   AC_DEFINE(TRACING))
 166
 167 dnl --- Libraries ---
 168
 169 mdw_CHECK_MANYLIBS(socket, socket,,
 170   [AC_MSG_ERROR([Socket library not found])])
 171
 172 mdw_CHECK_MANYLIBS(gethostbyname, resolv nsl,,
 173   [AC_MSG_ERROR([Resolver library not found])])
 174
 175 mdw_CHECK_MANYLIBS(yp_all, nsl, AC_DEFINE(HAVE_YP))
 176
 177 dnl --- Other functions ---
 178
 179 AC_CHECK_FUNCS(sigprocmask)
 180
 181 dnl --- Types ---
 182
 183 AC_TYPE_PID_T
 184 AC_TYPE_UID_T
 185 AC_CHECK_TYPE(ssize_t, int)
 186
 187 dnl --- Check on type sizes ---
 188
 189 AC_CHECK_SIZEOF(int, 2)
 190
 191 dnl --- Set the path separator ---
 192
 193 AC_DEFINE(PATHSEP, '/')
 194
 195 dnl --- Check for some useful functions ---
 196
 197 AC_CHECK_FUNCS(setreuid setgroups)
 198 AC_CHECK_FUNCS(getrusage vtimes)
 199
 200 dnl --- Done ---
 201
 202 AC_OUTPUT(Makefile conf/Makefile src/Makefile manual/Makefile,
 203           [test -z "$CONFIG_HEADERS" || echo timestamp >stamp-h])
 204
 205 dnl----- That's all, folks --------------------------------------------------