sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 tile_th = 3;
  11 post_dia = 8;
  12
  13 post_shorter = 1;
  14
  15 screw_dia = 2.2;
  16 screw_big_dia = 3.6;
  17 screw_big_len = 4.0;
  18
  19 round_edge_rad = 2.0;
  20
  21 round_cnr_rad = 10;
  22
  23 interlock_dia = 10;
  24 interlock_fine = 0.66;
  25
  26 interlock_fine_slope = 1.0;
  27 interlock_fine_lenslop = 1.0;
  28
  29 demo_slop = 0.1;
  30
  31 // cutout
  32
  33 machine_rear_to_front = 85;
  34
  35 machine_rear_profile = [
  36                         [ -  0,  -0.00 ],
  37                         [ -  2,  -0.10 ],
  38                         [ -  4,  -0.20 ],
  39                         [ -  5,  -0.30 ],
  40                         [ -  6,  -0.40 ],
  41                         [ -  7,  -0.50 ],
  42                         [ -  8,  -0.75 ],
  43                         [ - 10,  -1.50 ],
  44                         [ - 12,  -2.25 ],
  45                         [ - 14,  -3.25 ],
  46                         [ - 16,  -4.25 ],
  47                         [ - 18,  -5.75 ],
  48                         [ - 20,  -8.00 ]
  49                         ];
  50
  51 machine_front_profile =  [
  52                           [  128,  -3.70,  ],
  53                           [  124,  -2.90,  ],
  54                           [  120,  -2.45,  ],
  55                           [  116,  -2.10,  ],
  56                           [  112,  -1.80,  ],
  57                           [  108,  -1.55,  ],
  58                           [  104,  -1.25,  ],
  59                           [  100,  -1.00,  ],
  60                           [   96,  -0.80,  ],
  61                           [   92,  -0.65,  ],
  62                           [   88,  -0.55,  ],
  63                           [   84,  -0.50,  ]
  64                           ];
  65
  66 cutout_l_end_y_front_slop = 0.5;
  67 cutout_l_end_y_rear_slop = 0.5;
  68 cutout_l_end_x_slop = 0.25;
  69
  70 cutout_l_end_x = 22;
  71 cutout_l_end_y = machine_rear_to_front;
  72 cutout_l_end_curve = 1;
  73 cutout_l_end_y_total = cutout_l_end_y
  74   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  75
  76 tile02_tr = [-250, 0];
  77 tile01_tr = [  0, 0];
  78
  79 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  80 cutout_tile11_x = cutout_l_end_x + cutout_l_end_curve;
  81 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  82
  83 // front and rear curves
  84
  85 rearedge_len = 170;
  86
  87 rearcurve_strt_len = 52;
  88
  89 rearcurve_z_slop = 0.75;
  90
  91 rearcurve_avoid_y = 35;
  92
  93 rearcurve_double_inrad = 26.10 + 8.04;
  94
  95 reartablet_z = 2.54;
  96 reartablet_x = 5 + 1;
  97 reartablet_y = 8;
  98
  99 frontcurve_side_skew = 3.5 / 72;
 100 frontcurve_avoid_y = 70;
 101 frontcurve_z_slop = 0.75;
 102
 103 frontcurve_strt_len = 60;
 104 frontcurve_dualcurve_angle = 90 - 65;
 105
 106 // calculated
 107
 108 TEST = false;
 109
 110 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
 111
 112 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
 113
 114 hole_slop = (ply_hole_dia - post_dia)/2;
 115 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
 116
 117 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
 118          tile_hard_edge_hole_dist));
 119
 120 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
 121          tile_hard_edge_hole_dist + round_edge_rad));
 122
 123 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
 124 thehd_tr = thehd;
 125 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 126 thehd_bl = -thehd_tr;
 127 thehd_br = -thehd_tl;
 128
 129 tablet_z_slop = rearcurve_z_slop;
 130
 131 interlock_rad = interlock_dia/2;
 132 interlock_negative_rad = interlock_rad + 0.125;
 133
 134 interlock_sq_adj = 0.2; // arbitrary
 135
 136 first_front = machine_front_profile[len(machine_front_profile)-1];
 137
 138 m4_define(`POST_TCROSSSZ',
 139           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 140
 141 module Post(){
 142   mirror([0,0,1]) {
 143     difference(){
 144       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 145       translate([0,0, tile_th]) {
 146         cylinder(r= screw_big_dia/2, h= screw_big_len);
 147         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
 148       }
 149     }
 150     if (TEST) {
 151       translate([0,0, tile_th/2]) {
 152         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 153         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 154       }
 155     }
 156   }
 157 }
 158
 159 module Posts(posts) {
 160   for (p= posts) {
 161     translate(concat(p, [0]))
 162       Post();
 163   }
 164 }
 165
 166 module TileBase(botleft, topright){
 167   size = topright - botleft;
 168   botleft_post = botleft + thehd_tr;
 169   topright_post = topright + thehd_bl;
 170   difference(){
 171     mirror([0,0,1])
 172       translate(concat(botleft, [0]))
 173       cube(concat(size, [tile_th]));
 174     if (!TEST) {
 175       cidsz = topright_post-botleft_post
 176         + [-post_dia,-post_dia]
 177         + [0, thehd[1]];
 178       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
 179       echo("CID",cidsz,cidszr);
 180       translate( concat(botleft_post, [ -tile_th ])
 181                  + 0.5 * [ post_dia, post_dia, 0 ]
 182                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
 183         Commitid_BestCount_M(cidszr);
 184     }
 185     if (TEST) {
 186       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
 187       cidsz = [ thehd[0], size[1] - 2*crossoff ];
 188       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
 189       translate( concat(botleft + [0, crossoff] + (cidsz-cidszr)/2, [0]) )
 190         Commitid_BestCount(cidszr);
 191       difference(){
 192         mirror([0,0,1]) {
 193           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 194             cube(concat(size - [test_edge,test_edge]*2, [tile_th]));
 195           translate(concat(botleft_post, [-1]))
 196             cube(concat(topright_post-botleft_post, [tile_th+2]));
 197         }
 198         shufflesz = max(test_edge, tile_hard_edge_hole_dist)*2;
 199         minkowski(){
 200           MachineEnvelope();
 201           cube(shufflesz, center=true);
 202         }
 203       }
 204     }
 205   }
 206 }
 207
 208 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 209 m4_define(`INREFFRAME',`
 210   length_vec = ($2) - ($1);
 211   length = dist2d([0,0], length_vec);
 212   length_uvec = length_vec / length;
 213   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 214   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 215         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 216         [ 0,              0,              1,            0, ],
 217         [ 0,              0,              0,            1, ] ];
 218   $3
 219   multmatrix(m)
 220 ')
 221
 222 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 223 m4_dnl    INREFFRAME_EDGE { body; }
 224 m4_define(`INREFFRAME_EDGE',`
 225   translate([0,0, -round_edge_rad])
 226 ')
 227
 228 module RoundEdge(left_cnr, right_cnr) {
 229   INREFFRAME(left_cnr, right_cnr)
 230     INREFFRAME_EDGE {
 231     difference(){
 232       rotate([0,90,0])
 233         cylinder(r= round_edge_rad, h= length, $fn=50);
 234       translate([-1, 0, -20])
 235         cube([length+2, 20, 20]);
 236     }
 237   }
 238 }
 239
 240 module RoundCornerCut(ci) {
 241   // ci should be [this_cnr, right_cnr]
 242   // where right_cnr is to the right (ie, anticlockwise)
 243   this_cnr = ci[0];
 244   right_cnr = ci[1];
 245   offr= round_cnr_rad - round_edge_rad;
 246   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 247     difference(){
 248       cube(offr*2 - 0.1, center=true);
 249       translate([offr, offr, 0])
 250         cylinder(center=true, h=20, r= offr);
 251     }
 252   }
 253 }
 254
 255 module RoundCornerAdd(ci) {
 256   this_cnr = ci[0];
 257   right_cnr = ci[1];
 258   bigr = round_cnr_rad - round_edge_rad;
 259   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 260     intersection(){
 261       cube(bigr*2 + 0.1, center=true);
 262       translate([bigr, bigr, 0])
 263         rotate_extrude(convexity=10, $fn=50)
 264         translate([bigr, 0])
 265         difference(){
 266           circle(r= round_edge_rad, $fn=50);
 267           mirror([1,1])
 268             square([20,20]);
 269         }
 270     }
 271   }
 272 }
 273
 274 module InterlockLobePlan(negative) {
 275   r = negative ? interlock_negative_rad : interlock_rad;
 276   ymir = negative ? 0 : 1;
 277
 278   dx = sqrt(3) * r;
 279   $fn= 80;
 280   translate([thehd[0], 0]){
 281     mirror([0,ymir]){
 282       circle(r=r);
 283       difference(){
 284         translate([-dx, -0.1])
 285           square([ dx*2, r/2 + 0.1 ]);
 286         for (xi = [-1, 1]) {
 287           translate([ xi*dx, r ])
 288             circle(r=r);
 289         }
 290       }
 291     }
 292   }
 293 }
 294
 295 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 296   for (lobei = [ 0 : nlobes-1 ]) {
 297     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 298     translate([lobex, 0, 0]) {
 299       InterlockLobePlan(negative);
 300     }
 301   }
 302
 303   if (dosquare) {
 304     iadj = 0;
 305     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 306     mirror([0, negative])
 307       translate([slotshorter, iadj])
 308       square([length - slotshorter*2, interlock_fine + iadj*2]);
 309   }
 310 }
 311
 312 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 313   plusth = negative * 1.0;
 314   protr = interlock_fine + interlock_sq_adj;
 315
 316   z2 = -tile_th/2;
 317   z1 = -tile_th/2 - protr / interlock_fine_slope;
 318   z3 = -tile_th/2 + protr / interlock_fine_slope;
 319
 320   negsign = negative ? -1 : +1;
 321   yprotr = negsign * protr;
 322
 323   INREFFRAME(left_cnr, right_cnr) {
 324     for (vsect = [ // zs0            zs1      ys0,            ys1
 325                   [ -tile_th-plusth, plusth,  0,              0],
 326                   [ z1,              z2,      0, yprotr],
 327                   [ z2,              z3,      yprotr, 0],
 328                   ]) {
 329       zs0 = vsect[0];
 330       zs1 = vsect[1];
 331       zsd = zs1-zs0;
 332       ys0 = vsect[2];
 333       ys1 = vsect[3];
 334       ysd = ys1-ys0;
 335       sl = ysd/zsd;
 336       m = [ [ 1,0,   0,    0 ],
 337             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 338             [ 0,0,   1,  zs0 ],
 339             [ 0,0,   0,    1 ] ];
 340       multmatrix(m)
 341         linear_extrude(height=zsd, convexity=10)
 342         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 343     }
 344   }
 345 }
 346
 347 function TestPiece_holes2corners(holes) =
 348   [ holes[0] + thehd_bl,
 349     holes[1] + thehd_br,
 350     holes[1] + thehd_tr,
 351     holes[0] + thehd_tl ];
 352
 353 module TestPiece1(){ ////toplevel
 354   holes = [ [-100, 0],
 355             [   0, 0]
 356             ];
 357   corners = TestPiece_holes2corners(holes);
 358   rcs = [corners[0], corners[1]];
 359   difference(){
 360     union(){
 361       TileBase(corners[0], corners[2]);
 362       Posts(holes);
 363       RoundEdge(corners[0], corners[1]);
 364       RoundEdge(corners[3], corners[0]);
 365     }
 366     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 367     RoundCornerCut(rcs);
 368   }
 369   RoundCornerAdd(rcs);
 370 }
 371
 372 module TestPiece2(){ ////toplevel
 373   holes = [ [   0, 0],
 374             [  50, 0]
 375             ];
 376   corners = TestPiece_holes2corners(holes);
 377   TileBase(corners[0], corners[2]);
 378   Posts(holes);
 379   RoundEdge(corners[0], corners[1]);
 380   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 381 }
 382
 383 module TestDemo(){ ////toplevel
 384   translate([ -thehd[0], 0 ])
 385     color("blue")
 386     TestPiece1();
 387   translate([ +thehd[0] + demo_slop, 0 ])
 388     TestPiece2();
 389 }
 390
 391 module Machine_Arm(){
 392   ysz = cutout_l_end_y_total;
 393   // assume the round end is arc of a circle
 394   chordlen = dist2d([0,0], [ cutout_l_end_y, cutout_l_end_curve ]);
 395   endrad = cutout_l_end_y / cutout_l_end_curve * chordlen;
 396
 397   translate([0,0,-30]) linear_extrude(height=60) {
 398     translate(tile01_tr + [0, (-cutout_tile01_y + cutout_tile11_y)/2]) {
 399       intersection(){
 400         translate([-50, -ysz/2])
 401           square([400, ysz]);
 402         translate([ endrad - cutout_tile11_x - cutout_l_end_x_slop, 0 ])
 403           circle(r=endrad, $fa=0.01,$fd=5);
 404       }
 405     }
 406   }
 407 }
 408
 409 module Machine_Profile(){
 410   first_rear = machine_rear_profile[0];
 411   below_point = 0.5 * ( first_rear + first_front ) + [ 0, -10 ];
 412   pol = concat( machine_rear_profile,
 413                 [ below_point ],
 414                 machine_front_profile);
 415   skew_angle = atan2( first_front[1] - first_rear[1],
 416                       first_front[0] - first_rear[0] );
 417   //echo(below_point, pol, skew_angle);
 418   hull(){
 419     for (z=[0,-40]) {
 420       translate([0,z]) {
 421         //scale([1,5])
 422         rotate([0,0, -skew_angle ]){
 423           //translate( - first_front )
 424           polygon(pol);
 425         }
 426       }
 427     }
 428   }
 429 }
 430
 431 module Machine_NewRearProfile(){
 432   // figures copied out of xfig edit boxes
 433   // best not to edit the posbox size if poss - just move it
 434   posbox = 10 * ([7.2333,-14.1267] - [-16.2289,40.0289]); // box, Green
 435   sideline = -10 * ([-6.2400,13.5600] - [-2.4467,28.2556]); // line, Blue
 436   scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
 437   scaleline_mm = 12+5+10+5+3;
 438   sh = -[abs(posbox[0]), abs(posbox[1])];
 439   rot = atan2(-sideline[0], sideline[1]);
 440   sc = scaleline_mm / scaleline;
 441   //echo("SH",sh,rot,sc);
 442   scale(sc) rotate(rot) translate(sh){
 443     import("sewing-table-rear-profile.dxf", convexity=10); // spline, Pink3
 444   }
 445 }
 446
 447 module Machine_NewRearCurve(){
 448   slant = atan2(4,210-10);
 449   //echo("SL",slant);
 450   translate([0,0, rearcurve_double_inrad]) rotate([slant,0,0]){
 451     translate([ rearcurve_double_inrad,
 452                 0,
 453                 -rearcurve_double_inrad + 10 ]){
 454       rotate([180,0,0]) rotate([0,0,90]) linear_extrude(height=30){
 455         hull(){
 456           Machine_NewRearProfile();
 457           translate([0,-100]) Machine_NewRearProfile();
 458         }
 459       }
 460     }
 461     rotate([0,90,0]) rotate([90,0,0]) {
 462       intersection(){
 463         rotate_extrude(convexity=10, $fn=64)
 464           rotate(90)
 465           translate([ 0, -rearcurve_double_inrad ])
 466           Machine_NewRearProfile();
 467         translate([0,0,-500])
 468           cube([500,500,1000]);
 469       }
 470     }
 471     translate([1,0,-rearcurve_double_inrad])
 472       rotate([0,-90,0]) rotate([0,0,-90])
 473       linear_extrude(height= rearcurve_strt_len + 1)
 474       Machine_NewRearProfile();
 475   }
 476 }
 477
 478 module Machine_RearProfile(){ ////toplevel
 479   intersection(){
 480     Machine_Profile();
 481     translate([ -200 + machine_rear_to_front/2, -100 ]) {
 482       square([200,200]);
 483     }
 484   }
 485 }
 486
 487 module Machine_FrontProfile(){
 488   intersection(){
 489     Machine_Profile();
 490     translate([ machine_rear_to_front/2, -100 ]) {
 491       square([200,200]);
 492     }
 493   }
 494 }
 495
 496 module Machine_Curves(){ ////toplevel
 497   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 498               cutout_tile11_y,
 499               0 ]){
 500     //%cube([20,20,20]);
 501     translate([ -reartablet_x,
 502                 -1,
 503                 -reartablet_z + tablet_z_slop])
 504       mirror([0,0,1])
 505       cube([ reartablet_x+1,
 506              reartablet_y+1,
 507              20 ]);
 508   }
 509   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 510               cutout_tile11_y,
 511               frontcurve_z_slop ]){
 512     translate([ 0, -first_front[0] , 0 ])
 513       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 514                   [0,  1,   0, 0],
 515                   [0,  0,   1, 0],
 516                   [0,  0,   0, 1]])
 517       translate([ 0, first_front[0] , 0 ])
 518       mirror([1,0,0]){
 519       rotate([0,-90,0])rotate([0,0,-90]){
 520         linear_extrude(height= 200)
 521           Machine_FrontProfile();
 522       }
 523     }
 524     translate([ rearcurve_strt_len,
 525                 0,
 526                 rearcurve_z_slop ]){
 527       Machine_NewRearCurve();
 528     }
 529   }
 530 }
 531
 532 module Machine(){ ////toplevel
 533   Machine_Arm();
 534   Machine_Curves();
 535 }
 536
 537 module MachineEnvelope(){
 538   // used for testing
 539   p_arm_bl = [-cutout_tile11_x, -cutout_tile01_y];
 540   y_arm_t  = cutout_tile11_y;
 541   p_crv_fl = p_arm_bl + [rearedge_len, -frontcurve_avoid_y];
 542   y_crv_b  = y_arm_t + rearcurve_avoid_y;
 543
 544   translate([0,0,-50]) linear_extrude(height= 100){
 545     translate(p_arm_bl) square([400, y_arm_t] - p_arm_bl);
 546     translate(p_crv_fl) square([400, y_crv_b] - p_crv_fl);
 547   }
 548 }
 549
 550 function Rectangle_corners(c0, sz) =
 551   // returns the corners of a rectangle from c0 to c0+sz
 552   // if sz is positive, the corners are anticlockwise starting with c0
 553   [ c0 + [ 0,     0     ],
 554     c0 + [ sz[0], 0     ],
 555     c0 + [ sz[0], sz[1] ],
 556     c0 + [ 0,     sz[1] ] ];
 557
 558 function Rectangle_corners2posts(c) =
 559   [ c[0] + thehd_tr,
 560     c[1] + thehd_tl,
 561     c[2] + thehd_bl,
 562     c[3] + thehd_br ];
 563
 564 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 565
 566 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 567
 568 m4_dnl   R_EDGE(c,ix)
 569 m4_dnl        c is from Rectangle_corners and
 570 m4_dnl        ix is a corner number
 571 m4_dnl    expands to two comma-separated corners:
 572 m4_dnl    that denoted by ix, and the next one anticlockwise
 573 m4_define(`R_EDGE',`$1[$2],$1[(($2)+1)%4]')
 574
 575 module FitTest_general(c0,sz, dobrace=false){
 576   c = Rectangle_corners(c0, sz);
 577   brace = [7,7,9];
 578   difference(){
 579     union(){
 580       Rectangle_TileBase(c);
 581       if (dobrace) {
 582         translate(concat(c0, [-brace[2] + 0.1])){
 583           difference(){
 584             cube(concat(sz,[brace[2]]) - [5,0,0]);
 585             translate(brace + [0,0, -25])
 586               cube(concat(sz, [50]) - brace*2 + [10,0,0]);
 587           }
 588         }
 589       }
 590       RoundEdge(R_EDGE(c,1));
 591     }
 592     Machine();
 593   }
 594 }
 595
 596 module FitTest_Entire(){ ////toplevel
 597   FitTest_general([-40,-80], [275,180], dobrace=true);
 598 }
 599
 600 module FitTest_RearCurve(){ ////toplevel
 601   FitTest_general([110,0], [170,100]);
 602 }
 603
 604 module FitTest_FrontCurve(){ ////toplevel
 605   FitTest_general([110,-80], [170,80]);
 606 }
 607
 608 module Tile02(){ ////toplevel
 609   sz = [100,170];
 610   c0 = tile02_tr + -sz;
 611   c = Rectangle_corners(c0, sz);
 612   posts = Rectangle_corners2posts(c);
 613   rcs = [R_EDGE(c,0)];
 614   difference(){
 615     union(){
 616       Rectangle_TileBase(c);
 617       Posts(posts);
 618       RoundEdge(R_EDGE(c,0));
 619       RoundEdge(R_EDGE(c,3));
 620       InterlockEdge(R_EDGE(c,2), 0);
 621     }
 622     InterlockEdge(R_EDGE(c,1), 1);
 623     RoundCornerCut(rcs);
 624   }
 625   RoundCornerAdd(rcs);
 626 }
 627
 628 module Tile12(){ ////toplevel
 629   sz = [100,250];
 630   c0 = tile02_tr + [-sz[0], 0];
 631   c = Rectangle_corners(c0, sz);
 632   posts = Rectangle_corners2posts(c);
 633   rcs = [R_EDGE(c,3)];
 634   difference(){
 635     union(){
 636       Rectangle_TileBase(c);
 637       Posts(posts);
 638       RoundEdge(R_EDGE(c,2));
 639       RoundEdge(R_EDGE(c,3));
 640     }
 641     InterlockEdge(R_EDGE(c,0), 1);
 642     InterlockEdge(R_EDGE(c,1), 1);
 643     RoundCornerCut(rcs);
 644   }
 645   RoundCornerAdd(rcs);
 646 }
 647
 648 tile_01_11_cnr = tile01_tr + [-cutout_tile11_x, 0];
 649 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 650 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 651
 652 module Tile11(){ ////toplevel
 653   sz = [250,250];
 654   c0 = tile01_tr + [-sz[0],0];
 655   c = Rectangle_corners(c0, sz);
 656   cnr_posts = Rectangle_corners2posts(c);
 657   posts = concat(
 658                  Posts_interpolate_one(cnr_posts[0],
 659                                        cnr_posts[1] - [cutout_tile11_x, 0]),
 660                  [ cnr_posts[1] + [0, cutout_tile11_y],
 661                    cnr_posts[2],
 662                    cnr_posts[3]
 663                    ]);
 664   difference(){
 665     union(){
 666       Rectangle_TileBase(c);
 667       Posts(posts);
 668       RoundEdge(R_EDGE(c,2));
 669       InterlockEdge(R_EDGE(c,3));
 670     }
 671     InterlockEdge(c[0], tile_01_11_cnr, 1);
 672     InterlockEdge(tile_11_10_cnr, c[2], 1);
 673     Machine();
 674   }
 675 }
 676
 677 module Tile01(){ ////toplevel
 678   sz = [250,170];
 679   c0 = tile01_tr + -sz;
 680   c = Rectangle_corners(c0, sz);
 681   cnr_posts = Rectangle_corners2posts(c);
 682   posts = concat(
 683                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 684                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 685                  Posts_interpolate_one(cnr_posts[2] - [cutout_tile11_x, 0],
 686                                        cnr_posts[3])
 687                  );
 688   difference(){
 689     union(){
 690       Rectangle_TileBase(c);
 691       Posts(posts);
 692       RoundEdge(R_EDGE(c,0));
 693       InterlockEdge(tile_01_11_cnr, c[3]);
 694       InterlockEdge(R_EDGE(c,3));
 695     }
 696     InterlockEdge(c[1], tile_01_00_cnr, 1);
 697     Machine();
 698   }
 699 }
 700
 701 module Tile10(){ ////toplevel
 702   sz = [250,250];
 703   c0 = tile01_tr + [0,0];
 704   c = Rectangle_corners(c0, sz);
 705   cnr_posts = Rectangle_corners2posts(c);
 706   cty = cutout_tile11_y;
 707   rcy = cty + rearcurve_avoid_y;
 708   posts = [ cnr_posts[0] + [ 0,                             cty ],
 709             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 710             cnr_posts[1] + [ 0,                             rcy ],
 711             cnr_posts[2],
 712             cnr_posts[3] ];
 713   rcs = [R_EDGE(c,2)];
 714   difference(){
 715     union(){
 716       Rectangle_TileBase(c);
 717       Posts(posts);
 718       RoundEdge(R_EDGE(c,1));
 719       RoundEdge(R_EDGE(c,2));
 720       InterlockEdge(c[3], tile_11_10_cnr);
 721     }
 722     RoundCornerCut(rcs);
 723     Machine();
 724   }
 725   RoundCornerAdd(rcs);
 726 }
 727
 728 module Tile00(){ ////toplevel
 729   sz = [250,170];
 730   c0 = tile01_tr + [0,-sz[1]];
 731   c = Rectangle_corners(c0, sz);
 732
 733   // the edge c[1]..c[2] needs a diagonal chunk, from c1bis to c2bis
 734   c2bis = [ -cutout_l_end_x + rearedge_len + frontcurve_strt_len, c[2][1] ];
 735   c1bis = [ c[1][0],
 736             c[2][1] -
 737             (c[2][0] - c2bis[0]) * tan(90 - frontcurve_dualcurve_angle) ];
 738
 739   cnr_posts = Rectangle_corners2posts(c);
 740   cty = cutout_tile01_y;
 741   rcy = cty + frontcurve_avoid_y;
 742   posts = [ cnr_posts[0],
 743             cnr_posts[1],
 744             cnr_posts[2] + [ 0,                             -rcy ],
 745             cnr_posts[2] + [ -sz[0] + rearedge_len - cutout_l_end_x, -cty ],
 746             cnr_posts[3] + [ 0,                             -cty ]
 747             ];
 748   rcs = [R_EDGE(c,1)];
 749   difference(){
 750     union(){
 751       Rectangle_TileBase(c);
 752       Posts(posts);
 753       RoundEdge(R_EDGE(c,0));
 754       RoundEdge(R_EDGE(c,1));
 755       InterlockEdge(tile_01_00_cnr, c[0]);
 756     }
 757     RoundCornerCut(rcs);
 758     Machine();
 759     translate([0,0,-20]) linear_extrude(height=40) {
 760       polygon([ c1bis, c1bis + [50,0], c2bis + [50,0], c2bis ]);
 761     }
 762   }
 763   RoundCornerAdd(rcs);
 764 }
 765
 766 module Demo(){ ////toplevel
 767   translate(demo_slop*[-2,1]) color("blue") Tile12();
 768   translate(demo_slop*[-2,0]) color("red")  Tile02();
 769   translate(demo_slop*[-2,1]) color("orange") Tile11();
 770   translate(demo_slop*[-2,0]) color("purple") Tile01();
 771   translate(demo_slop*[-3,1]) color("blue")   Tile10();
 772   translate(demo_slop*[-3,0]) color("red")    Tile00();
 773   %Machine();
 774 }
 775
 776 //TestPiece1();
 777 //TestPiece2();
 778 //Demo();
 779
 780 //Machine_Profile();
 781 //Machine_NewRearProfile();
 782 //Machine_NewRearCurve();
 783 //Machine_Curves();
 784 //Machine();
 785 //FitTest();
 786 //MachineEnvelope();