sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 ply_hole_dia_real = 12;
  11
  12 tile_th = 3;
  13 post_dia = 8;
  14
  15 post_shorter = 1;
  16
  17 screw_dia = 2.2;
  18 screw_big_dia = 3.6;
  19 screw_big_len = 4.0;
  20
  21 round_edge_rad = 2.0;
  22
  23 round_cnr_rad = 10;
  24
  25 interlock_dia = 10;
  26 interlock_fine = 0.66;
  27
  28 interlock_fine_slope = 1.0;
  29 interlock_fine_lenslop = 1.0;
  30
  31 demo_slop = 0.1;
  32
  33 // cutout
  34
  35 machine_rear_to_front = 84 + 0.25 - 1.4;
  36
  37 cutout_l_end_y_front_slop = 0.5;
  38 cutout_l_end_y_rear_slop = 0.5;
  39
  40 cutout_l_end_x = 22;
  41 cutout_l_end_y = machine_rear_to_front;
  42 cutout_l_end_new_x_slop = 1.4 - 1.95;
  43 cutout_l_end_y_total = cutout_l_end_y
  44   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  45
  46 tile02_tr = [-250, 0];
  47 tile01_tr = [  0, 0];
  48
  49 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  50 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  51
  52 // front and rear curves
  53
  54 rearedge_len = 170 + 0.70;
  55 frontedge_len = 170;
  56
  57 rearcurve_strt_len = 52;
  58
  59 rearcurve_z_slop = -0.50;
  60
  61 rearcurve_avoid_y = 35;
  62
  63 rearcurve_double_inrad = 26.10 + 8.04;
  64
  65 reartablet_z = 2.54;
  66 reartablet_x = 5 + 1;
  67 reartablet_y = 8;
  68
  69 frontcurve_side_skew = 3.5 / 72;
  70 frontcurve_avoid_y = 70;
  71 frontcurve_z_slop = 0.75;
  72
  73 frontcurve_strt_len = 50;
  74 frontcurve_dualcurve_angle = 30;
  75
  76 teststrapslots_at = [ [ 110, 70 ], [ 110, -35 ],
  77                       [ 180, 90 ],
  78                       [ 190, -80 ], // do not change index of this one
  79                       [   0, 70 ],  [  0, -35 ],
  80                       ];
  81
  82 teststrap = [ 3, 5 ];
  83 teststrap_peg = [7.5, 3.5];
  84
  85 ply_edge_hole_dist_real = 14;
  86
  87 // calculated
  88
  89 TEST = false;
  90 JIG = false;
  91
  92 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
  93
  94 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
  95
  96 hole_slop = (ply_hole_dia - post_dia)/2;
  97 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
  98
  99 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
 100          tile_hard_edge_hole_dist));
 101
 102 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
 103          tile_hard_edge_hole_dist + round_edge_rad));
 104
 105 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
 106 thehd_tr = thehd;
 107 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 108 thehd_bl = -thehd_tr;
 109 thehd_br = -thehd_tl;
 110
 111 tablet_z_slop = 1.00;
 112
 113 interlock_rad = interlock_dia/2;
 114 interlock_negative_rad = interlock_rad + 0.125;
 115
 116 interlock_sq_adj = 0.2; // arbitrary
 117
 118 m4_define(`POST_TCROSSSZ',
 119           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 120
 121 module Post(){
 122   mirror([0,0,1]) {
 123     if (!JIG) {
 124       difference(){
 125         cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 126         translate([0,0, tile_th]) {
 127           cylinder(r= screw_big_dia/2, h= screw_big_len);
 128           cylinder(r= screw_dia/2, h= ply_th, $fn=20);
 129         }
 130       }
 131     }
 132     if (TEST) {
 133       translate([0,0, tile_th/2]) {
 134         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 135         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 136       }
 137     }
 138     if (JIG) {
 139       translate([0,0, tile_th/2]) {
 140         cube([POST_TCROSSSZ, POST_TCROSSSZ, tile_th], center=true);
 141       }
 142     }
 143   }
 144 }
 145
 146 module PostHole(){
 147   if (JIG) {
 148     translate([0,0,-5])
 149       cylinder(r= post_dia/2 + jig_post_hole_slop, h=10);
 150     translate([0,0, -jig_min_th])
 151       cylinder(r= ply_hole_dia_real/2, h = 5);
 152     for (rot=[0:90:270]) rotate(rot) {
 153         translate([ ply_edge_hole_dist_real, 0, 0 ])
 154           cube([ jig_pencil_rad*2, jig_pencil_slotlen, 20 ], center=true);
 155       }
 156   }
 157 }
 158
 159 module Posts(posts) {
 160   for (p= posts) {
 161     translate(concat(p, [0]))
 162       Post();
 163   }
 164 }
 165 module PostHoles(posts) {
 166   for (p= posts)  {
 167     translate(concat(p, [0]))
 168       PostHole();
 169   }
 170 }
 171
 172 module TileBase(botleft, topright){
 173   size = topright - botleft;
 174   botleft_post = botleft + thehd_tr;
 175   topright_post = topright + thehd_bl;
 176   difference(){
 177     mirror([0,0,1])
 178       translate(concat(botleft, [0]))
 179       cube(concat(size, [tile_th]));
 180     if (!(TEST || JIG)) {
 181       cidsz = topright_post-botleft_post
 182         + [-post_dia,-post_dia]
 183         + [0, thehd[1]];
 184       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
 185       echo("CID",cidsz,cidszr);
 186       translate( concat(botleft_post, [ -tile_th ])
 187                  + 0.5 * [ post_dia, post_dia, 0 ]
 188                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
 189         Commitid_BestCount_M(cidszr);
 190     }
 191     if ((TEST || JIG)) {
 192       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
 193       cidsz = [ thehd[0], size[1] - 2*crossoff ];
 194       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
 195       if (TEST)
 196         translate( concat(botleft + [0, crossoff] + (cidsz-cidszr)/2, [0]) )
 197           Commitid_BestCount(cidszr);
 198       difference(){
 199         mirror([0,0,1]) {
 200           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 201             cube(concat(size - [test_edge,test_edge]*2, [tile_th*2]));
 202           translate(concat(botleft_post, [-1]))
 203             cube(concat(topright_post-botleft_post, [tile_th+2]));
 204         }
 205         shufflesz = max(test_edge, tile_hard_edge_hole_dist)*2;
 206         minkowski(){
 207           MachineEnvelope();
 208           cube(shufflesz, center=true);
 209         }
 210         if (JIG) {
 211           translate([0,0,-20]) linear_extrude(height=20) {
 212             translate(botleft)
 213               rotate(atan2(size[1],size[0]))
 214               translate([0, -test_edge/2])
 215               square([vectorlen2d(size), test_edge]);
 216           }
 217         }
 218       }
 219     }
 220   }
 221 }
 222
 223 m4_dnl   R_EDGE(c,ix)
 224 m4_dnl        c is from Rectangle_corners and
 225 m4_dnl        ix is a corner number
 226 m4_dnl    expands to two comma-separated corners:
 227 m4_dnl    that denoted by ix, and the next one anticlockwise
 228 m4_define(`R_EDGE',`$1[$2], $1[(($2)+1)%4]')
 229
 230 m4_dnl   R_CNR(c,ix)
 231 m4_dnl        c is from Rectangle_corners and
 232 m4_dnl        ix is a corner number
 233 m4_dnl    expands to an array of corners as for RoundCorner
 234 m4_define(`R_CNR',`[ $1[$2], $1[(($2)+1)%4], $1[(($2)+3)%4] ]')
 235
 236 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 237 m4_define(`INREFFRAME',`
 238   length_vec = ($2) - ($1);
 239   length = dist2d([0,0], length_vec);
 240   length_uvec = length_vec / length;
 241   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 242   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 243         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 244         [ 0,              0,              1,            0, ],
 245         [ 0,              0,              0,            1, ] ];
 246   $3
 247   multmatrix(m)
 248 ')
 249
 250 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 251 m4_dnl    INREFFRAME_EDGE { body; }
 252 m4_define(`INREFFRAME_EDGE',`
 253   translate([0,0, -round_edge_rad])
 254 ')
 255
 256 module RoundEdge(left_cnr, right_cnr) {
 257   INREFFRAME(left_cnr, right_cnr)
 258     INREFFRAME_EDGE {
 259     difference(){
 260       rotate([0,90,0])
 261         cylinder(r= round_edge_rad, h= length, $fn=50);
 262       translate([-1, 0, -20])
 263         cube([length+2, 20, 20]);
 264     }
 265   }
 266 }
 267
 268 m4_define(`ROUNDCORNER_VARS',`
 269   this_cnr = ci[0];
 270   right_cnr = ci[1];
 271   left_cnr = ci[2];
 272   bigr= round_cnr_rad - round_edge_rad;
 273   l_uvec = unitvector2d(left_cnr - this_cnr);
 274   r_uvec = unitvector2d(right_cnr - this_cnr);
 275   lp1 = left_cnr  + clockwise2d(l_uvec) * bigr;
 276   lp2 = this_cnr  + clockwise2d(l_uvec) * bigr;
 277   lp3 = this_cnr  - clockwise2d(r_uvec) * bigr;
 278   lp4 = right_cnr - clockwise2d(r_uvec) * bigr;
 279   ctr = line_intersection_2d(lp1,lp2,lp3,lp4);
 280   ctr3 = concat(ctr,[0])
 281 ')
 282
 283 module RoundCorner_selector(ci, adj) {
 284   ROUNDCORNER_VARS;
 285   intersection(){
 286     union(){
 287       INREFFRAME(ctr3,concat(lp1,[4])){
 288         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 289           translate([-bigr*2 + adj, -bigr])
 290             square([bigr*2, bigr*3]);
 291         }
 292       }
 293     }
 294     union(){
 295       INREFFRAME(ctr3,concat(lp4,[0])){
 296         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 297           translate([-bigr*2, -bigr*2])
 298             square([bigr*2 + adj, bigr*3]);
 299         }
 300       }
 301     }
 302   }
 303 }
 304
 305 module RoundCornerCut(ci) {
 306   // ci should be [this_cnr, right_cnr, left_cnr]
 307   // where right_cnr is to the right (ie, anticlockwise)
 308   ROUNDCORNER_VARS;
 309   difference(){
 310     RoundCorner_selector(ci, -0.1);
 311     translate(ctr3)
 312       cylinder(center=true, h=20, r= bigr);
 313   }
 314 }
 315
 316 module RoundCornerAdd(ci) {
 317   ROUNDCORNER_VARS;
 318   intersection(){
 319     RoundCorner_selector(ci, +0.1);
 320     INREFFRAME_EDGE {
 321       translate(ctr3){
 322         rotate_extrude(convexity=10, $fn=50)
 323           translate([bigr, 0])
 324           difference(){
 325           circle(r= round_edge_rad, $fn=50);
 326           mirror([1,1])
 327             square([20,20]);
 328         }
 329       }
 330     }
 331   }
 332 }
 333
 334 module InterlockLobePlan(negative) {
 335   r = negative ? interlock_negative_rad : interlock_rad;
 336   ymir = negative ? 0 : 1;
 337
 338   dx = sqrt(3) * r;
 339   $fn= 80;
 340   translate([thehd[0], 0]){
 341     mirror([0,ymir]){
 342       circle(r=r);
 343       difference(){
 344         translate([-dx, -0.1])
 345           square([ dx*2, r/2 + 0.1 ]);
 346         for (xi = [-1, 1]) {
 347           translate([ xi*dx, r ])
 348             circle(r=r);
 349         }
 350       }
 351     }
 352   }
 353 }
 354
 355 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 356   for (lobei = [ 0 : nlobes-1 ]) {
 357     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 358     translate([lobex, 0, 0]) {
 359       InterlockLobePlan(negative);
 360     }
 361   }
 362
 363   if (dosquare) {
 364     iadj = 0;
 365     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 366     mirror([0, negative])
 367       translate([slotshorter, iadj])
 368       square([length - slotshorter*2, interlock_fine + iadj*2]);
 369   }
 370 }
 371
 372 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 373   plusth = negative * 1.0;
 374   protr = interlock_fine + interlock_sq_adj;
 375
 376   z2 = -tile_th/2;
 377   z1 = -tile_th/2 - protr / interlock_fine_slope;
 378   z3 = -tile_th/2 + protr / interlock_fine_slope;
 379
 380   negsign = negative ? -1 : +1;
 381   yprotr = negsign * protr;
 382
 383   INREFFRAME(left_cnr, right_cnr) {
 384     for (vsect = [ // zs0            zs1      ys0,            ys1
 385                   [ -tile_th-plusth, plusth,  0,              0],
 386                   [ z1,              z2,      0, yprotr],
 387                   [ z2,              z3,      yprotr, 0],
 388                   ]) {
 389       zs0 = vsect[0];
 390       zs1 = vsect[1];
 391       zsd = zs1-zs0;
 392       ys0 = vsect[2];
 393       ys1 = vsect[3];
 394       ysd = ys1-ys0;
 395       sl = ysd/zsd;
 396       m = [ [ 1,0,   0,    0 ],
 397             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 398             [ 0,0,   1,  zs0 ],
 399             [ 0,0,   0,    1 ] ];
 400       multmatrix(m)
 401         linear_extrude(height=zsd, convexity=10)
 402         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 403     }
 404   }
 405 }
 406
 407 function TestPiece_holes2corners(holes) =
 408   [ holes[0] + thehd_bl,
 409     holes[1] + thehd_br,
 410     holes[1] + thehd_tr,
 411     holes[0] + thehd_tl ];
 412
 413 module TestPiece1(){ ////toplevel
 414   holes = [ [-100, 0],
 415             [   0, 0]
 416             ];
 417   corners = TestPiece_holes2corners(holes);
 418   rcs = R_CNR(corners,0);
 419   difference(){
 420     union(){
 421       TileBase(corners[0], corners[2]);
 422       Posts(holes);
 423       RoundEdge(corners[0], corners[1]);
 424       RoundEdge(corners[3], corners[0]);
 425     }
 426     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 427     RoundCornerCut(rcs);
 428     PostHoles(holes);
 429   }
 430   RoundCornerAdd(rcs);
 431 }
 432
 433 module TestPiece2(){ ////toplevel
 434   holes = [ [   0, 0],
 435             [  50, 0]
 436             ];
 437   corners = TestPiece_holes2corners(holes);
 438   difference(){
 439     union(){
 440       TileBase(corners[0], corners[2]);
 441       Posts(holes);
 442       RoundEdge(corners[0], corners[1]);
 443       InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 444     }
 445     PostHoles(holes);
 446   }
 447 }
 448
 449 module TestDemo(){ ////toplevel
 450   translate([ -thehd[0], 0 ])
 451     color("blue")
 452     TestPiece1();
 453   translate([ +thehd[0] + demo_slop, 0 ])
 454     TestPiece2();
 455 }
 456
 457 module Machine_NewRearProfile(){
 458   // figures copied out of xfig edit boxes
 459   // best not to edit the posbox size if poss - just move it
 460   posbox = 10 * ([7.2333,-14.1267] - [-16.2289,40.0289]); // box, Green
 461   sideline = -10 * ([-6.2400,13.5600] - [-2.4467,28.2556]); // line, Blue
 462   scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
 463   scaleline_mm = 12+5+10+5+3;
 464   sh = -[abs(posbox[0]), abs(posbox[1])];
 465   rot = atan2(-sideline[0], sideline[1]);
 466   sc = scaleline_mm / scaleline;
 467   //echo("SH",sh,rot,sc);
 468   scale(sc) rotate(rot) translate(sh){
 469     import("sewing-table-rear-profile.dxf", convexity=10); // spline, Pink3
 470   }
 471 }
 472
 473 module Machine_NewFrontProfile(){
 474   // figures copied out of xfig edit boxes
 475   // best not to edit the posbox size if poss - just move it
 476   posbox = 10 * ([11.8022,8.0600] - [4.2044,19.1867]); // box, Green
 477   refline = 10 * ([7.6778,16.7222] - [27.8689,17.6578]); // line, Blue
 478   refline_mm = (11-1)*10;
 479   sh = -[abs(posbox[0]), abs(posbox[1])];
 480   rot = atan2(-refline[0], refline[1]);
 481   sc = refline_mm / vectorlen2d(refline);
 482   //echo("SH",sh,rot,sc);
 483   mirror([1,0]) scale(sc) rotate(rot+90) translate(sh){
 484     import("sewing-table-front-profile.dxf", convexity=10); // spline, Pink3
 485   }
 486 }
 487
 488 module Machine_NewEndProfile(){
 489   // figures copied out of xfig edit boxes
 490   // NB that y coords are reversed - xfig origin is at bottom left
 491   posboxs = 10 * [[4.0400,17.7956], [11.6622,32.5511]]; // box, Pink3
 492   refline = 10 * ([8.4000,22.6000] - [50.3000,22.2000]); // line, Blue
 493   refline_mm = 10 * (11 - 2.5);
 494   sidelines = 10 * [[[9.0889,20.6178], [8.9644,14.6889]],
 495                     [[50.3800,21.9578], [50.1933,14.4933]]]; // lines, Blue3
 496   baseline = 10 * [[8.4000,18.0822], [50.3000,17.6822]]; // line, Green2
 497
 498   rot_adj = -0.38;
 499
 500   posbox = [min(posboxs[0][0],posboxs[1][0]),
 501             max(posboxs[0][1],posboxs[1][1])];
 502
 503   m4_define(`MNEP_ELP',
 504      `line_intersection_2d(baseline[0],baseline[1],
 505                            sidelines[$1][0],sidelines[$1][1])')
 506   endline = [MNEP_ELP(0),MNEP_ELP(1)];
 507
 508   rot = atan2(-refline[1], -refline[0]);
 509   sc = refline_mm / vectorlen2d(refline);
 510   sh = (0.5 * (endline[0] + endline[1])) - posbox;
 511
 512   ellen = sc * dist2d(endline[0],endline[1]);
 513   scy = cutout_l_end_y_total / ellen;
 514
 515   scale([scy,1]) scale(sc) rotate(rot + rot_adj) translate(-[sh[0],-sh[1]]){
 516
 517     mirror([0,1]){
 518   //%translate(1 * (posboxs[0] - posbox)) square(50);
 519   //%translate(1 * (posboxs[1] - posbox)) square(50);
 520 //  %translate(1 * (baseline[0] - posbox)) square([50,10]);
 521
 522 //  %translate(1 * (endline[0] - posbox)) square([50,10]);
 523 //  %translate(1 * (endline[1] - posbox)) square([50,10]);
 524
 525 //  %translate(1 * (sidelines[0][0] - posbox)) square([10,50]);
 526 //  %translate(1 * (sidelines[0][1] - posbox)) square([10,50]);
 527 //  %translate(1 * (sidelines[1][0] - posbox)) square([10,50]);
 528 //  %translate(1 * (sidelines[1][1] - posbox)) square([10,50]);
 529     }
 530
 531     import("sewing-table-end-profile.dxf", convexity=10); // spline, Pink3
 532   }
 533 }
 534
 535 module Machine_NewEndProfileDemo(){ ////toplevel
 536     translate([0,5,0])                             Machine_NewEndProfile();
 537     translate([0,5,1]) color("blue") mirror([1,0]) Machine_NewEndProfile();
 538   mirror([0,1,0]){
 539     translate([0,5, 0])                             Machine_NewEndProfile();
 540     translate([0,5,-1]) color("blue") mirror([1,0]) Machine_NewEndProfile();
 541   }
 542 }
 543
 544 module Machine_NewArm(){
 545   translate([0,0,-30]) linear_extrude(height=60) {
 546     translate(tile01_tr + [ -cutout_l_end_x - cutout_l_end_new_x_slop,
 547                             (-cutout_tile01_y + cutout_tile11_y)/2 ]){
 548       rotate(-90){
 549         hull(){
 550           for (d=[0,400])
 551             translate([0,d]) Machine_NewEndProfile();
 552         }
 553       }
 554     }
 555   }
 556 }
 557
 558 module Machine_NewRearCurve(){
 559   slant = atan2(4,210-10);
 560   //echo("SL",slant);
 561   translate([0,0, rearcurve_double_inrad]) rotate([slant,0,0]){
 562     translate([ rearcurve_double_inrad,
 563                 0,
 564                 -rearcurve_double_inrad + 10 ]){
 565       rotate([180,0,0]) rotate([0,0,90]) linear_extrude(height=30){
 566         hull(){
 567           Machine_NewRearProfile();
 568           translate([0,-100]) Machine_NewRearProfile();
 569         }
 570       }
 571     }
 572     rotate([0,90,0]) rotate([90,0,0]) {
 573       intersection(){
 574         rotate_extrude(convexity=10, $fn=64)
 575           rotate(90)
 576           translate([ 0, -rearcurve_double_inrad ])
 577           Machine_NewRearProfile();
 578         translate([0,0,-500])
 579           cube([500,500,1000]);
 580       }
 581     }
 582     translate([1,0,-rearcurve_double_inrad])
 583       rotate([0,-90,0]) rotate([0,0,-90])
 584       linear_extrude(height= rearcurve_strt_len + 1)
 585       Machine_NewRearProfile();
 586   }
 587 }
 588
 589 module Machine_Curves(){ ////toplevel
 590   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 591               cutout_tile11_y,
 592               0 ]){
 593     //%cube([20,20,20]);
 594     translate([ -reartablet_x,
 595                 -1,
 596                 -reartablet_z + tablet_z_slop])
 597       mirror([0,0,1])
 598       cube([ reartablet_x+1,
 599              reartablet_y+1,
 600              20 ]);
 601   }
 602   translate([ tile01_tr[0] - cutout_l_end_x + frontedge_len,
 603               cutout_tile11_y,
 604               frontcurve_z_slop ]){
 605     translate([0, -machine_rear_to_front, 0])
 606       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 607                   [0,  1,   0, 0],
 608                   [0,  0,   1, 0],
 609                   [0,  0,   0, 1]])
 610       mirror([1,0,0]) rotate([0,-90,0])rotate([0,0,-90])
 611       linear_extrude(height= 200)
 612       Machine_NewFrontProfile();
 613   }
 614   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 615               cutout_tile11_y,
 616               frontcurve_z_slop ]){
 617     translate([ rearcurve_strt_len,
 618                 0,
 619                 rearcurve_z_slop ]){
 620       Machine_NewRearCurve();
 621     }
 622   }
 623 }
 624
 625 module TestStrapSlots(){
 626   pegwidth = teststrap_peg[0];
 627   for (pos = teststrapslots_at) {
 628     echo("TSS",pos);
 629     translate(concat(pos,[0]))
 630       for (mx = [0,1]) mirror([mx,0,0]) {
 631           translate([ pegwidth/2, -teststrap[1]/2, -20 ])
 632             cube(concat(teststrap,[40]));
 633         }
 634   }
 635 }
 636
 637 module TestStrapPeg_any(l){ cube(concat([l],teststrap_peg)); }
 638
 639 module TestStrapPeg_Short(){ ////toplevel
 640   TestStrapPeg_any(35);
 641 }
 642
 643 module TestStrapPeg_Long(){ ////toplevel
 644   TestStrapPeg_any(60);
 645 }
 646
 647 module Machine(){ ////toplevel
 648   Machine_NewArm();
 649   Machine_Curves();
 650   if (TEST)
 651     TestStrapSlots();
 652 }
 653
 654 module MachineEnvelope(){
 655   // used for testing
 656   p_arm_bl = [-cutout_l_end_x, -cutout_tile01_y];
 657   y_arm_t  = cutout_tile11_y;
 658   p_crv_fl = p_arm_bl + [frontedge_len, -frontcurve_avoid_y];
 659   y_crv_b  = y_arm_t + rearcurve_avoid_y;
 660
 661   translate([0,0,-50]) linear_extrude(height= 100){
 662     translate(p_arm_bl) square([400, y_arm_t] - p_arm_bl);
 663     translate(p_crv_fl) square([400, y_crv_b] - p_crv_fl);
 664   }
 665 }
 666
 667 function Rectangle_corners(c0, sz) =
 668   // returns the corners of a rectangle from c0 to c0+sz
 669   // if sz is positive, the corners are anticlockwise starting with c0
 670   [ c0 + [ 0,     0     ],
 671     c0 + [ sz[0], 0     ],
 672     c0 + [ sz[0], sz[1] ],
 673     c0 + [ 0,     sz[1] ] ];
 674
 675 function Rectangle_corners2posts(c) =
 676   [ c[0] + thehd_tr,
 677     c[1] + thehd_tl,
 678     c[2] + thehd_bl,
 679     c[3] + thehd_br ];
 680
 681 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 682
 683 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 684
 685 module Tile02(){ ////toplevel
 686   sz = [100,170];
 687   c0 = tile02_tr + -sz;
 688   c = Rectangle_corners(c0, sz);
 689   posts = Rectangle_corners2posts(c);
 690   rcs = R_CNR(c,0);
 691   difference(){
 692     union(){
 693       Rectangle_TileBase(c);
 694       Posts(posts);
 695       RoundEdge(R_EDGE(c,0));
 696       RoundEdge(R_EDGE(c,3));
 697       InterlockEdge(R_EDGE(c,2), 0);
 698     }
 699     InterlockEdge(R_EDGE(c,1), 1);
 700     RoundCornerCut(rcs);
 701     PostHoles(posts);
 702   }
 703   RoundCornerAdd(rcs);
 704 }
 705
 706 module Tile12(){ ////toplevel
 707   sz = [100,250];
 708   c0 = tile02_tr + [-sz[0], 0];
 709   c = Rectangle_corners(c0, sz);
 710   posts = Rectangle_corners2posts(c);
 711   rcs = R_CNR(c,3);
 712   difference(){
 713     union(){
 714       Rectangle_TileBase(c);
 715       Posts(posts);
 716       RoundEdge(R_EDGE(c,2));
 717       RoundEdge(R_EDGE(c,3));
 718     }
 719     InterlockEdge(R_EDGE(c,0), 1);
 720     InterlockEdge(R_EDGE(c,1), 1);
 721     RoundCornerCut(rcs);
 722     PostHoles(posts);
 723   }
 724   RoundCornerAdd(rcs);
 725 }
 726
 727 tile_01_11_cnr = tile01_tr + [-cutout_l_end_x, 0];
 728 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 729 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 730
 731 module Tile11(){ ////toplevel
 732   sz = [250,250];
 733   c0 = tile01_tr + [-sz[0],0];
 734   c = Rectangle_corners(c0, sz);
 735   cnr_posts = Rectangle_corners2posts(c);
 736   posts = concat(
 737                  Posts_interpolate_one(cnr_posts[0],
 738                                        cnr_posts[1] - [cutout_l_end_x, 0]),
 739                  [ cnr_posts[1] + [0, cutout_tile11_y],
 740                    cnr_posts[2],
 741                    cnr_posts[3]
 742                    ]);
 743   difference(){
 744     union(){
 745       Rectangle_TileBase(c);
 746       Posts(posts);
 747       RoundEdge(R_EDGE(c,2));
 748       InterlockEdge(R_EDGE(c,3));
 749     }
 750     InterlockEdge(c[0], tile_01_11_cnr, 1);
 751     InterlockEdge(tile_11_10_cnr, c[2], 1);
 752     PostHoles(posts);
 753     Machine();
 754   }
 755 }
 756
 757 module Tile01(){ ////toplevel
 758   sz = [250,170];
 759   c0 = tile01_tr + -sz;
 760   c = Rectangle_corners(c0, sz);
 761   cnr_posts = Rectangle_corners2posts(c);
 762   posts = concat(
 763                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 764                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 765                  Posts_interpolate_one(cnr_posts[2] - [cutout_l_end_x, 0],
 766                                        cnr_posts[3])
 767                  );
 768   difference(){
 769     union(){
 770       Rectangle_TileBase(c);
 771       Posts(posts);
 772       RoundEdge(R_EDGE(c,0));
 773       InterlockEdge(tile_01_11_cnr, c[3]);
 774       InterlockEdge(R_EDGE(c,3));
 775     }
 776     PostHoles(posts);
 777     InterlockEdge(c[1], tile_01_00_cnr, 1);
 778     Machine();
 779   }
 780 }
 781
 782 module Tile10(){ ////toplevel
 783   sz = [250,250];
 784   c0 = tile01_tr + [0,0];
 785   c = Rectangle_corners(c0, sz);
 786   cnr_posts = Rectangle_corners2posts(c);
 787   cty = cutout_tile11_y;
 788   rcy = cty + rearcurve_avoid_y;
 789   posts = [ cnr_posts[0] + [ 0,                             cty ],
 790             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 791             cnr_posts[1] + [ 0,                             rcy ],
 792             cnr_posts[2],
 793             cnr_posts[3] ];
 794   rcs = R_CNR(c,2);
 795   difference(){
 796     union(){
 797       Rectangle_TileBase(c);
 798       Posts(posts);
 799       RoundEdge(R_EDGE(c,1));
 800       RoundEdge(R_EDGE(c,2));
 801       InterlockEdge(c[3], tile_11_10_cnr);
 802     }
 803     PostHoles(posts);
 804     RoundCornerCut(rcs);
 805     Machine();
 806   }
 807   RoundCornerAdd(rcs);
 808 }
 809
 810 module Tile00(){ ////toplevel
 811   sz = [250,170];
 812   c0 = tile01_tr + [0,-sz[1]];
 813   c = Rectangle_corners(c0, sz);
 814
 815   // the edge c[1]..c[2] needs a diagonal chunk, from c1bis to c2bis
 816   c2bis = [ -cutout_l_end_x + frontedge_len + frontcurve_strt_len, c[2][1] ];
 817   c1bis = [ c[1][0],
 818             c[2][1] -
 819             (c[2][0] - c2bis[0]) * tan(90 - frontcurve_dualcurve_angle) ];
 820
 821   cnr_posts = Rectangle_corners2posts(c);
 822   cty = cutout_tile01_y;
 823   rcy = cty + frontcurve_avoid_y;
 824   posts = [ cnr_posts[0],
 825             cnr_posts[1],
 826             0.5 * (cnr_posts[0] + cnr_posts[1]),
 827             cnr_posts[2] + [ 0,                             -rcy ],
 828             cnr_posts[2] + [ -sz[0] + frontedge_len - cutout_l_end_x, -cty ],
 829             cnr_posts[3] + [ 0,                             -cty ]
 830             ];
 831   rcs = R_CNR(c,1);
 832   rc2 = [c1bis,c2bis,c[1]];
 833   difference(){
 834     union(){
 835       difference(){
 836         union(){
 837           Rectangle_TileBase(c);
 838           Posts(posts);
 839           RoundEdge(R_EDGE(c,0));
 840           RoundEdge(c[1], c1bis);
 841           InterlockEdge(tile_01_00_cnr, c[0]);
 842         }
 843         RoundCornerCut(rcs);
 844         translate([0,0,-20]) linear_extrude(height=40) {
 845           polygon([ c1bis, c1bis + [50,0], c2bis + [50,0], c2bis ]);
 846         }
 847       }
 848       RoundEdge(c1bis, c2bis);
 849     }
 850     Machine();
 851     PostHoles(posts);
 852     RoundCornerCut(rc2);
 853   }
 854   RoundCornerAdd(rcs);
 855   RoundCornerAdd(rc2);
 856 }
 857
 858 module FitTest_general(c0,sz, dobrace=false, bracexx=0){
 859   c = Rectangle_corners(c0, sz);
 860   brace = [7,7,9];
 861   bsz = sz + [bracexx,0,0];
 862   difference(){
 863     union(){
 864       Rectangle_TileBase(c);
 865       if (dobrace) {
 866         translate(concat(c0, [-brace[2] + 0.1])){
 867           difference(){
 868             cube(concat(bsz, [brace[2]]) - [5,0,0]);
 869             translate(brace + [0,0, -25])
 870               cube(concat(bsz, [50]) - brace*2 + [10,0,0]);
 871           }
 872         }
 873       }
 874       RoundEdge(R_EDGE(c,1));
 875     }
 876     Machine();
 877   }
 878 }
 879
 880 module FitTest_PairLink(cut=false){ ////toplevel
 881   cy0=-55; cy1=85; cx=132;
 882   bar = [10,10];
 883   legrad = 12;
 884   footrad_min = 1; footrad_max = 4; footrad_depth = 5;
 885   strap = [3,5];
 886   adj_neg_slop = 1.0;
 887   bar_z_slop = 1.75;
 888
 889   // calculated
 890   straphole_x_max = legrad/sqrt(2) + footrad_max;
 891   dz = cut ? adj_neg_slop : 0;
 892
 893   translate([cx - bar[0]/2, cy0, dz + bar_z_slop])
 894     cube([bar[0], cy1-cy0, bar[1] - bar_z_slop]);
 895
 896   for (endy=[cy0,cy1]) {
 897     $fn=32;
 898     translate([cx,endy,dz]){
 899       // feet
 900       for (rot=[45:90:315]) rotate(rot) {
 901         translate([legrad,0,0]){
 902           hull(){
 903             cylinder(r= footrad_max, h=1);
 904             translate([0,0,-footrad_depth])
 905               cylinder(r= footrad_min, h=1);
 906           }
 907           if (cut)
 908             translate([0,0,-10])
 909             cylinder(r= footrad_min +
 910                      adj_neg_slop * (footrad_max-footrad_min)/footrad_depth,
 911                      h=20);
 912         }
 913       }
 914       // legs
 915       for (rot=[45,135]) rotate(rot) {
 916         hull(){
 917           for (s=[-1,+1]){
 918             translate([s*legrad,0,0])
 919               cylinder(r= footrad_max, h=bar[1]);
 920           }
 921         }
 922       }
 923       // strap holes
 924       if (cut) {
 925         for (rot=[0,180]) rotate(rot) {
 926             translate([ straphole_x_max - strap[0]/2, 0,0 ])
 927               cube(concat(strap,[20]), center=true);
 928           }
 929       }
 930     }
 931   }
 932 }
 933
 934 module FitTest_RearCurve(){ ////toplevel
 935   difference(){
 936     FitTest_general([100,0], [180,100]);
 937     FitTest_PairLink(true);
 938     TestStrapSlots();
 939   }
 940 }
 941
 942 module FitTest_FrontCurve(){ ////toplevel
 943   p0 = [100,-80];
 944   sz = [180,80];
 945   difference(){
 946     intersection() {
 947       Tile00();
 948       translate([0,0,-8]) linear_extrude(height=18) {
 949         translate(p0) square(sz);
 950         translate(teststrapslots_at[3])
 951           scale(2* [ teststrap_peg[0], teststrap[1] ])
 952           circle(r=1, $fn=20);
 953       }
 954     }
 955     FitTest_PairLink(true);
 956     TestStrapSlots();
 957   }
 958 }
 959
 960 module FitTest_Entire(){ ////toplevel
 961   p0 = [-33,-80];
 962   szrear = [263,180];
 963   szfront = [243,szrear[1]];
 964   difference(){
 965     FitTest_general(p0, szrear, dobrace=true, bracexx=0);
 966     FitTest_PairLink(true);
 967     translate(concat(p0,[0]) + [szfront[0],-10,-40])
 968       cube([100, -p0[1], 80]);
 969     TestStrapSlots();
 970   }
 971   intersection(){
 972     FitTest_RearCurve();
 973     translate(concat(p0,[-20])) cube(concat(szrear,[40]));
 974   }
 975   FitTest_FrontCurve();
 976 }
 977
 978 module FitTest_EntireDemo(){ ////toplevel
 979   FitTest_Entire();
 980   //%Tile00();
 981 }
 982
 983 module FitTest_EndEnd(){ ////toplevel
 984   p0 = [-30,-32];
 985   sz = [156,81] - p0;
 986   sz2 = [136,68] - p0;
 987   difference(){
 988     FitTest_general(p0, sz);
 989     translate([ p0[0] -1, p0[1]+sz2[1], -10])
 990       cube([ sz2[0] +1, 50, 20 ]);
 991   }
 992 }
 993
 994 module FitTest_PairDemo(){ ////toplevel
 995   sh=[-90,-15,0];
 996   translate(sh){
 997     FitTest_PairLink();
 998     %FitTest_FrontCurve();
 999     %FitTest_RearCurve();
1000   }
1001   rotate([0,0,180]){
1002     translate(sh){
1003       difference(){
1004         union(){
1005           FitTest_FrontCurve();
1006           FitTest_RearCurve();
1007         }
1008         #FitTest_PairLink(true);
1009       }
1010     }
1011   }
1012 }
1013
1014 module RoundCornerDemo_plat(cnr){
1015   mirror([0,0,1]) linear_extrude(height=1) polygon(cnr);
1016 }
1017
1018 module RoundCornerDemo(){ ////toplevel
1019   cnr = [ [-2,-3], [13,-3], [-12,9] ];
1020   translate([0,25,0]) RoundCornerDemo_plat(cnr);
1021   translate([25,0,0]) RoundCornerAdd(cnr);
1022   translate([-25,0,0]) RoundCornerCut(cnr);
1023   translate([0,-25,0]) RoundCorner_selector(cnr, 0);
1024   difference(){
1025     RoundCornerDemo_plat(cnr);
1026     RoundCornerCut(cnr);
1027   }
1028   RoundCornerAdd(cnr);
1029 }
1030
1031 module Demo(){ ////toplevel
1032   translate(demo_slop*[-2,1]) color("blue") Tile12();
1033   translate(demo_slop*[-2,0]) color("red")  Tile02();
1034   translate(demo_slop*[-2,1]) color("orange") Tile11();
1035   translate(demo_slop*[-2,0]) color("purple") Tile01();
1036   translate(demo_slop*[-3,1]) color("blue")   Tile10();
1037   translate(demo_slop*[-3,0]) color("red")    Tile00();
1038   %Machine();
1039   // Can also do this, to print reference sheet:
1040   //  load this into openscad
1041   //  select Ctrl-4 view, view all, scale appropriately
1042   //  import sewing-table,Demo-flat.png
1043   //  pngtopnm <sewing-table,Demo-flat.png | ppmbrighten -s -50 -v +100 >t.pnm
1044   //  lpr t.pnm
1045 }
1046
1047 //TestPiece1();
1048 //TestPiece2();
1049 //Demo();
1050
1051 //Machine_NewRearProfile();
1052 //Machine_NewRearCurve();
1053 //Machine_NewFrontProfile();
1054 //Machine_NewEndProfile();
1055 //Machine_NewEndProfileDemo();
1056 //Machine_Curves();
1057 //Machine();
1058 //FitTest();
1059 //MachineEnvelope();