trackpump-mutlihead-clip.scad

   1 // -*- C -*-
   2
   3 pump_main_dia = 38;
   4 pump_side_width = 5;
   5 pump_side_thick = 5;
   6 pump_shaft_dia = 14;
   7 baseplate = 4;
   8
   9 pump_protr_flat = 3;
  10 pump_protr_slope = 1.0;
  11
  12 hose_head_dia = 28;
  13 hose_side_thick = 5;
  14 hose_base_offset = 10;
  15 hose_head_width = 22;
  16 hose_side_width = 4;
  17
  18 pump_protr_protr = 3;
  19 pump_side_height = 20;
  20
  21 // calculated
  22 pump_protr_slheight = pump_protr_protr / pump_protr_slope;
  23
  24 pump_side_outer_rad = pump_side_width + pump_main_dia/2;
  25
  26 $fa=5;
  27
  28 module PumpSidePlan() {
  29   xm = baseplate + pump_main_dia/2;
  30   or = pump_side_outer_rad;
  31   difference(){
  32     union(){
  33       intersection(){
  34         translate([-xm, 0]) circle(r=or);
  35         translate([-(xm+or), -or]) square([xm+or, or*2]);
  36       }
  37       translate([-xm, -or]) square([xm, or*2]);
  38     }
  39     translate([-xm-or, 0])
  40       square(center=true, [pump_side_width*4, pump_shaft_dia]);
  41   }
  42 }
  43
  44 module PumpSideElevation(){
  45   x3 = 0;
  46   x2 = x3 - baseplate;
  47   x1 = x2 - pump_main_dia;
  48   x0 = x1 - pump_side_width;
  49   x2a = x2 - pump_protr_protr;
  50
  51   z0 = 0;
  52   z1 = z0 - pump_side_thick;
  53   z2 = z1 - pump_side_height;
  54   z2a = z2 - pump_protr_slheight;
  55   z2b = z2a - pump_protr_flat;
  56
  57   arcx = x2-x1;
  58   arcy = z1-z2;
  59
  60   translate([x0,z1]) square([x1-x0, z0-z1]);
  61
  62   difference(){
  63     translate([x1,z2]) square([x3-x1, z0-z2]);
  64     translate([x1,z2]) scale([1,arcy/arcx]) circle(r=arcx);
  65   }
  66
  67   translate([x2,z2a]) square([x3-x2, z0-z2a]);
  68
  69   hull(){
  70     translate([x2,z2a]) square([x3-x2, z2-z2a]);
  71     translate([x2a,z2b]) square([x3-x2a, z2a-z2b]);
  72   }
  73 }
  74
  75 module PumpSide(){
  76   difference(){
  77     intersection(){
  78       translate([0,100,0])
  79         rotate([90,0,0])
  80         linear_extrude(height=200)
  81       PumpSideElevation();
  82       translate([0,0,-100])
  83         linear_extrude(height=200)
  84         PumpSidePlan();
  85     }
  86     translate([-(baseplate + pump_main_dia/2), 0,
  87                 -(pump_side_thick + pump_side_height)])
  88       cylinder(r=pump_main_dia/2, h=200);
  89   }
  90 }
  91
  92 module HoseSideElevation(){
  93   or = hose_head_dia/2 + hose_side_thick;
  94
  95   x3 = 0;
  96   x4 = x3 + hose_base_offset;
  97   x5 = x4 + hose_head_dia/2;
  98   x6 = x4 + hose_head_dia;
  99   x7 = x5 + or;
 100
 101   z0 = 0;
 102   zm = -or;
 103
 104   difference(){
 105     intersection(){
 106       translate([-100,-100]) square([x7+210, 100]);
 107       hull(){
 108         translate([x5, 0]) circle(r=or);
 109         translate([-1, zm]) square([1,z0-zm]);
 110       }
 111     }
 112     translate([x5,0]) circle(r=hose_head_dia/2);
 113   }
 114 }
 115
 116 module HoseSide(){
 117   for (m=[0,1]) {
 118     mirror([0,m,0])
 119       translate([0, hose_head_width, 0])
 120       rotate([90,0,0])
 121       linear_extrude(height= hose_side_width)
 122       HoseSideElevation();
 123   }
 124 }
 125
 126 module Clip(){
 127   PumpSide();
 128   HoseSide();
 129 }
 130
 131 module ClipPrint(){
 132   rotate([180,0,0])
 133     Clip();
 134 }
 135
 136 //PumpSidePlan();
 137 //PumpSideElevation();
 138 //HoseSideElevation();
 139 //PumpSide();
 140 //HoseSide();
 141 //Clip();
 142 ClipPrint();