detpic/program.asm

   1 ;======================================================================
   2 ; MAIN PROGRAM AND GLUE
   3
   4   include common.inc
   5   code
   6
   7 ;======================================================================
   8 ; COMMON TO MASTER AND SLAVE
   9
  10 ;----------------------------------------
  11 vector_reset @
  12         clr_f   INTCON
  13         bs_f    RCON, IPEN      ; interrupt priorities
  14
  15         call    idlocs_init
  16
  17         bt_f_if0 idloc1,idloc1_master
  18         call    slave_init
  19
  20         bt_f_if1 idloc1,idloc1_master
  21         call    master_init
  22
  23         bs_f    INTCON, GIEH
  24         bs_f    INTCON, GIEL
  25
  26         bt_f_if1 idloc1,idloc1_master
  27         goto    backgroundloop_master
  28         bt_f_if1 idloc1,idloc1_boarddet
  29         goto    backgroundloop_detectors
  30         goto    backgroundloop_reversers
  31
  32 ;----------
  33 common_local_init
  34 ; called by {master,slave}_init immediately after they've init'd i2c.
  35         clr_f   PCLATU
  36         call    bitnum2bit_init
  37
  38         call    points_local_init
  39         call    polarity_local_init
  40         call    detect_local_init
  41         return
  42
  43 ;----------------------------------------
  44 panic_kill_hook @
  45         call    power_panichook
  46         call    cdu_panichook
  47         return
  48
  49 ;----------
  50 intrl_handled_routine @
  51         mov_ff  isr_low_save_stkptr, STKPTR
  52         intrl_handled_core
  53
  54 ;======================================================================
  55 ; MASTER
  56
  57 ;----------------------------------------
  58 master_init
  59 ; Master-specific initialisation.
  60         call    memory_erase
  61         clr_f   flags
  62         call    serial_init
  63         call    i2cm_init
  64         call    serialtxbuf_init
  65         call    polarity_master_init
  66         call    points_master_init
  67         call    common_local_init
  68         call    nmra_init
  69         call    serialtxfc_init
  70         call    mascan_init
  71         call    tick_init
  72         call    cdu_init
  73         call    power_polarising_init
  74         call    power_fault_init
  75         call    watchdog_init
  76         return
  77
  78 ;----------------------------------------
  79 master_interrupt_low @
  80         enter_interrupt_low
  81         Dl 0x80
  82         call    tick_intrl
  83         call    nmra_serialrx_intrl
  84         call    power_fault_intrl
  85         call    serialtxfc_intrl
  86         call    serialtx_intrl
  87         call    points_local_intrl
  88         call    i2cm_intrl
  89         panic   morse_IL
  90
  91 ;----------------------------------------------------------------------
  92 serialrx_table_section  code    0x2000
  93
  94 ;--------------------
  95 command_tellmode
  96         mov_lw  0x09
  97         goto    serial_addbyte
  98
  99 ;--------------------
 100 serialrx_generalmsg @
 101 ;command_<something>  has same calling convention:
 102 ;
 103 ;  FSR0 ->      start of message                undefined
 104 ;  *FSR0        message                         undefined
 105 ;
 106         mov_fw  INDF0
 107         bra_n   serialrx_if_multibyte
 108         bra_z   command_crashed
 109
 110         xor_lw  0x11
 111         bra_z   command_power_on
 112         xor_lw  0x10 ^ 0x11
 113         bra_z   command_power_off
 114         xor_lw  0x0a ^ 0x10
 115         bra_z   command_tellmode
 116         bra     serialrx_bad
 117
 118 ;-----
 119 serialrx_if_multibyte
 120         rr_fw   INDF0           ; W =   ii MM ww ww ww ww ii ii
 121         and_lw  0x3c            ; W =   zz zz ww ww ww ww zz zz
 122         bt_f_if0 PCL, 0 ; always true, but reads PCL
 123         add_wff PCL
 124         ; <--- here is zero
 125
 126         goto    serialrx_bad            ; 1 0000 xxx
 127         goto    command_ping            ; 1 0001 xxx
 128         goto    command_polarity        ; 1 0010 xxx
 129         goto    command_watchdog        ; 1 0011 xxx
 130         goto    command_point           ; 1 0100 xxx
 131         goto    serialrx_bad            ; 1 0101 xxx
 132         goto    serialrx_bad            ; 1 0110 xxx
 133         goto    serialrx_bad            ; 1 0111 xxx
 134         goto    serialrx_bad            ; 1 1000 xxx
 135         goto    serialrx_bad            ; 1 1001 xxx
 136         goto    serialrx_bad            ; 1 1010 xxx
 137         goto    serialrx_bad            ; 1 1011 xxx
 138         goto    serialrx_bad            ; 1 1100 xxx
 139         goto    serialrx_bad            ; 1 1101 xxx
 140         goto    serialrx_bad            ; 1 1110 xxx
 141         goto    serialrx_bad            ; 1 1111 xxx
 142
 143 ;-----
 144 serialrx_bad
 145         mov_ff  INDF0, t
 146         panic   morse_HX
 147
 148 code2 code
 149 ;--------------------
 150 command_ping
 151         mov_fw  POSTINC0
 152         mov_ff  INDF0, t
 153         call    serial_addbyte
 154         mov_fw  t
 155         bra_n   command_ping_bad
 156         goto    serial_addbyte_another
 157
 158 command_ping_bad panic morse_HP
 159
 160 ;======================================================================
 161 ; SLAVE
 162
 163 ;----------------------------------------
 164 slave_init
 165 ; Slave-specific initialisation.
 166         clr_f   flags
 167
 168         mov_fw  picno
 169         call    i2cs_init
 170
 171         bc_f    T0CON, TMR0ON
 172
 173         call    common_local_init
 174         call    detect_slave_init
 175         return
 176
 177 ;----------------------------------------
 178 slave_interrupt_low @
 179         enter_interrupt_low
 180         call    points_local_intrl
 181         panic   morse_IL
 182
 183 ;----------------------------------------
 184 i2csu_write_begin
 185         return
 186
 187 near_local_do code
 188 ;----------------------------------------
 189 i2csu_write_data
 190         call    led_green
 191
 192         bt_w_if0 7
 193         bra     i2csu_write_if_special
 194         bt_w_if1 6
 195         bra     polarity_local_do
 196         bt_w_if0 5
 197         bra     point_local_do
 198 i2csu_write_if_bad
 199         mov_wf  t
 200         panic   morse_DX
 201
 202 i2csu_write_if_special
 203         tst_w_ifnz
 204         bra     i2csu_write_if_bad
 205         goto    panic_crashread_commanded
 206
 207 code3 code
 208 ;======================================================================
 209 ; MASTER/SLAVE deviations
 210
 211 ;----------
 212 message_for_master @
 213 ; Either transmits the message to the master, or if we are the master,
 214 ; handles it as an incoming message from the notional `slave 0'.
 215 ;  W            message         unchanged
 216 ;  GIEH         set             set
 217         bt_f_if0 idloc1,idloc1_master
 218         goto    slave_add_short_message
 219         goto    loopback_read_byte
 220
 221 ;======================================================================
 222   include final.inc