sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 tile_th = 3;
  11 post_dia = 8;
  12
  13 post_shorter = 1;
  14
  15 screw_dia = 2.2;
  16 screw_big_dia = 3.6;
  17 screw_big_len = 4.0;
  18
  19 round_edge_rad = 2.0;
  20
  21 round_cnr_rad = 10;
  22
  23 interlock_dia = 10;
  24 interlock_fine = 0.66;
  25
  26 interlock_fine_slope = 1.0;
  27 interlock_fine_lenslop = 1.0;
  28
  29 demo_slop = 0.1;
  30
  31 // cutout
  32
  33 machine_rear_to_front = 85;
  34
  35 machine_rear_profile = [
  36                         [ -  0,  -0.00 ],
  37                         [ -  2,  -0.10 ],
  38                         [ -  4,  -0.20 ],
  39                         [ -  5,  -0.30 ],
  40                         [ -  6,  -0.40 ],
  41                         [ -  7,  -0.50 ],
  42                         [ -  8,  -0.75 ],
  43                         [ - 10,  -1.50 ],
  44                         [ - 12,  -2.25 ],
  45                         [ - 14,  -3.25 ],
  46                         [ - 16,  -4.25 ],
  47                         [ - 18,  -5.75 ],
  48                         [ - 20,  -8.00 ]
  49                         ];
  50
  51 machine_front_profile =  [
  52                           [  128,  -3.70,  ],
  53                           [  124,  -2.90,  ],
  54                           [  120,  -2.45,  ],
  55                           [  116,  -2.10,  ],
  56                           [  112,  -1.80,  ],
  57                           [  108,  -1.55,  ],
  58                           [  104,  -1.25,  ],
  59                           [  100,  -1.00,  ],
  60                           [   96,  -0.80,  ],
  61                           [   92,  -0.65,  ],
  62                           [   88,  -0.55,  ],
  63                           [   84,  -0.50,  ]
  64                           ];
  65
  66 cutout_l_end_y_front_slop = 0.5;
  67 cutout_l_end_y_rear_slop = 0.5;
  68 cutout_l_end_x_slop = 0.25;
  69
  70 cutout_l_end_x = 22;
  71 cutout_l_end_y = machine_rear_to_front;
  72 cutout_l_end_curve = 1;
  73 cutout_l_end_y_total = cutout_l_end_y
  74   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  75
  76 tile02_tr = [-250, 0];
  77 tile01_tr = [  0, 0];
  78
  79 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  80 cutout_tile11_x = cutout_l_end_x + cutout_l_end_curve;
  81 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  82
  83 // front and rear curves
  84
  85 rearedge_len = 170;
  86
  87 rearcurve_strt_len = 52;
  88
  89 rearcurve_z_slop = 0.75;
  90
  91 rearcurve_avoid_y = 35;
  92
  93 rearcurve_double_inrad = 26.10 + 8.04;
  94
  95 reartablet_z = 2.54;
  96 reartablet_x = 5 + 1;
  97 reartablet_y = 5;
  98
  99 frontcurve_side_skew = 3.5 / 72;
 100 frontcurve_avoid_y = 70;
 101 frontcurve_z_slop = 0.75;
 102
 103 // calculated
 104
 105 TEST = false;
 106
 107 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
 108
 109 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
 110
 111 hole_slop = (ply_hole_dia - post_dia)/2;
 112 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
 113
 114 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
 115          tile_hard_edge_hole_dist));
 116
 117 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
 118          tile_hard_edge_hole_dist + round_edge_rad));
 119
 120 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
 121 thehd_tr = thehd;
 122 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 123 thehd_bl = -thehd_tr;
 124 thehd_br = -thehd_tl;
 125
 126 interlock_rad = interlock_dia/2;
 127 interlock_negative_rad = interlock_rad + 0.125;
 128
 129 interlock_sq_adj = 0.2; // arbitrary
 130
 131 first_front = machine_front_profile[len(machine_front_profile)-1];
 132
 133 m4_define(`POST_TCROSSSZ',
 134           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 135
 136 module Post(){
 137   mirror([0,0,1]) {
 138     difference(){
 139       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 140       translate([0,0, tile_th]) {
 141         cylinder(r= screw_big_dia/2, h= screw_big_len);
 142         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
 143       }
 144     }
 145     if (TEST) {
 146       translate([0,0, tile_th/2]) {
 147         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 148         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 149       }
 150     }
 151   }
 152 }
 153
 154 module Posts(posts) {
 155   for (p= posts) {
 156     translate(concat(p, [0]))
 157       Post();
 158   }
 159 }
 160
 161 module TileBase(botleft, topright){
 162   size = topright - botleft;
 163   botleft_post = botleft + thehd_tr;
 164   topright_post = topright + thehd_bl;
 165   difference(){
 166     mirror([0,0,1])
 167       translate(concat(botleft, [0]))
 168       cube(concat(size, [tile_th]));
 169     if (!TEST) {
 170       translate( concat(botleft_post, [ -tile_th ])
 171                  + 0.5 * [ post_dia, post_dia, 0 ] )
 172         Commitid_BestCount_M( topright_post-botleft_post
 173                               + [-post_dia,-post_dia]
 174                               + [0, thehd[1]]);
 175     }
 176     if (TEST) {
 177       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
 178       translate( concat(botleft + [crossoff, 0], [0]) )
 179         Commitid_BestCount([ size[0] - 2*crossoff, thehd[1] ]);
 180       difference(){
 181         mirror([0,0,1]) {
 182           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 183             cube(concat(size - [test_edge,test_edge]*2, [tile_th]));
 184           translate(concat(botleft_post, [-1]))
 185             cube(concat(topright_post-botleft_post, [tile_th+2]));
 186         }
 187         minkowski(){
 188           Machine();
 189           cube(max(test_edge, tile_hard_edge_hole_dist)*2, center=true);
 190         }
 191       }
 192     }
 193   }
 194 }
 195
 196 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 197 m4_define(`INREFFRAME',`
 198   length_vec = ($2) - ($1);
 199   length = dist2d([0,0], length_vec);
 200   length_uvec = length_vec / length;
 201   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 202   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 203         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 204         [ 0,              0,              1,            0, ],
 205         [ 0,              0,              0,            1, ] ];
 206   $3
 207   multmatrix(m)
 208 ')
 209
 210 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 211 m4_dnl    INREFFRAME_EDGE { body; }
 212 m4_define(`INREFFRAME_EDGE',`
 213   translate([0,0, -round_edge_rad])
 214 ')
 215
 216 module RoundEdge(left_cnr, right_cnr) {
 217   INREFFRAME(left_cnr, right_cnr)
 218     INREFFRAME_EDGE {
 219     difference(){
 220       rotate([0,90,0])
 221         cylinder(r= round_edge_rad, h= length, $fn=50);
 222       translate([-1, 0, -20])
 223         cube([length+2, 20, 20]);
 224     }
 225   }
 226 }
 227
 228 module RoundCornerCut(ci) {
 229   // ci should be [this_cnr, right_cnr]
 230   // where right_cnr is to the right (ie, anticlockwise)
 231   this_cnr = ci[0];
 232   right_cnr = ci[1];
 233   offr= round_cnr_rad - round_edge_rad;
 234   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 235     difference(){
 236       cube(offr*2 - 0.1, center=true);
 237       translate([offr, offr, 0])
 238         cylinder(center=true, h=20, r= offr);
 239     }
 240   }
 241 }
 242
 243 module RoundCornerAdd(ci) {
 244   this_cnr = ci[0];
 245   right_cnr = ci[1];
 246   bigr = round_cnr_rad - round_edge_rad;
 247   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 248     intersection(){
 249       cube(bigr*2 + 0.1, center=true);
 250       translate([bigr, bigr, 0])
 251         rotate_extrude(convexity=10, $fn=50)
 252         translate([bigr, 0])
 253         difference(){
 254           circle(r= round_edge_rad, $fn=50);
 255           mirror([1,1])
 256             square([20,20]);
 257         }
 258     }
 259   }
 260 }
 261
 262 module InterlockLobePlan(negative) {
 263   r = negative ? interlock_negative_rad : interlock_rad;
 264   ymir = negative ? 0 : 1;
 265
 266   dx = sqrt(3) * r;
 267   $fn= 80;
 268   translate([thehd[0], 0]){
 269     mirror([0,ymir]){
 270       circle(r=r);
 271       difference(){
 272         translate([-dx, -0.1])
 273           square([ dx*2, r/2 + 0.1 ]);
 274         for (xi = [-1, 1]) {
 275           translate([ xi*dx, r ])
 276             circle(r=r);
 277         }
 278       }
 279     }
 280   }
 281 }
 282
 283 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 284   for (lobei = [ 0 : nlobes-1 ]) {
 285     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 286     translate([lobex, 0, 0]) {
 287       InterlockLobePlan(negative);
 288     }
 289   }
 290
 291   if (dosquare) {
 292     iadj = 0;
 293     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 294     mirror([0, negative])
 295       translate([slotshorter, iadj])
 296       square([length - slotshorter*2, interlock_fine + iadj*2]);
 297   }
 298 }
 299
 300 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 301   plusth = negative * 1.0;
 302   protr = interlock_fine + interlock_sq_adj;
 303
 304   z2 = -tile_th/2;
 305   z1 = -tile_th/2 - protr / interlock_fine_slope;
 306   z3 = -tile_th/2 + protr / interlock_fine_slope;
 307
 308   negsign = negative ? -1 : +1;
 309   yprotr = negsign * protr;
 310
 311   INREFFRAME(left_cnr, right_cnr) {
 312     for (vsect = [ // zs0            zs1      ys0,            ys1
 313                   [ -tile_th-plusth, plusth,  0,              0],
 314                   [ z1,              z2,      0, yprotr],
 315                   [ z2,              z3,      yprotr, 0],
 316                   ]) {
 317       zs0 = vsect[0];
 318       zs1 = vsect[1];
 319       zsd = zs1-zs0;
 320       ys0 = vsect[2];
 321       ys1 = vsect[3];
 322       ysd = ys1-ys0;
 323       sl = ysd/zsd;
 324       m = [ [ 1,0,   0,    0 ],
 325             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 326             [ 0,0,   1,  zs0 ],
 327             [ 0,0,   0,    1 ] ];
 328       multmatrix(m)
 329         linear_extrude(height=zsd, convexity=10)
 330         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 331     }
 332   }
 333 }
 334
 335 function TestPiece_holes2corners(holes) =
 336   [ holes[0] + thehd_bl,
 337     holes[1] + thehd_br,
 338     holes[1] + thehd_tr,
 339     holes[0] + thehd_tl ];
 340
 341 module TestPiece1(){ ////toplevel
 342   holes = [ [-100, 0],
 343             [   0, 0]
 344             ];
 345   corners = TestPiece_holes2corners(holes);
 346   rcs = [corners[0], corners[1]];
 347   difference(){
 348     union(){
 349       TileBase(corners[0], corners[2]);
 350       Posts(holes);
 351       RoundEdge(corners[0], corners[1]);
 352       RoundEdge(corners[3], corners[0]);
 353     }
 354     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 355     RoundCornerCut(rcs);
 356   }
 357   RoundCornerAdd(rcs);
 358 }
 359
 360 module TestPiece2(){ ////toplevel
 361   holes = [ [   0, 0],
 362             [  50, 0]
 363             ];
 364   corners = TestPiece_holes2corners(holes);
 365   TileBase(corners[0], corners[2]);
 366   Posts(holes);
 367   RoundEdge(corners[0], corners[1]);
 368   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 369 }
 370
 371 module TestDemo(){ ////toplevel
 372   translate([ -thehd[0], 0 ])
 373     color("blue")
 374     TestPiece1();
 375   translate([ +thehd[0] + demo_slop, 0 ])
 376     TestPiece2();
 377 }
 378
 379 module Machine_Arm(){
 380   ysz = cutout_l_end_y_total;
 381   // assume the round end is arc of a circle
 382   chordlen = dist2d([0,0], [ cutout_l_end_y, cutout_l_end_curve ]);
 383   endrad = cutout_l_end_y / cutout_l_end_curve * chordlen;
 384
 385   translate([0,0,-30]) linear_extrude(height=60) {
 386     translate(tile01_tr + [0, (-cutout_tile01_y + cutout_tile11_y)/2]) {
 387       intersection(){
 388         translate([-100, -ysz/2])
 389           square([400, ysz]);
 390         translate([ endrad - cutout_tile11_x - cutout_l_end_x_slop, 0 ])
 391           circle(r=endrad, $fa=0.01,$fd=5);
 392       }
 393     }
 394   }
 395 }
 396
 397 module Machine_Profile(){
 398   first_rear = machine_rear_profile[0];
 399   below_point = 0.5 * ( first_rear + first_front ) + [ 0, -10 ];
 400   pol = concat( machine_rear_profile,
 401                 [ below_point ],
 402                 machine_front_profile);
 403   skew_angle = atan2( first_front[1] - first_rear[1],
 404                       first_front[0] - first_rear[0] );
 405   echo(below_point, pol, skew_angle);
 406   hull(){
 407     for (z=[0,-40]) {
 408       translate([0,z]) {
 409         //scale([1,5])
 410         rotate([0,0, -skew_angle ]){
 411           //translate( - first_front )
 412           polygon(pol);
 413         }
 414       }
 415     }
 416   }
 417 }
 418
 419 module Machine_RearProfile(){
 420   intersection(){
 421     Machine_Profile();
 422     translate([ -200 + machine_rear_to_front/2, -100 ]) {
 423       square([200,200]);
 424     }
 425   }
 426 }
 427
 428 module Machine_FrontProfile(){
 429   intersection(){
 430     Machine_Profile();
 431     translate([ machine_rear_to_front/2, -100 ]) {
 432       square([200,200]);
 433     }
 434   }
 435 }
 436
 437 module Machine_Curves(){ ////toplevel
 438   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 439               cutout_tile11_y,
 440               0 ]){
 441     //%cube([20,20,20]);
 442     translate([ -reartablet_x,
 443                 -1,
 444                 -reartablet_z])
 445       mirror([0,0,1])
 446       cube([ reartablet_x+1,
 447              reartablet_y+1,
 448              20 ]);
 449   }
 450   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 451               cutout_tile11_y,
 452               frontcurve_z_slop ]){
 453     translate([ 0, -first_front[0] , 0 ])
 454       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 455                   [0,  1,   0, 0],
 456                   [0,  0,   1, 0],
 457                   [0,  0,   0, 1]])
 458       translate([ 0, first_front[0] , 0 ])
 459       mirror([1,0,0]){
 460       rotate([0,-90,0])rotate([0,0,-90]){
 461         linear_extrude(height= 200)
 462           Machine_FrontProfile();
 463       }
 464     }
 465     translate([ rearcurve_strt_len,
 466                 0,
 467                 rearcurve_z_slop ]){
 468       translate([ 1,
 469                   0,
 470                   0
 471                   ]){
 472         rotate([0,-90,0])rotate([0,0,-90]){
 473           linear_extrude(height= rearcurve_strt_len + 1)
 474           Machine_RearProfile();
 475         }
 476       }
 477       translate([ 0,
 478                   0,
 479                   rearcurve_double_inrad ]) {
 480         intersection(){
 481           rotate([90,0,0]){
 482             rotate_extrude(convexity=10, $fn=32) {
 483               rotate([0,0,90]) translate([ 0,
 484                           -rearcurve_double_inrad ]) {
 485                 Machine_RearProfile();
 486               }
 487             }
 488           }
 489           mirror([0,0,1])
 490             translate([0,-75,0]) cube([150,150,150]);
 491         }
 492       }
 493     }
 494   }
 495 }
 496
 497 module Machine(){ ////toplevel
 498   Machine_Arm();
 499   Machine_Curves();
 500 }
 501
 502 function Rectangle_corners(c0, sz) =
 503   // returns the corners of a rectangle from c0 to c0+sz
 504   // if sz is positive, the corners are anticlockwise starting with c0
 505   [ c0 + [ 0,     0     ],
 506     c0 + [ sz[0], 0     ],
 507     c0 + [ sz[0], sz[1] ],
 508     c0 + [ 0,     sz[1] ] ];
 509
 510 function Rectangle_corners2posts(c) =
 511   [ c[0] + thehd_tr,
 512     c[1] + thehd_tl,
 513     c[2] + thehd_bl,
 514     c[3] + thehd_br ];
 515
 516 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 517
 518 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 519
 520 m4_dnl   R_EDGE(c,ix)
 521 m4_dnl        c is from Rectangle_corners and
 522 m4_dnl        ix is a corner number
 523 m4_dnl    expands to two comma-separated corners:
 524 m4_dnl    that denoted by ix, and the next one anticlockwise
 525 m4_define(`R_EDGE',`$1[$2],$1[(($2)+1)%4]')
 526
 527 module Tile02(){ ////toplevel
 528   sz = [100,170];
 529   c0 = tile02_tr + -sz;
 530   c = Rectangle_corners(c0, sz);
 531   posts = Rectangle_corners2posts(c);
 532   rcs = [R_EDGE(c,0)];
 533   difference(){
 534     union(){
 535       Rectangle_TileBase(c);
 536       Posts(posts);
 537       RoundEdge(R_EDGE(c,0));
 538       RoundEdge(R_EDGE(c,3));
 539       InterlockEdge(R_EDGE(c,2), 0);
 540     }
 541     InterlockEdge(R_EDGE(c,1), 1);
 542     RoundCornerCut(rcs);
 543   }
 544   RoundCornerAdd(rcs);
 545 }
 546
 547 module Tile12(){ ////toplevel
 548   sz = [100,250];
 549   c0 = tile02_tr + [-sz[0], 0];
 550   c = Rectangle_corners(c0, sz);
 551   posts = Rectangle_corners2posts(c);
 552   rcs = [R_EDGE(c,3)];
 553   difference(){
 554     union(){
 555       Rectangle_TileBase(c);
 556       Posts(posts);
 557       RoundEdge(R_EDGE(c,2));
 558       RoundEdge(R_EDGE(c,3));
 559     }
 560     InterlockEdge(R_EDGE(c,0), 1);
 561     InterlockEdge(R_EDGE(c,1), 1);
 562     RoundCornerCut(rcs);
 563   }
 564   RoundCornerAdd(rcs);
 565 }
 566
 567 tile_01_11_cnr = tile01_tr + [-cutout_tile11_x, 0];
 568 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 569 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 570
 571 module Tile11(){ ////toplevel
 572   sz = [250,250];
 573   c0 = tile01_tr + [-sz[0],0];
 574   c = Rectangle_corners(c0, sz);
 575   cnr_posts = Rectangle_corners2posts(c);
 576   posts = concat(
 577                  Posts_interpolate_one(cnr_posts[0],
 578                                        cnr_posts[1] - [cutout_tile11_x, 0]),
 579                  [ cnr_posts[1] + [0, cutout_tile11_y],
 580                    cnr_posts[2],
 581                    cnr_posts[3]
 582                    ]);
 583   difference(){
 584     union(){
 585       Rectangle_TileBase(c);
 586       Posts(posts);
 587       RoundEdge(R_EDGE(c,2));
 588       InterlockEdge(R_EDGE(c,3));
 589     }
 590     InterlockEdge(c[0], tile_01_11_cnr, 1);
 591     InterlockEdge(tile_11_10_cnr, c[2], 1);
 592     Machine();
 593   }
 594 }
 595
 596 module Tile01(){ ////toplevel
 597   sz = [250,170];
 598   c0 = tile01_tr + -sz;
 599   c = Rectangle_corners(c0, sz);
 600   cnr_posts = Rectangle_corners2posts(c);
 601   posts = concat(
 602                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 603                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 604                  Posts_interpolate_one(cnr_posts[2] - [cutout_tile11_x, 0],
 605                                        cnr_posts[3])
 606                  );
 607   difference(){
 608     union(){
 609       Rectangle_TileBase(c);
 610       Posts(posts);
 611       RoundEdge(R_EDGE(c,0));
 612       InterlockEdge(tile_01_11_cnr, c[3]);
 613       InterlockEdge(R_EDGE(c,3));
 614     }
 615     InterlockEdge(c[1], tile_01_00_cnr, 1);
 616     Machine();
 617   }
 618 }
 619
 620 module Tile10(){ ////toplevel
 621   sz = [250,250];
 622   c0 = tile01_tr + [0,0];
 623   c = Rectangle_corners(c0, sz);
 624   cnr_posts = Rectangle_corners2posts(c);
 625   cty = cutout_tile11_y;
 626   rcy = cty + rearcurve_avoid_y;
 627   posts = [ cnr_posts[0] + [ 0,                             cty ],
 628             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 629             cnr_posts[1] + [ 0,                             rcy ],
 630             cnr_posts[2],
 631             cnr_posts[3] ];
 632   rcs = [R_EDGE(c,2)];
 633   difference(){
 634     union(){
 635       Rectangle_TileBase(c);
 636       Posts(posts);
 637       RoundEdge(R_EDGE(c,1));
 638       RoundEdge(R_EDGE(c,2));
 639       InterlockEdge(c[3], tile_11_10_cnr);
 640     }
 641     RoundCornerCut(rcs);
 642     Machine();
 643   }
 644   RoundCornerAdd(rcs);
 645 }
 646
 647 module Tile00(){ ////toplevel
 648   sz = [250,170];
 649   c0 = tile01_tr + [0,-sz[1]];
 650   c = Rectangle_corners(c0, sz);
 651   cnr_posts = Rectangle_corners2posts(c);
 652   cty = cutout_tile01_y;
 653   rcy = cty + frontcurve_avoid_y;
 654   posts = [ cnr_posts[0],
 655             cnr_posts[1],
 656             cnr_posts[2] + [ 0,                             -rcy ],
 657             cnr_posts[2] + [ -sz[0] + rearedge_len - cutout_l_end_x, -cty ],
 658             cnr_posts[3] + [ 0,                             -cty ]
 659             ];
 660   rcs = [R_EDGE(c,1)];
 661   difference(){
 662     union(){
 663       Rectangle_TileBase(c);
 664       Posts(posts);
 665       RoundEdge(R_EDGE(c,0));
 666       RoundEdge(R_EDGE(c,1));
 667       InterlockEdge(tile_01_00_cnr, c[0]);
 668     }
 669     RoundCornerCut(rcs);
 670     Machine();
 671   }
 672   RoundCornerAdd(rcs);
 673 }
 674
 675 module Demo(){ ////toplevel
 676   translate(demo_slop*[-2,1]) color("blue") Tile12();
 677   translate(demo_slop*[-2,0]) color("red")  Tile02();
 678   translate(demo_slop*[-2,1]) color("orange") Tile11();
 679   translate(demo_slop*[-2,0]) color("purple") Tile01();
 680   translate(demo_slop*[-3,1]) color("blue")   Tile10();
 681   translate(demo_slop*[-3,0]) color("red")    Tile00();
 682   %Machine();
 683 }
 684
 685 //TestPiece1();
 686 //TestPiece2();
 687 //Demo();
 688
 689 //Machine_Profile();
 690 //Machine_RearProfile();