numbered-alias-sheet

   1 #!/usr/bin/perl -w
   2 use strict;
   3 our $us = $0; $us =~ s#.*/##;
   4
   5 use POSIX;
   6 use Data::Dumper;
   7
   8 our @paperpts = ('creditcard');
   9 our @bigpaperpts = ();
  10 our $fontname_num = 'Helvetica';
  11 our $fontscale_num = 0.8;
  12 our $fontname = 'Helvetica';
  13 our $gapratio = 1.5;
  14 our $lineratio = 1;
  15 our $blankratio = 1.0;
  16 our @borders = (4,4);
  17 our @tiles = (1,1);
  18
  19 our @lp_options = ( [ 'blank-below', 'blank-to-right', ],
  20                     [ 'landscape', 'portrait' ],
  21                     [ 'single-column', 'multi-column', ] );
  22 our @lp_fixed;
  23
  24 our $usage = <<END;
  25 usage: $us [<options>] <foo-mail-pregen>...
  26
  27 examples:
  28   $us -T2 evade-mail-pregen range 12+12 >page.ps
  29   ssh chiark $us slimy-rot13-mail-pregen range 24+12 |gv -
  30   ssh chiark $us slimy-rot13-mail-pregen -q range 36+12 |lpr
  31
  32 options:
  33   -p<papersize>           for libpaper, or "creditcard", default is $paperpts[0]
  34   -P<actual-papersize>    centre in this; default is not to center
  35   -f<bothfont>            set both to same font name
  36   -f[<numfont>[*<scale>]],[<addrfont>]  default is $fontname_num*$fontscale_num,$fontname
  37   -b<border>|-b<bx>x<by>  all in mm
  38   -T[<xtiles>x]<ytiles>   default is $tiles[0]x$tiles[1]
  39   -g<gapratio>            number-to-addr gap adjustment, default $gapratio
  40   -l<lineratio>           inter-line space ("leading") adjustment, def. $lineratio
  41   -B<blankratio>          (blank space size) / (text size), default $blankratio
  42   -D                      debug
  43 END
  44
  45 foreach my $spec (@lp_options) { $usage .= <<END foreach @$spec; }
  46   --$_
  47 END
  48
  49 open DEBUG, ">/dev/null" or die $!;
  50
  51 sub badusage () { die "bad usage\n\n$usage"; }
  52
  53 sub mm2pt { map { $_ * 72.0 / 25.4 } @_; }
  54
  55 sub max {
  56     my $r = undef;
  57     foreach (@_) {
  58         $r = $_ if !defined $r or $_ > $r;
  59     }
  60     return $r;
  61 }
  62
  63 sub min {
  64     my $r = undef;
  65     foreach (@_) {
  66         $r = $_ if !defined $r or $_ < $r;
  67     }
  68     return $r;
  69 }
  70
  71 my $fontname_re = '[^()\\,]+';
  72 my $dbl_re = '(?:[0-9]+\.?|[0-9]*\.[0-9]+)';
  73 my $dom_re = '\@.*$';
  74
  75 for (;;) {
  76     badusage unless @ARGV;
  77     last unless $ARGV[0] =~ m/^-/;
  78     $_ = shift @ARGV;
  79     last if m/^--?$/;
  80     while (m/^-./) {
  81         if (s/^-p(\w+)$//) {
  82             @paperpts = ($1);
  83         } elsif (s/^-P(\w+)$//) {
  84             @bigpaperpts = ($1);
  85         } elsif (s/^-p($dbl_re)x($dbl_re)$//o) {
  86             @paperpts = mm2pt($1,$2);
  87         } elsif (s/^-P($dbl_re)x($dbl_re)$//o) {
  88             @bigpaperpts = mm2pt($1,$2);
  89         } elsif (s/^-f($fontname_re)$//o) {
  90             $fontname = $fontname_num = $1;
  91         } elsif (s/^-f(?:($fontname_re)(?:\*($dbl_re))?)?,($fontname_re)?$//o) {
  92             if (defined $1) {
  93                 $fontname_num = $1;
  94                 $fontscale_num = defined($2) ? $2 : 1.0;
  95             }
  96             if (defined $3) {
  97                 $fontname = $3;
  98             }
  99         } elsif (s/^-b($dbl_re)$//o) {
 100             @borders = ($1,$1);
 101         } elsif (s/^-b($dbl_re)x($dbl_re)$//o) {
 102             @borders = ($1,$1);
 103         } elsif (s/^-l($dbl_re)$//o) {
 104             $lineratio = $1;
 105         } elsif (s/^-g($dbl_re)$//o) {
 106             $gapratio = $1;
 107         } elsif (s/^-B($dbl_re)$//o) {
 108             $blankratio = $1;
 109         } elsif (s/^-T(?:(\d+)x)?(\d+)$//o) {
 110             $tiles[0] = $1 || 1;
 111             $tiles[1] = $2;
 112         } elsif (s/^-D/-/) {
 113             open DEBUG, ">&STDERR" or die $!;
 114         } else {
 115             if (m/^--([-a-z]+)$/) {
 116                 my ($lpi) = grep {
 117                     grep { $1 eq $_ } @{ $lp_options[$_] }
 118                 } 0..$#lp_options;
 119                 if (defined $lpi) {
 120                     $lp_fixed[$lpi] = $1;
 121                     $_ = '';
 122                     next;
 123                 }
 124             }
 125             badusage;
 126         }
 127     }
 128 }
 129
 130 sub canonpaper ($) {
 131     my ($pts) = @_;
 132
 133     return unless @$pts==1;
 134     my ($name) = @$pts;
 135
 136     if ($name eq 'creditcard') {
 137         # ISO/IEC 7810 ID-1, from en.wikipedia.org/wiki/Payment_card
 138         @$pts = mm2pt qw(85.60 53.98);
 139     } else {
 140         $!=0; $?=0; my $r = `paperconf -sp $name`;
 141         defined $r or die "paperconf failed: $? $!\n";
 142         $r =~ m/^([0-9.]+) ([0-9.]+)$/ or die "$_ ?";
 143         @$pts = ($1,$2);
 144     }
 145 }
 146
 147 canonpaper(\@paperpts);
 148 canonpaper(\@bigpaperpts);
 149
 150 @borders = mm2pt @borders;
 151
 152 @ARGV >= 2 or badusage;
 153
 154 our @strings;
 155 our $domain_suffix;
 156 our $pertile;
 157
 158 sub readstrings () {
 159     my $nlen = 0;
 160
 161     open P, "-|", @ARGV or die $!;
 162     while (<P>) {
 163         chomp or die;
 164         m/^(\d+) (\S+)$/ or die "$_ ?";
 165         $nlen = length($1) if length($1) > $nlen;
 166         push @strings, [ $1, $2 ];
 167     }
 168     $!=0; $?=0; close P or die "$us: generator failed: $! $?\n";
 169
 170     @strings or die "$us: nothing to show\n";
 171
 172     if ($strings[0][1] =~ m/$dom_re/o) {
 173         my $dom = $&;
 174         if (!grep { $_->[1] !~ m/$dom_re/o && $& eq $dom } @strings) {
 175             $domain_suffix = $dom;
 176             $_->[1] =~ s/$dom_re//o foreach @strings;
 177         }
 178     }
 179
 180     $pertile = ceil(@strings / ($tiles[0] * $tiles[1]));
 181 }
 182
 183 our @lp_values;
 184 our @numbers_metr;
 185 our @texts_metr;
 186 our @domain_metr;
 187 our $gap_width;
 188 our $colgap_width;
 189 our @core_size;
 190 our @item_size;
 191 our $domain_vsize;
 192 our $rotate_paper;
 193 our @eff_paper_size;
 194
 195 sub wontfit ($) {
 196     print DEBUG " NO @_\n";
 197     return 0;
 198 }
 199
 200 sub psstring ($) {
 201     local ($_) = @_;
 202     s/[()\\]/\\$&/g;
 203     return "($_)";
 204 }
 205
 206 our @numbers_1_metr;
 207 our @nom_gap_1_metr;
 208 our @texts_1_metr;
 209 our @domain_1_metr;
 210
 211 sub prepare_metrics () {
 212     print DEBUG " prepare_metrics\n";
 213     my $pchild = open GI, "-|"; defined $pchild or die $!;
 214     my @sets =
 215         ([ \@numbers_1_metr, $fontname_num, map { $_->[0] } @strings ],
 216          [ \@nom_gap_1_metr, $fontname_num, ' '                      ],
 217          [ \@texts_1_metr,   $fontname,     map { $_->[1] } @strings ],
 218         );
 219     if (defined $domain_suffix) {
 220         push @sets, [ \@domain_1_metr, $fontname, $domain_suffix ];
 221     }
 222     if (!$pchild) {
 223         foreach my $set (@sets) {
 224             my ($ra, $fn, @s) = @$set;
 225             print DEBUG "  want $fn ",scalar(@s),"\n";
 226             printf <<END, psstring($fn) or die $!;
 227  %s findfont 10 scalefont setfont
 228 END
 229             printf <<END, psstring($_) or die $! foreach @s;
 230  newpath
 231  0 0 moveto
 232  %s
 233  dup stringwidth pop =
 234  true charpath pathbbox = = = =
 235 END
 236         }
 237         close STDOUT or die $!;
 238         exit 0;
 239     }
 240     my $gchild = open GO, "-|"; defined $gchild or die $!;
 241     if (!$gchild) {
 242         open STDIN, "<&GI" or die $!;
 243         exec qw(gs -dSAFER -dNOPAUSE -q -dBATCH
 244                    -sDEVICE=pswrite -sOutputFile=/dev/null
 245                    -)
 246 #exec qw(tee sponge)
 247             or die "$us: exec gs: $!\n";
 248     }
 249     foreach my $set (@sets) {
 250         my ($ra, $fn, @s) = @$set;
 251         my @bb;
 252         for (my $count=0; $count < @s; $count++) {
 253             my @tbb;
 254             foreach my $ix (0..4) {
 255                 $_ = <GO>; defined or die "gs fail or eof";
 256                 printf DEBUG "    %s (%d,$ix) |%s", $fn, $count, $_;
 257                 chomp;
 258                 m/^-?$dbl_re$/o or die "gs $_ ?";
 259                 push @tbb, $_;
 260             }
 261             print DEBUG "   metrics $fn [$count]: @tbb\n";
 262             $bb[0] = min $bb[0], $tbb[4];
 263             $bb[1] = min $bb[1], $tbb[3];
 264             $bb[2] = max $bb[2], $tbb[2];
 265             $bb[3] = max $bb[3], $tbb[1];
 266             $bb[4] = max $bb[4], $tbb[0];
 267         }
 268         print DEBUG "  metrics $fn: @bb\n";
 269         @$ra = map { $_ * 0.1 } @bb;
 270     }
 271     $!=0; $?=0; close GO or die "gs $! $?";
 272     $!=0; $?=0; close GI or die "gs paste $! $?";
 273 }
 274
 275 sub do_layout_recursive_search ($);
 276 sub do_layout_recursive_search ($) {
 277     my ($lpi) = @_;
 278
 279     if ($lpi < @lp_options) {
 280         foreach my $v ($lp_fixed[$lpi] or @{ $lp_options[$lpi] }) {
 281             $lp_values[$lpi] = $v;
 282             my $r = do_layout_recursive_search $lpi+1;
 283             return $r if $r;
 284         }
 285         return 0;
 286     }
 287
 288     print DEBUG " try", (map { sprintf " %-10.10s", $_ } @lp_values), ":";
 289
 290     my %lp_y;
 291     $lp_y{$_} = 1 foreach @lp_values;
 292
 293     $lp_y{rotate_paper} =
 294         ($paperpts[0] > $paperpts[1] # paper looks like landscape
 295          xor $lp_y{'landscape'});
 296     $eff_paper_size[$_] = $paperpts[$_] - 2.0*$borders[$_] foreach qw(0 1);
 297     @eff_paper_size = reverse @eff_paper_size if $lp_y{rotate_paper};
 298
 299     $eff_paper_size[0] >= $domain_metr[4]
 300         or return wontfit "domain suffix too long";
 301
 302     @item_size = @core_size;
 303     my $blank_coord = !!$lp_y{'blank-below'};
 304     $item_size[$blank_coord] *= (1.0 + $blankratio);
 305
 306     foreach my $coord (qw(0 1)) {
 307         my $avail = $eff_paper_size[$coord];
 308         my $each = $item_size[$coord];
 309         if (!$coord) {
 310             $each += $colgap_width;
 311             $avail += $colgap_width;
 312         } else {
 313             if (defined $domain_suffix) {
 314                 $avail -= $domain_vsize;
 315             }
 316         }
 317         $lp_y{$coord} = floor($avail / $each);
 318         $lp_y{$coord} >= 1 or return wontfit "cannot fit even one $coord";
 319     }
 320
 321     if ($lp_y{'single-column'}) {
 322         $lp_y{0} = 1;
 323     } else {
 324         $lp_y{0} >= 2
 325             or return wontfit "requested multi-column but only one";
 326     }
 327
 328     my $laycountshow = "$lp_y{0} $lp_y{1}";
 329
 330     $lp_y{0} * $lp_y{1} >= $pertile
 331         or return wontfit "layout fits too few $laycountshow";
 332
 333     print DEBUG " OK $laycountshow\n";
 334     return \%lp_y;
 335 }
 336
 337 sub do_layout ($) {
 338     my ($fontsize) = @_;
 339
 340     print DEBUG "layout $fontsize\n";
 341
 342     @numbers_metr = map { $_ * $fontsize * $fontscale_num } @numbers_1_metr;
 343     $gap_width = $gapratio * $fontsize * $nom_gap_1_metr[4];
 344     $colgap_width = $gap_width * 2;
 345     @texts_metr = map { $_ * $fontsize } @texts_1_metr;
 346     @domain_metr = map { $_ * $fontsize } @domain_1_metr;
 347
 348     $core_size[0] = $numbers_metr[4] + $gap_width + $texts_metr[4];
 349
 350     $core_size[1] = $lineratio * $fontsize;
 351
 352     $domain_vsize = $lineratio * $fontsize;
 353
 354     return do_layout_recursive_search 0;
 355 }
 356
 357 our $lp_y;
 358
 359 sub determine_size_layout () {
 360     my $minsz;
 361     my $maxsz;
 362     my $usesz;
 363
 364     for (;;) {
 365         my $trysz =
 366             !defined $minsz ? 1 :
 367             !defined $maxsz ? $minsz * 4 :
 368             sqrt($minsz * $maxsz);
 369
 370         my $ok = do_layout $trysz;
 371
 372         if ($ok) { $minsz = $trysz; } else { $maxsz = $trysz; }
 373
 374         defined $minsz or die "cannot fit at even at ${trysz}pt\n";
 375
 376         if (defined $maxsz && ($maxsz / $minsz) < 1.001) {
 377             $usesz = $minsz;
 378             last;
 379         }
 380     }
 381
 382     $lp_y = do_layout $usesz or die;
 383     $lp_y->{f} = $usesz;
 384
 385     print DEBUG Dumper($usesz, \@lp_values, \@numbers_metr,
 386                        \@texts_metr, $gap_width, $colgap_width, \@core_size,
 387                        \@item_size, \@eff_paper_size,
 388                        $lp_y);
 389 }
 390
 391 sub prf { printf @_ or die $!; }
 392
 393 sub write_output_tile ($) {
 394     my ($tile_string_off) = @_;
 395     my @cnr;
 396     my $c;
 397     for ($cnr[0]=0; $cnr[0]<2; $cnr[0]++) {
 398         for ($cnr[1]=0; $cnr[1]<2; $cnr[1]++) {
 399             foreach my $cnrc (qw(0 1)) {
 400                 prf "newpath ";
 401                 prf "%s ", $cnr[$_] ? $paperpts[$_] : 0 foreach qw(0 1);
 402                 prf "moveto ";
 403                 prf "%s ", ($cnrc!=$_ ? 0 : $cnr[$_] ? -1 : +1) * $borders[$_]
 404                     foreach qw(0 1);
 405                 prf "rlineto stroke\n";
 406             }
 407         }
 408     }
 409     prf "%s ", $borders[$_] foreach qw(0 1);
 410     prf "translate\n";
 411     if ($lp_y->{rotate_paper}) {
 412         prf "90 rotate\n";
 413         prf "0 %s translate\n", -$eff_paper_size[1];
 414     }
 415     my $rows = ceil($pertile / $lp_y->{0});
 416     my @cell_size;
 417
 418     $cell_size[0] = ($eff_paper_size[0] + $colgap_width) / $lp_y->{0};
 419     $cell_size[1] = ($eff_paper_size[1] +
 420                      (defined $domain_suffix ? -$domain_vsize : 0)
 421                      ) / $rows;
 422
 423     prf "/rightadjust { dup stringwidth pop neg 0 rmoveto } bind def\n";
 424
 425     foreach my $nums (qw(1 0)) {
 426         prf("%s findfont %s scalefont setfont\n",
 427             psstring($nums ? $fontname_num : $fontname),
 428             ($nums ? $fontscale_num : 1.0) * $lp_y->{f});
 429         prf "%s setlinewidth\n", $gap_width * 0.1;
 430         print DEBUG "nums? $nums rows=$rows\n";
 431         foreach my $col (0..$lp_y->{0}-1) {
 432             my $col_lhs = $cell_size[0] * $col;
 433             if ($col > 0 && $nums) {
 434                 prf "newpath %s ", $col_lhs - $colgap_width*0.5;
 435                 prf "%s moveto ", $eff_paper_size[1];
 436                 prf "0 %s rlineto ", -$cell_size[1] * $rows;
 437                 prf "stroke\n";
 438             }
 439             foreach my $row (0..$rows-1) {
 440                 my $se = $strings[$col*$rows + $row + $tile_string_off];
 441                 next unless $se;
 442                 prf "newpath ";
 443                 prf "%s ", $col_lhs
 444                     + ($nums ? $numbers_metr[4]
 445                        : $numbers_metr[4] + $gap_width);
 446                 prf "%s ", $eff_paper_size[1] - $cell_size[1] * $row
 447                     - $core_size[1];
 448                 prf "moveto %s ", psstring($se->[!$nums]);
 449                 if ($nums) {
 450                     prf "rightadjust ";
 451                 }
 452 #               prf " gsave 10 10 rlineto stroke grestore\n";
 453                 prf "show\n";
 454             }
 455         }
 456         if (!$nums) {
 457             if (defined $domain_suffix) {
 458                 prf "%s 0 moveto", $eff_paper_size[0];
 459                 prf "%s ", psstring($domain_suffix);
 460                 prf "rightadjust show\n";
 461             }
 462         }
 463     }
 464 }
 465
 466 sub write_output () {
 467     prf "%%!\n";
 468     my @tile;
 469     for ($tile[0]=0; $tile[0]<$tiles[0]; $tile[0]++) {
 470         for ($tile[1]=0; $tile[1]<$tiles[1]; $tile[1]++) {
 471             prf "%% tile @tile\n";
 472             prf "gsave\n";
 473             if (@bigpaperpts) {
 474                 foreach (qw(0 1)) {
 475                     my $spare = $bigpaperpts[$_] - $tiles[$_] * $paperpts[$_];
 476                     $spare >= 0 or die "too many tiles: will not fit!\n";
 477                     prf "%s ", $spare*0.5;
 478                 }
 479                 prf "translate\n";
 480             }
 481             prf "%s ", $tile[$_] * $paperpts[$_] foreach qw(0 1);
 482             prf "translate\n";
 483             write_output_tile($tile[0] * $pertile +
 484                               $tile[1] * $pertile * $tiles[0]);
 485             prf "grestore\n";
 486         }
 487     }
 488     prf "showpage\n";
 489 }
 490
 491 readstrings();
 492 prepare_metrics();
 493 determine_size_layout();
 494 write_output();