chiark - git - mdw - autoys/blob - configure.ac

   1 dnl -*-autoconf-*-
   2 dnl
   3 dnl Configuration script for `autoys'
   4 dnl
   5 dnl (c) 2016 Mark Wooding
   6 dnl
   7
   8 dnl----- Licensing notice ---------------------------------------------------
   9 dnl
  10 dnl This file is part of the `autoys' audio tools collection.
  11 dnl
  12 dnl `autoys' is free software; you can redistribute it and/or modify
  13 dnl it under the terms of the GNU General Public License as published by
  14 dnl the Free Software Foundation; either version 2 of the License, or
  15 dnl (at your option) any later version.
  16 dnl
  17 dnl `autoys' is distributed in the hope that it will be useful,
  18 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 dnl GNU General Public License for more details.
  21 dnl
  22 dnl You should have received a copy of the GNU General Public License
  23 dnl along with `autoys'; if not, write to the Free Software Foundation,
  24 dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 dnl--------------------------------------------------------------------------
  27 dnl Initialization.
  28
  29 mdw_AUTO_VERSION
  30 AC_INIT([autoys], AUTO_VERSION, [mdw@distorted.org.uk])
  31 AC_CONFIG_SRCDIR([gremlin/gremlin.in])
  32 AC_CONFIG_AUX_DIR([config])
  33 AM_INIT_AUTOMAKE([foreign])
  34 mdw_SILENT_RULES
  35
  36 dnl--------------------------------------------------------------------------
  37 dnl C programming environment.
  38
  39 AC_PROG_CC
  40 AX_FLAGS_WARN_ALL
  41
  42 dnl--------------------------------------------------------------------------
  43 dnl Various scripting languages.
  44
  45 ## Python
  46 AM_PATH_PYTHON([2.5], [have_python=yes], [have_python=no])
  47 AM_CONDITIONAL([HAVE_PYTHON], [test $have_python = yes])
  48
  49 ## Bash.
  50 case "$BASH" in /bin/sh) unset BASH ;; esac
  51 AC_ARG_VAR([BASH], [Path to the Bourne Again Shell.])
  52 AC_PATH_PROG([BASH], [bash], [false])
  53 AC_MSG_CHECKING([bash version])
  54 bashver=$("$BASH" -c 'echo $BASH_VERSION')
  55 if "$BASH" 2>/dev/null -c '[[[ ${BASH_VERSINFO[0]} -ge 3 ]]]'; then
  56   have_bash=yes
  57   AC_MSG_RESULT([$bashver])
  58 else
  59   have_bash=no
  60   AC_MSG_RESULT([too old ($bashver)])
  61 fi
  62 AM_CONDITIONAL([HAVE_BASH], [test $have_bash = yes])
  63
  64 dnl--------------------------------------------------------------------------
  65 dnl Output.
  66
  67 AC_CONFIG_FILES(
  68   [Makefile]
  69   [gremlin/Makefile])
  70 AC_OUTPUT
  71
  72 dnl----- That's all, folks --------------------------------------------------