numbered-alias-sheet

   1 #!/usr/bin/perl -w
   2 use strict;
   3 our $us = $0; $us =~ s#.*/##;
   4
   5 use POSIX;
   6 use Data::Dumper;
   7
   8 our @paperpts = ('creditcard');
   9 our @bigpaperpts = ();
  10 our $fontname_num = 'Helvetica';
  11 our $fontscale_num = 0.8;
  12 our $fontname = 'Helvetica';
  13 our $gapratio = 1.5;
  14 our $lineratio = 1;
  15 our $blankratio = 1.0;
  16 our @borders = (4,4);
  17 our @tiles = (1,1);
  18
  19 our @lp_options = ( [ 'blank-below', 'blank-to-right', ],
  20                     [ 'landscape', 'portrait' ],
  21                     [ 'single-column', 'multi-column', ] );
  22 our @lp_fixed;
  23
  24 our $usage = <<END;
  25 usage: $us [<options>] <foo-mail-pregen> <foo-mail-pregen-opts>...
  26 options:
  27   -p<papersize>           for libpaper, or "creditcard", default is $paperpts[0]
  28   -P<actual-papersize>    center in this; default is not to center
  29   -f<bothfont>            set both to same font name
  30   -f[<numfont>[*<scale>]],[<addrfont>]  default is $fontname_num*$fontscale_num,$fontname
  31   -b<border>|-b<bx>x<by>  all in mm
  32   -T[<xtiles>x]<ytiles>   default is $tiles[0]x$tiles[1]
  33   -g<gapratio>            number-to-addr gap adjustment
  34   -l<lineratio>           inter-line space ("leading") adjustment factor
  35   -B<blankratio>          (blank space size) / (text size)
  36   -D                      debug
  37 END
  38
  39 foreach my $spec (@lp_options) { $usage .= <<END foreach @$spec; }
  40   --$_
  41 END
  42
  43 open DEBUG, ">/dev/null" or die $!;
  44
  45 sub badusage () { die "bad usage\n\n$usage"; }
  46
  47 sub mm2pt { map { $_ * 72.0 / 25.4 } @_; }
  48
  49 sub max {
  50     my $r = undef;
  51     foreach (@_) {
  52         $r = $_ if !defined $r or $_ > $r;
  53     }
  54     return $r;
  55 }
  56
  57 sub min {
  58     my $r = undef;
  59     foreach (@_) {
  60         $r = $_ if !defined $r or $_ < $r;
  61     }
  62     return $r;
  63 }
  64
  65 my $fontname_re = '[^()\\,]+';
  66 my $dbl_re = '(?:[0-9]+\.?|[0-9]*\.[0-9]+)';
  67 my $dom_re = '\@.*$';
  68
  69 for (;;) {
  70     badusage unless @ARGV;
  71     last unless $ARGV[0] =~ m/^-/;
  72     $_ = shift @ARGV;
  73     last if m/^--?$/;
  74     while (m/^-./) {
  75         if (s/^-p(\w+)$//) {
  76             @paperpts = ($1);
  77         } elsif (s/^-P(\w+)$//) {
  78             @bigpaperpts = ($1);
  79         } elsif (s/^-p($dbl_re)x($dbl_re)$//o) {
  80             @paperpts = mm2pt($1,$2);
  81         } elsif (s/^-P($dbl_re)x($dbl_re)$//o) {
  82             @bigpaperpts = mm2pt($1,$2);
  83         } elsif (s/^-f($fontname_re)$//o) {
  84             $fontname = $fontname_num = $1;
  85         } elsif (s/^-f(?:($fontname_re)(?:\*($dbl_re))?)?,($fontname_re)?$//o) {
  86             if (defined $1) {
  87                 $fontname_num = $1;
  88                 $fontscale_num = defined($2) ? $2 : 1.0;
  89             }
  90             if (defined $3) {
  91                 $fontname = $3;
  92             }
  93         } elsif (s/^-b($dbl_re)$//o) {
  94             @borders = ($1,$1);
  95         } elsif (s/^-b($dbl_re)x($dbl_re)$//o) {
  96             @borders = ($1,$1);
  97         } elsif (s/^-l($dbl_re)$//o) {
  98             $lineratio = $1;
  99         } elsif (s/^-g($dbl_re)$//o) {
 100             $gapratio = $1;
 101         } elsif (s/^-B($dbl_re)$//o) {
 102             $blankratio = $1;
 103         } elsif (s/^-T(?:(\d+)x)?(\d+)$//o) {
 104             $tiles[0] = $1 || 1;
 105             $tiles[1] = $2;
 106         } elsif (s/^-D/-/) {
 107             open DEBUG, ">&STDERR" or die $!;
 108         } else {
 109             if (m/^--([-a-z]+)$/) {
 110                 my ($lpi) = grep {
 111                     grep { $1 eq $_ } @{ $lp_options[$_] }
 112                 } 0..$#lp_options;
 113                 if (defined $lpi) {
 114                     $lp_fixed[$lpi] = $1;
 115                     $_ = '';
 116                     next;
 117                 }
 118             }
 119             badusage;
 120         }
 121     }
 122 }
 123
 124 sub canonpaper ($) {
 125     my ($pts) = @_;
 126
 127     return unless @$pts==1;
 128     my ($name) = @$pts;
 129
 130     if ($name eq 'creditcard') {
 131         # ISO/IEC 7810 ID-1, from en.wikipedia.org/wiki/Payment_card
 132         @$pts = mm2pt qw(85.60 53.98);
 133     } else {
 134         $!=0; $?=0; my $r = `paperconf -sp $name`;
 135         defined $r or die "paperconf failed: $? $!\n";
 136         $r =~ m/^([0-9.]+) ([0-9.]+)$/ or die "$_ ?";
 137         @$pts = ($1,$2);
 138     }
 139 }
 140
 141 canonpaper(\@paperpts);
 142 canonpaper(\@bigpaperpts);
 143
 144 @borders = mm2pt @borders;
 145
 146 @ARGV >= 2 or badusage;
 147
 148 our @strings;
 149 our $domain_suffix;
 150 our $pertile;
 151
 152 sub readstrings () {
 153     my $nlen = 0;
 154
 155     open P, "-|", @ARGV or die $!;
 156     while (<P>) {
 157         chomp or die;
 158         m/^(\d+) (\S+)$/ or die "$_ ?";
 159         $nlen = length($1) if length($1) > $nlen;
 160         push @strings, [ $1, $2 ];
 161     }
 162     $!=0; $?=0; close P or die "$us: generator failed: $! $?\n";
 163
 164     @strings or die "$us: nothing to show\n";
 165
 166     if ($strings[0][1] =~ m/$dom_re/o) {
 167         my $dom = $&;
 168         if (!grep { $_->[1] !~ m/$dom_re/o && $& eq $dom } @strings) {
 169             $domain_suffix = $dom;
 170             $_->[1] =~ s/$dom_re//o foreach @strings;
 171         }
 172     }
 173
 174     $pertile = ceil(@strings / ($tiles[0] * $tiles[1]));
 175 }
 176
 177 our @lp_values;
 178 our @numbers_metr;
 179 our @texts_metr;
 180 our @domain_metr;
 181 our $gap_width;
 182 our $colgap_width;
 183 our @core_size;
 184 our @item_size;
 185 our $domain_vsize;
 186 our $rotate_paper;
 187 our @eff_paper_size;
 188
 189 sub wontfit ($) {
 190     print DEBUG " NO @_\n";
 191     return 0;
 192 }
 193
 194 sub psstring ($) {
 195     local ($_) = @_;
 196     s/[()\\]/\\$&/g;
 197     return "($_)";
 198 }
 199
 200 our @numbers_1_metr;
 201 our @nom_gap_1_metr;
 202 our @texts_1_metr;
 203 our @domain_1_metr;
 204
 205 sub prepare_metrics () {
 206     print DEBUG " prepare_metrics\n";
 207     my $pchild = open GI, "-|"; defined $pchild or die $!;
 208     my @sets =
 209         ([ \@numbers_1_metr, $fontname_num, map { $_->[0] } @strings ],
 210          [ \@nom_gap_1_metr, $fontname_num, ' '                      ],
 211          [ \@texts_1_metr,   $fontname,     map { $_->[1] } @strings ],
 212         );
 213     if (defined $domain_suffix) {
 214         push @sets, [ \@domain_1_metr, $fontname, $domain_suffix ];
 215     }
 216     if (!$pchild) {
 217         foreach my $set (@sets) {
 218             my ($ra, $fn, @s) = @$set;
 219             print DEBUG "  want $fn ",scalar(@s),"\n";
 220             printf <<END, psstring($fn) or die $!;
 221  %s findfont 10 scalefont setfont
 222 END
 223             printf <<END, psstring($_) or die $! foreach @s;
 224  newpath
 225  0 0 moveto
 226  %s
 227  dup stringwidth pop =
 228  true charpath pathbbox = = = =
 229 END
 230         }
 231         close STDOUT or die $!;
 232         exit 0;
 233     }
 234     my $gchild = open GO, "-|"; defined $gchild or die $!;
 235     if (!$gchild) {
 236         open STDIN, "<&GI" or die $!;
 237         exec qw(gs -dSAFER -dNOPAUSE -q -dBATCH
 238                    -sDEVICE=pswrite -sOutputFile=/dev/null
 239                    -)
 240 #exec qw(tee sponge)
 241             or die "$us: exec gs: $!\n";
 242     }
 243     foreach my $set (@sets) {
 244         my ($ra, $fn, @s) = @$set;
 245         my @bb;
 246         for (my $count=0; $count < @s; $count++) {
 247             my @tbb;
 248             foreach my $ix (0..4) {
 249                 $_ = <GO>; defined or die "gs fail or eof";
 250                 printf DEBUG "    %s (%d,$ix) |%s", $fn, $count, $_;
 251                 chomp;
 252                 m/^-?$dbl_re$/o or die "gs $_ ?";
 253                 push @tbb, $_;
 254             }
 255             print DEBUG "   metrics $fn [$count]: @tbb\n";
 256             $bb[0] = min $bb[0], $tbb[4];
 257             $bb[1] = min $bb[1], $tbb[3];
 258             $bb[2] = max $bb[2], $tbb[2];
 259             $bb[3] = max $bb[3], $tbb[1];
 260             $bb[4] = max $bb[4], $tbb[0];
 261         }
 262         print DEBUG "  metrics $fn: @bb\n";
 263         @$ra = map { $_ * 0.1 } @bb;
 264     }
 265     $!=0; $?=0; close GO or die "gs $! $?";
 266     $!=0; $?=0; close GI or die "gs paste $! $?";
 267 }
 268
 269 sub do_layout_recursive_search ($);
 270 sub do_layout_recursive_search ($) {
 271     my ($lpi) = @_;
 272
 273     if ($lpi < @lp_options) {
 274         foreach my $v ($lp_fixed[$lpi] or @{ $lp_options[$lpi] }) {
 275             $lp_values[$lpi] = $v;
 276             my $r = do_layout_recursive_search $lpi+1;
 277             return $r if $r;
 278         }
 279         return 0;
 280     }
 281
 282     print DEBUG " try", (map { sprintf " %-10.10s", $_ } @lp_values), ":";
 283
 284     my %lp_y;
 285     $lp_y{$_} = 1 foreach @lp_values;
 286
 287     $lp_y{rotate_paper} =
 288         ($paperpts[0] > $paperpts[1] # paper looks like landscape
 289          xor $lp_y{'landscape'});
 290     $eff_paper_size[$_] = $paperpts[$_] - 2.0*$borders[$_] foreach qw(0 1);
 291     @eff_paper_size = reverse @eff_paper_size if $lp_y{rotate_paper};
 292
 293     $eff_paper_size[0] >= $domain_metr[4]
 294         or return wontfit "domain suffix too long";
 295
 296     @item_size = @core_size;
 297     my $blank_coord = !!$lp_y{'blank-below'};
 298     $item_size[$blank_coord] *= (1.0 + $blankratio);
 299
 300     foreach my $coord (qw(0 1)) {
 301         my $avail = $eff_paper_size[$coord];
 302         my $each = $item_size[$coord];
 303         if (!$coord) {
 304             $each += $colgap_width;
 305             $avail += $colgap_width;
 306         } else {
 307             if (defined $domain_suffix) {
 308                 $avail -= $domain_vsize;
 309             }
 310         }
 311         $lp_y{$coord} = floor($avail / $each);
 312         $lp_y{$coord} >= 1 or return wontfit "cannot fit even one $coord";
 313     }
 314
 315     if ($lp_y{'single-column'}) {
 316         $lp_y{0} = 1;
 317     } else {
 318         $lp_y{0} >= 2
 319             or return wontfit "requested multi-column but only one";
 320     }
 321
 322     my $laycountshow = "$lp_y{0} $lp_y{1}";
 323
 324     $lp_y{0} * $lp_y{1} >= $pertile
 325         or return wontfit "layout fits too few $laycountshow";
 326
 327     print DEBUG " OK $laycountshow\n";
 328     return \%lp_y;
 329 }
 330
 331 sub do_layout ($) {
 332     my ($fontsize) = @_;
 333
 334     print DEBUG "layout $fontsize\n";
 335
 336     @numbers_metr = map { $_ * $fontsize * $fontscale_num } @numbers_1_metr;
 337     $gap_width = $gapratio * $fontsize * $nom_gap_1_metr[4];
 338     $colgap_width = $gap_width * 2;
 339     @texts_metr = map { $_ * $fontsize } @texts_1_metr;
 340     @domain_metr = map { $_ * $fontsize } @domain_1_metr;
 341
 342     $core_size[0] = $numbers_metr[4] + $gap_width + $texts_metr[4];
 343
 344     $core_size[1] = $lineratio * $fontsize;
 345
 346     $domain_vsize = $lineratio * $fontsize;
 347
 348     return do_layout_recursive_search 0;
 349 }
 350
 351 our $lp_y;
 352
 353 sub determine_size_layout () {
 354     my $minsz;
 355     my $maxsz;
 356     my $usesz;
 357
 358     for (;;) {
 359         my $trysz =
 360             !defined $minsz ? 1 :
 361             !defined $maxsz ? $minsz * 4 :
 362             sqrt($minsz * $maxsz);
 363
 364         my $ok = do_layout $trysz;
 365
 366         if ($ok) { $minsz = $trysz; } else { $maxsz = $trysz; }
 367
 368         defined $minsz or die "cannot fit at even at ${trysz}pt\n";
 369
 370         if (defined $maxsz && ($maxsz / $minsz) < 1.001) {
 371             $usesz = $minsz;
 372             last;
 373         }
 374     }
 375
 376     $lp_y = do_layout $usesz or die;
 377     $lp_y->{f} = $usesz;
 378
 379     print DEBUG Dumper($usesz, \@lp_values, \@numbers_metr,
 380                        \@texts_metr, $gap_width, $colgap_width, \@core_size,
 381                        \@item_size, \@eff_paper_size,
 382                        $lp_y);
 383 }
 384
 385 sub prf { printf @_ or die $!; }
 386
 387 sub write_output_tile ($) {
 388     my ($tile_string_off) = @_;
 389     my @cnr;
 390     my $c;
 391     for ($cnr[0]=0; $cnr[0]<2; $cnr[0]++) {
 392         for ($cnr[1]=0; $cnr[1]<2; $cnr[1]++) {
 393             foreach my $cnrc (qw(0 1)) {
 394                 prf "newpath ";
 395                 prf "%s ", $cnr[$_] ? $paperpts[$_] : 0 foreach qw(0 1);
 396                 prf "moveto ";
 397                 prf "%s ", ($cnrc!=$_ ? 0 : $cnr[$_] ? -1 : +1) * $borders[$_]
 398                     foreach qw(0 1);
 399                 prf "rlineto stroke\n";
 400             }
 401         }
 402     }
 403     prf "%s ", $borders[$_] foreach qw(0 1);
 404     prf "translate\n";
 405     if ($lp_y->{rotate_paper}) {
 406         prf "90 rotate\n";
 407         prf "0 %s translate\n", -$eff_paper_size[1];
 408     }
 409     my $rows = ceil($pertile / $lp_y->{0});
 410     my @cell_size;
 411
 412     $cell_size[0] = ($eff_paper_size[0] + $colgap_width) / $lp_y->{0};
 413     $cell_size[1] = ($eff_paper_size[1] +
 414                      (defined $domain_suffix ? -$domain_vsize : 0)
 415                      ) / $rows;
 416
 417     prf "/rightadjust { dup stringwidth pop neg 0 rmoveto } bind def\n";
 418
 419     foreach my $nums (qw(1 0)) {
 420         prf("%s findfont %s scalefont setfont\n",
 421             psstring($nums ? $fontname_num : $fontname),
 422             ($nums ? $fontscale_num : 1.0) * $lp_y->{f});
 423         prf "%s setlinewidth\n", $gap_width * 0.1;
 424         print DEBUG "nums? $nums rows=$rows\n";
 425         foreach my $col (0..$lp_y->{0}-1) {
 426             my $col_lhs = $cell_size[0] * $col;
 427             if ($col > 0 && $nums) {
 428                 prf "newpath %s ", $col_lhs - $colgap_width*0.5;
 429                 prf "%s moveto ", $eff_paper_size[1];
 430                 prf "0 %s rlineto ", -$cell_size[1] * $rows;
 431                 prf "stroke\n";
 432             }
 433             foreach my $row (0..$rows-1) {
 434                 my $se = $strings[$col*$rows + $row + $tile_string_off];
 435                 next unless $se;
 436                 prf "newpath ";
 437                 prf "%s ", $col_lhs
 438                     + ($nums ? $numbers_metr[4]
 439                        : $numbers_metr[4] + $gap_width);
 440                 prf "%s ", $eff_paper_size[1] - $cell_size[1] * $row
 441                     - $core_size[1];
 442                 prf "moveto %s ", psstring($se->[!$nums]);
 443                 if ($nums) {
 444                     prf "rightadjust ";
 445                 }
 446 #               prf " gsave 10 10 rlineto stroke grestore\n";
 447                 prf "show\n";
 448             }
 449         }
 450         if (!$nums) {
 451             if (defined $domain_suffix) {
 452                 prf "%s 0 moveto", $eff_paper_size[0];
 453                 prf "%s ", psstring($domain_suffix);
 454                 prf "rightadjust show\n";
 455             }
 456         }
 457     }
 458 }
 459
 460 sub write_output () {
 461     prf "%%!\n";
 462     my @tile;
 463     for ($tile[0]=0; $tile[0]<$tiles[0]; $tile[0]++) {
 464         for ($tile[1]=0; $tile[1]<$tiles[1]; $tile[1]++) {
 465             prf "%% tile @tile\n";
 466             prf "gsave\n";
 467             if (@bigpaperpts) {
 468                 foreach (qw(0 1)) {
 469                     my $spare = $bigpaperpts[$_] - $tiles[$_] * $paperpts[$_];
 470                     $spare >= 0 or die "too many tiles: will not fit!\n";
 471                     prf "%s ", $spare*0.5;
 472                 }
 473                 prf "translate\n";
 474             }
 475             prf "%s ", $tile[$_] * $paperpts[$_] foreach qw(0 1);
 476             prf "translate\n";
 477             write_output_tile($tile[0] * $pertile +
 478                               $tile[1] * $pertile * $tiles[0]);
 479             prf "grestore\n";
 480         }
 481     }
 482     prf "showpage\n";
 483 }
 484
 485 readstrings();
 486 prepare_metrics();
 487 determine_size_layout();
 488 write_output();