sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 tile_th = 3;
  11 post_dia = 8;
  12
  13 post_shorter = 1;
  14
  15 screw_dia = 2.2;
  16 screw_big_dia = 3.6;
  17 screw_big_len = 4.0;
  18
  19 round_edge_rad = 2.0;
  20
  21 round_cnr_rad = 10;
  22
  23 interlock_dia = 10;
  24 interlock_fine = 0.66;
  25
  26 interlock_fine_slope = 1.0;
  27 interlock_fine_lenslop = 1.0;
  28
  29 demo_slop = 0.1;
  30
  31 // cutout
  32
  33 machine_rear_to_front = 84 + 0.25 - 1.4;
  34
  35 cutout_l_end_y_front_slop = 0.5;
  36 cutout_l_end_y_rear_slop = 0.5;
  37 cutout_l_end_x_slop = 0.25;
  38
  39 cutout_l_end_x = 22;
  40 cutout_l_end_y = machine_rear_to_front;
  41 cutout_l_end_curve = 1;
  42 cutout_l_end_y_total = cutout_l_end_y
  43   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  44
  45 tile02_tr = [-250, 0];
  46 tile01_tr = [  0, 0];
  47
  48 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  49 cutout_tile11_x = cutout_l_end_x + cutout_l_end_curve;
  50 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  51
  52 // front and rear curves
  53
  54 rearedge_len = 170;
  55
  56 rearcurve_strt_len = 52;
  57
  58 rearcurve_z_slop = -0.50;
  59
  60 rearcurve_avoid_y = 35;
  61
  62 rearcurve_double_inrad = 26.10 + 8.04;
  63
  64 reartablet_z = 2.54;
  65 reartablet_x = 5 + 1;
  66 reartablet_y = 8;
  67
  68 frontcurve_side_skew = 3.5 / 72;
  69 frontcurve_avoid_y = 70;
  70 frontcurve_z_slop = 0.75;
  71
  72 frontcurve_strt_len = 50;
  73 frontcurve_dualcurve_angle = 30;
  74
  75 teststrapslots_at = [ [ 110, 70 ], [ 110, -35 ],
  76                       [ 180, 90 ],
  77                       [ 190, -80 ], // do not change index of this one
  78                       [   0, 70 ],  [  0, -35 ],
  79                       ];
  80
  81 teststrap = [ 3, 5 ];
  82 teststrap_peg = [7.5, 3.5];
  83
  84 // calculated
  85
  86 TEST = false;
  87
  88 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
  89
  90 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
  91
  92 hole_slop = (ply_hole_dia - post_dia)/2;
  93 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
  94
  95 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
  96          tile_hard_edge_hole_dist));
  97
  98 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
  99          tile_hard_edge_hole_dist + round_edge_rad));
 100
 101 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
 102 thehd_tr = thehd;
 103 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 104 thehd_bl = -thehd_tr;
 105 thehd_br = -thehd_tl;
 106
 107 tablet_z_slop = 0.25;
 108
 109 interlock_rad = interlock_dia/2;
 110 interlock_negative_rad = interlock_rad + 0.125;
 111
 112 interlock_sq_adj = 0.2; // arbitrary
 113
 114 m4_define(`POST_TCROSSSZ',
 115           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 116
 117 module Post(){
 118   mirror([0,0,1]) {
 119     difference(){
 120       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 121       translate([0,0, tile_th]) {
 122         cylinder(r= screw_big_dia/2, h= screw_big_len);
 123         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
 124       }
 125     }
 126     if (TEST) {
 127       translate([0,0, tile_th/2]) {
 128         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 129         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 130       }
 131     }
 132   }
 133 }
 134
 135 module Posts(posts) {
 136   for (p= posts) {
 137     translate(concat(p, [0]))
 138       Post();
 139   }
 140 }
 141
 142 module TileBase(botleft, topright){
 143   size = topright - botleft;
 144   botleft_post = botleft + thehd_tr;
 145   topright_post = topright + thehd_bl;
 146   difference(){
 147     mirror([0,0,1])
 148       translate(concat(botleft, [0]))
 149       cube(concat(size, [tile_th]));
 150     if (!TEST) {
 151       cidsz = topright_post-botleft_post
 152         + [-post_dia,-post_dia]
 153         + [0, thehd[1]];
 154       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
 155       echo("CID",cidsz,cidszr);
 156       translate( concat(botleft_post, [ -tile_th ])
 157                  + 0.5 * [ post_dia, post_dia, 0 ]
 158                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
 159         Commitid_BestCount_M(cidszr);
 160     }
 161     if (TEST) {
 162       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
 163       cidsz = [ thehd[0], size[1] - 2*crossoff ];
 164       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
 165       translate( concat(botleft + [0, crossoff] + (cidsz-cidszr)/2, [0]) )
 166         Commitid_BestCount(cidszr);
 167       difference(){
 168         mirror([0,0,1]) {
 169           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 170             cube(concat(size - [test_edge,test_edge]*2, [tile_th]));
 171           translate(concat(botleft_post, [-1]))
 172             cube(concat(topright_post-botleft_post, [tile_th+2]));
 173         }
 174         shufflesz = max(test_edge, tile_hard_edge_hole_dist)*2;
 175         minkowski(){
 176           MachineEnvelope();
 177           cube(shufflesz, center=true);
 178         }
 179       }
 180     }
 181   }
 182 }
 183
 184 m4_dnl   R_EDGE(c,ix)
 185 m4_dnl        c is from Rectangle_corners and
 186 m4_dnl        ix is a corner number
 187 m4_dnl    expands to two comma-separated corners:
 188 m4_dnl    that denoted by ix, and the next one anticlockwise
 189 m4_define(`R_EDGE',`$1[$2], $1[(($2)+1)%4]')
 190
 191 m4_dnl   R_CNR(c,ix)
 192 m4_dnl        c is from Rectangle_corners and
 193 m4_dnl        ix is a corner number
 194 m4_dnl    expands to an array of corners as for RoundCorner
 195 m4_define(`R_CNR',`[ $1[$2], $1[(($2)+1)%4], $1[(($2)+3)%4] ]')
 196
 197 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 198 m4_define(`INREFFRAME',`
 199   length_vec = ($2) - ($1);
 200   length = dist2d([0,0], length_vec);
 201   length_uvec = length_vec / length;
 202   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 203   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 204         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 205         [ 0,              0,              1,            0, ],
 206         [ 0,              0,              0,            1, ] ];
 207   $3
 208   multmatrix(m)
 209 ')
 210
 211 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 212 m4_dnl    INREFFRAME_EDGE { body; }
 213 m4_define(`INREFFRAME_EDGE',`
 214   translate([0,0, -round_edge_rad])
 215 ')
 216
 217 module RoundEdge(left_cnr, right_cnr) {
 218   INREFFRAME(left_cnr, right_cnr)
 219     INREFFRAME_EDGE {
 220     difference(){
 221       rotate([0,90,0])
 222         cylinder(r= round_edge_rad, h= length, $fn=50);
 223       translate([-1, 0, -20])
 224         cube([length+2, 20, 20]);
 225     }
 226   }
 227 }
 228
 229 m4_define(`ROUNDCORNER_VARS',`
 230   this_cnr = ci[0];
 231   right_cnr = ci[1];
 232   left_cnr = ci[2];
 233   bigr= round_cnr_rad - round_edge_rad;
 234   l_uvec = unitvector2d(left_cnr - this_cnr);
 235   r_uvec = unitvector2d(right_cnr - this_cnr);
 236   lp1 = left_cnr  + clockwise2d(l_uvec) * bigr;
 237   lp2 = this_cnr  + clockwise2d(l_uvec) * bigr;
 238   lp3 = this_cnr  - clockwise2d(r_uvec) * bigr;
 239   lp4 = right_cnr - clockwise2d(r_uvec) * bigr;
 240   ctr = line_intersection_2d(lp1,lp2,lp3,lp4);
 241   ctr3 = concat(ctr,[0])
 242 ')
 243
 244 module RoundCorner_selector(ci, adj) {
 245   ROUNDCORNER_VARS;
 246   intersection(){
 247     union(){
 248       INREFFRAME(ctr3,concat(lp1,[4])){
 249         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 250           translate([-bigr*2 + adj, -bigr])
 251             square([bigr*2, bigr*3]);
 252         }
 253       }
 254     }
 255     union(){
 256       INREFFRAME(ctr3,concat(lp4,[0])){
 257         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 258           translate([-bigr*2, -bigr*2])
 259             square([bigr*2 + adj, bigr*3]);
 260         }
 261       }
 262     }
 263   }
 264 }
 265
 266 module RoundCornerCut(ci) {
 267   // ci should be [this_cnr, right_cnr, left_cnr]
 268   // where right_cnr is to the right (ie, anticlockwise)
 269   ROUNDCORNER_VARS;
 270   difference(){
 271     RoundCorner_selector(ci, -0.1);
 272     translate(ctr3)
 273       cylinder(center=true, h=20, r= bigr);
 274   }
 275 }
 276
 277 module RoundCornerAdd(ci) {
 278   ROUNDCORNER_VARS;
 279   intersection(){
 280     RoundCorner_selector(ci, +0.1);
 281     INREFFRAME_EDGE {
 282       translate(ctr3){
 283         rotate_extrude(convexity=10, $fn=50)
 284           translate([bigr, 0])
 285           difference(){
 286           circle(r= round_edge_rad, $fn=50);
 287           mirror([1,1])
 288             square([20,20]);
 289         }
 290       }
 291     }
 292   }
 293 }
 294
 295 module InterlockLobePlan(negative) {
 296   r = negative ? interlock_negative_rad : interlock_rad;
 297   ymir = negative ? 0 : 1;
 298
 299   dx = sqrt(3) * r;
 300   $fn= 80;
 301   translate([thehd[0], 0]){
 302     mirror([0,ymir]){
 303       circle(r=r);
 304       difference(){
 305         translate([-dx, -0.1])
 306           square([ dx*2, r/2 + 0.1 ]);
 307         for (xi = [-1, 1]) {
 308           translate([ xi*dx, r ])
 309             circle(r=r);
 310         }
 311       }
 312     }
 313   }
 314 }
 315
 316 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 317   for (lobei = [ 0 : nlobes-1 ]) {
 318     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 319     translate([lobex, 0, 0]) {
 320       InterlockLobePlan(negative);
 321     }
 322   }
 323
 324   if (dosquare) {
 325     iadj = 0;
 326     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 327     mirror([0, negative])
 328       translate([slotshorter, iadj])
 329       square([length - slotshorter*2, interlock_fine + iadj*2]);
 330   }
 331 }
 332
 333 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 334   plusth = negative * 1.0;
 335   protr = interlock_fine + interlock_sq_adj;
 336
 337   z2 = -tile_th/2;
 338   z1 = -tile_th/2 - protr / interlock_fine_slope;
 339   z3 = -tile_th/2 + protr / interlock_fine_slope;
 340
 341   negsign = negative ? -1 : +1;
 342   yprotr = negsign * protr;
 343
 344   INREFFRAME(left_cnr, right_cnr) {
 345     for (vsect = [ // zs0            zs1      ys0,            ys1
 346                   [ -tile_th-plusth, plusth,  0,              0],
 347                   [ z1,              z2,      0, yprotr],
 348                   [ z2,              z3,      yprotr, 0],
 349                   ]) {
 350       zs0 = vsect[0];
 351       zs1 = vsect[1];
 352       zsd = zs1-zs0;
 353       ys0 = vsect[2];
 354       ys1 = vsect[3];
 355       ysd = ys1-ys0;
 356       sl = ysd/zsd;
 357       m = [ [ 1,0,   0,    0 ],
 358             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 359             [ 0,0,   1,  zs0 ],
 360             [ 0,0,   0,    1 ] ];
 361       multmatrix(m)
 362         linear_extrude(height=zsd, convexity=10)
 363         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 364     }
 365   }
 366 }
 367
 368 function TestPiece_holes2corners(holes) =
 369   [ holes[0] + thehd_bl,
 370     holes[1] + thehd_br,
 371     holes[1] + thehd_tr,
 372     holes[0] + thehd_tl ];
 373
 374 module TestPiece1(){ ////toplevel
 375   holes = [ [-100, 0],
 376             [   0, 0]
 377             ];
 378   corners = TestPiece_holes2corners(holes);
 379   rcs = R_CNR(corners,0);
 380   difference(){
 381     union(){
 382       TileBase(corners[0], corners[2]);
 383       Posts(holes);
 384       RoundEdge(corners[0], corners[1]);
 385       RoundEdge(corners[3], corners[0]);
 386     }
 387     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 388     RoundCornerCut(rcs);
 389   }
 390   RoundCornerAdd(rcs);
 391 }
 392
 393 module TestPiece2(){ ////toplevel
 394   holes = [ [   0, 0],
 395             [  50, 0]
 396             ];
 397   corners = TestPiece_holes2corners(holes);
 398   TileBase(corners[0], corners[2]);
 399   Posts(holes);
 400   RoundEdge(corners[0], corners[1]);
 401   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 402 }
 403
 404 module TestDemo(){ ////toplevel
 405   translate([ -thehd[0], 0 ])
 406     color("blue")
 407     TestPiece1();
 408   translate([ +thehd[0] + demo_slop, 0 ])
 409     TestPiece2();
 410 }
 411
 412 module Machine_Arm(){
 413   ysz = cutout_l_end_y_total;
 414   // assume the round end is arc of a circle
 415   chordlen = dist2d([0,0], [ cutout_l_end_y, cutout_l_end_curve ]);
 416   endrad = cutout_l_end_y / cutout_l_end_curve * chordlen;
 417
 418   translate([0,0,-30]) linear_extrude(height=60) {
 419     translate(tile01_tr + [0, (-cutout_tile01_y + cutout_tile11_y)/2]) {
 420       intersection(){
 421         translate([-50, -ysz/2])
 422           square([400, ysz]);
 423         translate([ endrad - cutout_tile11_x - cutout_l_end_x_slop, 0 ])
 424           circle(r=endrad, $fa=0.01,$fd=5);
 425       }
 426     }
 427   }
 428 }
 429
 430 module Machine_NewRearProfile(){
 431   // figures copied out of xfig edit boxes
 432   // best not to edit the posbox size if poss - just move it
 433   posbox = 10 * ([7.2333,-14.1267] - [-16.2289,40.0289]); // box, Green
 434   sideline = -10 * ([-6.2400,13.5600] - [-2.4467,28.2556]); // line, Blue
 435   scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
 436   scaleline_mm = 12+5+10+5+3;
 437   sh = -[abs(posbox[0]), abs(posbox[1])];
 438   rot = atan2(-sideline[0], sideline[1]);
 439   sc = scaleline_mm / scaleline;
 440   //echo("SH",sh,rot,sc);
 441   scale(sc) rotate(rot) translate(sh){
 442     import("sewing-table-rear-profile.dxf", convexity=10); // spline, Pink3
 443   }
 444 }
 445
 446 module Machine_NewFrontProfile(){
 447   // figures copied out of xfig edit boxes
 448   // best not to edit the posbox size if poss - just move it
 449   posbox = 10 * ([11.8022,8.0600] - [4.2044,19.1867]); // box, Green
 450   refline = 10 * ([7.6778,16.7222] - [27.8689,17.6578]); // line, Blue
 451   refline_mm = (11-1)*10;
 452   sh = -[abs(posbox[0]), abs(posbox[1])];
 453   rot = atan2(-refline[0], refline[1]);
 454   sc = refline_mm / vectorlen2d(refline);
 455   //echo("SH",sh,rot,sc);
 456   mirror([1,0]) scale(sc) rotate(rot+90) translate(sh){
 457     import("sewing-table-front-profile.dxf", convexity=10); // spline, Pink3
 458   }
 459 }
 460
 461 module Machine_NewEndProfile(){
 462   // figures copied out of xfig edit boxes
 463   // best not to edit the posbox size if poss - just move it
 464   posboxs = 10 * [[4.0400,17.7956], [11.6622,32.5511]]; // box, Pink3
 465   refline = 10 * ([8.4000,22.6000] - [50.3000,22.2000]); // line, Blue
 466   refline_mm = 10 * (11 - 2.5);
 467   sidelines = 10 * [[[9.0889,20.6178], [8.9644,14.6889]],
 468                     [[50.3800,21.9578], [50.1933,14.4933]]]; // lines, Blue3
 469   baseline = 10 * [[8.4000,18.0822], [50.3000,17.6822]]; // line, Green2
 470
 471   posbox = [min(posboxs[0][0],posboxs[1][0]),
 472             max(posboxs[0][1],posboxs[1][1])];
 473
 474 m4_define(`MNEP_ELP',
 475    `line_intersection_2d(baseline[0],baseline[1],
 476                          sidelines[$1][0],sidelines[$1][1])')
 477   endline = [MNEP_ELP(0),MNEP_ELP(1)];
 478   echo("PBS",posboxs,"PB",posbox,"SL00",sidelines[0][0]);
 479
 480   //%translate(posbox) square(10);
 481
 482   rot = atan2(-refline[1], -refline[0]);
 483   sc = refline_mm / vectorlen2d(refline);
 484   sh = (0.5 * (endline[0] + endline[1])) - posbox;
 485 //  scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
 486 //  scaleline_mm = 12+5+10+5+3;
 487 //  sh = -[abs(posbox[0]), abs(posbox[1])];
 488 //  rot = atan2(-sideline[0], sideline[1]);
 489 //  sc = scaleline_mm / scaleline;
 490   //echo("SH",sh,rot,sc);
 491   scale(sc) rotate(rot) translate(-[sh[0],-sh[1]]){
 492
 493     mirror([0,1]){
 494   //%translate(1 * (posboxs[0] - posbox)) square(50);
 495   //%translate(1 * (posboxs[1] - posbox)) square(50);
 496   %translate(1 * (baseline[0] - posbox)) square([50,10]);
 497
 498   %translate(1 * (endline[0] - posbox)) square([50,10]);
 499   %translate(1 * (endline[1] - posbox)) square([50,10]);
 500
 501 //  %translate(1 * (sidelines[0][0] - posbox)) square([10,50]);
 502 //  %translate(1 * (sidelines[0][1] - posbox)) square([10,50]);
 503 //  %translate(1 * (sidelines[1][0] - posbox)) square([10,50]);
 504 //  %translate(1 * (sidelines[1][1] - posbox)) square([10,50]);
 505     }
 506
 507     import("sewing-table-end-profile.dxf", convexity=10); // spline, Pink3
 508   }
 509 }
 510
 511 module Machine_NewRearCurve(){
 512   slant = atan2(4,210-10);
 513   //echo("SL",slant);
 514   translate([0,0, rearcurve_double_inrad]) rotate([slant,0,0]){
 515     translate([ rearcurve_double_inrad,
 516                 0,
 517                 -rearcurve_double_inrad + 10 ]){
 518       rotate([180,0,0]) rotate([0,0,90]) linear_extrude(height=30){
 519         hull(){
 520           Machine_NewRearProfile();
 521           translate([0,-100]) Machine_NewRearProfile();
 522         }
 523       }
 524     }
 525     rotate([0,90,0]) rotate([90,0,0]) {
 526       intersection(){
 527         rotate_extrude(convexity=10, $fn=64)
 528           rotate(90)
 529           translate([ 0, -rearcurve_double_inrad ])
 530           Machine_NewRearProfile();
 531         translate([0,0,-500])
 532           cube([500,500,1000]);
 533       }
 534     }
 535     translate([1,0,-rearcurve_double_inrad])
 536       rotate([0,-90,0]) rotate([0,0,-90])
 537       linear_extrude(height= rearcurve_strt_len + 1)
 538       Machine_NewRearProfile();
 539   }
 540 }
 541
 542 module Machine_Curves(){ ////toplevel
 543   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 544               cutout_tile11_y,
 545               0 ]){
 546     //%cube([20,20,20]);
 547     translate([ -reartablet_x,
 548                 -1,
 549                 -reartablet_z + tablet_z_slop])
 550       mirror([0,0,1])
 551       cube([ reartablet_x+1,
 552              reartablet_y+1,
 553              20 ]);
 554   }
 555   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 556               cutout_tile11_y,
 557               frontcurve_z_slop ]){
 558     translate([0, -machine_rear_to_front, 0])
 559       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 560                   [0,  1,   0, 0],
 561                   [0,  0,   1, 0],
 562                   [0,  0,   0, 1]])
 563       mirror([1,0,0]) rotate([0,-90,0])rotate([0,0,-90])
 564       linear_extrude(height= 200)
 565       Machine_NewFrontProfile();
 566
 567     translate([ rearcurve_strt_len,
 568                 0,
 569                 rearcurve_z_slop ]){
 570       Machine_NewRearCurve();
 571     }
 572   }
 573 }
 574
 575 module TestStrapSlots(){
 576   pegwidth = teststrap_peg[0];
 577   for (pos = teststrapslots_at) {
 578     echo("TSS",pos);
 579     translate(concat(pos,[0]))
 580       for (mx = [0,1]) mirror([mx,0,0]) {
 581           translate([ pegwidth/2, -teststrap[1]/2, -20 ])
 582             cube(concat(teststrap,[40]));
 583         }
 584   }
 585 }
 586
 587 module TestStrapPeg_any(l){ cube(concat([l],teststrap_peg)); }
 588
 589 module TestStrapPeg_Short(){ ////toplevel
 590   TestStrapPeg_any(35);
 591 }
 592
 593 module TestStrapPeg_Long(){ ////toplevel
 594   TestStrapPeg_any(60);
 595 }
 596
 597 module Machine(){ ////toplevel
 598   Machine_Arm();
 599   Machine_Curves();
 600   if (TEST)
 601     TestStrapSlots();
 602 }
 603
 604 module MachineEnvelope(){
 605   // used for testing
 606   p_arm_bl = [-cutout_tile11_x, -cutout_tile01_y];
 607   y_arm_t  = cutout_tile11_y;
 608   p_crv_fl = p_arm_bl + [rearedge_len, -frontcurve_avoid_y];
 609   y_crv_b  = y_arm_t + rearcurve_avoid_y;
 610
 611   translate([0,0,-50]) linear_extrude(height= 100){
 612     translate(p_arm_bl) square([400, y_arm_t] - p_arm_bl);
 613     translate(p_crv_fl) square([400, y_crv_b] - p_crv_fl);
 614   }
 615 }
 616
 617 function Rectangle_corners(c0, sz) =
 618   // returns the corners of a rectangle from c0 to c0+sz
 619   // if sz is positive, the corners are anticlockwise starting with c0
 620   [ c0 + [ 0,     0     ],
 621     c0 + [ sz[0], 0     ],
 622     c0 + [ sz[0], sz[1] ],
 623     c0 + [ 0,     sz[1] ] ];
 624
 625 function Rectangle_corners2posts(c) =
 626   [ c[0] + thehd_tr,
 627     c[1] + thehd_tl,
 628     c[2] + thehd_bl,
 629     c[3] + thehd_br ];
 630
 631 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 632
 633 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 634
 635 module Tile02(){ ////toplevel
 636   sz = [100,170];
 637   c0 = tile02_tr + -sz;
 638   c = Rectangle_corners(c0, sz);
 639   posts = Rectangle_corners2posts(c);
 640   rcs = R_CNR(c,0);
 641   difference(){
 642     union(){
 643       Rectangle_TileBase(c);
 644       Posts(posts);
 645       RoundEdge(R_EDGE(c,0));
 646       RoundEdge(R_EDGE(c,3));
 647       InterlockEdge(R_EDGE(c,2), 0);
 648     }
 649     InterlockEdge(R_EDGE(c,1), 1);
 650     RoundCornerCut(rcs);
 651   }
 652   RoundCornerAdd(rcs);
 653 }
 654
 655 module Tile12(){ ////toplevel
 656   sz = [100,250];
 657   c0 = tile02_tr + [-sz[0], 0];
 658   c = Rectangle_corners(c0, sz);
 659   posts = Rectangle_corners2posts(c);
 660   rcs = R_CNR(c,3);
 661   difference(){
 662     union(){
 663       Rectangle_TileBase(c);
 664       Posts(posts);
 665       RoundEdge(R_EDGE(c,2));
 666       RoundEdge(R_EDGE(c,3));
 667     }
 668     InterlockEdge(R_EDGE(c,0), 1);
 669     InterlockEdge(R_EDGE(c,1), 1);
 670     RoundCornerCut(rcs);
 671   }
 672   RoundCornerAdd(rcs);
 673 }
 674
 675 tile_01_11_cnr = tile01_tr + [-cutout_tile11_x, 0];
 676 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 677 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 678
 679 module Tile11(){ ////toplevel
 680   sz = [250,250];
 681   c0 = tile01_tr + [-sz[0],0];
 682   c = Rectangle_corners(c0, sz);
 683   cnr_posts = Rectangle_corners2posts(c);
 684   posts = concat(
 685                  Posts_interpolate_one(cnr_posts[0],
 686                                        cnr_posts[1] - [cutout_tile11_x, 0]),
 687                  [ cnr_posts[1] + [0, cutout_tile11_y],
 688                    cnr_posts[2],
 689                    cnr_posts[3]
 690                    ]);
 691   difference(){
 692     union(){
 693       Rectangle_TileBase(c);
 694       Posts(posts);
 695       RoundEdge(R_EDGE(c,2));
 696       InterlockEdge(R_EDGE(c,3));
 697     }
 698     InterlockEdge(c[0], tile_01_11_cnr, 1);
 699     InterlockEdge(tile_11_10_cnr, c[2], 1);
 700     Machine();
 701   }
 702 }
 703
 704 module Tile01(){ ////toplevel
 705   sz = [250,170];
 706   c0 = tile01_tr + -sz;
 707   c = Rectangle_corners(c0, sz);
 708   cnr_posts = Rectangle_corners2posts(c);
 709   posts = concat(
 710                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 711                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 712                  Posts_interpolate_one(cnr_posts[2] - [cutout_tile11_x, 0],
 713                                        cnr_posts[3])
 714                  );
 715   difference(){
 716     union(){
 717       Rectangle_TileBase(c);
 718       Posts(posts);
 719       RoundEdge(R_EDGE(c,0));
 720       InterlockEdge(tile_01_11_cnr, c[3]);
 721       InterlockEdge(R_EDGE(c,3));
 722     }
 723     InterlockEdge(c[1], tile_01_00_cnr, 1);
 724     Machine();
 725   }
 726 }
 727
 728 module Tile10(){ ////toplevel
 729   sz = [250,250];
 730   c0 = tile01_tr + [0,0];
 731   c = Rectangle_corners(c0, sz);
 732   cnr_posts = Rectangle_corners2posts(c);
 733   cty = cutout_tile11_y;
 734   rcy = cty + rearcurve_avoid_y;
 735   posts = [ cnr_posts[0] + [ 0,                             cty ],
 736             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 737             cnr_posts[1] + [ 0,                             rcy ],
 738             cnr_posts[2],
 739             cnr_posts[3] ];
 740   rcs = R_CNR(c,2);
 741   difference(){
 742     union(){
 743       Rectangle_TileBase(c);
 744       Posts(posts);
 745       RoundEdge(R_EDGE(c,1));
 746       RoundEdge(R_EDGE(c,2));
 747       InterlockEdge(c[3], tile_11_10_cnr);
 748     }
 749     RoundCornerCut(rcs);
 750     Machine();
 751   }
 752   RoundCornerAdd(rcs);
 753 }
 754
 755 module Tile00(){ ////toplevel
 756   sz = [250,170];
 757   c0 = tile01_tr + [0,-sz[1]];
 758   c = Rectangle_corners(c0, sz);
 759
 760   // the edge c[1]..c[2] needs a diagonal chunk, from c1bis to c2bis
 761   c2bis = [ -cutout_l_end_x + rearedge_len + frontcurve_strt_len, c[2][1] ];
 762   c1bis = [ c[1][0],
 763             c[2][1] -
 764             (c[2][0] - c2bis[0]) * tan(90 - frontcurve_dualcurve_angle) ];
 765
 766   cnr_posts = Rectangle_corners2posts(c);
 767   cty = cutout_tile01_y;
 768   rcy = cty + frontcurve_avoid_y;
 769   posts = [ cnr_posts[0],
 770             cnr_posts[1],
 771             cnr_posts[2] + [ 0,                             -rcy ],
 772             cnr_posts[2] + [ -sz[0] + rearedge_len - cutout_l_end_x, -cty ],
 773             cnr_posts[3] + [ 0,                             -cty ]
 774             ];
 775   rcs = R_CNR(c,1);
 776   rc2 = [c1bis,c2bis,c[1]];
 777   difference(){
 778     union(){
 779       difference(){
 780         union(){
 781           Rectangle_TileBase(c);
 782           Posts(posts);
 783           RoundEdge(R_EDGE(c,0));
 784           RoundEdge(c[1], c1bis);
 785           InterlockEdge(tile_01_00_cnr, c[0]);
 786         }
 787         RoundCornerCut(rcs);
 788         translate([0,0,-20]) linear_extrude(height=40) {
 789           polygon([ c1bis, c1bis + [50,0], c2bis + [50,0], c2bis ]);
 790         }
 791       }
 792       RoundEdge(c1bis, c2bis);
 793     }
 794     Machine();
 795     RoundCornerCut(rc2);
 796   }
 797   RoundCornerAdd(rcs);
 798   RoundCornerAdd(rc2);
 799 }
 800
 801 module FitTest_general(c0,sz, dobrace=false, bracexx=0){
 802   c = Rectangle_corners(c0, sz);
 803   brace = [7,7,9];
 804   bsz = sz + [bracexx,0,0];
 805   difference(){
 806     union(){
 807       Rectangle_TileBase(c);
 808       if (dobrace) {
 809         translate(concat(c0, [-brace[2] + 0.1])){
 810           difference(){
 811             cube(concat(bsz, [brace[2]]) - [5,0,0]);
 812             translate(brace + [0,0, -25])
 813               cube(concat(bsz, [50]) - brace*2 + [10,0,0]);
 814           }
 815         }
 816       }
 817       RoundEdge(R_EDGE(c,1));
 818     }
 819     Machine();
 820   }
 821 }
 822
 823 module FitTest_PairLink(cut=false){ ////toplevel
 824   cy0=-55; cy1=85; cx=132;
 825   bar = [10,10];
 826   legrad = 12;
 827   footrad_min = 1; footrad_max = 4; footrad_depth = 5;
 828   strap = [3,5];
 829   adj_neg_slop = 1.0;
 830   bar_z_slop = 1.75;
 831
 832   // calculated
 833   straphole_x_max = legrad/sqrt(2) + footrad_max;
 834   dz = cut ? adj_neg_slop : 0;
 835
 836   translate([cx - bar[0]/2, cy0, dz + bar_z_slop])
 837     cube([bar[0], cy1-cy0, bar[1] - bar_z_slop]);
 838
 839   for (endy=[cy0,cy1]) {
 840     $fn=32;
 841     translate([cx,endy,dz]){
 842       // feet
 843       for (rot=[45:90:315]) rotate(rot) {
 844         translate([legrad,0,0]){
 845           hull(){
 846             cylinder(r= footrad_max, h=1);
 847             translate([0,0,-footrad_depth])
 848               cylinder(r= footrad_min, h=1);
 849           }
 850           if (cut)
 851             translate([0,0,-10])
 852             cylinder(r= footrad_min +
 853                      adj_neg_slop * (footrad_max-footrad_min)/footrad_depth,
 854                      h=20);
 855         }
 856       }
 857       // legs
 858       for (rot=[45,135]) rotate(rot) {
 859         hull(){
 860           for (s=[-1,+1]){
 861             translate([s*legrad,0,0])
 862               cylinder(r= footrad_max, h=bar[1]);
 863           }
 864         }
 865       }
 866       // strap holes
 867       if (cut) {
 868         for (rot=[0,180]) rotate(rot) {
 869             translate([ straphole_x_max - strap[0]/2, 0,0 ])
 870               cube(concat(strap,[20]), center=true);
 871           }
 872       }
 873     }
 874   }
 875 }
 876
 877 module FitTest_RearCurve(){ ////toplevel
 878   difference(){
 879     FitTest_general([100,0], [180,100]);
 880     FitTest_PairLink(true);
 881     TestStrapSlots();
 882   }
 883 }
 884
 885 module FitTest_FrontCurve(){ ////toplevel
 886   p0 = [100,-80];
 887   sz = [180,80];
 888   difference(){
 889     intersection() {
 890       Tile00();
 891       translate([0,0,-8]) linear_extrude(height=18) {
 892         translate(p0) square(sz);
 893         translate(teststrapslots_at[3])
 894           scale(2* [ teststrap_peg[0], teststrap[1] ])
 895           circle(r=1, $fn=20);
 896       }
 897     }
 898     FitTest_PairLink(true);
 899     TestStrapSlots();
 900   }
 901 }
 902
 903 module FitTest_Entire(){ ////toplevel
 904   p0 = [-33,-80];
 905   szrear = [263,180];
 906   szfront = [243,szrear[1]];
 907   difference(){
 908     FitTest_general(p0, szrear, dobrace=true, bracexx=0);
 909     FitTest_PairLink(true);
 910     translate(concat(p0,[0]) + [szfront[0],-10,-40])
 911       cube([100, -p0[1], 80]);
 912     TestStrapSlots();
 913   }
 914   intersection(){
 915     FitTest_RearCurve();
 916     translate(concat(p0,[-20])) cube(concat(szrear,[40]));
 917   }
 918   FitTest_FrontCurve();
 919 }
 920
 921 module FitTest_EntireDemo(){ ////toplevel
 922   FitTest_Entire();
 923   //%Tile00();
 924 }
 925
 926 module FitTest_EndEnd(){ ////toplevel
 927   p0 = [-32,-32];
 928   sz = [188,113];
 929   sz2 = [168,100];
 930   difference(){
 931     FitTest_general(p0, sz);
 932     translate([ p0[0] -1, p0[1]+sz2[1], -10])
 933       cube([ sz2[0] +1, 50, 20 ]);
 934   }
 935 }
 936
 937 module FitTest_PairDemo(){ ////toplevel
 938   sh=[-90,-15,0];
 939   translate(sh){
 940     FitTest_PairLink();
 941     %FitTest_FrontCurve();
 942     %FitTest_RearCurve();
 943   }
 944   rotate([0,0,180]){
 945     translate(sh){
 946       difference(){
 947         union(){
 948           FitTest_FrontCurve();
 949           FitTest_RearCurve();
 950         }
 951         #FitTest_PairLink(true);
 952       }
 953     }
 954   }
 955 }
 956
 957 module RoundCornerDemo_plat(cnr){
 958   mirror([0,0,1]) linear_extrude(height=1) polygon(cnr);
 959 }
 960
 961 module RoundCornerDemo(){ ////toplevel
 962   cnr = [ [-2,-3], [13,-3], [-12,9] ];
 963   translate([0,25,0]) RoundCornerDemo_plat(cnr);
 964   translate([25,0,0]) RoundCornerAdd(cnr);
 965   translate([-25,0,0]) RoundCornerCut(cnr);
 966   translate([0,-25,0]) RoundCorner_selector(cnr, 0);
 967   difference(){
 968     RoundCornerDemo_plat(cnr);
 969     RoundCornerCut(cnr);
 970   }
 971   RoundCornerAdd(cnr);
 972 }
 973
 974 module Demo(){ ////toplevel
 975   translate(demo_slop*[-2,1]) color("blue") Tile12();
 976   translate(demo_slop*[-2,0]) color("red")  Tile02();
 977   translate(demo_slop*[-2,1]) color("orange") Tile11();
 978   translate(demo_slop*[-2,0]) color("purple") Tile01();
 979   translate(demo_slop*[-3,1]) color("blue")   Tile10();
 980   translate(demo_slop*[-3,0]) color("red")    Tile00();
 981   %Machine();
 982 }
 983
 984 //TestPiece1();
 985 //TestPiece2();
 986 //Demo();
 987
 988 //Machine_NewRearProfile();
 989 //Machine_NewRearCurve();
 990 //Machine_NewFrontProfile();
 991 //Machine_NewEndProfile();
 992 //Machine_Curves();
 993 //Machine();
 994 //FitTest();
 995 //MachineEnvelope();