layout/layout

   1 #!/usr/bin/perl -w
   2
   3 use POSIX;
   4 use IO::Handle;
   5 use IO::File;
   6
   7 use strict;
   8 no strict 'subs';
   9
  10 our $scale= 7.0;
  11 our $page_x= 0;
  12 our $page_y= 0;
  13 our $quiet=0;
  14 our $debug=0;
  15 our $output_layer= '*';
  16 our $subsegcmapreq=0;
  17 our $subsegmovfeatpos='f';
  18 our $subsegcmapangscale;
  19
  20 our $ps_page_shift= 615;
  21 our $ps_page_xmul= 765.354;
  22 our $ps_page_ymul= 538.583;
  23
  24 our @eopts;
  25 our @segments= ('/');
  26 our %subsegcmap;
  27
  28 our $drawers= 'arscldmnog';
  29 our %chdraw_emap= qw(A ARScgd
  30                      R aRscgD
  31                      S aRScgd
  32                      C arsCgd
  33                      c Arscgd
  34                      r arcs
  35                      L LMg
  36                      l l
  37                      M Mnog
  38                      N MNog
  39                      O MNOg
  40                      m mnol
  41                      G Garsclmno);
  42
  43 while (@ARGV && $ARGV[0] =~ m/^\-/) {
  44     last if $ARGV[0] eq '-';
  45     $_= shift @ARGV;
  46     last if $_ eq '--';
  47     s/^\-//;
  48     while (length) {
  49         if (s/^D(\d+)//) { $debug= $1; }
  50         elsif (s/^D//) { $debug++; }
  51         elsif (s/^q//) { $quiet=1; }
  52         elsif (s/^l(\d+|\*)//) { $output_layer=$1; }
  53         elsif (s/^S([0-9.]+)$//) { $scale= $1 * 1.0; }
  54         elsif (s/^P(\d+)x(\d+)$//) { $page_x= $1; $page_y= $2; }
  55         elsif (s/^GR//) { $subsegcmapreq=1; }
  56         elsif (s/^GP(\d+|f)$//) { $subsegmovfeatpos=$1; }
  57         elsif (s/^GL(.*)$//) {
  58             my ($sscmfn) = $1;
  59             my ($sscmf, $datum, $csss, $angbits);
  60             local ($_);
  61             $sscmf= new IO::File $sscmfn, 'r'
  62                 or die "$sscmfn: cannot open: $!\n";
  63             for (;;) {
  64                 $!=0; $_= <$sscmf>; die $! unless defined $_;
  65                 last if m/^E/;
  66                 next unless m/^C/;
  67                 m,^C\s+(\w*/(?:[A-Za-z_]+)?)\s+(0x[0-9a-f]+)\s+(\d+)\s*$,
  68                     or die "$sscmfn:$.: syntax error in subseg cmap\n";
  69                 ($csss,$datum,$angbits)= ($1,$2,$3);
  70                 if (!defined $subsegcmapangscale) {
  71                     $subsegcmapangscale= 1<<$angbits;
  72                 } else {
  73                     die "angbits varies" if $subsegcmapangscale != 1<<$angbits;
  74                 }
  75                 $datum= hex($datum);
  76                 if ($datum & 0x0ff) {
  77                     die "sorry, cannot put any movfeatpos or segment in red";
  78                 }
  79                 $subsegcmap{$csss}= sprintf("%.6f %.6f",
  80                                             (($datum >> 8) & 0xff)/255.0,
  81                                             (($datum >> 16) & 0xff)/255.0);
  82             }
  83             $sscmf->error and die "$sscmfn: error reading: $!\n";
  84             close $sscmf;
  85         } elsif (s/^(e)
  86                ((?:[a-z]|\*|\?|\[[a-z][-a-z]*\])*?)
  87                (\~?) (\d*) (\=*|\-+|\++) (\d*|\*)
  88                ([a-z]+)$//ix) {
  89             my ($ee,$g,$n,$d,$c,$v,$cc) = ($1,$2,$3,$4,$5,$6,$7);
  90             my ($eo, $invert, $lfn, $ccc, $sense,$limit);
  91             $g =~ s/\?/\./g; $g =~ s/\*/\.\*/g;
  92             die '-[eE]GND[=]* not allowed' if $v eq '*' && length $d;
  93             $d= $output_layer if !length $d;
  94             $d= 5 if $d eq '*';
  95             $invert= length $n;
  96             $c= '=' if !length $c;
  97             if (length $v && $v ne '*') {
  98                 die '-[eE]GN[D]CCV not allowed' if length $c > 1;
  99                 $c= $c x $v;
 100             }
 101             if ($c =~ m/^[-+]/) {
 102                 die '-[eE]GN+/-* not allowed' if $v eq '*';
 103                 $sense= ($&.'1') + 0;
 104                 $limit= ($sense * $d) + length($c) - 1;
 105                 $lfn= sub {
 106                     ($output_layer eq '*' ? $d
 107                      : $_[0]) * $sense >= $limit
 108                          xor $invert;
 109                 };
 110             } elsif ($v eq '*') {
 111                 $lfn= sub { !$invert; };
 112             } else {
 113                 $limit= length($c) - 1;
 114                 $lfn= sub {
 115 #my ($lfn_result)=(
 116                     ($output_layer eq '*' ? 1
 117                      : abs($_[0] - $d) <= $limit)
 118                         xor $invert
 119 #)
 120                             ;
 121 #print STDERR "output layer $output_layer; asking re $_[0] rel $d lim $limit invert $invert result $lfn_result\n";
 122 #$lfn_result;
 123                 };
 124             }
 125             $ccc= '';
 126             foreach $c (split //, $cc) {
 127                 if ($ee eq 'e') {
 128                     die "bad -e option $c" unless defined $chdraw_emap{$c};
 129                     $ccc .=  $chdraw_emap{$c};
 130                 } else {
 131                     die "bad -E option $c" unless $c =~ m/[$drawers]/i;
 132                     $ccc .= $c;
 133                 }
 134             }
 135             $eo->{GlobRe}= $g;
 136             $eo->{LayerCheck}= $lfn;
 137             $eo->{DrawMods}= $ccc;
 138 #print STDERR "created eo $eo re $eo->{GlobRe} n=$n d=$d v=$v c=$c limit=$limit cc=$cc\n";
 139             push @eopts, $eo;
 140         } elsif (m/^S/) {
 141             die "-S option must come right at the start and have numeric arg";
 142         } else {
 143             die "unknown option -$_";
 144         }
 145     }
 146 }
 147
 148 our $ptscale= 72/25.4 / $scale;
 149
 150 our $psu_ulen= 4.5;
 151 our $psu_edgelw= 0.5;
 152 our $psu_ticklw= 0.1;
 153 our $psu_ticksperu= 1;
 154 our $psu_ticklen= 5.0;
 155 our $psu_gauge= 9;
 156 our $psu_sleeperlen= 17;
 157 our $psu_sleeperlw= 15;
 158 our $psu_raillw= 1.0;
 159 our $psu_thinlw= 1.0;
 160 our %psu_subseglw;
 161 $psu_subseglw{'e'}= 20.0;
 162 $psu_subseglw{'m'}= 15.0;
 163
 164 our $lmu_marklw= 4;
 165 our $lmu_marktpt= 11;
 166 our $lmu_txtboxtxty= $lmu_marktpt * 0.300;
 167 our $lmu_txtboxh= $lmu_marktpt * 1.100;
 168 our $lmu_lenboxh= $lmu_marktpt * 1.100;
 169 our $lmu_txtboxpadx= $lmu_marktpt * 0.335;
 170 our $lmu_lenboxpadx= $lmu_marktpt * 0.005;
 171 our $lmu_txtboxoff= $lmu_marklw / 2;
 172 our $lmu_lenboxoff= -$lmu_marklw * 1.0;
 173 our $lmu_txtboxlw= 1;
 174
 175 our $olu_left= 10 * $scale;
 176 our $olu_right= 217 * $scale - $olu_left;
 177 our $olu_bottom= 20 * $scale;
 178 our $olu_top= 270 * $scale - $olu_bottom;
 179 our $olu_gap_x= 30;
 180 our $olu_gap_y= 60;
 181 our $olu_textheight= 15;
 182 our $olu_textallowperc= $lmu_marktpt * 5.0/11;
 183
 184 our $pi= atan2(0,-1);
 185
 186 sub allwidth2 ($) {
 187     my ($radius)= @_;
 188     return 27 unless defined $radius;
 189     $radius= abs($radius);
 190     return ($radius >= 450 ? 33 :
 191             $radius >= 400 ? 35 :
 192             37);
 193 }
 194 sub allwidth ($) { return allwidth2($_[0]) * 0.5; }
 195
 196 our $allwidthmax= allwidth(0);
 197 our $allwidthmin= allwidth(undef);
 198
 199 # Data structures:
 200 #  $ctx->{CmdLog}= undef                  } not in defobj
 201 #  $ctx->{CmdLog}[]= [ command args ]     } in defobj
 202 #  $ctx->{Parent}= $parent_ctx or undef
 203 #  $ctx->{LocsMade}[]{Id}= $id
 204 #  $ctx->{LocsMade}[]{Neg}= 1 or 0
 205 #  $ctx->{Loc}{$id}{X}
 206 #  $ctx->{Loc}{$id}{Y}
 207 #  $ctx->{Loc}{$id}{A}
 208 #  $ctx->{Loc}{$id}{LayerKind}
 209 #  $ctx->{Trans}{X}       # transformation.  is ev representing
 210 #  $ctx->{Trans}{Y}       # new origin.  (is applied at _input_
 211 #  $ctx->{Trans}{A}       # not at plot-time)
 212 #  $ctx->{Trans}{R}       # but multiply all y coords by this!
 213 #  $ctx->{Draw}           # sequence of one or more chrs from uc $drawers
 214 #                         #  possibly including X meaning never draw
 215 #                         #  anything now (eg in defobj)
 216 #  $ctx->{DrawMap}        # =$fn s.t.
 217 #                         #  &$fn($drawchrs_spec_by_layer_cmdline)
 218 #                         #   = $drawchrs_we_should_use_due_to_obj_etc
 219 #  $ctx->{SegName}        # initial segment name (at start of object or file)
 220 #                         #  or nonexistent if in object in unknown segment
 221 #                         #  may have leading `-'
 222 #  $ctx->{SegMapN}{$s}= $o
 223 #  $ctx->{SegMapNM}{$s}= $o
 224 #  $ctx->{SavedSegment}   # exists iff segment command used, is a $csss
 225 #  $ctx->{Layer}{Level}
 226 #  $ctx->{Layer}{Kind}
 227 #
 228 #  $objs{$id}{CmdLog}
 229 #  $objs{$id}{Loc}
 230 #  $objs{$id}{Part}       # 1 iff object is a part
 231 #
 232 #  $eopts[]{GlobRe}       # regexp for K
 233 #  $eopts[]{LayerCheck}   # =$fn where &$fn($l) is true iff layer matches
 234 #  $eopts[]{DrawMods}     # modifier chars for drawing
 235 #
 236 #  @segments= ( $csss0, $dist0, $csss1, $dist1, ..., $csssn )
 237 #                         # here each csss may have preceding `-'
 238 #
 239 #  $subsegcmap{$csss} = "$green $blue"
 240 #                         # $csss is canonical subseg spec; always has '/'
 241
 242 our $ctx;
 243 our %objs;
 244 our @al; # current cmd
 245
 246 our $o='';
 247 our $ol='';
 248
 249 our $param; # for parametric_segment
 250
 251 # ev_... functions
 252 #
 253 # Operate on Enhanced Vectors which are a location (coordinates) and a
 254 # direction at that location.  Representation is a hash with members X
 255 # Y and A (angle of the direction in radians, anticlockwise from
 256 # East).  May be absolute, or interpreted as relative, according to
 257 # context.
 258 #
 259 # Each function's first argument is a hashref whose X Y A members will
 260 # be created or overwritten; this hashref will be returned (so you can
 261 # use it `functionally' by passing {}).  The other arguments may be ev
 262 # hashrefs, or other info.  The results are in general undefined if
 263 # one of the arguments is the same hash as the result.
 264
 265 sub ev_byang ($$;$) {
 266     # ev_byang(R, ANG,[LEN])
 267     # result is evec LEN (default=1.0) from origin pointing in direction ANG
 268     my ($res,$ang,$len)=@_;
 269     $len=1.0 unless defined $len;
 270     $res->{X}= $len * cos($ang);
 271     $res->{Y}= $len * sin($ang);
 272     $res->{A}= $ang;
 273     $res;
 274 }
 275 sub ev_compose ($$$) {
 276     # ev_compose(SUM_R, A,B);
 277     # appends B to A, result is end of new B
 278     # (B's X is forwards from end of A, Y is translating left from end of A)
 279     # A may have a member R, which if provided then it should be 1.0 or -1.0,
 280     # and B's Y and A will be multiplied by R first (ie, we can reflect);
 281     my ($sum,$a,$b) = @_;
 282     my ($r);
 283     $r= defined $a->{R} ? $a->{R} : 1.0;
 284     $sum->{X}= $a->{X} + $b->{X} * cos($a->{A}) - $r * $b->{Y} * sin($a->{A});
 285     $sum->{Y}= $a->{Y} + $r * $b->{Y} * cos($a->{A}) + $b->{X} * sin($a->{A});
 286     $sum->{A}= $a->{A} + $r * $b->{A};
 287     $sum;
 288 }
 289 sub ev_decompose ($$$) {
 290     # ev_decompose(B_R, A,SUM)
 291     # computes B_R s.t. ev_compose({}, A, B_R) gives SUM
 292     my ($b,$a,$sum)=@_;
 293     my ($r,$brx,$bry);
 294     $r= defined $a->{R} ? $a->{R} : 1.0;
 295     $brx= $sum->{X} - $a->{X};
 296     $bry= $r * ($sum->{Y} - $a->{Y});
 297     $b->{X}= $brx * cos($a->{A}) + $bry * sin($a->{A});
 298     $b->{Y}= $bry * cos($a->{A}) - $brx * sin($a->{A});
 299     $b->{A}= $r * ($sum->{A} - $a->{A});
 300     $b;
 301 }
 302 sub ev_lincomb ($$$$) {
 303     # ev_linkcomb(RES,A,B,P)
 304     # gives P*A + (1-P)*B
 305     my ($r,$a,$b,$p) = @_;
 306     my ($q) = 1.0-$p;
 307     map { $r->{$_} = $q * $a->{$_} + $p * $b->{$_} } qw(X Y A);
 308     $r;
 309 }
 310 sub a_normalise ($$) {
 311     # a_normalise(A,Z)
 312     # adds or subtracts 2*$pi to/from A until it is in [ Z , Z+2*$pi >
 313     my ($a,$z)=@_;
 314     my ($r);
 315     $r= $z + fmod($a - $z, 2.0*$pi);
 316     $r += 2*$pi if $r < $z;
 317     return $r;
 318 }
 319 sub ev_bearing ($$) {
 320     # ev_bearing(A,B)
 321     # returns bearing of B from A
 322     # value returned is in [ A->{A}, A->{A} + 2*$pi >
 323     # A->{A} and B->{A} are otherwise ignored
 324     my ($a,$b)= @_;
 325     my ($r);
 326     $r= atan2($b->{Y} - $a->{Y},
 327               $b->{X} - $a->{X});
 328     $r= a_normalise($r,$a->{A});
 329     return $r;
 330 }
 331
 332 sub v_rotateright ($) {
 333     # v_rotateright(A)
 334     # returns image of A rotated 90 deg clockwise
 335     my ($a)= @_;
 336     return { X => $a->{Y}, Y => -$a->{X} };
 337 }
 338 sub v_dotproduct ($$) {
 339     # v_dotproduct(A,B)
 340     my ($a,$b)= @_;
 341     return $a->{X} * $b->{X} + $a->{Y} * $b->{Y};
 342 }
 343 sub v_scalarmult ($$) {
 344     # v_scalarmult(S,V)
 345     # multiplies V by scalar S and returns product
 346     my ($s,$v)=@_;
 347     return { X => $s * $v->{X}, Y => $s * $v->{Y} };
 348 }
 349 sub v_add ($;@) {
 350     # v_add(A,B,...)
 351     # vector sum of all inputs
 352     my (@i) = @_;
 353     my ($r,$i);
 354     $r= { X => 0.0, Y => 0.0 };
 355     foreach $i (@i) { $r->{X} += $i->{X}; $r->{Y} += $i->{Y}; }
 356     return $r;
 357 }
 358 sub v_subtract ($$) {
 359     # v_subtract(A,B)
 360     # returns vector from A to B, ie B - A
 361     my ($a,$b)= @_;
 362     return { X => $b->{X} - $a->{X},
 363              Y => $b->{Y} - $a->{Y} };
 364 }
 365 sub v_len ($) {
 366     # v_len(V)
 367     # scalar length of V
 368     my ($v)=@_;
 369     my ($x,$y) = ($v->{X}, $v->{Y});
 370     return sqrt($x*$x + $y*$y);
 371 }
 372 sub v_dist ($$) {
 373     # v_dist(A,B)
 374     # returns distance from A to B
 375     return v_len(v_subtract($_[0],$_[1]));
 376 }
 377
 378 sub upd_min ($$) {
 379     my ($limr,$now)=@_;
 380     $$limr= $now unless defined $$limr && $$limr <= $now;
 381 }
 382 sub upd_max ($$) {
 383     my ($limr,$now)=@_;
 384     $$limr= $now unless defined $$limr && $$limr >= $now;
 385 }
 386
 387 sub canf ($$) {
 388     my ($converter,$defaulter)=@_;
 389     my ($spec,$v);
 390     return &$defaulter unless @al;
 391     $spec= shift @al;
 392     $v= &$converter($spec);
 393     dv('canf ','$spec',$spec, '$v',$v);
 394     return $v;
 395 }
 396 sub can ($) { my ($c)=@_; canf($c, sub { die "too few args"; }); }
 397 sub cano ($$) { my ($c,$def)=@_; canf($c, sub { return $def }); }
 398
 399 sub signum ($) { return ($_[0] > 0) - ($_[0] < 0); }
 400
 401 sub bbox ($) {
 402     my ($objhash) = @_;
 403     my ($min_x, $max_x, $min_y, $max_y);
 404     my ($loc);
 405     foreach $loc (values %$objhash) {
 406         upd_min(\$min_x, $loc->{X} - abs($allwidthmax * sin($loc->{A})));
 407         upd_max(\$max_x, $loc->{X} + abs($allwidthmax * sin($loc->{A})));
 408         upd_min(\$min_y, $loc->{Y} - abs($allwidthmax * cos($loc->{A})));
 409         upd_max(\$max_y, $loc->{Y} + abs($allwidthmax * cos($loc->{A})));
 410     }
 411     return ($min_x, $max_x, $min_y, $max_y);
 412 }
 413
 414 our %units_len= qw(- mm  mm 1  cm 10  m 1000);
 415 our %units_ang= qw(- d   r 1); $units_ang{'d'}= 2*$pi / 360;
 416
 417 sub cva_len ($) { my ($sp)=@_; cva_units($sp,\%units_len); }
 418 sub cva_identity ($) { my ($sp)=@_; $sp; }
 419 sub cva_ang ($) { my ($sp)=@_; cva_units($sp,\%units_ang); }
 420 sub cva_absang ($) { input_absang(cva_ang($_[0])) }
 421 sub cva_units ($$) {
 422     my ($sp,$ua)=@_;
 423     my ($n,$u,$r);
 424     $sp =~ m/^([-0-9eE.]*[0-9.])([A-Za-z]*)$/
 425         or die "lexically invalid quantity";
 426     ($n,$u)= ($1,$2);
 427     $u=$ua->{'-'} unless length $u;
 428     defined $ua->{$u} or die "unknown unit $u";
 429     $r= $n * $ua->{$u};
 430     print DEBUG "cva_units($sp,)=$r ($n $u $ua->{$u})\n";
 431     return $r;
 432 }
 433 sub cva_idstr ($) {
 434     my ($sp)=@_;
 435     die "invalid id" unless $sp =~ m/^[a-z][_0-9A-Za-z]*$/;
 436     return $&;
 437 }
 438 sub cva_idex ($) {
 439     my ($sp)=@_;
 440     my ($id,$r,$d,$k,$neg,$na,$obj_id,$vflip,$locs);
 441     if ($sp =~ s/^(\^?)(\w+)\!//) {
 442         $vflip= length($1);
 443         $obj_id= $2;
 444         die "invalid obj $obj_id in loc" unless exists $objs{$obj_id};
 445         $locs= $objs{$obj_id}{Loc};
 446     } else {
 447         $locs= $ctx->{Loc};
 448         $vflip= 0;
 449     }
 450     $neg= $sp =~ s/^\-//;
 451     $id= cva_idstr($sp);
 452     die "unknown $id" unless defined $locs->{$id};
 453     $r= $locs->{$id};
 454     $d= "idex $id";
 455     foreach $k (sort keys %$r) { $d .= " $k=$r->{$k}"; }
 456     printf DEBUG "%s\n", $d;
 457     if ($vflip) {
 458         $r= { X => $r->{X}, Y => -$r->{Y}, A => -$r->{A} };
 459     }
 460     if ($neg) {
 461         $na= $r->{A} + $pi;
 462         $na= a_normalise($na,0);
 463         $r= { X => $r->{X}, Y => $r->{Y}, A => $na };
 464     }
 465     return $r;
 466 }
 467 sub cva_idnew ($) {
 468     my ($sp)=@_;
 469     my ($id, $neg);
 470     $neg = $sp =~ s/^\-//;
 471     $id=cva_idstr($sp);
 472     die "duplicate $id" if exists $ctx->{Loc}{$id};
 473     $ctx->{Loc}{$id}{LayerKind}= $ctx->{Layer}{Kind};
 474     push @{ $ctx->{LocsMade} }, {
 475         Id => $id,
 476         Neg => $neg,
 477     };
 478     return $ctx->{Loc}{$id};
 479 }
 480 sub cva_cmd ($) { return cva_idstr($_[0]); }
 481 sub cva__enum ($$) {
 482     my ($sp,$el)=@_;
 483     return $sp if grep { $_ eq $sp } @$el;
 484     die "invalid option (permitted: @$el)";
 485 }
 486 sub cvam_enum { my (@e) = @_; return sub { cva__enum($_[0],\@e); }; }
 487
 488 sub cmd_abs {
 489     my ($i,$nl);
 490     $nl= can(\&cva_idnew);
 491     $i->{X}= can(\&cva_len);
 492     $i->{Y}= can(\&cva_len);
 493     $i->{A}= can(\&cva_ang);
 494     ev_compose($nl, $ctx->{Trans}, $i);
 495 }
 496 sub cmd_rel {
 497     my ($from,$to,$len,$right,$turn);
 498     $from= can(\&cva_idex);
 499     $to= can(\&cva_idnew);
 500     $len= cano(\&cva_len,0);
 501     $right= cano(\&cva_len,0) * $ctx->{Trans}{R};
 502     $turn= cano(\&cva_ang, 0) * $ctx->{Trans}{R};
 503     my ($u)= ev_compose({}, $from, { X => $len, Y => -$right, A => 0 });
 504     ev_compose($to, $u, { X => 0, Y => 0, A => $turn });
 505 }
 506
 507 sub dv__evreff ($) {
 508     my ($pfx) = @_;
 509     $pfx . ($pfx =~ m/\}$|\]$/ ? '' : '->');
 510 }
 511 sub dv__evr ($) {
 512     my ($v) = @_;
 513     return 'undef' if !defined $v;
 514     return $v if $v !~ m/\W/ && $v =~ m/[A-Z]/ && $v =~ m/^[a-z_]/i;
 515     return $v if $v =~ m/^[0-9.]+/;
 516     $v =~ s/[\\\']/\\$&/g;
 517     return "'$v'";
 518 }
 519 sub dv1 ($$$);
 520 sub dv1_kind ($$$$$$$) {
 521     my ($pfx,$expr,$ref,$ref_exp,$ixfmt,$ixesfn,$ixmapfn) = @_;
 522     my ($ix,$any);
 523     return 0 if $ref ne $ref_exp;
 524     $any=0;
 525     foreach $ix (&$ixesfn) {
 526         $any=1;
 527         my ($v)= &$ixmapfn($ix);
 528 #print STDERR "dv1_kind($pfx,$expr,$ref,$ref_exp,$ixmapfn) ix=$ix v=$v\n";
 529         dv1($pfx,$expr.sprintf($ixfmt,dv__evr($ix)),$v);
 530     }
 531     if (!$any) {
 532         printf DEBUG "%s%s= $ixfmt\n", $pfx, $expr, ' ';
 533     }
 534     1;
 535 }
 536 sub dv1 ($$$) {
 537     return 0 unless $debug;
 538     my ($pfx,$expr,$v) = @_;
 539     my ($ref);
 540     $ref= ref $v;
 541 #print STDERR "dv1 >$pfx|$ref<\n";
 542     if (!$ref) {
 543         printf DEBUG "%s%s= %s\n", $pfx,$expr, dv__evr($v);
 544         return;
 545     } elsif ($ref eq 'SCALAR') {
 546         dv1($pfx, ($expr =~ m/^\$/ ? "\$$expr" : '${'.$expr.'}'), $$v);
 547         return;
 548     }
 549     $expr.='->' unless $expr =~ m/\]$|\}$/;
 550     return if dv1_kind($pfx,$expr,$ref,'ARRAY','[%s]',
 551                        sub { ($[ .. $#$v) },
 552                        sub { $v->[$_[0]] });
 553     return if dv1_kind($pfx,$expr,$ref,'HASH','{%s}',
 554                        sub { sort keys %$v },
 555                        sub { $v->{$_[0]} });
 556     printf DEBUG "%s%s is %s\n", $pfx, $expr, $ref;
 557 }
 558
 559 sub dv {
 560     my ($pfx,@l) = @_;
 561     my ($expr,$v,$ref);
 562     while (@l) {
 563         ($expr,$v,@l)=@l;
 564         dv1($pfx,$expr,$v);
 565     }
 566 }
 567
 568 sub o ($) { $o .= $_[0]; }
 569 sub ol ($) { $ol .= $_[0]; }
 570 sub oflushpage () {
 571     return if $subsegcmapreq;
 572     print $o, $ol, "  showpage\n"
 573         or die $!;
 574     $o=$ol='';
 575 }
 576
 577 our $o_path_verb;
 578
 579 sub o_path_begin () {
 580     o("      newpath\n");
 581     $o_path_verb= 'moveto';
 582 }
 583 sub o_path_point ($) {
 584     my ($pt)=@_;
 585     o("        $pt $o_path_verb\n");
 586     $o_path_verb= 'lineto';
 587 }
 588 sub o_path_stroke ($) {
 589     my ($width)=@_;
 590     o("        $width setlinewidth stroke\n");
 591 }
 592 sub o_path_strokeonly () {
 593     o("      stroke\n");
 594 }
 595
 596 sub o_line ($$$) {
 597     my ($a,$b,$width)=@_;
 598     o_path_begin();
 599     o_path_point($a);
 600     o_path_point($b);
 601     o_path_stroke($width);
 602 }
 603
 604 sub current_draw () {
 605     my ($r);
 606     $r= $ctx->{Draw} =~ m/X/ ? '' : $ctx->{Draw};
 607     $r;
 608 }
 609
 610 sub psu_coords ($$$) {
 611     my ($ends,$inunit,$across)=@_;
 612     # $ends->[0]{X} etc.; $inunit 0 to 1 (but go to 1.5);
 613     # $across in mm, +ve to right.
 614     my (%ea_zo, $zo, $prop);
 615     $ea_zo{X}=$ea_zo{Y}=0;
 616     foreach $zo (qw(0 1)) {
 617         $prop= $zo ? $inunit : (1.0 - $inunit);
 618         $ea_zo{X} += $prop * ($ends->[$zo]{X} - $across * sin($ends->[0]{A}));
 619         $ea_zo{Y} += $prop * ($ends->[$zo]{Y} + $across * cos($ends->[0]{A}));
 620     }
 621 #    dv("psu_coords ", '$ends',$ends, '$inunit',$inunit, '$across',$across,
 622 #       '\\%ea_zo', \%ea_zo);
 623     return $ea_zo{X}." ".$ea_zo{Y};
 624 }
 625
 626 sub parametric__o_pt ($) {
 627     my ($pt)=@_;
 628     o_path_point("$pt->{X} $pt->{Y}");
 629 }
 630
 631 our $segused_incurrent;
 632 our $segused_currentpt;
 633 our $segmentpart_counter=0;
 634 our $segused_restorecounter;
 635
 636 sub segment_used__print ($) {
 637     my ($pt) = @_;
 638     if ($segused_incurrent > 0 && $segused_restorecounter==1) {
 639         o("%L segmentpart ".
 640           $segmentpart_counter++." ".
 641           $ctx->{Layer}{Level}.$ctx->{Layer}{Kind}." ".
 642           $segments[0]." ".
 643           $segused_incurrent." ".
 644           loc2dbg($segused_currentpt)." ".
 645           loc2dbg($pt)."\n");
 646     }
 647     $segused_incurrent= undef;
 648     $segused_currentpt= undef;
 649 }
 650
 651 sub segment_used__len ($$) {
 652     my ($used,$pt) = @_;
 653     $segused_incurrent++;
 654
 655     return if @segments < 3;
 656     $segments[1] -= $used;
 657     return if $segments[1] > 0;
 658
 659     segment_used__print($pt);
 660     segment_used_begin($pt);
 661
 662     @segments= @segments[2..$#segments];
 663     o("% segments @segments\n");
 664 }
 665
 666 sub segment_state_save () {
 667     return [ 0, $segused_incurrent, $segused_currentpt,
 668              $segmentpart_counter, @segments ];
 669 }
 670 sub segment_state_restore ($) {
 671     my ($r) = @_;
 672     ($segused_restorecounter, $segused_incurrent, $segused_currentpt,
 673      $segmentpart_counter, @segments) = @$r;
 674     $r->[0]++;
 675 }
 676
 677 sub segment_used_begin ($) {
 678     $segused_incurrent= 0;
 679     $segused_currentpt= $_[0];
 680 }
 681 sub segment_used_middle ($$) {
 682     my ($used,$pt) = @_;
 683     segment_used__len($used,$pt);
 684 }
 685 sub segment_used_end ($$) {
 686     my ($used,$pt) = @_;
 687     segment_used__len($used,$pt);
 688     segment_used__print($pt);
 689 }
 690 sub parametric_segment ($$$$$) {
 691     my ($p0,$p1,$lenperp,$minradius,$calcfn) = @_;
 692     # makes $param (global) go from $p0 to $p1  ($p1>$p0)
 693     # $lenperp is the length of one unit p, ie the curve
 694     # must have a uniform `density' in parameter space
 695     # $calcfn is invoked with $param set and should return a loc
 696     # (ie, ref to X =>, Y =>, A =>).
 697     my ($pa,$pb,@ends,$side,$ppu,$e,$v,$tick,$draw,$allwidth);
 698     return unless $ctx->{Draw} =~ m/[ARSCG]/;
 699     $ppu= $psu_ulen/$lenperp;
 700     $allwidth= allwidth($minradius);
 701     my ($railctr)=($psu_gauge + $psu_raillw)*0.5;
 702     my ($tickend)=($allwidth - $psu_ticklen);
 703     my ($tickpitch)=($psu_ulen / $psu_ticksperu);
 704     my ($sleeperctr)=($psu_ulen*0.5);
 705     my ($sleeperend)=($psu_sleeperlen*0.5);
 706 print DEBUG "ps $p0 $p1 $lenperp ($ppu)\n";
 707     $draw= current_draw();
 708     if ($draw =~ m/G/) {
 709         my ($pt,$going,$red,$csegbare,$movfeat,$movstroke);
 710         my ($used_last,$me,$segsave);
 711         $segsave= segment_state_save();
 712         foreach $me (qw(e m)) {
 713             segment_state_restore($segsave);
 714             $going=0;
 715             o("% segments @segments\n");
 716             $param=$p0;
 717             $pt= &$calcfn;
 718             segment_used_begin($pt);
 719             for (;;) {
 720                 $movstroke= "      cmapreq-stroke\n";
 721                 $csegbare= $segments[0];
 722                 $csegbare =~ s/^\-//;
 723                 if ($subsegcmapreq) {
 724                     if (!exists $subsegcmap{$csegbare}) {
 725                         print "$csegbare\n" or die $!;
 726                         $subsegcmap{$csegbare}++;
 727                     }
 728                 } else {
 729                     $movfeat= $csegbare =~ s,(/\D+)(\d+)$,$1, ? $2 : 'f';
 730                     die "unknown subsegment colour for $csegbare\n"
 731                         unless exists $subsegcmap{$csegbare};
 732                     $red= $pt->{A} / (2*$pi);
 733                     $red *= $subsegcmapangscale;
 734                     $red += $subsegcmapangscale*2;
 735                     $red += $subsegcmapangscale/2 if $segments[0] =~ m/^\-/;
 736                     $red %= $subsegcmapangscale;
 737                     $red += $subsegcmapangscale if $me eq 'e';
 738                     $red= sprintf("%f", $red / 255.0);
 739                     $movstroke=
 740                         ("    $red $subsegcmap{$csegbare} setrgbcolor\n".
 741                          "    $psu_subseglw{$me} setlinewidth stroke\n");
 742                     if ($subsegmovfeatpos ne $movfeat ||
 743                         ($me eq 'e' && $csegbare =~ m,^/,)) {
 744                         $movstroke= "%     no-stroke\n";
 745                     }
 746                 }
 747                 o_path_begin();
 748                 parametric__o_pt($pt);
 749
 750                 $param += $ppu;
 751                 last if $param>=$p1;
 752                 $pt= &$calcfn;
 753                 segment_used_middle($psu_ulen,$pt);
 754                 parametric__o_pt($pt);
 755                 o($movstroke);
 756             }
 757             $used_last= $p1-($param-$ppu);
 758             $param=$p1;
 759             $pt= &$calcfn;
 760             segment_used_end($used_last * $lenperp, $pt);
 761             parametric__o_pt($pt);
 762             o($movstroke);
 763         }
 764     }
 765     if ($draw =~ m/C/) {
 766         my ($pt);
 767         o("    $psu_thinlw setlinewidth\n");
 768         o_path_begin();
 769         for ($param=$p0; $param<$p1; $param += $ppu) {
 770             parametric__o_pt(&$calcfn);
 771         }
 772         $param=$p1;
 773         parametric__o_pt(&$calcfn);
 774         o("      stroke\n");
 775     }
 776     if ($draw =~ m/D/) {
 777         my ($pt,$ad,$len);
 778         $param= ($p0+$p1)*0.5;
 779         $pt= &$calcfn;
 780         $ad= ang2deg($pt->{A});
 781         $len= sprintf "%.0f", $lenperp * abs($p1-$p0);
 782         ol("      gsave\n".
 783            "        $pt->{X} $pt->{Y} translate\n".
 784            "        $ad rotate\n".
 785            "        lf setfont  0 $lmu_lenboxoff moveto  ($len) show\n".
 786            "      grestore\n");
 787     }
 788     return unless $draw =~ m/[ARS]/;
 789     for ($pa= $p0; $pa<$p1; $pa=$pb) {
 790         $pb= $pa + $ppu;
 791         $param= $pa; $ends[0]= @ends ? $ends[1] : &$calcfn;
 792         $param= $pb; $ends[1]= &$calcfn;
 793 #print DEBUG "pa $pa $ends[0]{X} $ends[0]{Y} $ends[0]{A}\n";
 794 #print DEBUG "pb $pb $ends[1]{X} $ends[1]{Y} $ends[1]{A}\n";
 795         $e= $pb<=$p1 ? 1.0 : ($p1-$pa)/$ppu;
 796         o("    gsave\n");
 797         o_path_begin();
 798         o_path_point(psu_coords(\@ends,0,-$allwidth));
 799         o_path_point(psu_coords(\@ends,0,$allwidth));
 800         o_path_point(psu_coords(\@ends,$e,$allwidth));
 801         o_path_point(psu_coords(\@ends,$e,-$allwidth));
 802         o("        closepath clip\n");
 803         foreach $side qw(-1 1) {
 804             if ($draw =~ m/R/) {
 805                 o_line(psu_coords(\@ends,0,$side*$railctr),
 806                        psu_coords(\@ends,1.5,$side*$railctr),
 807                        $psu_raillw);
 808             }
 809         }
 810         if ($draw =~ m/S/) {
 811             o_line(psu_coords(\@ends,$sleeperctr,-$sleeperend),
 812                    psu_coords(\@ends,$sleeperctr,+$sleeperend),
 813                    $psu_sleeperlw);
 814         }
 815         if ($draw =~ m/A/) {
 816             o("        0.5 setgray\n");
 817             foreach $side qw(-1 1) {
 818                 o_line(psu_coords(\@ends,0,$side*$allwidth),
 819                        psu_coords(\@ends,1.5,$side*$allwidth),
 820                        $psu_edgelw);
 821                 for ($tick=0; $tick<1.5; $tick+=$tickpitch/$psu_ulen) {
 822                     o_line(psu_coords(\@ends,$tick,$side*$allwidth),
 823                            psu_coords(\@ends,$tick,$side*$tickend),
 824                            $psu_ticklw);
 825                 }
 826             }
 827         }
 828         o("      grestore\n");
 829     }
 830 }
 831
 832 sub arc ($$$$$) {
 833     my ($to, $ctr,$from, $radius,$delta) = @_;
 834     # does parametric_segment to draw an arc centred on $ctr
 835     # ($ctr->{A} ignored)
 836     # from $from with radius $radius (this must be consistent!)
 837     # and directionally-subtending an angle $delta.
 838     # sets $to->... to be the other end, and returns $to
 839     my ($beta);
 840     $to->{A}= $beta= $from->{A} + $delta;
 841     $to->{X}= $ctr->{X} - $radius * sin($beta);
 842     $to->{Y}= $ctr->{Y} + $radius * cos($beta);
 843     return if abs($delta*$radius) < 1e-9;
 844     parametric_segment(0.0,1.0, abs($radius*$delta), $radius, sub {
 845         my ($beta) = $from->{A} + $delta * $param;
 846         return { X => $ctr->{X} - $radius * sin($beta),
 847                  Y => $ctr->{Y} + $radius * cos($beta),
 848                  A => $beta }
 849     });
 850 }
 851
 852 # joins_xxx all take $results, $from, $to, $minradius
 853 # where $results->[]{Path}{K} etc. and $results->[]{SolKinds}[]
 854
 855 sub joins_twoarcs ($$$$) {
 856     my ($results, $from,$to,$minradius) = @_;
 857     # two circular arcs of equal maximum possible radius
 858     # algorithm courtesy of Simon Tatham (`Railway problem',
 859     # pers.comm. to ijackson@chiark 23.1.2004)
 860     my ($sigma,$distfact, $theta,$phi, $a,$b,$c,$d, $m,$r, $radius);
 861     my ($cvec,$cfrom,$cto,$midpt, $delta1,$delta2, $path,$reverse);
 862     $sigma= ev_bearing($from,$to);
 863     $distfact= v_dist($from,$to);
 864     $theta= 0.5 * $pi - ($from->{A} - $sigma);
 865     $phi=   0.5 * $pi - ($to->{A} + $pi - $sigma);
 866     $a= 2 * (1 + cos($theta - $phi));
 867     $b= 2 * (cos($theta) - cos($phi));
 868     $c= -1;
 869     $d= sqrt($b*$b - 4*$a*$c);
 870     o("%     twoarcs theta=".ang2deg($theta)." phi=".ang2deg($phi).
 871       " ${a}r^2 + ${b}r + ${c} = 0\n");
 872     foreach $m (qw(-1 1)) {
 873         if ($a < 1e-6) {
 874             o("%     twoarcs $m insoluble\n");
 875             next;
 876         }
 877         $r= -0.5 * (-$b + $m*$d) / $a;
 878         $radius= -$r * $distfact;
 879         o("%     twoarcs $m radius $radius ");
 880         if (abs($radius) < $minradius) { o("too-small\n"); next; }
 881         $cfrom=  ev_compose({}, $from, { X=>0, Y=>-$radius, A=>-0.5*$pi });
 882         $cto=    ev_compose({}, $to,   { X=>0, Y=> $radius, A=> 0.5*$pi });
 883         $midpt=  ev_lincomb({}, $cfrom, $cto, 0.5);
 884         $reverse= signum($r);
 885         if ($reverse<0) {
 886             $cfrom->{A} += $pi;
 887             $cto->{A} += $pi;
 888         }
 889         $delta1= ev_bearing($cfrom, $midpt) - $cfrom->{A};
 890         $delta2= ev_bearing($cto,   $midpt) - $cto->{A};
 891         o("ok deltas ".ang2deg($delta1)." ".ang2deg($delta2)."\n");
 892         if ($reverse<0) {
 893             $delta1 -= 2*$pi;
 894             $delta2 -= 2*$pi;
 895         }
 896         my ($fs);
 897         $path= [{ T=>Arc, F=>$from, C=>$cfrom, R=> $radius, D=>$delta1 },
 898                 { T=>Arc, F=>$to,   C=>$cto,   R=>-$radius, D=>$delta2 }];
 899         push @$results, { Path => $path,
 900                           SolKinds =>  [ 'twoarcs', 'cross' ] };
 901     }
 902 }
 903
 904 sub joins_arcsline ($$$$) {
 905     my ($results, $from,$to,$minradius) = @_;
 906     # two circular arcs of specified radius
 907     # with an intervening straight
 908     my ($lr,$inv, $c,$d,$alpha,$t,$k,$l,$rpmsina,$rcosa,$linelen, $path);
 909     if ($minradius<=1e-6) { o("%     arcsline no-radius\n"); return; }
 910     foreach $lr (qw(-1 +1)) {
 911         foreach $inv (qw(-1 +1)) {
 912             $c=ev_compose({},$from,{X=>0,Y=>-$lr*$minradius, A=>0 });
 913             $d=ev_compose({},$to,{X=>0, Y=>-$inv*$lr*$minradius, A=>$pi });
 914             $t= v_dist($c,$d);
 915             o("%     arcsline $lr $inv t=$t ");
 916             if ($t < 1e-6) { o("concentric"); next; }
 917             $c->{A}= $d->{A}= ev_bearing($c,$d);
 918             o("bearing ".ang2deg($c->{A}));
 919             if ($inv>0) {
 920                 o("\n");
 921                 $k= ev_compose({}, $c, { X=>0, Y=>$lr*$minradius, A=>0 });
 922                 $l= ev_compose({}, $d, { X=>0, Y=>$lr*$minradius, A=>0 });
 923                 $linelen= $t;
 924             } else {
 925                 my ($cosalpha) = 2.0 * $minradius / $t;
 926                 if ($cosalpha > (1.0 - 1e-6)) { o(" too-close\n"); next; }
 927                 $alpha= acos($cosalpha);
 928                 $rpmsina= $lr * $minradius * sin($alpha);
 929                 $rcosa= $minradius * $cosalpha;
 930                 $k= ev_compose({}, $c, { X=>$rcosa, Y=>$rpmsina, A=>0 });
 931                 $l= ev_compose({}, $d, { X=>-$rcosa, Y=>-$rpmsina, A=>0 });
 932                 $k->{A}= $l->{A}= ev_bearing($k,$l);
 933                 o(" alpha=".ang2deg($alpha)." kl^=".ang2deg($k->{A})."\n");
 934                 $linelen= v_dist($k,$l);
 935             }
 936             $path= [{ T => Arc, F => $from, C => $c,
 937                       R =>$lr*$minradius,
 938                       D => -$lr * a_normalise
 939                           ($lr * ($from->{A} - $k->{A}), 0) },
 940                     { T => Line, A => $k, B => $l, L => $linelen },
 941                     { T => Arc, F => $l, C => $d,
 942                       R => $inv*$lr*$minradius,
 943                       D => -$lr*$inv * a_normalise
 944                           (-$lr*$inv * ($to->{A} - $l->{A}), 0) }];
 945             push @$results,
 946             { Path => $path,
 947               SolKinds => [ 'arcsline', ($inv<0 ? 'cross' : 'loop') ] };
 948         }
 949     }
 950 }
 951
 952 sub joins_arcline ($$$$) {
 953     my ($results, $from,$to,$minradius) = @_;
 954     # one circular arc and a straight line
 955     my ($swap,$echoice,$path, $ap,$bp,$av,$bv, $e,$f, $ae,$af,$afae);
 956     my ($dak,$ak,$kj,$k,$j,$aja,$jl,$l,$jc,$lc,$c,$rj,$rb);
 957     foreach $swap (qw(-1 +1)) {
 958         foreach $echoice (qw(0 1)) {
 959             $ap= $from; $bp= { %$to }; $bp->{A} += $pi;
 960             ($ap,$bp)= ($bp,$ap) if $swap<0;
 961             $av= ev_byang({}, $ap->{A});
 962             $bv= ev_byang({}, $bp->{A});
 963             $e= ev_byang({}, 0.5 * ($ap->{A} + $bp->{A} + $echoice * $pi));
 964             $f= v_rotateright($e);
 965             o("%     arcline $swap $echoice e ".loc2dbg($e)."\n");
 966             $ae= v_dotproduct($av,$e);
 967             $af= v_dotproduct($av,$f);
 968             o("%     arcline $swap $echoice a.e=$ae a.f=$af ");
 969             if (abs($ae) < 1e-6) { o(" singular\n"); next; }
 970             $afae= $af/$ae;
 971             o("a.f/a.e=$afae\n");
 972             $dak= v_dotproduct(v_subtract($ap,$bp), $e);
 973             $ak= v_scalarmult($dak, $e);
 974             $kj= v_scalarmult($dak * $afae, $f);
 975             $k= v_add($ap, $ak);
 976             $j= v_add($k, $kj);
 977             $aja= v_dotproduct(v_subtract($ap,$j), $av);
 978             o("%     arcline $swap $echoice d_ak=$dak aj.a=$aja ");
 979             if ($aja < 0) { o(" backwards aj\n"); next; }
 980             $jl= v_scalarmult(0.5, v_subtract($j, $bp));
 981             $lc= v_scalarmult(-v_dotproduct($jl, $f) * $afae, $e);
 982             $l= v_add($j, $jl);
 983             $c= v_add($l, $lc);
 984             $rj= v_dotproduct(v_subtract($j,$c), v_rotateright($av));
 985             $rb= v_dotproduct(v_subtract($c,$bp), v_rotateright($bv));
 986             o("r_j=$rj r_b=$rb ");
 987             if ($rj * $rb < 0) { o(" backwards b\n"); next; }
 988             if (abs($rj) < $minradius) { o(" too-small\n"); next; }
 989             o("ok\n");
 990             $j->{A}= $ap->{A};
 991             $c->{A}= 0;
 992             $path= [{ T => Line, A => $ap, B => $j, L => $aja },
 993                     { T => Arc, F => $j, C => $c, R => $rj,
 994                       D => -signum($rj) * a_normalise
 995                           (-signum($rj) * ($bp->{A} + $pi - $j->{A}), 0) }];
 996             $path= [ reverse @$path ] if $swap<0;
 997             push @$results, { Path => $path, SolKinds =>  [ 'arcline' ] };
 998         }
 999     }
1000 }
1001
1002 sub cmd_join {
1003     my ($from,$to,$minradius);
1004     my (@results,$result);
1005     my ($path,$segment,$bestpath,$len,$scores,$bestscores,@bends,$skl);
1006     my ($crit,$cs,$i,$cmp);
1007     $from= can(\&cva_idex);
1008     $to= can(\&cva_idex);
1009     $minradius= can(\&cva_len);
1010     o("%   join ".loc2dbg($from)."..".loc2dbg($to)." $minradius\n");
1011     joins_twoarcs(\@results, $from,$to,$minradius);
1012     joins_arcsline(\@results, $from,$to,$minradius);
1013     joins_arcline(\@results, $from,$to,$minradius);
1014     foreach $result (@results) {
1015         $path= $result->{Path};
1016         $skl= $result->{SolKinds};
1017         o("%   possible path @$skl $path\n");
1018         $len= 0;
1019         @bends= ();
1020         foreach $segment (@$path) {
1021             if ($segment->{T} eq Arc) {
1022                 o("%     Arc C ".loc2dbg($segment->{C}).
1023                   " R $segment->{R} D ".ang2deg($segment->{D})."\n");
1024                 $len += abs($segment->{R} * $segment->{D});
1025                 push @bends, -abs($segment->{R}) * $segment->{D}; # right +ve
1026             } elsif ($segment->{T} eq Line) {
1027                 o("%     Line A ".loc2dbg($segment->{A}).
1028                   " B ".loc2dbg($segment->{A})." L $segment->{L}\n");
1029                 $len += abs($segment->{L});
1030             } else {
1031                 die "unknown segment $segment->{T}";
1032             }
1033         }
1034         o("%    length $len bends @bends.\n");
1035         $scores= [];
1036         foreach $crit (@al, 'short') {
1037             if ($crit eq 'long') { $cs= $len; }
1038             elsif ($crit eq 'short') { $cs= -$len; }
1039             elsif ($crit =~ m/^(begin|end|)(left|right)$/) {
1040                 if ($1 eq 'begin') { $cs= $bends[0]; }
1041                 elsif ($1 eq 'end') { $cs= $bends[$#bends]; }
1042                 else { $cs=0; map { $cs += $_ } @bends; }
1043                 $cs= -$cs if $2 eq 'left';
1044             } elsif ($crit =~ m/^(\!?)(twoarcs|arcs?line|cross|loop)$/) {
1045                 $cs= !!(grep { $2 eq $_ } @$skl) != ($1 eq '!');
1046             } else {
1047                 die "unknown sort criterion $crit";
1048             }
1049             push @$scores, $cs;
1050         }
1051         o("%    scores @$scores\n");
1052         if (defined $bestpath) {
1053             for ($i=0,$cmp=0; !$cmp && $i<@$scores; $i++) {
1054                 $cmp= $scores->[$i] <=> $bestscores->[$i];
1055             }
1056             next if $cmp < 0;
1057         }
1058         $bestpath= $path;
1059         $bestscores= $scores;
1060     }
1061     die "no solution" unless defined $bestpath;
1062     o("%   chose path $bestpath @al\n");
1063     @al= ();
1064     foreach $segment (@$bestpath) {
1065         if ($segment->{T} eq 'Arc') {
1066             arc({}, $segment->{C},$segment->{F},$segment->{R},$segment->{D});
1067         } elsif ($segment->{T} eq 'Line') {
1068             line($segment->{A}, $segment->{B}, $segment->{L});
1069         } else {
1070             die "unknown segment";
1071         }
1072     }
1073 }
1074
1075 sub line ($$$) {
1076     my ($from,$to,$len) = @_;
1077     if ($len < 0) {
1078         ($from,$to,$len) = ($to,$from,-$len);
1079     }
1080     parametric_segment(0.0, 1.0, $len + 1e-6, undef, sub {
1081         ev_lincomb({}, $from, $to, $param);
1082     });
1083 }
1084
1085 sub cmd_extend {
1086     my ($from,$to,$radius,$len,$upto,$ctr,$beta,$ang,$how,$sign_r);
1087     $from= can(\&cva_idex);
1088     $to= can(\&cva_idnew);
1089     printf DEBUG "from $from->{X} $from->{Y} $from->{A}\n";
1090     $how= can(cvam_enum(qw(len upto ang uptoang parallel)));
1091     if ($how eq 'len') { $len= can(\&cva_len); }
1092     elsif ($how =~ m/ang$/) { $ang= can(\&cva_ang); }
1093     elsif ($how eq 'parallel' || $how eq 'upto') { $upto= can(\&cva_idex); }
1094     $radius= cano(\&cva_len, 'Inf'); # +ve is right hand bend
1095     if ($radius eq 'Inf') {
1096 #       print DEBUG "extend inf $len\n";
1097         if ($how eq 'upto') {
1098             $len= ($upto->{X} - $from->{X}) * cos($from->{A})
1099                 + ($upto->{Y} - $from->{Y}) * sin($from->{A});
1100         } elsif ($how eq 'len') {
1101         } else {
1102             die "len of straight spec by angle";
1103         }
1104         printf DEBUG "len $len\n";
1105         $to->{X}= $from->{X} + $len * cos($from->{A});
1106         $to->{Y}= $from->{Y} + $len * sin($from->{A});
1107         $to->{A}= $from->{A};
1108         line($from,$to,$len);
1109     } else {
1110         my ($sign_r, $sign_ang, $ctr, $beta_interval, $beta, $delta);
1111         print DEBUG "radius >$radius<\n";
1112         $radius *= $ctx->{Trans}{R};
1113         $sign_r= signum($radius);
1114         $sign_ang= 1;
1115         $ctr->{X}= $from->{X} + $radius * sin($from->{A});
1116         $ctr->{Y}= $from->{Y} - $radius * cos($from->{A});
1117         if ($how eq 'upto') {
1118             $beta= atan2(-$sign_r * ($upto->{X} - $ctr->{X}),
1119                          $sign_r * ($upto->{Y} - $ctr->{Y}));
1120             $beta_interval= 1.0;
1121         } elsif ($how eq 'parallel') {
1122             $beta= $upto->{A};
1123             $beta_interval= 1.0;
1124         } elsif ($how eq 'uptoang') {
1125             $beta= input_absang($ang);
1126             $beta_interval= 2.0;
1127         } elsif ($how eq 'len') {
1128             $sign_ang= signum($len);
1129             $beta= $from->{A} - $sign_r * $len / abs($radius);
1130             $beta_interval= 2.0;
1131         } else {
1132             $sign_ang= signum($ang);
1133             $beta= $from->{A} - $sign_r * $ang;
1134             $beta_interval= 2.0;
1135         }
1136     printf DEBUG "ctr->{Y}=$ctr->{Y} radius=$radius beta=$beta\n";
1137         $beta += $sign_ang * $sign_r * 4.0 * $pi;
1138         for (;;) {
1139             $delta= $beta - $from->{A};
1140             last if $sign_ang * $sign_r * $delta <= 0;
1141             $beta -= $sign_ang * $sign_r * $beta_interval * $pi;
1142         }
1143     printf DEBUG "ctr->{Y}=$ctr->{Y} radius=$radius beta=$beta\n";
1144         arc($to, ,$ctr,$from, $radius,$delta);
1145     }
1146     printf DEBUG "to $to->{X} $to->{Y} $to->{A}\n";
1147 }
1148
1149 sub loc2dbg ($) {
1150     my ($loc) = @_;
1151     return "$loc->{X} $loc->{Y} ".ang2deg($loc->{A});
1152 }
1153 sub ang2deg ($) {
1154     return $_[0] * 180 / $pi;
1155 }
1156 sub input_absang ($) {
1157     return $_[0] * $ctx->{Trans}{R} + $ctx->{Trans}{A};
1158 }
1159 sub input_abscoords ($$) {
1160     my ($in,$out);
1161     ($in->{X}, $in->{Y}) = @_;
1162     $in->{A}= 0.0;
1163     $out= ev_compose({}, $ctx->{Trans}, $in);
1164     return ($out->{X}, $out->{Y});
1165 }
1166
1167 sub newctx (;$) {
1168     my ($ctx_save) = @_;
1169     $ctx= {
1170         Trans => { X => 0.0, Y => 0.0, A => 0.0, R => 1.0 },
1171         InRunObj => "",
1172         DrawMap => sub { $_[0]; },
1173         SegMapN => { },
1174         SegMapNM => { }
1175         };
1176     if (defined $ctx_save) {
1177         %{ $ctx->{Layer} }= %{ $ctx_save->{Layer} };
1178         $ctx->{Parent}= $ctx_save;
1179     }
1180 }
1181
1182 our $defobj_save;
1183 our $defobj_ispart;
1184
1185 sub cmd_defobj { cmd__defobj(0); }
1186 sub cmd_defpart { cmd__defobj(1); }
1187 sub cmd__defobj ($) {
1188     my ($ispart) = @_;
1189     my ($id);
1190     $id= can(\&cva_idstr);
1191     die "nested defobj" if $defobj_save;
1192     die "repeated defobj" if exists $objs{$id};
1193     $defobj_save= $ctx;
1194     $defobj_ispart= $ispart;
1195     newctx($defobj_save);
1196     $ctx->{CmdLog}= [ ];
1197     $ctx->{InDefObj}= $id;
1198     $ctx->{Draw}= $defobj_save->{Draw}.'X';
1199     $ctx->{DrawMap}= sub { ''; };
1200     $ctx->{Layer}= { Level => 5, Kind => '' };
1201 }
1202
1203 sub cmd_enddef {
1204     my ($bit,$id);
1205     $id= $ctx->{InDefObj};
1206     die "unmatched enddef" unless defined $id;
1207     foreach $bit (qw(CmdLog Loc)) {
1208         $objs{$id}{$bit}= $ctx->{$bit};
1209     }
1210     $objs{$id}{Part}= $defobj_ispart;
1211     $ctx= $defobj_save;
1212     $defobj_save= undef;
1213     $defobj_ispart= undef;
1214 }
1215
1216 sub cmd__runobj ($) {
1217     my ($obj_id)=@_;
1218     my ($c);
1219     local (@al);
1220     dv("cmd__runobj $obj_id ",'$ctx',$ctx);
1221     foreach $c (@{ $objs{$obj_id}{CmdLog} }) {
1222         @al= @$c;
1223         next if $al[0] eq 'enddef';
1224         cmd__one();
1225     }
1226 }
1227
1228 sub cva_subsegspec ($) {
1229     my ($sp)=@_;
1230     die "invalid subsegment spec" unless
1231         $sp =~ m,^(\-?)([0-9A-Za-z_]*)(?:/(?:([A-Za-z_]+)(\d+))?)?$,;
1232     my ($sign,$segname,$movfeat,$movconf)=($1,$2,$3,$4);
1233
1234     if (!exists $ctx->{SegName}) {
1235         $segname= '';
1236         $sign= '';
1237     } else {
1238         my ($map_ctx);
1239
1240         $ctx->{SegName} =~ m/^\-?/ or die;
1241         $sign .= $&;
1242         $segname= $'.$segname;
1243
1244         for ($map_ctx= $ctx;
1245              defined $map_ctx;
1246              $map_ctx= $map_ctx->{Parent}) {
1247             if (defined $movfeat &&
1248                 exists $map_ctx->{SegMapNM}{"$segname/$movfeat"}) {
1249                 $movfeat= $map_ctx->{SegMapNM}{"$segname/$movfeat"};
1250             }
1251             if (exists $map_ctx->{SegMapN}{$segname}) {
1252                 $map_ctx->{SegMapN}{$segname} =~ m/^\-?/ or die;
1253                 $sign .= $&;
1254                 $segname= $';
1255             }
1256         }
1257         $sign =~ s/\-\-//g;
1258     }
1259
1260     return $sign.$segname.'/'.
1261         (defined $movfeat ? sprintf "%s%d", $movfeat, $movconf : '');
1262 }
1263
1264 sub cmd_segment {
1265     my ($csss,$length);
1266     $ctx->{SavedSegment}= pop @segments
1267         unless exists $ctx->{SavedSegment};
1268     @segments= ();
1269     while (@al>1) {
1270         $csss= can(\&cva_subsegspec);
1271         $length= can(\&cva_len);
1272         push @segments, $csss, $length;
1273     }
1274     $csss= can(\&cva_subsegspec);
1275     push @segments, $csss;
1276 }
1277
1278 sub cva_segmap_s {
1279     my ($sp) = @_;
1280     $sp =~ m,^\w+(?:/[a-zA-Z_]+)?$,
1281         or die "invalid (sub)segment mapping S \`$sp'";
1282     return $sp;
1283 }
1284
1285 sub cva_segmap_n {
1286     my ($sp) = @_;
1287     $sp =~ m,^\-?\w+$, or die "invalid segment mapping N' \`$sp'";
1288     return $sp;
1289 }
1290
1291 sub cva_segmap_m {
1292     my ($sp) = @_;
1293     $sp =~ m,^[a-zA-Z_]+$, or die "invalid segment mapping M' \`$sp'";
1294     return $sp;
1295 }
1296
1297 sub cmd_segmap {
1298     my ($s,$d);
1299     while (@al) {
1300         $s= can(\&cva_segmap_s);
1301         if ($s =~ m,/,) {
1302             $ctx->{SegMapNM}{$s}= can(\&cva_segmap_m);
1303         } else {
1304             $ctx->{SegMapN}{$s}= can(\&cva_segmap_n);
1305         }
1306     }
1307 }
1308
1309 sub layer_draw ($$) {
1310     my ($k,$l) = @_;
1311     my ($eo,$cc, $r);
1312     if ($k eq '') {
1313         $r= 'RLMN';
1314     } elsif ($k eq 's') {
1315         $r= '';
1316     } elsif ($k eq 'l') {
1317         $r= 'CLMN';
1318     } else {
1319         $r= 'ARSCLMNO';
1320     }
1321     foreach $eo (@eopts) {
1322 #print STDERR "$. layer $k$l eo $eo re $eo->{GlobRe} then $eo->{DrawMods} now $r\n";
1323         next unless $k =~ m/^$eo->{GlobRe}$/;
1324 #print STDERR "$. layer $k$l eo re $eo->{GlobRe} match\n";
1325         next unless &{ $eo->{LayerCheck} }($l);
1326 #print STDERR "$. layer $k$l eo re $eo->{GlobRe} checked\n";
1327         foreach $cc (split //, $eo->{DrawMods}) {
1328             $r =~ s/$cc//ig;
1329             $r .= $cc if $cc =~ m/[A-Z]/;
1330         }
1331     }
1332 #print STDERR "layer $k$l gives $r (before map)\n";
1333     $r= &{ $ctx->{DrawMap} }($r);
1334     return $r;
1335 }
1336
1337 sub cmd_layer {
1338     my ($kl, $k,$l);
1339     $kl= can(\&cva_identity);
1340     $kl =~ m/^([A-Za-z_]*)(\d*|\=|\*)$/ or die "invalid layer spec";
1341     ($k,$l)=($1,$2);
1342     $l= $output_layer if $l eq '*';
1343     $l= $ctx->{Layer}{Level} if $l =~ m/^\=?$/;
1344     $ctx->{Layer}{Kind}= $k;
1345     $ctx->{Layer}{Level}= $l;
1346     $ctx->{Draw}= layer_draw($k,$l);
1347 }
1348
1349 sub cmd_part { cmd__obj(Part); }
1350 sub cmd_obj { cmd__obj(1); }
1351 sub cmd_objflip { cmd__obj(-1); }
1352
1353 sub cmd__obj ($) {
1354     my ($how)=@_;
1355     my ($obj_id, $ctx_save, $pfx, $actual, $formal_id, $formal, $formcv);
1356     my ($part_name, $ctx_inobj, $obj, $id, $newid, $newpt);
1357     if ($how eq Part) {
1358         $part_name= can(\&cva_idstr);
1359         $how= (@al && $al[0] =~ s/^\^//) ? -1 : +1;
1360     }
1361     $obj_id= can(\&cva_idstr);
1362     if (defined $part_name) {
1363         $formal_id= can(\&cva_idstr);
1364         $actual= cano(\&cva_idex, undef);
1365         if (!defined $actual) {
1366             $actual= cva_idex("${part_name}_${formal_id}");
1367         }
1368     } else {
1369         $actual= can(\&cva_idex);
1370         $formal_id= can(\&cva_idstr);
1371     }
1372     $obj= $objs{$obj_id};
1373     dv("cmd__obj ",'$obj',$obj);
1374     die "unknown obj $obj_id" unless $obj;
1375     $formal= $obj->{Loc}{$formal_id};
1376     die "unknown formal $formal_id" unless $formal;
1377     $ctx_save= $ctx;
1378     newctx($ctx_save);
1379     $how *= $ctx_save->{Trans}{R};
1380     $ctx->{Trans}{R}= $how;
1381     $ctx->{Trans}{A}= $actual->{A} - $formal->{A}/$how;
1382     $formcv= ev_compose({}, $ctx->{Trans},$formal);
1383     $ctx->{Trans}{X}= $actual->{X} - $formcv->{X};
1384     $ctx->{Trans}{Y}= $actual->{Y} - $formcv->{Y};
1385     if (defined $part_name) {
1386         $ctx->{InRunObj}= $ctx_save->{InRunObj}."${part_name}:";
1387     } else {
1388         $ctx->{InRunObj}= $ctx_save->{InRunObj}."${obj_id}::";
1389     }
1390     if ($segments[0] =~ m,(.*[^-]+)/,) {
1391         $ctx->{SegName}= $1;
1392     }
1393     $ctx->{DrawMap}= sub {
1394         my ($i) = @_;
1395         $i= &{ $ctx_save->{DrawMap} }($i);
1396         if ($obj->{Part}) {
1397             $i =~ s/[LMN]//g;
1398             $i =~ s/O/MNO/;
1399         } else {
1400             $i =~ s/[LM]//g;
1401             $i =~ s/N/MN/;
1402         }
1403         return $i;
1404     };
1405     $ctx->{Draw}= &{ $ctx->{DrawMap} }($ctx_save->{Draw});
1406     cmd__runobj($obj_id);
1407     if (defined $part_name) {
1408         $pfx= $part_name.'_';
1409     } else {
1410         if (@al && $al[0] eq '=') {
1411             $pfx= ''; shift @al;
1412         } else {
1413             $pfx= cano(\&cva_idstr,undef);
1414         }
1415     }
1416     if (exists $ctx->{SavedSegment}) {
1417         @segments= ($ctx->{SavedSegment});
1418     }
1419     $ctx_inobj= $ctx;
1420     $ctx= $ctx_save;
1421     if (defined $pfx) {
1422         foreach $id (keys %{ $ctx_inobj->{Loc} }) {
1423             next if $id eq $formal_id;
1424             $newid= $pfx.$id;
1425             next if exists $ctx_save->{Loc}{$newid};
1426             $newpt= cva_idnew($newid);
1427             %$newpt= %{ $ctx_inobj->{Loc}{$id} };
1428         }
1429     }
1430     if (defined $part_name) {
1431         my ($formalr_id, $actualr_id, $formalr, $actualr);
1432         while (@al) {
1433             die "part results come in pairs\n" unless @al>=2;
1434             ($formalr_id, $actualr_id, @al) = @al;
1435             if ($actualr_id =~ s/^\-//) {
1436                 $formalr_id= "-$formalr_id";
1437                 $formalr_id =~ s/^\-\-//;
1438             }
1439             {
1440                 local ($ctx) = $ctx_inobj;
1441                 $formalr= cva_idex($formalr_id);
1442             }
1443             $actualr= cva_idnew($actualr_id);
1444             %$actualr= %$formalr;
1445         }
1446     }
1447 }
1448
1449 sub cmd__do {
1450     my ($cmd);
1451 dv("cmd__do $ctx @al ",'$ctx',$ctx);
1452     $cmd= can(\&cva_cmd);
1453     my ($lm,$id,$loc,$io,$ad,$draw,$thendrawre);
1454     $io= defined $ctx->{InDefObj} ? "$ctx->{InDefObj}!" : $ctx->{InRunObj};
1455     o("%L cmd   $io $cmd @al\n");
1456     $ctx->{LocsMade}= [ ];
1457     {
1458         no strict 'refs';
1459         &{ "cmd_$cmd" };
1460     };
1461     die "too many args" if @al;
1462     foreach $lm (@{ $ctx->{LocsMade} }) {
1463         $id= $lm->{Id};
1464         $loc= $ctx->{Loc}{$id};
1465         $loc->{A} += $pi if $lm->{Neg};
1466         $ad= ang2deg($loc->{A});
1467         ol("%L point $io$id ".loc2dbg($loc)." ($lm->{Neg})\n");
1468         $draw= layer_draw($loc->{LayerKind}, $ctx->{Layer}{Level});
1469         if ($draw =~ m/[LM]/) {
1470             ol("    gsave\n".
1471                "      $loc->{X} $loc->{Y} translate $ad rotate\n");
1472             if ($draw =~ m/M/) {
1473                 ol("      0 $allwidthmin newpath moveto\n".
1474                    "      0 -$allwidthmin lineto\n".
1475                    "      $lmu_marklw setlinewidth stroke\n");
1476             }
1477             if ($draw =~ m/L/) {
1478                 ol("      $lmu_txtboxlw $lmu_txtboxh $lmu_txtboxpadx".
1479                    " $lmu_txtboxoff ($id) label_in_box\n");
1480             }
1481             ol("      grestore\n");
1482         }
1483     }
1484 }
1485
1486 sub cmd_showlibrary {
1487     my ($obj_id, $y, $x, $ctx_save, $width, $height);
1488     my ($max_x, $min_x, $max_y, $min_y, $nxty, $obj, $loc, $pat, $got, $glob);
1489     my ($adj);
1490     $x=$olu_left; $y=$olu_bottom; undef $nxty;
1491     $ctx_save= $ctx;
1492     foreach $obj_id (sort keys %objs) {
1493         $got= 1;
1494         foreach $glob (@al) {
1495             $pat= $glob;
1496             $got= !($pat =~ s/^\!//);
1497             die "bad pat" if $pat =~ m/[^0-9a-zA-Z_*?]/;
1498             $pat =~ s/\*/\.*/g; $pat =~ s/\?/./g;
1499             last if $obj_id =~ m/^$pat$/;
1500             $got= !$got;
1501         }
1502         next unless $got;
1503         $obj= $objs{$obj_id};
1504         next unless $obj->{Part};
1505         ($min_x, $max_x, $min_y, $max_y) = bbox($obj->{Loc});
1506         newctx($ctx_save);
1507
1508         for (;;) {
1509             $width= $max_x - $min_x;
1510             $height= $max_y - $min_y;
1511             if ($width < $height) {
1512                 $ctx->{Trans}{A}= 0;
1513                 $ctx->{Trans}{X}= $x - $min_x;
1514                 $ctx->{Trans}{Y}= $y - $min_y + $olu_textheight;
1515             } else {
1516                 ($width,$height)=($height,$width);
1517                 $ctx->{Trans}{A}= 0.5 * $pi;
1518                 $ctx->{Trans}{X}= $x + $max_y;
1519                 $ctx->{Trans}{Y}= $y - $min_x + $olu_textheight;
1520             }
1521             $adj= length($obj_id) * $olu_textallowperc - $width;
1522             $adj=0 if $adj<0;
1523             $width += $adj;
1524             $ctx->{Trans}{X} += 0.5 * $adj;
1525             if ($x + $width > $olu_right && defined $nxty) {
1526                 $x= $olu_left;
1527                 $y= $nxty;
1528                 undef $nxty;
1529             } elsif ($y + $height > $olu_top && $y > $olu_bottom) {
1530                 oflushpage();
1531                 $x= $olu_left; $y= $olu_bottom;
1532                 undef $nxty;
1533             } else {
1534                 last;
1535             }
1536         }
1537
1538         $ctx->{InRunObj}= $ctx_save->{InRunObj}."${obj_id}//";
1539         $ctx->{Draw}= $ctx_save->{Draw};
1540         cmd__runobj($obj_id);
1541         ol("    gsave\n".
1542            "      /s ($obj_id) def\n".
1543            "      lf setfont\n      ".
1544            ($x + 0.5*$width)." ".($y - $olu_textheight)." moveto\n".
1545            "      s stringwidth pop -0.5 mul  0  rmoveto\n".
1546            "      s show grestore\n");
1547         $x += $width + $olu_gap_x;
1548         upd_max(\$nxty, $y + $height + $olu_gap_y + $olu_textheight);
1549     }
1550     @al= ();
1551     $ctx= $ctx_save;
1552 }
1553
1554 sub cmd__one {
1555     cmd__do();
1556 }
1557
1558 o("%!\n".
1559   "  /lf /Courier-New findfont $lmu_marktpt scalefont def\n".
1560   "  $ps_page_shift 0 translate 90 rotate\n");
1561
1562 if ($page_x || $page_y) {
1563     o("  /Courier-New findfont 15 scalefont setfont\n".
1564       "  30 30 moveto (${page_x}x${page_y}) show\n");
1565 }
1566
1567 o("  -$ps_page_xmul $page_x mul  -$ps_page_ymul $page_y mul  translate\n".
1568   "  $ptscale $ptscale scale\n");
1569
1570 o("/label_in_box {\n".
1571   '% linewidth $lmu_*boxh $lmu_*padx $lmu_*boxoff (s)'.
1572   '  label_in_box  => _'."\n".
1573   "  /s exch def\n".
1574   "  /boxoff exch def\n".
1575   "  /padx exch def\n".
1576   "  /boxh exch def\n".
1577   "  setlinewidth\n".
1578   "  lf setfont\n".
1579   "  /sx5  s stringwidth pop\n".
1580   "  0.5 mul padx add def\n".
1581   "  -90 rotate  0 boxoff translate  newpath\n".
1582   "  sx5 neg  0             moveto\n".
1583   "  sx5 neg  boxh  lineto\n".
1584   "  sx5      boxh  lineto\n".
1585   "  sx5      0             lineto closepath\n".
1586   "  gsave  1 setgray fill  grestore\n".
1587   "  stroke\n".
1588   "  sx5 neg padx add  $lmu_txtboxtxty\n".
1589   "  moveto s show\n".
1590   "} def\n");
1591
1592 newctx();
1593
1594 open DEBUG, ($debug ? ">&2" : ">/dev/null") or die $!;
1595
1596 if ($debug) {
1597     select(DEBUG); $|=1;
1598     select(STDOUT); $|=1;
1599 }
1600
1601 $ctx->{Draw}= '';
1602 $ctx->{SegName}= '';
1603
1604 @al= qw(layer 5);
1605 cmd__one();
1606
1607 while (<>) {
1608     next if m/^\s*\#/;
1609     chomp; s/^\s+//; s/\s+$//;
1610     @al= split /\s+/, $_;
1611     next unless @al;
1612     print DEBUG "=== @al\n";
1613     last if $al[0] eq 'eof';
1614     push @{ $ctx->{CmdLog} }, [ @al ] if exists $ctx->{CmdLog};
1615     cmd__one();
1616 }
1617
1618 {
1619     my ($min_x, $max_x, $min_y, $max_y) = bbox($ctx->{Loc});
1620     my ($bboxstr);
1621     if (defined $min_x) {
1622         $bboxstr= sprintf("width  %.2d (%.2d..%2.d)\n".
1623                           "height %.2d (%.2d..%2.d)\n",
1624                           $max_x - $min_x, $min_x, $max_x,
1625                           $max_y - $min_y, $min_y, $max_y);
1626     } else {
1627         $bboxstr= "no locs, no bbox\n";
1628     }
1629     if (!$quiet) { print STDERR $bboxstr; }
1630     $bboxstr =~ s/^/\%L bbox /mg;
1631     o($bboxstr) or die $!;
1632
1633     if ($scale < 1.5) {
1634         my ($tick_x, $tick_y, $ticklen);
1635         $ticklen= 10;
1636         printf("    gsave 0.5 setgray 0.33 setlinewidth\n".
1637                "      /regmark {\n".
1638                "        newpath moveto\n".
1639                "        -%d 0 rmoveto %d 0 rlineto\n".
1640                "        -%d -%d rmoveto 0 %d rlineto stroke\n".
1641                "      } def\n",
1642                $ticklen, $ticklen*2, $ticklen, $ticklen, $ticklen*2)
1643             or die $!;
1644         for ($tick_x= $min_x; $tick_x < $max_x; $tick_x += 150) {
1645             for ($tick_y= $min_y; $tick_y < $max_y; $tick_y += 150) {
1646                 printf("      %f %f regmark\n",
1647                        $tick_x, $tick_y)
1648                     or die $!;
1649             }
1650         }
1651         printf("    grestore\n")
1652             or die $!;
1653     }
1654 }
1655
1656 oflushpage();