trackpump-mutlihead-clip.scad

   1 // -*- C -*-
   2
   3 pump_main_dia = 38;
   4 pump_side_width = 5;
   5 pump_side_thick = 5;
   6 pump_shaft_dia = 14;
   7 baseplate = 4;
   8
   9 pump_protr_flat = 3;
  10 pump_protr_slope = 1.0;
  11
  12 hose_head_dia = 28;
  13 hose_side_thick = 5;
  14 hose_base_offset = 10;
  15 hose_head_width = 22;
  16 hose_side_width = 4;
  17
  18 // need reconfirm:
  19 pump_protr_protr = 3;
  20 pump_side_height = 20;
  21
  22 // calculated
  23 pump_protr_slheight = pump_protr_protr / pump_protr_slope;
  24
  25 pump_side_outer_rad = pump_side_width + pump_main_dia/2;
  26
  27 $fa=5;
  28
  29 module PumpSidePlan() {
  30   xm = baseplate + pump_main_dia/2;
  31   or = pump_side_outer_rad;
  32   difference(){
  33     union(){
  34       intersection(){
  35         translate([-xm, 0]) circle(r=or);
  36         translate([-(xm+or), -or]) square([xm+or, or*2]);
  37       }
  38       translate([-xm, -or]) square([xm, or*2]);
  39     }
  40     translate([-xm-or, 0])
  41       square(center=true, [pump_side_width*4, pump_shaft_dia]);
  42   }
  43 }
  44
  45 module PumpSideElevation(){
  46   x3 = 0;
  47   x2 = x3 - baseplate;
  48   x1 = x2 - pump_main_dia;
  49   x0 = x1 - pump_side_width;
  50   x2a = x2 - pump_protr_protr;
  51
  52   z0 = 0;
  53   z1 = z0 - pump_side_thick;
  54   z2 = z1 - pump_side_height;
  55   z2a = z2 - pump_protr_slheight;
  56   z2b = z2a - pump_protr_flat;
  57
  58   arcx = x2-x1;
  59   arcy = z1-z2;
  60
  61   translate([x0,z1]) square([x1-x0, z0-z1]);
  62
  63   difference(){
  64     translate([x1,z2]) square([x3-x1, z0-z2]);
  65     translate([x1,z2]) scale([1,arcy/arcx]) circle(r=arcx);
  66   }
  67
  68   translate([x2,z2a]) square([x3-x2, z0-z2a]);
  69
  70   hull(){
  71     translate([x2,z2a]) square([x3-x2, z2-z2a]);
  72     translate([x2a,z2b]) square([x3-x2a, z2a-z2b]);
  73   }
  74 }
  75
  76 module PumpSide(){
  77   difference(){
  78     intersection(){
  79       translate([0,100,0])
  80         rotate([90,0,0])
  81         linear_extrude(height=200)
  82       PumpSideElevation();
  83       translate([0,0,-100])
  84         linear_extrude(height=200)
  85         PumpSidePlan();
  86     }
  87     translate([-(baseplate + pump_main_dia/2), 0,
  88                 -(pump_side_thick + pump_side_height)])
  89       cylinder(r=pump_main_dia/2, h=200);
  90   }
  91 }
  92
  93 module HoseSideElevation(){
  94   or = hose_head_dia/2 + hose_side_thick;
  95
  96   x3 = 0;
  97   x4 = x3 + hose_base_offset;
  98   x5 = x4 + hose_head_dia/2;
  99   x6 = x4 + hose_head_dia;
 100   x7 = x5 + or;
 101
 102   z0 = 0;
 103   zm = -or;
 104
 105   difference(){
 106     intersection(){
 107       translate([-100,-100]) square([x7+210, 100]);
 108       hull(){
 109         translate([x5, 0]) circle(r=or);
 110         translate([-1, zm]) square([1,z0-zm]);
 111       }
 112     }
 113     translate([x5,0]) circle(r=hose_head_dia/2);
 114   }
 115 }
 116
 117 module HoseSide(){
 118   for (m=[0,1]) {
 119     mirror([0,m,0])
 120       translate([0, hose_head_width, 0])
 121       rotate([90,0,0])
 122       linear_extrude(height= hose_side_width)
 123       HoseSideElevation();
 124   }
 125 }
 126
 127 module Clip(){
 128   PumpSide();
 129   HoseSide();
 130 }
 131
 132 module ClipPrint(){
 133   rotate([180,0,0])
 134     Clip();
 135 }
 136
 137 //PumpSidePlan();
 138 //PumpSideElevation();
 139 //HoseSideElevation();
 140 //PumpSide();
 141 //HoseSide();
 142 //Clip();
 143 ClipPrint();