generate

   1 #!/usr/bin/perl -w
   2 #
   3 # subdirmk - &-filter (makefile generation program)
   4 #  Copyright 2019 Ian Jackson
   5 # SPDX-License-Identifier: LGPL-2.0-or-later
   6 #
   7 # $(srcdir)/subdirmk/generate [--srcdir=SRCDIR] [--] SUBDIR...
   8 #
   9 # generates in each subdirectory
  10 #     Dir.mk.tmp
  11 #     Makefile
  12 # and in toplevel
  13 #     main.mk.tmp
  14
  15 use strict;
  16 use POSIX;
  17
  18 print "$0 @ARGV\n" or die $!;
  19
  20 our $srcdir='.';
  21
  22 # error handling methods:
  23 #
  24 # Error in input file, while $err_file and $. set, eg in most of
  25 # process_input_mk:
  26 #         err "message";
  27 #
  28 # Other input or usage errors:
  29 #         die "subdirmk: $file:$lno: problem\n";
  30 #         die "subdirmk: some problem not locatable in that way\n";
  31 #
  32 # Usage error:
  33 #         die "subdirmk $0: explanation of problem\n";
  34 #
  35 # System call error (not ENOENT) accessing input/output files:
  36 #         die "description of problem eg maybe erbing noun: $!\n";
  37 #
  38 # Bug detedcted in `generate':
  39 #         die "internal error (some information)?"; # or similar
  40
  41 while (@ARGV && $ARGV[0] =~ m/^-/) {
  42     $_ = shift @ARGV;
  43     last if $_ eq '--';
  44     if (s/^--srcdir=//) {
  45         $srcdir=$';
  46     } else {
  47         die "subdirmk $0: unknown option \`$_'\n";
  48     }
  49 }
  50 our @subdirs = @ARGV;
  51
  52 s{/+$}{} foreach @subdirs;
  53
  54 our $root = [ '.', [ ], 1 ];
  55 # each node is [ 'relative subdir name', \@children, $mentioned ]
  56
  57 sub build_tree () {
  58     foreach my $subdir (@subdirs) {
  59         my @path = $subdir eq '.' ? () : split m{/+}, $subdir;
  60         my $node = $root;
  61         foreach my $d (@path) {
  62             my ($c,) = grep { $_->[0] eq $d } @{ $node->[1] };
  63             if (!$c) {
  64                 $c = [ $d, [ ] ];
  65                 push @{ $node->[1] }, $c;
  66             }
  67             $node = $c;
  68         }
  69         $node->[2] = 1;
  70     }
  71 }
  72
  73 sub target_varname ($$) {
  74     my ($var_prefix, $target) = @_;
  75     return $var_prefix.'TARGETS'.($target eq 'all' ? '' : "_$target");
  76 }
  77
  78 our $writing_output;
  79 our $buffering_output;
  80 our %output_files;
  81 our %input_files;
  82 our @output_makefiles;
  83
  84 sub close_any_output_file() {
  85     return unless defined $writing_output;
  86     O->error and die "error writing $writing_output.tmp: $! (?)\n";
  87     close O or die "error closing $writing_output.tmp: $!\n";
  88     $writing_output = undef;
  89 }
  90
  91 sub oraw {
  92     die 'internal error' unless defined $writing_output;
  93     print O @_ or die "error writing $writing_output.tmp: $!\n";
  94 }
  95
  96 sub oud { # undoubled
  97     if (defined $buffering_output) {
  98         $buffering_output .= $_ foreach @_;
  99         return;
 100     }
 101     oraw @_;
 102 }
 103
 104 our $ddbl;
 105
 106 sub od { # maybe $-doubled
 107     if (!$ddbl) {
 108         oud @_;
 109         return;
 110     }
 111     foreach (@_) {
 112         my $e = $_;
 113         $e =~ s{\$}{\$\$}g;
 114         oud $e;
 115     }
 116 }
 117
 118 sub start_output_file ($) {
 119     close_any_output_file();
 120     ($writing_output) = @_;
 121     die "internal error ($writing_output?)"
 122         if $output_files{$writing_output}++;
 123     my $tmp = "$writing_output.tmp";
 124     open O, ">", $tmp or die "create $tmp: $!\n";
 125     oraw "# autogenerated - do not edit\n";
 126 }
 127
 128 sub install_output_files () {
 129     close_any_output_file();
 130     foreach my $f (sort keys %output_files) {
 131         rename "$f.tmp", $f or die "install new $f: $!\n";
 132     }
 133 }
 134
 135 sub write_makefile ($$) {
 136     my ($dir_prefix,$depth) = @_;
 137     #print STDERR "write_makefile @_\n";
 138     start_output_file("${dir_prefix}Makefile");
 139     my $cd = $depth ? join('/', ('..',) x $depth) : '.';
 140     my $suppress_templates=
 141         '$(if $(filter-out clean real-clean, $(subdirmk_targets)),,'.
 142         ' MAKEFILE_TEMPLATES=)';
 143     oraw <<END;
 144 default: all
 145 \$(filter-out all,\$(MAKECMDGOALS)) all: run-main.mk
 146         \@:
 147 subdirmk_targets:=\$(or \$(MAKECMDGOALS),all)
 148 Makefile run-main.mk:
 149         \$(MAKE) -C $cd -f main.mk \$(addprefix ${dir_prefix},\$(subdirmk_targets))$suppress_templates
 150 .SUFFIXES:
 151 .PHONY: run-main.mk
 152 END
 153 }
 154
 155 our %varref;
 156
 157 our ($dir_prefix, $dir_suffix, $dir_name,
 158      $var_prefix, $var_prefix_name);
 159
 160 sub dir_prefix ($) {
 161     my ($path) = @_;
 162     join '', map { "$_/" } @$path;
 163 }
 164
 165 sub set_dir_vars ($) {
 166     my ($path) = @_;
 167     $dir_prefix = dir_prefix($path);
 168     $dir_suffix = join '', map { "/$_" } @$path;
 169     $dir_name = join '/', @$path ? @$path : '.';
 170     $var_prefix_name = join '_', @$path ? @$path : qw(TOP);
 171     $var_prefix = "${var_prefix_name}_";
 172 }
 173
 174 our $err_file;
 175
 176 sub err ($) {
 177     my ($m) = @_;
 178     die "subdirmk: ${err_file}:$.: $m\n";
 179 }
 180
 181 sub wrn ($) {
 182     my ($m) = @_;
 183     print STDERR "subdirmk: warning: ${err_file}:$.: $m\n";
 184 }
 185
 186 sub ddbl_only ($) {
 187     my ($e) = @_;
 188     return if $ddbl;
 189     err "escape &$e is valid only during \$-doubling";
 190 }
 191
 192 sub process_input_mk ($$$$);
 193 sub process_input_mk ($$$$) {
 194     my ($targets, $f, $esclitr, $enoent_ok) = @_;
 195
 196     my $caps_re = qr{[A-Z]};
 197     my $lc_re = qr{[a-z]};
 198
 199     my $esc;
 200     my $set_esc = sub {
 201         $esc = $$esclitr;
 202         $esc =~ s/\W/\\$&/g;
 203     };
 204     $set_esc->();
 205
 206     my $input = new IO::File $f, '<';
 207     if (!$input) {
 208         err "open $f: $!" unless $!==ENOENT && $enoent_ok;
 209         return;
 210     }
 211     $input_files{$f}++;
 212
 213     local $err_file=$f;
 214
 215     my %srcdirmap = (
 216                   '^' => "\$(top_srcdir)${dir_suffix}",
 217                   '~' => "\$(top_srcdir)",
 218                     );
 219     my %pfxmap = (
 220                   ''  => $dir_prefix,
 221                  );
 222     $pfxmap{$_} = $srcdirmap{$_}.'/' foreach keys %srcdirmap;
 223
 224     local $ddbl;
 225     my @nest = (['']);
 226     my $evalcall_brackets;
 227
 228     my $push_nest = sub {
 229         my ($nk, $nndbl, $what) = @_;
 230         unshift @nest, [ $nk, $ddbl, $what, $. ];
 231         $ddbl = $nndbl;
 232     };
 233     my $pop_nest = sub {
 234         my ($nk) = @_;
 235         err "unexpectedly closed $nk in middle of $nest[0][0] ($nest[0][2])"
 236             unless $nest[0][0] eq $nk;
 237         $ddbl = (shift @nest)[1];
 238     };
 239
 240     # Our detection of variable settings does not have to be completely
 241     # accurate, since it is only going to be used for advice to the user.
 242     my $note_varref = sub {
 243         my ($vn,$amp) = @_;
 244         $varref{$vn}{$amp}{"$f:$."} = 1;
 245     };
 246
 247     while (<$input>) {
 248         if (s#^\s*$esc\:changequote\s+(\S+)\s+$##) {
 249             $$esclitr = $1;
 250             $set_esc->();
 251             next;
 252         } elsif (s#^\s*$esc\:endm\s+$##) {
 253             $pop_nest->('macro');
 254             od "endef\n";
 255             next;
 256         } elsif (s#^\s*$esc\:(?=(-?)include|macro)##) {
 257             $buffering_output='';
 258         } elsif (m#^\s*$esc\:([a-z][-0-9a-z_]*)#) {
 259             err "unknown directive &:$1 or bad argumnt syntax";
 260         } elsif (s{^\s*${esc}TARGETS(?:_([0-9a-zA-Z_]+))?(?=\W)}{}) {
 261             my $t = $1 // 'all';
 262             od target_varname($var_prefix, $t);
 263             $targets->{$t} //= [ ];
 264         }
 265         for (;;) {
 266             err 'cannot $-double &-processed RHS of directive'
 267                 if $ddbl && defined $buffering_output;
 268             unless ($nest[0][0] eq 'eval'
 269                     ? s{^(.*?)($esc|[{}])}{}
 270                     : s{^(.*?)($esc)}{}) { od $_; last; }
 271             od $1;
 272             if ($2 eq '{') {
 273                 od $2;
 274                 $evalcall_brackets++;
 275                 next;
 276             } elsif ($2 eq '}') {
 277                 od $2;
 278                 next if --$evalcall_brackets;
 279                 $pop_nest->('eval');
 280                 od '}';
 281                 next;
 282             }
 283             if (s{^\\$esc}{}) { od "$$esclitr" }
 284             elsif (s{^\\\$}{}) { oud '$' }
 285             elsif (s{^\\\s+$}{}) { }
 286             elsif (s{^$esc}{}) { od "$$esclitr$$esclitr" }
 287             elsif (m{^(?=$caps_re)}) { od $var_prefix }
 288             elsif (s{^\$([A-Za-z]\w+)}{}) { od "\$(${var_prefix}$1)" }
 289             elsif (s{^([~^]?)(?=$lc_re)}{}) { od $pfxmap{$1} }
 290             elsif (s{^_}{}) { od $var_prefix }
 291             elsif (s{^=}{}) { od $var_prefix_name }
 292             elsif (s{^([~^]?)/}{}) { od $pfxmap{$1} }
 293             elsif (s{^\.}{}) { od $dir_name }
 294             elsif (s{^([~^])\.}{}) { od $srcdirmap{$1} }
 295             elsif (s{^\$\-}{}) { $ddbl=undef; }
 296             elsif (s{^\$\+}{}) { $ddbl=1; }
 297             elsif (s{^\$\(}{}) { ddbl_only($&); oud "\$("; }
 298             elsif (s{^\$(\d+)}{}) { ddbl_only($&); oud "\$($1)"; }
 299             elsif (s{^\$\{}{}) {
 300                 err 'macro invocation cannot be re-$-doubled' if $ddbl;
 301                 od '${eval ${call ';
 302                 $evalcall_brackets = 1;
 303                 $push_nest->('eval',1, '&${...}');
 304             } elsif (s{^([~^]?)(?=[ \t])}{}) {
 305                 my $prefix = $pfxmap{$1} // die "internal error ($1?)";
 306                 my $after='';
 307                 if (m{([ \t])$esc}) { ($_,$after) = ($`, $1.$'); }
 308                 s{(?<=[ \t])(?=\S)(?!\\\s*$)}{$prefix}g;
 309                 od $_;
 310                 $_ = $after;
 311             } elsif (s{^\#}{}) {
 312                 $_ = '';
 313             } elsif (s{^![ \t]+}{}) {
 314                 od $_;
 315                 $_ = '';
 316             } else {
 317                 m{^.{0,5}};
 318                 err "bad &-escape \`$$esclitr$&'";
 319             }
 320         }
 321         if (defined $buffering_output) {
 322             $_=$buffering_output;
 323             $buffering_output=undef;
 324             if (m#^(-?)include\s+(\S+)\s+$#) {
 325                 my $subf = "$srcdir/$2";
 326                 process_input_mk($targets, $subf, $esclitr, $1);
 327                 od "\n";
 328             } elsif (m#^macro\s+(\S+)\s+$#) {
 329                 od "define $1\n";
 330                 $push_nest->('macro', 1, '&:macro');
 331             } else {
 332                 err "bad directive argument syntax";
 333             }
 334         }
 335     }
 336     die "subdirmk: $f:$nest[0][3]: unclosed $nest[0][0] ($nest[0][2])\n"
 337         if $nest[0][0];
 338     $input->error and die "read $f: $!\n";
 339     close $input or die "close $f: $!\n";
 340 }
 341
 342 sub filter_subdir_mk ($) {
 343     my ($targets) = @_;
 344
 345     #use Data::Dumper;
 346     #print STDERR "filter @_\n";
 347
 348     my $esclit = '&';
 349
 350     my $pi = sub {
 351         my ($f, $enoentok) = @_;
 352         process_input_mk($targets, "${srcdir}/$f", \$esclit, $enoentok);
 353     };
 354     $pi->("Prefix.sd.mk",           1);
 355     $pi->("${dir_prefix}Dir.sd.mk", 0);
 356     $pi->("Suffix.sd.mk",           1);
 357 }
 358
 359 sub process_subtree ($$);
 360 sub process_subtree ($$) {
 361     # => list of targets (in form SUBDIR/)
 362     # recursive, children first
 363     my ($node, $path) = @_;
 364
 365     #use Data::Dumper;
 366     #print STDERR Dumper(\@_);
 367
 368     my $dir_prefix = dir_prefix($path);
 369     # ^ this is the only var which we need before we come back from
 370     #   the recursion.
 371
 372     push @output_makefiles, "${dir_prefix}Dir.mk";
 373     write_makefile($dir_prefix, scalar @$path);
 374
 375     my %targets = (all => []);
 376     foreach my $child (@{ $node->[1] }) {
 377         my @childpath = (@$path, $child->[0]);
 378         my $child_subdir = join '/', @childpath;
 379         mkdir $child_subdir or $!==EEXIST or die "mkdir $child_subdir: $!\n";
 380         push @{ $targets{$_} }, $child_subdir foreach
 381             process_subtree($child, \@childpath);
 382     }
 383
 384     set_dir_vars($path);
 385     start_output_file("${dir_prefix}Dir.mk.tmp");
 386
 387     if ($node->[2]) {
 388         filter_subdir_mk(\%targets);
 389     } else {
 390         my $sdmk = "${dir_prefix}Dir.sd.mk";
 391         if (stat $sdmk) {
 392             die
 393  "subdirmk: $sdmk unexpectedly exists (${dir_prefix} not mentioned on subdirmk/generate command line, maybe directory is missing from SUBDIRMK_SUBDIRS)";
 394         } elsif ($!==ENOENT) {
 395         } else {
 396             die "stat $sdmk: $!\n";
 397         }
 398     }
 399
 400     oraw "\n";
 401
 402     my @targets = sort keys %targets;
 403     foreach my $target (@targets) {
 404         my $target_varname = target_varname($var_prefix, $target);
 405         oraw "${dir_prefix}${target}:: \$($target_varname)";
 406         foreach my $child_subdir (@{ $targets{$target} }) {
 407             oraw " $child_subdir/$target";
 408         }
 409         oraw "\n";
 410     }
 411     if (@targets) {
 412         oraw ".PHONY:";
 413         oraw " ${dir_prefix}${_}" foreach @targets;
 414         oraw "\n";
 415     }
 416
 417     return @targets;
 418 }
 419
 420 sub process_final ($) {
 421     my ($otargets) = @_;
 422     set_dir_vars([]);
 423     push @output_makefiles, "Final.mk";
 424     start_output_file("Final.mk.tmp");
 425     my %ntargets;
 426     my $esclit='&';
 427     process_input_mk(\%ntargets, "${srcdir}/Final.sd.mk", \$esclit, 1);
 428     delete $ntargets{$_} foreach @$otargets;
 429     my @ntargets = sort keys %ntargets;
 430     die "subdirmk: Final.sd.mk may not introduce new top-level targets".
 431         " (@ntargets)\n" if @ntargets;
 432 }
 433
 434 sub process_tree() {
 435     my @targets = process_subtree($root, [ ]);
 436     process_final(\@targets);
 437     start_output_file("main.mk.tmp");
 438     foreach my $v (qw(top_srcdir abs_top_srcdir)) {
 439         oraw "$v=\@$v@\n";
 440     }
 441     oraw "SUBDIRMK_MAKEFILES :=\n";
 442     oraw "MAKEFILE_TEMPLATES :=\n";
 443     foreach my $mf (@output_makefiles) {
 444         oraw "SUBDIRMK_MAKEFILES += $mf\n";
 445     }
 446     foreach my $input (sort keys %input_files) {
 447         oraw "MAKEFILE_TEMPLATES += $input\n";
 448     }
 449     oraw "include \$(SUBDIRMK_MAKEFILES)\n";
 450 }
 451
 452 sub print_varref_warnings () {
 453     foreach my $vn (sort keys %varref) {
 454         my $vv = $varref{$vn};
 455         next unless $vv->{''} && $vv->{1};
 456         print STDERR "subdirmk: warning: saw both $vn and &$vn\n";
 457         foreach my $amp ('', 1) {
 458             printf STDERR " saw %s%s at %s\n",
 459                 ($amp ? '&' : ''), $vn, $_
 460                 foreach sort keys %{ $vv->{$amp} };
 461         }
 462     }
 463 }
 464
 465 build_tree();
 466 process_tree();
 467 print_varref_warnings();
 468 install_output_files();