generate

   1 #!/usr/bin/perl -w
   2 #
   3 # subdirmk - &-filter (makefile generation program)
   4 #  Copyright 2019 Ian Jackson
   5 # SPDX-License-Identifier: LGPL-2.0-or-later
   6 #
   7 # $(srcdir)/subdirmk/generate [--srcdir=SRCDIR] [--] SUBDIR...
   8 #
   9 # generates in each subdirectory        from in each subdirectory
  10 #     Subdir.mk.tmp                         Subdir.sd.mk
  11 #     Makefile                          and included files
  12 # and in toplevel                       and in toplevel
  13 #     main.mk.tmp                           Perdir.sd.mk
  14
  15 use strict;
  16 use POSIX;
  17
  18 print "$0 @ARGV\n" or die $!;
  19
  20 our $srcdir='.';
  21
  22 while (@ARGV && $ARGV[0] =~ m/^-/) {
  23     $_ = shift @ARGV;
  24     last if $_ eq '--';
  25     if (s/^--srcdir=//) {
  26         $srcdir=$';
  27     } else {
  28         die "$0: unknown option \`$_'\n";
  29     }
  30 }
  31 our @subdirs = @ARGV;
  32
  33 s{/+$}{} foreach @subdirs;
  34
  35 our $root = [ '.', [ ], 1 ];
  36 # each node is [ 'relative subdir name', \@children, $mentioned ]
  37
  38 sub build_tree () {
  39     foreach my $subdir (@subdirs) {
  40         my @path = $subdir eq '.' ? () : split m{/+}, $subdir;
  41         my $node = $root;
  42         foreach my $d (@path) {
  43             my ($c,) = grep { $_->[0] eq $d } @{ $node->[1] };
  44             if (!$c) {
  45                 $c = [ $d, [ ] ];
  46                 push @{ $node->[1] }, $c;
  47             }
  48             $node = $c;
  49         }
  50         $node->[2] = 1;
  51     }
  52 }
  53
  54 sub target_varname ($$) {
  55     my ($var_prefix, $target) = @_;
  56     return $var_prefix.'TARGETS'.($target eq 'all' ? '' : "_$target");
  57 }
  58
  59 our $writing_output;
  60 our $buffering_output;
  61 our %output_files;
  62 our %input_files;
  63
  64 sub close_any_output_file() {
  65     return unless defined $writing_output;
  66     O->error and die "error writing $writing_output.tmp: $! (?)\n";
  67     close O or die "error closing $writing_output.tmp: $!\n";
  68     $writing_output = undef;
  69 }
  70
  71 sub o {
  72     if (defined $buffering_output) {
  73         $buffering_output .= $_ foreach @_;
  74         return;
  75     }
  76     die unless defined $writing_output;
  77     print O @_ or die "error writing $writing_output.tmp: $!\n";
  78 }
  79
  80 sub start_output_file ($) {
  81     close_any_output_file();
  82     ($writing_output) = @_;
  83     die "$writing_output ?" if $output_files{$writing_output}++;
  84     my $tmp = "$writing_output.tmp";
  85     open O, ">", $tmp or die "create $tmp: $!\n";
  86     o "# autogenerated - do not edit\n";
  87 }
  88
  89 sub install_output_files () {
  90     close_any_output_file();
  91     foreach my $f (sort keys %output_files) {
  92         rename "$f.tmp", $f or die "install new $f: $!\n";
  93     }
  94 }
  95
  96 sub write_makefile ($$) {
  97     my ($dir_prefix,$depth) = @_;
  98     #print STDERR "write_makefile @_\n";
  99     start_output_file("${dir_prefix}Makefile");
 100     my $cd = $depth ? join('/', ('..',) x $depth) : '.';
 101     my $suppress_templates=
 102         '$(if $(filter-out clean real-clean, $(subdirmk_targets)),,'.
 103         ' MAKEFILE_TEMPLATES=)';
 104     o <<END;
 105 default: all
 106 \$(filter-out all,\$(MAKECMDGOALS)) all: run-main.mk
 107         \@:
 108 subdirmk_targets:=\$(or \$(MAKECMDGOALS),all)
 109 Makefile run-main.mk:
 110         \$(MAKE) -C $cd -f main.mk \$(addprefix ${dir_prefix},\$(subdirmk_targets))$suppress_templates
 111 .SUFFIXES:
 112 .PHONY: run-main.mk
 113 END
 114 }
 115
 116 sub process_input_mk ($$$$$$$$);
 117 sub process_input_mk ($$$$$$$$) {
 118     my ($dir_prefix, $dir_suffix, $dir_name,
 119         $var_prefix, $targets,
 120         $f, $esclitr, $enoent_ok) = @_;
 121
 122     my $caps_re = qr{[A-Z]};
 123     my $lc_re = qr{[a-z]};
 124
 125     my $esc;
 126     my $set_esc = sub {
 127         $esc = $$esclitr;
 128         $esc =~ s/\W/\\$&/g;
 129     };
 130     $set_esc->();
 131
 132     my $input = new IO::File $f, '<';
 133     if (!$input) {
 134         die "open $f: $!\n" unless $!==ENOENT && $enoent_ok;
 135         return;
 136     }
 137     $input_files{$f}++;
 138
 139     my %pfxmap = (
 140                   ''  => $dir_prefix,
 141                   '^' => "\$(top_srcdir)${dir_suffix}/",
 142                   '~' => "\$(top_srcdir)/",
 143                  );
 144
 145     while (<$input>) {
 146         if (s#^\s*$esc\:##) {
 147             $buffering_output='';
 148         }
 149         for (;;) {
 150             unless (s{^(.*?)(\\)?(?=$esc)}{}) { o $_; last; }
 151             o $1;
 152             if ($2) { s#^$esc##; o $$esclitr; next; }
 153             s{^$esc}{} or die "$_ ?";
 154             if (s{^$esc}{}) { o "$$esclitr$$esclitr" }
 155             elsif (s{^TARGETS(?:_([0-9a-zA-Z_]+))?(?=\W)}{}) {
 156                 my $t = $1 // 'all';
 157                 o target_varname($var_prefix, $t);
 158                 $targets->{$t} //= [ ];
 159             }
 160             elsif (m{^(?=$caps_re)}) { o $var_prefix }
 161             elsif (s{^([~^]?)(?=$lc_re)}{}) { o $pfxmap{$1} }
 162             elsif (s{^_}{}) { o $var_prefix }
 163             elsif (s{^=_}{}) { o $var_prefix }
 164             elsif (s{^([~^]?)/}{}) { o $pfxmap{$1} }
 165             elsif (s{^=/}{}) { o $dir_name }
 166             elsif (s{^([~^]?)(?=[ \t])}{}) {
 167                 my $prefix = $pfxmap{$1} // die;
 168                 my $after='';
 169                 if (m{([ \t])$esc}) { ($_,$after) = ($`, $1.$'); }
 170                 s{(?<=[ \t])(?=\S)(?!\\\s*$)}{$prefix}g;
 171                 o $_;
 172                 $_ = $after;
 173             } elsif (s{^\#}{}) {
 174                 $_ = '';
 175             } elsif (s{^![ \t]+}{}) {
 176                 o $_;
 177                 $_ = '';
 178             } elsif (s{^!(\S+)(?:[ \t]+|$)}{}) {
 179                 $$esclitr = $1;
 180                 $set_esc->();
 181             } else {
 182                 die "bad escape $$esclitr$_ ";
 183             }
 184         }
 185         if (defined $buffering_output) {
 186             $_=$buffering_output;
 187             $buffering_output=undef;
 188             if (m#^(-?)include\s+(\S+)\s+$#) {
 189                 my $subf = "$srcdir/$2";
 190                 process_input_mk($dir_prefix, $dir_suffix, $dir_name,
 191                                  $var_prefix, $targets,
 192                                  $subf, $esclitr, $1);
 193                 o "\n";
 194             } else {
 195                 die "unknown directive $_ ";
 196             }
 197         }
 198     }
 199     $input->error and die "read $f: $!\n";
 200     close $input or die "close $f: $!\n";
 201 }
 202
 203 sub filter_subdir_mk ($$$$$) {
 204     my ($dir_prefix, $dir_suffix, $dir_name,
 205         $var_prefix, $targets) = @_;
 206
 207     #use Data::Dumper;
 208     #print STDERR "filter @_\n";
 209
 210     my $esclit = '&';
 211
 212     my $pi = sub {
 213         my ($f, $enoentok) = @_;
 214         process_input_mk($dir_prefix, $dir_suffix, $dir_name,
 215                          $var_prefix, $targets,
 216                          "${srcdir}/$f", \$esclit, $enoentok);
 217     };
 218     $pi->("${dir_prefix}Subdir.sd.mk", 0);
 219     $pi->("Perdir.sd.mk",              1);
 220 }
 221
 222 sub process_subtree ($$);
 223 sub process_subtree ($$) {
 224     # => list of descendants (in form SUBDIR/)
 225     # recursive, children first
 226     my ($node, $path) = @_;
 227
 228     #use Data::Dumper;
 229     #print STDERR Dumper(\@_);
 230
 231     my $dir_prefix = join '', map { "$_/" } @$path;
 232     my $dir_suffix = join '', map { "/$_" } @$path;
 233     my $dir_name = join '/', @$path ? @$path : '.';
 234     my $var_prefix = join '', map { "${_}_" } @$path ? @$path : qw(TOP);
 235
 236     write_makefile($dir_prefix, scalar @$path);
 237
 238     my %targets = (all => []);
 239     foreach my $child (@{ $node->[1] }) {
 240         my @childpath = (@$path, $child->[0]);
 241         my $child_subdir = join '/', @childpath;
 242         mkdir $child_subdir or $!==EEXIST or die "mkdir $child_subdir: $!";
 243         push @{ $targets{$_} }, $child_subdir foreach
 244             process_subtree($child, \@childpath);
 245     }
 246     start_output_file("${dir_prefix}Subdir.mk.tmp");
 247
 248     if ($node->[2]) {
 249         filter_subdir_mk($dir_prefix, $dir_suffix, $dir_name,
 250                          $var_prefix, \%targets);
 251     } else {
 252         my $sdmk = "${dir_prefix}Subdir.sd.mk";
 253         if (stat $sdmk) {
 254             die "$sdmk unexpectedly exists (${dir_prefix} not mentioned)";
 255         } elsif ($!==ENOENT) {
 256         } else {
 257             die "stat $sdmk: $!";
 258         }
 259     }
 260
 261     o "\n";
 262
 263     my @targets = sort keys %targets;
 264     foreach my $target (@targets) {
 265         my $target_varname = target_varname($var_prefix, $target);
 266         print O "${dir_prefix}${target}:: \$($target_varname)";
 267         foreach my $child_subdir (@{ $targets{$target} }) {
 268             print O " $child_subdir/$target";
 269         }
 270         print O "\n";
 271     }
 272     if (@targets) {
 273         print O ".PHONY:";
 274         print O " ${dir_prefix}${_}" foreach @targets;
 275         print O "\n";
 276     }
 277
 278     return @targets;
 279 }
 280
 281 sub process_tree() {
 282     process_subtree($root, [ ]);
 283     start_output_file("main.mk.tmp");
 284     foreach my $v (qw(top_srcdir abs_top_srcdir)) {
 285         o "$v=\@$v@\n";
 286     }
 287     o "SUBDIRMK_MAKEFILES :=\n";
 288     o "MAKEFILE_TEMPLATES :=\n";
 289     o "SUBDIRMK_MAKEFILES += Subdir.mk\n";
 290     foreach my $subdir (@subdirs) {
 291         o "SUBDIRMK_MAKEFILES += $subdir/Subdir.mk\n";
 292     }
 293     foreach my $input (sort keys %input_files) {
 294         o "MAKEFILE_TEMPLATES += $input\n";
 295     }
 296     o "include \$(SUBDIRMK_MAKEFILES)\n";
 297 }
 298
 299 build_tree();
 300 process_tree();
 301 install_output_files();