sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 ply_hole_dia_real = 12;
  11
  12 tile_th = 3;
  13 post_dia = 8;
  14
  15 post_shorter = 1;
  16
  17 screw_dia = 2.2;
  18 screw_big_dia = 3.6;
  19 screw_big_len = 4.0;
  20
  21 round_edge_rad = 2.0;
  22
  23 round_cnr_rad = 10;
  24
  25 interlock_dia = 10;
  26 interlock_fine = 0.66;
  27
  28 interlock_fine_slope = 1.0;
  29 interlock_fine_lenslop = 1.0;
  30
  31 demo_slop = 0.1;
  32
  33 leg_height = 53.75 - 0.95;
  34
  35 leg_hole_dia = 5 + 0.75;
  36 leg_big_dia = 37;
  37 leg_bot_dia = 15;
  38 leg_top_flat_z = 2;
  39 leg_top_thick = 8;
  40
  41 leg_midspc_dia = 20;
  42 leg_bot_thick = 8;
  43 leg_bot_mid_dia = 12;
  44
  45 leg_fin_top_w = 3;
  46 leg_fin_bot_w = 5;
  47 leg_fin_bot_rad = 30;
  48 leg_fin_bot_flat_z = 5;
  49
  50 leg_n_fins = 4;
  51 leg_n_tubules = 4;
  52 leg_tubule_dia = 4;
  53
  54 // cutout
  55
  56 machine_rear_to_front = 84 + 0.25 - 1.4;
  57
  58 cutout_l_end_y_front_slop = 0.5;
  59 cutout_l_end_y_rear_slop = 0.5;
  60
  61 cutout_l_end_x = 22;
  62 cutout_l_end_y = machine_rear_to_front;
  63 cutout_l_end_new_x_slop = 1.4 - 1.95;
  64 cutout_l_end_y_total = cutout_l_end_y
  65   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  66
  67 tile02_tr = [-250, 0];
  68 tile01_tr = [  0, 0];
  69
  70 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  71 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  72
  73 // front and rear curves
  74
  75 rearedge_len = 170 + 0.70;
  76 frontedge_len = 170;
  77
  78 rearcurve_strt_len = 52;
  79
  80 rearcurve_z_slop = -0.50;
  81
  82 rearcurve_avoid_y = 35;
  83
  84 rearcurve_double_inrad = 26.10 + 8.04;
  85
  86 reartablet_z = 2.54;
  87 reartablet_x = 5 + 1;
  88 reartablet_y = 8;
  89
  90 frontcurve_side_skew = 3.5 / 72;
  91 frontcurve_avoid_y = 70;
  92 frontcurve_z_slop = 0.75;
  93
  94 frontcurve_strt_len = 50;
  95 frontcurve_dualcurve_angle = 30;
  96
  97 teststrapslots_at = [ [ 110, 70 ], [ 110, -35 ],
  98                       [ 180, 90 ],
  99                       [ 190, -80 ], // do not change index of this one
 100                       [   0, 70 ],  [  0, -35 ],
 101                       ];
 102
 103 teststrap = [ 3, 5 ];
 104 teststrap_peg = [7.5, 3.5];
 105
 106 ply_edge_hole_dist_real = 14;
 107
 108 // calculated
 109
 110 TEST = false;
 111 JIG = false;
 112
 113 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
 114
 115 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
 116
 117 hole_slop = (ply_hole_dia - post_dia)/2;
 118 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
 119
 120 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
 121          tile_hard_edge_hole_dist));
 122
 123 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
 124          tile_hard_edge_hole_dist + round_edge_rad));
 125
 126 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
 127 thehd_tr = thehd;
 128 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 129 thehd_bl = -thehd_tr;
 130 thehd_br = -thehd_tl;
 131
 132 tablet_z_slop = 1.00;
 133
 134 interlock_rad = interlock_dia/2;
 135 interlock_negative_rad = interlock_rad + 0.125;
 136
 137 interlock_sq_adj = 0.2; // arbitrary
 138
 139 leg_fin_top_rad = sqrt( pow(leg_big_dia/2,2) -
 140                         pow(leg_fin_top_w/2,2) );
 141
 142 leg_tubule_pos_rad = leg_big_dia/2 * 0.6;
 143
 144 m4_define(`POST_TCROSSSZ',
 145           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 146
 147 module Post(){
 148   mirror([0,0,1]) {
 149     if (!JIG) {
 150       difference(){
 151         cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 152         translate([0,0, tile_th]) {
 153           cylinder(r= screw_big_dia/2, h= screw_big_len);
 154           cylinder(r= screw_dia/2, h= ply_th, $fn=20);
 155         }
 156       }
 157     }
 158     if (TEST) {
 159       translate([0,0, tile_th/2]) {
 160         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 161         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 162       }
 163     }
 164     if (JIG) {
 165       translate([0,0, tile_th/2]) {
 166         cube([POST_TCROSSSZ, POST_TCROSSSZ, tile_th], center=true);
 167       }
 168     }
 169   }
 170 }
 171
 172 module PostHole(){
 173   if (JIG) {
 174     translate([0,0,-5])
 175       cylinder(r= post_dia/2 + jig_post_hole_slop, h=10);
 176     translate([0,0, -jig_min_th])
 177       cylinder(r= ply_hole_dia_real/2, h = 5);
 178     for (rot=[0:90:270]) rotate(rot) {
 179         translate([ ply_edge_hole_dist_real, 0, 0 ])
 180           cube([ jig_pencil_rad*2, jig_pencil_slotlen, 20 ], center=true);
 181       }
 182   }
 183 }
 184
 185 module Posts(posts) {
 186   for (p= posts) {
 187     translate(concat(p, [0]))
 188       Post();
 189   }
 190 }
 191 module PostHoles(posts) {
 192   for (p= posts)  {
 193     translate(concat(p, [0]))
 194       PostHole();
 195   }
 196 }
 197
 198 module TileBase(botleft, topright){
 199   size = topright - botleft;
 200   botleft_post = botleft + thehd_tr;
 201   topright_post = topright + thehd_bl;
 202   difference(){
 203     mirror([0,0,1])
 204       translate(concat(botleft, [0]))
 205       cube(concat(size, [tile_th]));
 206     if (!(TEST || JIG)) {
 207       cidsz = topright_post-botleft_post
 208         + [-post_dia,-post_dia]
 209         + [0, thehd[1]];
 210       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
 211       echo("CID",cidsz,cidszr);
 212       translate( concat(botleft_post, [ -tile_th ])
 213                  + 0.5 * [ post_dia, post_dia, 0 ]
 214                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
 215         Commitid_BestCount_M(cidszr);
 216     }
 217     if ((TEST || JIG)) {
 218       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
 219       cidsz = [ thehd[0], size[1] - 2*crossoff ];
 220       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
 221       if (TEST)
 222         translate( concat(botleft + [0, crossoff] + (cidsz-cidszr)/2, [0]) )
 223           Commitid_BestCount(cidszr);
 224       difference(){
 225         mirror([0,0,1]) {
 226           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 227             cube(concat(size - [test_edge,test_edge]*2, [tile_th*2]));
 228           translate(concat(botleft_post, [-1]))
 229             cube(concat(topright_post-botleft_post, [tile_th+2]));
 230         }
 231         shufflesz = max(test_edge, tile_hard_edge_hole_dist)*2;
 232         minkowski(){
 233           MachineEnvelope();
 234           cube(shufflesz, center=true);
 235         }
 236         if (JIG) {
 237           translate([0,0,-20]) linear_extrude(height=20) {
 238             for (diag=[[ +1, botleft                   ],
 239                        [ -1, [topright[0], botleft[1]] ]]) {
 240               translate(diag[1])
 241                 rotate(atan2(size[1], diag[0] * size[0]))
 242                 translate([0, -test_edge/2])
 243                 square([vectorlen2d(size), test_edge]);
 244             }
 245           }
 246         }
 247       }
 248     }
 249   }
 250 }
 251
 252 m4_dnl   R_EDGE(c,ix)
 253 m4_dnl        c is from Rectangle_corners and
 254 m4_dnl        ix is a corner number
 255 m4_dnl    expands to two comma-separated corners:
 256 m4_dnl    that denoted by ix, and the next one anticlockwise
 257 m4_define(`R_EDGE',`$1[$2], $1[(($2)+1)%4]')
 258
 259 m4_dnl   R_CNR(c,ix)
 260 m4_dnl        c is from Rectangle_corners and
 261 m4_dnl        ix is a corner number
 262 m4_dnl    expands to an array of corners as for RoundCorner
 263 m4_define(`R_CNR',`[ $1[$2], $1[(($2)+1)%4], $1[(($2)+3)%4] ]')
 264
 265 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 266 m4_define(`INREFFRAME',`
 267   length_vec = ($2) - ($1);
 268   length = dist2d([0,0], length_vec);
 269   length_uvec = length_vec / length;
 270   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 271   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 272         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 273         [ 0,              0,              1,            0, ],
 274         [ 0,              0,              0,            1, ] ];
 275   $3
 276   multmatrix(m)
 277 ')
 278
 279 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 280 m4_dnl    INREFFRAME_EDGE { body; }
 281 m4_define(`INREFFRAME_EDGE',`
 282   translate([0,0, -round_edge_rad])
 283 ')
 284
 285 module RoundEdge(left_cnr, right_cnr) {
 286   INREFFRAME(left_cnr, right_cnr)
 287     INREFFRAME_EDGE {
 288     difference(){
 289       rotate([0,90,0])
 290         cylinder(r= round_edge_rad, h= length, $fn=50);
 291       translate([-1, 0, -20])
 292         cube([length+2, 20, 20]);
 293     }
 294   }
 295 }
 296
 297 m4_define(`ROUNDCORNER_VARS',`
 298   this_cnr = ci[0];
 299   right_cnr = ci[1];
 300   left_cnr = ci[2];
 301   bigr= round_cnr_rad - round_edge_rad;
 302   l_uvec = unitvector2d(left_cnr - this_cnr);
 303   r_uvec = unitvector2d(right_cnr - this_cnr);
 304   lp1 = left_cnr  + clockwise2d(l_uvec) * bigr;
 305   lp2 = this_cnr  + clockwise2d(l_uvec) * bigr;
 306   lp3 = this_cnr  - clockwise2d(r_uvec) * bigr;
 307   lp4 = right_cnr - clockwise2d(r_uvec) * bigr;
 308   ctr = line_intersection_2d(lp1,lp2,lp3,lp4);
 309   ctr3 = concat(ctr,[0])
 310 ')
 311
 312 module RoundCorner_selector(ci, adj) {
 313   ROUNDCORNER_VARS;
 314   intersection(){
 315     union(){
 316       INREFFRAME(ctr3,concat(lp1,[4])){
 317         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 318           translate([-bigr*2 + adj, -bigr])
 319             square([bigr*2, bigr*3]);
 320         }
 321       }
 322     }
 323     union(){
 324       INREFFRAME(ctr3,concat(lp4,[0])){
 325         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 326           translate([-bigr*2, -bigr*2])
 327             square([bigr*2 + adj, bigr*3]);
 328         }
 329       }
 330     }
 331   }
 332 }
 333
 334 module RoundCornerCut(ci) {
 335   // ci should be [this_cnr, right_cnr, left_cnr]
 336   // where right_cnr is to the right (ie, anticlockwise)
 337   ROUNDCORNER_VARS;
 338   difference(){
 339     RoundCorner_selector(ci, -0.1);
 340     translate(ctr3)
 341       cylinder(center=true, h=20, r= bigr);
 342   }
 343 }
 344
 345 module RoundCornerAdd(ci) {
 346   ROUNDCORNER_VARS;
 347   intersection(){
 348     RoundCorner_selector(ci, +0.1);
 349     INREFFRAME_EDGE {
 350       translate(ctr3){
 351         rotate_extrude(convexity=10, $fn=50)
 352           translate([bigr, 0])
 353           difference(){
 354           circle(r= round_edge_rad, $fn=50);
 355           mirror([1,1])
 356             square([20,20]);
 357         }
 358       }
 359     }
 360   }
 361 }
 362
 363 module InterlockLobePlan(negative) {
 364   r = negative ? interlock_negative_rad : interlock_rad;
 365   ymir = negative ? 0 : 1;
 366
 367   dx = sqrt(3) * r;
 368   $fn= 80;
 369   translate([thehd[0], 0]){
 370     mirror([0,ymir]){
 371       circle(r=r);
 372       difference(){
 373         translate([-dx, -0.1])
 374           square([ dx*2, r/2 + 0.1 ]);
 375         for (xi = [-1, 1]) {
 376           translate([ xi*dx, r ])
 377             circle(r=r);
 378         }
 379       }
 380     }
 381   }
 382 }
 383
 384 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 385   for (lobei = [ 0 : nlobes-1 ]) {
 386     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 387     translate([lobex, 0, 0]) {
 388       InterlockLobePlan(negative);
 389     }
 390   }
 391
 392   if (dosquare) {
 393     iadj = 0;
 394     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 395     mirror([0, negative])
 396       translate([slotshorter, iadj])
 397       square([length - slotshorter*2, interlock_fine + iadj*2]);
 398   }
 399 }
 400
 401 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 402   plusth = negative * 1.0;
 403   protr = interlock_fine + interlock_sq_adj;
 404
 405   z2 = -tile_th/2;
 406   z1 = -tile_th/2 - protr / interlock_fine_slope;
 407   z3 = -tile_th/2 + protr / interlock_fine_slope;
 408
 409   negsign = negative ? -1 : +1;
 410   yprotr = negsign * protr;
 411
 412   INREFFRAME(left_cnr, right_cnr) {
 413     for (vsect = [ // zs0            zs1      ys0,            ys1
 414                   [ -tile_th-plusth, plusth,  0,              0],
 415                   [ z1,              z2,      0, yprotr],
 416                   [ z2,              z3,      yprotr, 0],
 417                   ]) {
 418       zs0 = vsect[0];
 419       zs1 = vsect[1];
 420       zsd = zs1-zs0;
 421       ys0 = vsect[2];
 422       ys1 = vsect[3];
 423       ysd = ys1-ys0;
 424       sl = ysd/zsd;
 425       m = [ [ 1,0,   0,    0 ],
 426             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 427             [ 0,0,   1,  zs0 ],
 428             [ 0,0,   0,    1 ] ];
 429       multmatrix(m)
 430         linear_extrude(height=zsd, convexity=10)
 431         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 432     }
 433   }
 434 }
 435
 436 function TestPiece_holes2corners(holes) =
 437   [ holes[0] + thehd_bl,
 438     holes[1] + thehd_br,
 439     holes[1] + thehd_tr,
 440     holes[0] + thehd_tl ];
 441
 442 module TestPiece1(){ ////toplevel
 443   holes = [ [-100, 0],
 444             [   0, 0]
 445             ];
 446   corners = TestPiece_holes2corners(holes);
 447   rcs = R_CNR(corners,0);
 448   difference(){
 449     union(){
 450       TileBase(corners[0], corners[2]);
 451       Posts(holes);
 452       RoundEdge(corners[0], corners[1]);
 453       RoundEdge(corners[3], corners[0]);
 454     }
 455     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 456     RoundCornerCut(rcs);
 457     PostHoles(holes);
 458   }
 459   RoundCornerAdd(rcs);
 460 }
 461
 462 module TestPiece2(){ ////toplevel
 463   holes = [ [   0, 0],
 464             [  50, 0]
 465             ];
 466   corners = TestPiece_holes2corners(holes);
 467   difference(){
 468     union(){
 469       TileBase(corners[0], corners[2]);
 470       Posts(holes);
 471       RoundEdge(corners[0], corners[1]);
 472       InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 473     }
 474     PostHoles(holes);
 475   }
 476 }
 477
 478 module TestDemo(){ ////toplevel
 479   translate([ -thehd[0], 0 ])
 480     color("blue")
 481     TestPiece1();
 482   translate([ +thehd[0] + demo_slop, 0 ])
 483     TestPiece2();
 484 }
 485
 486 module PostTestPiece(){ ////toplevel
 487   holes = [ [   0, 0] ];
 488   holes_forcnrs = concat(holes, [ [1, 0] ]);
 489   corners = TestPiece_holes2corners(holes_forcnrs);
 490   difference(){
 491     union(){
 492       TileBase(corners[0], corners[2]);
 493       Posts(holes);
 494       RoundEdge(corners[0], corners[1]);
 495       InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 496     }
 497     PostHoles(holes);
 498   }
 499 }
 500
 501 module Machine_NewRearProfile(){
 502   // figures copied out of xfig edit boxes
 503   // best not to edit the posbox size if poss - just move it
 504   posbox = 10 * ([7.2333,-14.1267] - [-16.2289,40.0289]); // box, Green
 505   sideline = -10 * ([-6.2400,13.5600] - [-2.4467,28.2556]); // line, Blue
 506   scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
 507   scaleline_mm = 12+5+10+5+3;
 508   sh = -[abs(posbox[0]), abs(posbox[1])];
 509   rot = atan2(-sideline[0], sideline[1]);
 510   sc = scaleline_mm / scaleline;
 511   //echo("SH",sh,rot,sc);
 512   scale(sc) rotate(rot) translate(sh){
 513     import("sewing-table-rear-profile.dxf", convexity=10); // spline, Pink3
 514   }
 515 }
 516
 517 module Machine_NewFrontProfile(){
 518   // figures copied out of xfig edit boxes
 519   // best not to edit the posbox size if poss - just move it
 520   posbox = 10 * ([11.8022,8.0600] - [4.2044,19.1867]); // box, Green
 521   refline = 10 * ([7.6778,16.7222] - [27.8689,17.6578]); // line, Blue
 522   refline_mm = (11-1)*10;
 523   sh = -[abs(posbox[0]), abs(posbox[1])];
 524   rot = atan2(-refline[0], refline[1]);
 525   sc = refline_mm / vectorlen2d(refline);
 526   //echo("SH",sh,rot,sc);
 527   mirror([1,0]) scale(sc) rotate(rot+90) translate(sh){
 528     import("sewing-table-front-profile.dxf", convexity=10); // spline, Pink3
 529   }
 530 }
 531
 532 module Machine_NewEndProfile(){
 533   // figures copied out of xfig edit boxes
 534   // NB that y coords are reversed - xfig origin is at bottom left
 535   posboxs = 10 * [[4.0400,17.7956], [11.6622,32.5511]]; // box, Pink3
 536   refline = 10 * ([8.4000,22.6000] - [50.3000,22.2000]); // line, Blue
 537   refline_mm = 10 * (11 - 2.5);
 538   sidelines = 10 * [[[9.0889,20.6178], [8.9644,14.6889]],
 539                     [[50.3800,21.9578], [50.1933,14.4933]]]; // lines, Blue3
 540   baseline = 10 * [[8.4000,18.0822], [50.3000,17.6822]]; // line, Green2
 541
 542   rot_adj = -0.38;
 543
 544   posbox = [min(posboxs[0][0],posboxs[1][0]),
 545             max(posboxs[0][1],posboxs[1][1])];
 546
 547   m4_define(`MNEP_ELP',
 548      `line_intersection_2d(baseline[0],baseline[1],
 549                            sidelines[$1][0],sidelines[$1][1])')
 550   endline = [MNEP_ELP(0),MNEP_ELP(1)];
 551
 552   rot = atan2(-refline[1], -refline[0]);
 553   sc = refline_mm / vectorlen2d(refline);
 554   sh = (0.5 * (endline[0] + endline[1])) - posbox;
 555
 556   ellen = sc * dist2d(endline[0],endline[1]);
 557   scy = cutout_l_end_y_total / ellen;
 558
 559   scale([scy,1]) scale(sc) rotate(rot + rot_adj) translate(-[sh[0],-sh[1]]){
 560
 561     mirror([0,1]){
 562   //%translate(1 * (posboxs[0] - posbox)) square(50);
 563   //%translate(1 * (posboxs[1] - posbox)) square(50);
 564 //  %translate(1 * (baseline[0] - posbox)) square([50,10]);
 565
 566 //  %translate(1 * (endline[0] - posbox)) square([50,10]);
 567 //  %translate(1 * (endline[1] - posbox)) square([50,10]);
 568
 569 //  %translate(1 * (sidelines[0][0] - posbox)) square([10,50]);
 570 //  %translate(1 * (sidelines[0][1] - posbox)) square([10,50]);
 571 //  %translate(1 * (sidelines[1][0] - posbox)) square([10,50]);
 572 //  %translate(1 * (sidelines[1][1] - posbox)) square([10,50]);
 573     }
 574
 575     import("sewing-table-end-profile.dxf", convexity=10); // spline, Pink3
 576   }
 577 }
 578
 579 module Machine_NewEndProfileDemo(){ ////toplevel
 580     translate([0,5,0])                             Machine_NewEndProfile();
 581     translate([0,5,1]) color("blue") mirror([1,0]) Machine_NewEndProfile();
 582   mirror([0,1,0]){
 583     translate([0,5, 0])                             Machine_NewEndProfile();
 584     translate([0,5,-1]) color("blue") mirror([1,0]) Machine_NewEndProfile();
 585   }
 586 }
 587
 588 module Machine_NewArm(){
 589   translate([0,0,-30]) linear_extrude(height=60) {
 590     translate(tile01_tr + [ -cutout_l_end_x - cutout_l_end_new_x_slop,
 591                             (-cutout_tile01_y + cutout_tile11_y)/2 ]){
 592       rotate(-90){
 593         hull(){
 594           for (d=[0,400])
 595             translate([0,d]) Machine_NewEndProfile();
 596         }
 597       }
 598     }
 599   }
 600 }
 601
 602 module Machine_NewRearCurve(){
 603   slant = atan2(4,210-10);
 604   //echo("SL",slant);
 605   translate([0,0, rearcurve_double_inrad]) rotate([slant,0,0]){
 606     translate([ rearcurve_double_inrad,
 607                 0,
 608                 -rearcurve_double_inrad + 10 ]){
 609       rotate([180,0,0]) rotate([0,0,90]) linear_extrude(height=30){
 610         hull(){
 611           Machine_NewRearProfile();
 612           translate([0,-100]) Machine_NewRearProfile();
 613         }
 614       }
 615     }
 616     rotate([0,90,0]) rotate([90,0,0]) {
 617       intersection(){
 618         rotate_extrude(convexity=10, $fn=64)
 619           rotate(90)
 620           translate([ 0, -rearcurve_double_inrad ])
 621           Machine_NewRearProfile();
 622         translate([0,0,-500])
 623           cube([500,500,1000]);
 624       }
 625     }
 626     translate([1,0,-rearcurve_double_inrad])
 627       rotate([0,-90,0]) rotate([0,0,-90])
 628       linear_extrude(height= rearcurve_strt_len + 1)
 629       Machine_NewRearProfile();
 630   }
 631 }
 632
 633 module Machine_Curves(){ ////toplevel
 634   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 635               cutout_tile11_y,
 636               0 ]){
 637     //%cube([20,20,20]);
 638     translate([ -reartablet_x,
 639                 -1,
 640                 -reartablet_z + tablet_z_slop])
 641       mirror([0,0,1])
 642       cube([ reartablet_x+1,
 643              reartablet_y+1,
 644              20 ]);
 645   }
 646   translate([ tile01_tr[0] - cutout_l_end_x + frontedge_len,
 647               cutout_tile11_y,
 648               frontcurve_z_slop ]){
 649     translate([0, -machine_rear_to_front, 0])
 650       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 651                   [0,  1,   0, 0],
 652                   [0,  0,   1, 0],
 653                   [0,  0,   0, 1]])
 654       mirror([1,0,0]) rotate([0,-90,0])rotate([0,0,-90])
 655       linear_extrude(height= 200)
 656       Machine_NewFrontProfile();
 657   }
 658   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 659               cutout_tile11_y,
 660               frontcurve_z_slop ]){
 661     translate([ rearcurve_strt_len,
 662                 0,
 663                 rearcurve_z_slop ]){
 664       Machine_NewRearCurve();
 665     }
 666   }
 667 }
 668
 669 module TestStrapSlots(){
 670   pegwidth = teststrap_peg[0];
 671   for (pos = teststrapslots_at) {
 672     echo("TSS",pos);
 673     translate(concat(pos,[0]))
 674       for (mx = [0,1]) mirror([mx,0,0]) {
 675           translate([ pegwidth/2, -teststrap[1]/2, -20 ])
 676             cube(concat(teststrap,[40]));
 677         }
 678   }
 679 }
 680
 681 module TestStrapPeg_any(l){ cube(concat([l],teststrap_peg)); }
 682
 683 module TestStrapPeg_Short(){ ////toplevel
 684   TestStrapPeg_any(35);
 685 }
 686
 687 module TestStrapPeg_Long(){ ////toplevel
 688   TestStrapPeg_any(60);
 689 }
 690
 691 module Machine(){ ////toplevel
 692   Machine_NewArm();
 693   Machine_Curves();
 694   if (TEST)
 695     TestStrapSlots();
 696 }
 697
 698 module MachineEnvelope(){
 699   // used for testing
 700   p_arm_bl = [-cutout_l_end_x, -cutout_tile01_y];
 701   y_arm_t  = cutout_tile11_y;
 702   p_crv_fl = p_arm_bl + [frontedge_len, -frontcurve_avoid_y];
 703   y_crv_b  = y_arm_t + rearcurve_avoid_y;
 704
 705   translate([0,0,-50]) linear_extrude(height= 100){
 706     translate(p_arm_bl) square([400, y_arm_t] - p_arm_bl);
 707     translate(p_crv_fl) square([400, y_crv_b] - p_crv_fl);
 708   }
 709 }
 710
 711 module Leg(){ ////toplevel
 712   difference(){
 713     union(){
 714       hull(){
 715         mirror([0,0,1])
 716           cylinder(r= leg_big_dia/2, h=leg_top_flat_z, $fn=100);
 717         translate([0,0, -leg_top_thick])
 718           cylinder(r= leg_bot_dia/2, height=1, $fn=100);
 719       }
 720       if (!TEST)
 721         translate([0,0,-leg_height])
 722           cylinder(r= leg_bot_mid_dia/2, h=leg_bot_thick);
 723       for (rot=[0: 360/leg_n_fins : 359]) rotate(rot) {
 724           hull(){
 725             mirror([0,0,1]) translate([0, -leg_fin_top_w/2, 0])
 726               cube([ leg_fin_top_rad - 0.1,
 727                      leg_fin_top_w,
 728                      1 ])
 729               ;
 730             translate([0, -leg_fin_bot_w/2, -leg_height])
 731               cube([ leg_fin_bot_rad,
 732                      leg_fin_bot_w,
 733                      leg_fin_bot_flat_z ]);
 734           }
 735         }
 736     }
 737     mirror([0,0,1]) translate([0,0,-1])
 738       cylinder(r= leg_hole_dia/2,
 739                h= (!TEST ? leg_height+2 : leg_height/2),
 740                $fn=30);
 741     mirror([0,0,1]) translate([0,0,leg_top_thick - 0.1])
 742       hull(){
 743         cylinder(r= (!TEST ? leg_midspc_dia/2 : 0.1),
 744                  h= leg_height - leg_top_thick - leg_bot_thick + 0.2,
 745                  $fn=30);
 746         if (TEST)
 747           cylinder(r= leg_midspc_dia/2,
 748                    h= leg_height - leg_top_thick - leg_bot_thick
 749                       + (!TEST ? 0.2 : -leg_midspc_dia/2),
 750                    $fn=30);
 751       }
 752     if (!TEST)
 753       for (rot=[45: 360/leg_n_tubules : 359]) rotate(rot) {
 754           mirror([0,0,1]) translate([ leg_tubule_pos_rad, 0, -1])
 755             cylinder(r= leg_tubule_dia/2, h=leg_height+2, $fn=20);
 756         }
 757   }
 758 }
 759
 760 function Rectangle_corners(c0, sz) =
 761   // returns the corners of a rectangle from c0 to c0+sz
 762   // if sz is positive, the corners are anticlockwise starting with c0
 763   [ c0 + [ 0,     0     ],
 764     c0 + [ sz[0], 0     ],
 765     c0 + [ sz[0], sz[1] ],
 766     c0 + [ 0,     sz[1] ] ];
 767
 768 function Rectangle_corners2posts(c) =
 769   [ c[0] + thehd_tr,
 770     c[1] + thehd_tl,
 771     c[2] + thehd_bl,
 772     c[3] + thehd_br ];
 773
 774 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 775
 776 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 777
 778 module Tile02(){ ////toplevel
 779   sz = [100,170];
 780   c0 = tile02_tr + -sz;
 781   c = Rectangle_corners(c0, sz);
 782   posts = Rectangle_corners2posts(c);
 783   rcs = R_CNR(c,0);
 784   difference(){
 785     union(){
 786       Rectangle_TileBase(c);
 787       Posts(posts);
 788       RoundEdge(R_EDGE(c,0));
 789       RoundEdge(R_EDGE(c,3));
 790       InterlockEdge(R_EDGE(c,2), 0);
 791     }
 792     InterlockEdge(R_EDGE(c,1), 1);
 793     RoundCornerCut(rcs);
 794     PostHoles(posts);
 795   }
 796   RoundCornerAdd(rcs);
 797 }
 798
 799 module Tile12(){ ////toplevel
 800   sz = [100,250];
 801   c0 = tile02_tr + [-sz[0], 0];
 802   c = Rectangle_corners(c0, sz);
 803   posts = Rectangle_corners2posts(c);
 804   rcs = R_CNR(c,3);
 805   difference(){
 806     union(){
 807       Rectangle_TileBase(c);
 808       Posts(posts);
 809       RoundEdge(R_EDGE(c,2));
 810       RoundEdge(R_EDGE(c,3));
 811     }
 812     InterlockEdge(R_EDGE(c,0), 1);
 813     InterlockEdge(R_EDGE(c,1), 1);
 814     RoundCornerCut(rcs);
 815     PostHoles(posts);
 816   }
 817   RoundCornerAdd(rcs);
 818 }
 819
 820 tile_01_11_cnr = tile01_tr + [-cutout_l_end_x, 0];
 821 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 822 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 823
 824 module Tile11(){ ////toplevel
 825   sz = [250,250];
 826   c0 = tile01_tr + [-sz[0],0];
 827   c = Rectangle_corners(c0, sz);
 828   cnr_posts = Rectangle_corners2posts(c);
 829   posts = concat(
 830                  Posts_interpolate_one(cnr_posts[0],
 831                                        cnr_posts[1] - [cutout_l_end_x, 0]),
 832                  [ cnr_posts[1] + [0, cutout_tile11_y],
 833                    cnr_posts[2],
 834                    cnr_posts[3]
 835                    ]);
 836   difference(){
 837     union(){
 838       Rectangle_TileBase(c);
 839       Posts(posts);
 840       RoundEdge(R_EDGE(c,2));
 841       InterlockEdge(R_EDGE(c,3));
 842     }
 843     InterlockEdge(c[0], tile_01_11_cnr, 1);
 844     InterlockEdge(tile_11_10_cnr, c[2], 1);
 845     PostHoles(posts);
 846     Machine();
 847   }
 848 }
 849
 850 module Tile01(){ ////toplevel
 851   sz = [250,170];
 852   c0 = tile01_tr + -sz;
 853   c = Rectangle_corners(c0, sz);
 854   cnr_posts = Rectangle_corners2posts(c);
 855   posts = concat(
 856                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 857                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 858                  Posts_interpolate_one(cnr_posts[2] - [cutout_l_end_x, 0],
 859                                        cnr_posts[3])
 860                  );
 861   difference(){
 862     union(){
 863       Rectangle_TileBase(c);
 864       Posts(posts);
 865       RoundEdge(R_EDGE(c,0));
 866       InterlockEdge(tile_01_11_cnr, c[3]);
 867       InterlockEdge(R_EDGE(c,3));
 868     }
 869     PostHoles(posts);
 870     InterlockEdge(c[1], tile_01_00_cnr, 1);
 871     Machine();
 872   }
 873 }
 874
 875 module Tile10(){ ////toplevel
 876   sz = [250,250];
 877   c0 = tile01_tr + [0,0];
 878   c = Rectangle_corners(c0, sz);
 879   cnr_posts = Rectangle_corners2posts(c);
 880   cty = cutout_tile11_y;
 881   rcy = cty + rearcurve_avoid_y;
 882   posts = [ cnr_posts[0] + [ 0,                             cty ],
 883             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 884             cnr_posts[1] + [ 0,                             rcy ],
 885             cnr_posts[2],
 886             cnr_posts[3] ];
 887   rcs = R_CNR(c,2);
 888   difference(){
 889     union(){
 890       Rectangle_TileBase(c);
 891       Posts(posts);
 892       RoundEdge(R_EDGE(c,1));
 893       RoundEdge(R_EDGE(c,2));
 894       InterlockEdge(c[3], tile_11_10_cnr);
 895     }
 896     PostHoles(posts);
 897     RoundCornerCut(rcs);
 898     Machine();
 899   }
 900   RoundCornerAdd(rcs);
 901 }
 902
 903 module Tile00(){ ////toplevel
 904   sz = [250,170];
 905   c0 = tile01_tr + [0,-sz[1]];
 906   c = Rectangle_corners(c0, sz);
 907
 908   // the edge c[1]..c[2] needs a diagonal chunk, from c1bis to c2bis
 909   c2bis = [ -cutout_l_end_x + frontedge_len + frontcurve_strt_len, c[2][1] ];
 910   c1bis = [ c[1][0],
 911             c[2][1] -
 912             (c[2][0] - c2bis[0]) * tan(90 - frontcurve_dualcurve_angle) ];
 913
 914   cnr_posts = Rectangle_corners2posts(c);
 915   cty = cutout_tile01_y;
 916   rcy = cty + frontcurve_avoid_y;
 917   posts = [ cnr_posts[0],
 918             cnr_posts[1],
 919             0.5 * (cnr_posts[0] + cnr_posts[1]),
 920             cnr_posts[2] + [ 0,                             -rcy ],
 921             cnr_posts[2] + [ -sz[0] + frontedge_len - cutout_l_end_x, -cty ],
 922             cnr_posts[3] + [ 0,                             -cty ]
 923             ];
 924   rcs = R_CNR(c,1);
 925   rc2 = [c1bis,c2bis,c[1]];
 926   difference(){
 927     union(){
 928       difference(){
 929         union(){
 930           Rectangle_TileBase(c);
 931           Posts(posts);
 932           RoundEdge(R_EDGE(c,0));
 933           RoundEdge(c[1], c1bis);
 934           InterlockEdge(tile_01_00_cnr, c[0]);
 935         }
 936         RoundCornerCut(rcs);
 937         translate([0,0,-20]) linear_extrude(height=40) {
 938           polygon([ c1bis, c1bis + [50,0], c2bis + [50,0], c2bis ]);
 939         }
 940       }
 941       RoundEdge(c1bis, c2bis);
 942     }
 943     Machine();
 944     PostHoles(posts);
 945     RoundCornerCut(rc2);
 946   }
 947   RoundCornerAdd(rcs);
 948   RoundCornerAdd(rc2);
 949 }
 950
 951 module FitTest_general(c0,sz, dobrace=false, bracexx=0){
 952   c = Rectangle_corners(c0, sz);
 953   brace = [7,7,9];
 954   bsz = sz + [bracexx,0,0];
 955   difference(){
 956     union(){
 957       Rectangle_TileBase(c);
 958       if (dobrace) {
 959         translate(concat(c0, [-brace[2] + 0.1])){
 960           difference(){
 961             cube(concat(bsz, [brace[2]]) - [5,0,0]);
 962             translate(brace + [0,0, -25])
 963               cube(concat(bsz, [50]) - brace*2 + [10,0,0]);
 964           }
 965         }
 966       }
 967       RoundEdge(R_EDGE(c,1));
 968     }
 969     Machine();
 970   }
 971 }
 972
 973 module FitTest_PairLink(cut=false){ ////toplevel
 974   cy0=-55; cy1=85; cx=132;
 975   bar = [10,10];
 976   legrad = 12;
 977   footrad_min = 1; footrad_max = 4; footrad_depth = 5;
 978   strap = [3,5];
 979   adj_neg_slop = 1.0;
 980   bar_z_slop = 1.75;
 981
 982   // calculated
 983   straphole_x_max = legrad/sqrt(2) + footrad_max;
 984   dz = cut ? adj_neg_slop : 0;
 985
 986   translate([cx - bar[0]/2, cy0, dz + bar_z_slop])
 987     cube([bar[0], cy1-cy0, bar[1] - bar_z_slop]);
 988
 989   for (endy=[cy0,cy1]) {
 990     $fn=32;
 991     translate([cx,endy,dz]){
 992       // feet
 993       for (rot=[45:90:315]) rotate(rot) {
 994         translate([legrad,0,0]){
 995           hull(){
 996             cylinder(r= footrad_max, h=1);
 997             translate([0,0,-footrad_depth])
 998               cylinder(r= footrad_min, h=1);
 999           }
1000           if (cut)
1001             translate([0,0,-10])
1002             cylinder(r= footrad_min +
1003                      adj_neg_slop * (footrad_max-footrad_min)/footrad_depth,
1004                      h=20);
1005         }
1006       }
1007       // legs
1008       for (rot=[45,135]) rotate(rot) {
1009         hull(){
1010           for (s=[-1,+1]){
1011             translate([s*legrad,0,0])
1012               cylinder(r= footrad_max, h=bar[1]);
1013           }
1014         }
1015       }
1016       // strap holes
1017       if (cut) {
1018         for (rot=[0,180]) rotate(rot) {
1019             translate([ straphole_x_max - strap[0]/2, 0,0 ])
1020               cube(concat(strap,[20]), center=true);
1021           }
1022       }
1023     }
1024   }
1025 }
1026
1027 module FitTest_RearCurve(){ ////toplevel
1028   difference(){
1029     FitTest_general([100,0], [180,100]);
1030     FitTest_PairLink(true);
1031     TestStrapSlots();
1032   }
1033 }
1034
1035 module FitTest_FrontCurve(){ ////toplevel
1036   p0 = [100,-80];
1037   sz = [180,80];
1038   difference(){
1039     intersection() {
1040       Tile00();
1041       translate([0,0,-8]) linear_extrude(height=18) {
1042         translate(p0) square(sz);
1043         translate(teststrapslots_at[3])
1044           scale(2* [ teststrap_peg[0], teststrap[1] ])
1045           circle(r=1, $fn=20);
1046       }
1047     }
1048     FitTest_PairLink(true);
1049     TestStrapSlots();
1050   }
1051 }
1052
1053 module FitTest_Entire(){ ////toplevel
1054   p0 = [-33,-80];
1055   szrear = [263,180];
1056   szfront = [243,szrear[1]];
1057   difference(){
1058     FitTest_general(p0, szrear, dobrace=true, bracexx=0);
1059     FitTest_PairLink(true);
1060     translate(concat(p0,[0]) + [szfront[0],-10,-40])
1061       cube([100, -p0[1], 80]);
1062     TestStrapSlots();
1063   }
1064   intersection(){
1065     FitTest_RearCurve();
1066     translate(concat(p0,[-20])) cube(concat(szrear,[40]));
1067   }
1068   FitTest_FrontCurve();
1069 }
1070
1071 module FitTest_EntireDemo(){ ////toplevel
1072   FitTest_Entire();
1073   //%Tile00();
1074 }
1075
1076 module FitTest_EndEnd(){ ////toplevel
1077   p0 = [-30,-32];
1078   sz = [156,81] - p0;
1079   sz2 = [136,68] - p0;
1080   difference(){
1081     FitTest_general(p0, sz);
1082     translate([ p0[0] -1, p0[1]+sz2[1], -10])
1083       cube([ sz2[0] +1, 50, 20 ]);
1084   }
1085 }
1086
1087 module FitTest_PairDemo(){ ////toplevel
1088   sh=[-90,-15,0];
1089   translate(sh){
1090     FitTest_PairLink();
1091     %FitTest_FrontCurve();
1092     %FitTest_RearCurve();
1093   }
1094   rotate([0,0,180]){
1095     translate(sh){
1096       difference(){
1097         union(){
1098           FitTest_FrontCurve();
1099           FitTest_RearCurve();
1100         }
1101         #FitTest_PairLink(true);
1102       }
1103     }
1104   }
1105 }
1106
1107 module RoundCornerDemo_plat(cnr){
1108   mirror([0,0,1]) linear_extrude(height=1) polygon(cnr);
1109 }
1110
1111 module RoundCornerDemo(){ ////toplevel
1112   cnr = [ [-2,-3], [13,-3], [-12,9] ];
1113   translate([0,25,0]) RoundCornerDemo_plat(cnr);
1114   translate([25,0,0]) RoundCornerAdd(cnr);
1115   translate([-25,0,0]) RoundCornerCut(cnr);
1116   translate([0,-25,0]) RoundCorner_selector(cnr, 0);
1117   difference(){
1118     RoundCornerDemo_plat(cnr);
1119     RoundCornerCut(cnr);
1120   }
1121   RoundCornerAdd(cnr);
1122 }
1123
1124 module Demo(){ ////toplevel
1125   translate(demo_slop*[-2,1]) color("blue") Tile12();
1126   translate(demo_slop*[-2,0]) color("red")  Tile02();
1127   translate(demo_slop*[-2,1]) color("orange") Tile11();
1128   translate(demo_slop*[-2,0]) color("purple") Tile01();
1129   translate(demo_slop*[-3,1]) color("blue")   Tile10();
1130   translate(demo_slop*[-3,0]) color("red")    Tile00();
1131   %Machine();
1132   // Can also do this, to print reference sheet:
1133   //  load this into openscad
1134   //  select Ctrl-4 view, view all, scale appropriately
1135   //  import sewing-table,Demo-flat.png
1136   //  pngtopnm <sewing-table,Demo-flat.png | ppmbrighten -s -50 -v +100 >t.pnm
1137   //  lpr t.pnm
1138 }
1139
1140 //TestPiece1();
1141 //TestPiece2();
1142 //Demo();
1143
1144 //Machine_NewRearProfile();
1145 //Machine_NewRearCurve();
1146 //Machine_NewFrontProfile();
1147 //Machine_NewEndProfile();
1148 //Machine_NewEndProfileDemo();
1149 //Machine_Curves();
1150 //Machine();
1151 //FitTest();
1152 //MachineEnvelope();