sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 tile_th = 3;
  11 post_dia = 8;
  12
  13 post_shorter = 1;
  14
  15 screw_dia = 2.2;
  16 screw_big_dia = 3.6;
  17 screw_big_len = 4.0;
  18
  19 round_edge_rad = 2.0;
  20
  21 round_cnr_rad = 10;
  22
  23 interlock_dia = 10;
  24 interlock_fine = 0.66;
  25
  26 interlock_fine_slope = 1.0;
  27 interlock_fine_lenslop = 1.0;
  28
  29 demo_slop = 0.1;
  30
  31 // cutout
  32
  33 machine_rear_to_front = 85;
  34
  35 machine_rear_profile = [
  36                         [ -  0,  -0.00 ],
  37                         [ -  2,  -0.10 ],
  38                         [ -  4,  -0.20 ],
  39                         [ -  5,  -0.30 ],
  40                         [ -  6,  -0.40 ],
  41                         [ -  7,  -0.50 ],
  42                         [ -  8,  -0.75 ],
  43                         [ - 10,  -1.50 ],
  44                         [ - 12,  -2.25 ],
  45                         [ - 14,  -3.25 ],
  46                         [ - 16,  -4.25 ],
  47                         [ - 18,  -5.75 ],
  48                         [ - 20,  -8.00 ]
  49                         ];
  50
  51 machine_front_profile =  [
  52                           [  128,  -3.70,  ],
  53                           [  124,  -2.90,  ],
  54                           [  120,  -2.45,  ],
  55                           [  116,  -2.10,  ],
  56                           [  112,  -1.80,  ],
  57                           [  108,  -1.55,  ],
  58                           [  104,  -1.25,  ],
  59                           [  100,  -1.00,  ],
  60                           [   96,  -0.80,  ],
  61                           [   92,  -0.65,  ],
  62                           [   88,  -0.55,  ],
  63                           [   84,  -0.50,  ]
  64                           ];
  65
  66 cutout_l_end_y_front_slop = 0.5;
  67 cutout_l_end_y_rear_slop = 0.5;
  68 cutout_l_end_x_slop = 0.25;
  69
  70 cutout_l_end_x = 22;
  71 cutout_l_end_y = machine_rear_to_front;
  72 cutout_l_end_curve = 1;
  73 cutout_l_end_y_total = cutout_l_end_y
  74   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  75
  76 tile02_tr = [-250, 0];
  77 tile01_tr = [  0, 0];
  78
  79 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  80 cutout_tile11_x = cutout_l_end_x + cutout_l_end_curve;
  81 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  82
  83 // front and rear curves
  84
  85 rearedge_len = 170;
  86
  87 rearcurve_strt_len = 52;
  88
  89 rearcurve_z_slop = 0.75;
  90
  91 rearcurve_avoid_y = 35;
  92
  93 rearcurve_double_inrad = 26.10 + 8.04;
  94
  95 reartablet_z = 2.54;
  96 reartablet_x = 5 + 1;
  97 reartablet_y = 5;
  98
  99 frontcurve_side_skew = 3.5 / 72;
 100 frontcurve_avoid_y = 70;
 101 frontcurve_z_slop = 0.75;
 102
 103 // calculated
 104
 105 TEST = false;
 106
 107 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
 108
 109 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
 110
 111 hole_slop = (ply_hole_dia - post_dia)/2;
 112 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
 113
 114 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
 115          tile_hard_edge_hole_dist));
 116
 117 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
 118          tile_hard_edge_hole_dist + round_edge_rad));
 119
 120 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
 121 thehd_tr = thehd;
 122 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 123 thehd_bl = -thehd_tr;
 124 thehd_br = -thehd_tl;
 125
 126 interlock_rad = interlock_dia/2;
 127 interlock_negative_rad = interlock_rad + 0.125;
 128
 129 interlock_sq_adj = 0.2; // arbitrary
 130
 131 first_front = machine_front_profile[len(machine_front_profile)-1];
 132
 133 m4_define(`POST_TCROSSSZ',
 134           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 135
 136 module Post(){
 137   mirror([0,0,1]) {
 138     difference(){
 139       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 140       translate([0,0, tile_th]) {
 141         cylinder(r= screw_big_dia/2, h= screw_big_len);
 142         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
 143       }
 144     }
 145     if (TEST) {
 146       translate([0,0, tile_th/2]) {
 147         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 148         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 149       }
 150     }
 151   }
 152 }
 153
 154 module Posts(posts) {
 155   for (p= posts) {
 156     translate(concat(p, [0]))
 157       Post();
 158   }
 159 }
 160
 161 module TileBase(botleft, topright){
 162   size = topright - botleft;
 163   botleft_post = botleft + thehd_tr;
 164   topright_post = topright + thehd_bl;
 165   difference(){
 166     mirror([0,0,1])
 167       translate(concat(botleft, [0]))
 168       cube(concat(size, [tile_th]));
 169     if (!TEST) {
 170       translate( concat(botleft_post, [ -tile_th ])
 171                  + 0.5 * [ post_dia, post_dia, 0 ] )
 172         Commitid_BestCount_M( topright_post-botleft_post
 173                               + [-post_dia,-post_dia]
 174                               + [0, thehd[1]]);
 175     }
 176     if (TEST) {
 177       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
 178       cidsz = [ size[0] - 2*crossoff, thehd[1] ];
 179       translate( concat(botleft + [crossoff, 0], [0]) )
 180         Commitid_BestCount(cidsz);
 181       difference(){
 182         mirror([0,0,1]) {
 183           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 184             cube(concat(size - [test_edge,test_edge]*2, [tile_th]));
 185           translate(concat(botleft_post, [-1]))
 186             cube(concat(topright_post-botleft_post, [tile_th+2]));
 187         }
 188         minkowski(){
 189           Machine();
 190           cube(max(test_edge, tile_hard_edge_hole_dist)*2, center=true);
 191         }
 192       }
 193     }
 194   }
 195 }
 196
 197 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 198 m4_define(`INREFFRAME',`
 199   length_vec = ($2) - ($1);
 200   length = dist2d([0,0], length_vec);
 201   length_uvec = length_vec / length;
 202   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 203   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 204         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 205         [ 0,              0,              1,            0, ],
 206         [ 0,              0,              0,            1, ] ];
 207   $3
 208   multmatrix(m)
 209 ')
 210
 211 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 212 m4_dnl    INREFFRAME_EDGE { body; }
 213 m4_define(`INREFFRAME_EDGE',`
 214   translate([0,0, -round_edge_rad])
 215 ')
 216
 217 module RoundEdge(left_cnr, right_cnr) {
 218   INREFFRAME(left_cnr, right_cnr)
 219     INREFFRAME_EDGE {
 220     difference(){
 221       rotate([0,90,0])
 222         cylinder(r= round_edge_rad, h= length, $fn=50);
 223       translate([-1, 0, -20])
 224         cube([length+2, 20, 20]);
 225     }
 226   }
 227 }
 228
 229 module RoundCornerCut(ci) {
 230   // ci should be [this_cnr, right_cnr]
 231   // where right_cnr is to the right (ie, anticlockwise)
 232   this_cnr = ci[0];
 233   right_cnr = ci[1];
 234   offr= round_cnr_rad - round_edge_rad;
 235   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 236     difference(){
 237       cube(offr*2 - 0.1, center=true);
 238       translate([offr, offr, 0])
 239         cylinder(center=true, h=20, r= offr);
 240     }
 241   }
 242 }
 243
 244 module RoundCornerAdd(ci) {
 245   this_cnr = ci[0];
 246   right_cnr = ci[1];
 247   bigr = round_cnr_rad - round_edge_rad;
 248   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 249     intersection(){
 250       cube(bigr*2 + 0.1, center=true);
 251       translate([bigr, bigr, 0])
 252         rotate_extrude(convexity=10, $fn=50)
 253         translate([bigr, 0])
 254         difference(){
 255           circle(r= round_edge_rad, $fn=50);
 256           mirror([1,1])
 257             square([20,20]);
 258         }
 259     }
 260   }
 261 }
 262
 263 module InterlockLobePlan(negative) {
 264   r = negative ? interlock_negative_rad : interlock_rad;
 265   ymir = negative ? 0 : 1;
 266
 267   dx = sqrt(3) * r;
 268   $fn= 80;
 269   translate([thehd[0], 0]){
 270     mirror([0,ymir]){
 271       circle(r=r);
 272       difference(){
 273         translate([-dx, -0.1])
 274           square([ dx*2, r/2 + 0.1 ]);
 275         for (xi = [-1, 1]) {
 276           translate([ xi*dx, r ])
 277             circle(r=r);
 278         }
 279       }
 280     }
 281   }
 282 }
 283
 284 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 285   for (lobei = [ 0 : nlobes-1 ]) {
 286     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 287     translate([lobex, 0, 0]) {
 288       InterlockLobePlan(negative);
 289     }
 290   }
 291
 292   if (dosquare) {
 293     iadj = 0;
 294     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 295     mirror([0, negative])
 296       translate([slotshorter, iadj])
 297       square([length - slotshorter*2, interlock_fine + iadj*2]);
 298   }
 299 }
 300
 301 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 302   plusth = negative * 1.0;
 303   protr = interlock_fine + interlock_sq_adj;
 304
 305   z2 = -tile_th/2;
 306   z1 = -tile_th/2 - protr / interlock_fine_slope;
 307   z3 = -tile_th/2 + protr / interlock_fine_slope;
 308
 309   negsign = negative ? -1 : +1;
 310   yprotr = negsign * protr;
 311
 312   INREFFRAME(left_cnr, right_cnr) {
 313     for (vsect = [ // zs0            zs1      ys0,            ys1
 314                   [ -tile_th-plusth, plusth,  0,              0],
 315                   [ z1,              z2,      0, yprotr],
 316                   [ z2,              z3,      yprotr, 0],
 317                   ]) {
 318       zs0 = vsect[0];
 319       zs1 = vsect[1];
 320       zsd = zs1-zs0;
 321       ys0 = vsect[2];
 322       ys1 = vsect[3];
 323       ysd = ys1-ys0;
 324       sl = ysd/zsd;
 325       m = [ [ 1,0,   0,    0 ],
 326             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 327             [ 0,0,   1,  zs0 ],
 328             [ 0,0,   0,    1 ] ];
 329       multmatrix(m)
 330         linear_extrude(height=zsd, convexity=10)
 331         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 332     }
 333   }
 334 }
 335
 336 function TestPiece_holes2corners(holes) =
 337   [ holes[0] + thehd_bl,
 338     holes[1] + thehd_br,
 339     holes[1] + thehd_tr,
 340     holes[0] + thehd_tl ];
 341
 342 module TestPiece1(){ ////toplevel
 343   holes = [ [-100, 0],
 344             [   0, 0]
 345             ];
 346   corners = TestPiece_holes2corners(holes);
 347   rcs = [corners[0], corners[1]];
 348   difference(){
 349     union(){
 350       TileBase(corners[0], corners[2]);
 351       Posts(holes);
 352       RoundEdge(corners[0], corners[1]);
 353       RoundEdge(corners[3], corners[0]);
 354     }
 355     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 356     RoundCornerCut(rcs);
 357   }
 358   RoundCornerAdd(rcs);
 359 }
 360
 361 module TestPiece2(){ ////toplevel
 362   holes = [ [   0, 0],
 363             [  50, 0]
 364             ];
 365   corners = TestPiece_holes2corners(holes);
 366   TileBase(corners[0], corners[2]);
 367   Posts(holes);
 368   RoundEdge(corners[0], corners[1]);
 369   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 370 }
 371
 372 module TestDemo(){ ////toplevel
 373   translate([ -thehd[0], 0 ])
 374     color("blue")
 375     TestPiece1();
 376   translate([ +thehd[0] + demo_slop, 0 ])
 377     TestPiece2();
 378 }
 379
 380 module Machine_Arm(){
 381   ysz = cutout_l_end_y_total;
 382   // assume the round end is arc of a circle
 383   chordlen = dist2d([0,0], [ cutout_l_end_y, cutout_l_end_curve ]);
 384   endrad = cutout_l_end_y / cutout_l_end_curve * chordlen;
 385
 386   translate([0,0,-30]) linear_extrude(height=60) {
 387     translate(tile01_tr + [0, (-cutout_tile01_y + cutout_tile11_y)/2]) {
 388       intersection(){
 389         translate([-100, -ysz/2])
 390           square([400, ysz]);
 391         translate([ endrad - cutout_tile11_x - cutout_l_end_x_slop, 0 ])
 392           circle(r=endrad, $fa=0.01,$fd=5);
 393       }
 394     }
 395   }
 396 }
 397
 398 module Machine_Profile(){
 399   first_rear = machine_rear_profile[0];
 400   below_point = 0.5 * ( first_rear + first_front ) + [ 0, -10 ];
 401   pol = concat( machine_rear_profile,
 402                 [ below_point ],
 403                 machine_front_profile);
 404   skew_angle = atan2( first_front[1] - first_rear[1],
 405                       first_front[0] - first_rear[0] );
 406   echo(below_point, pol, skew_angle);
 407   hull(){
 408     for (z=[0,-40]) {
 409       translate([0,z]) {
 410         //scale([1,5])
 411         rotate([0,0, -skew_angle ]){
 412           //translate( - first_front )
 413           polygon(pol);
 414         }
 415       }
 416     }
 417   }
 418 }
 419
 420 module Machine_RearProfile(){
 421   intersection(){
 422     Machine_Profile();
 423     translate([ -200 + machine_rear_to_front/2, -100 ]) {
 424       square([200,200]);
 425     }
 426   }
 427 }
 428
 429 module Machine_FrontProfile(){
 430   intersection(){
 431     Machine_Profile();
 432     translate([ machine_rear_to_front/2, -100 ]) {
 433       square([200,200]);
 434     }
 435   }
 436 }
 437
 438 module Machine_Curves(){ ////toplevel
 439   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 440               cutout_tile11_y,
 441               0 ]){
 442     //%cube([20,20,20]);
 443     translate([ -reartablet_x,
 444                 -1,
 445                 -reartablet_z])
 446       mirror([0,0,1])
 447       cube([ reartablet_x+1,
 448              reartablet_y+1,
 449              20 ]);
 450   }
 451   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 452               cutout_tile11_y,
 453               frontcurve_z_slop ]){
 454     translate([ 0, -first_front[0] , 0 ])
 455       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 456                   [0,  1,   0, 0],
 457                   [0,  0,   1, 0],
 458                   [0,  0,   0, 1]])
 459       translate([ 0, first_front[0] , 0 ])
 460       mirror([1,0,0]){
 461       rotate([0,-90,0])rotate([0,0,-90]){
 462         linear_extrude(height= 200)
 463           Machine_FrontProfile();
 464       }
 465     }
 466     translate([ rearcurve_strt_len,
 467                 0,
 468                 rearcurve_z_slop ]){
 469       translate([ 1,
 470                   0,
 471                   0
 472                   ]){
 473         rotate([0,-90,0])rotate([0,0,-90]){
 474           linear_extrude(height= rearcurve_strt_len + 1)
 475           Machine_RearProfile();
 476         }
 477       }
 478       translate([ 0,
 479                   0,
 480                   rearcurve_double_inrad ]) {
 481         intersection(){
 482           rotate([90,0,0]){
 483             rotate_extrude(convexity=10, $fn=32) {
 484               rotate([0,0,90]) translate([ 0,
 485                           -rearcurve_double_inrad ]) {
 486                 Machine_RearProfile();
 487               }
 488             }
 489           }
 490           mirror([0,0,1])
 491             translate([0,-75,0]) cube([150,150,150]);
 492         }
 493       }
 494     }
 495   }
 496 }
 497
 498 module Machine(){ ////toplevel
 499   Machine_Arm();
 500   Machine_Curves();
 501 }
 502
 503 function Rectangle_corners(c0, sz) =
 504   // returns the corners of a rectangle from c0 to c0+sz
 505   // if sz is positive, the corners are anticlockwise starting with c0
 506   [ c0 + [ 0,     0     ],
 507     c0 + [ sz[0], 0     ],
 508     c0 + [ sz[0], sz[1] ],
 509     c0 + [ 0,     sz[1] ] ];
 510
 511 function Rectangle_corners2posts(c) =
 512   [ c[0] + thehd_tr,
 513     c[1] + thehd_tl,
 514     c[2] + thehd_bl,
 515     c[3] + thehd_br ];
 516
 517 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 518
 519 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 520
 521 m4_dnl   R_EDGE(c,ix)
 522 m4_dnl        c is from Rectangle_corners and
 523 m4_dnl        ix is a corner number
 524 m4_dnl    expands to two comma-separated corners:
 525 m4_dnl    that denoted by ix, and the next one anticlockwise
 526 m4_define(`R_EDGE',`$1[$2],$1[(($2)+1)%4]')
 527
 528 module Tile02(){ ////toplevel
 529   sz = [100,170];
 530   c0 = tile02_tr + -sz;
 531   c = Rectangle_corners(c0, sz);
 532   posts = Rectangle_corners2posts(c);
 533   rcs = [R_EDGE(c,0)];
 534   difference(){
 535     union(){
 536       Rectangle_TileBase(c);
 537       Posts(posts);
 538       RoundEdge(R_EDGE(c,0));
 539       RoundEdge(R_EDGE(c,3));
 540       InterlockEdge(R_EDGE(c,2), 0);
 541     }
 542     InterlockEdge(R_EDGE(c,1), 1);
 543     RoundCornerCut(rcs);
 544   }
 545   RoundCornerAdd(rcs);
 546 }
 547
 548 module Tile12(){ ////toplevel
 549   sz = [100,250];
 550   c0 = tile02_tr + [-sz[0], 0];
 551   c = Rectangle_corners(c0, sz);
 552   posts = Rectangle_corners2posts(c);
 553   rcs = [R_EDGE(c,3)];
 554   difference(){
 555     union(){
 556       Rectangle_TileBase(c);
 557       Posts(posts);
 558       RoundEdge(R_EDGE(c,2));
 559       RoundEdge(R_EDGE(c,3));
 560     }
 561     InterlockEdge(R_EDGE(c,0), 1);
 562     InterlockEdge(R_EDGE(c,1), 1);
 563     RoundCornerCut(rcs);
 564   }
 565   RoundCornerAdd(rcs);
 566 }
 567
 568 tile_01_11_cnr = tile01_tr + [-cutout_tile11_x, 0];
 569 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 570 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 571
 572 module Tile11(){ ////toplevel
 573   sz = [250,250];
 574   c0 = tile01_tr + [-sz[0],0];
 575   c = Rectangle_corners(c0, sz);
 576   cnr_posts = Rectangle_corners2posts(c);
 577   posts = concat(
 578                  Posts_interpolate_one(cnr_posts[0],
 579                                        cnr_posts[1] - [cutout_tile11_x, 0]),
 580                  [ cnr_posts[1] + [0, cutout_tile11_y],
 581                    cnr_posts[2],
 582                    cnr_posts[3]
 583                    ]);
 584   difference(){
 585     union(){
 586       Rectangle_TileBase(c);
 587       Posts(posts);
 588       RoundEdge(R_EDGE(c,2));
 589       InterlockEdge(R_EDGE(c,3));
 590     }
 591     InterlockEdge(c[0], tile_01_11_cnr, 1);
 592     InterlockEdge(tile_11_10_cnr, c[2], 1);
 593     Machine();
 594   }
 595 }
 596
 597 module Tile01(){ ////toplevel
 598   sz = [250,170];
 599   c0 = tile01_tr + -sz;
 600   c = Rectangle_corners(c0, sz);
 601   cnr_posts = Rectangle_corners2posts(c);
 602   posts = concat(
 603                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 604                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 605                  Posts_interpolate_one(cnr_posts[2] - [cutout_tile11_x, 0],
 606                                        cnr_posts[3])
 607                  );
 608   difference(){
 609     union(){
 610       Rectangle_TileBase(c);
 611       Posts(posts);
 612       RoundEdge(R_EDGE(c,0));
 613       InterlockEdge(tile_01_11_cnr, c[3]);
 614       InterlockEdge(R_EDGE(c,3));
 615     }
 616     InterlockEdge(c[1], tile_01_00_cnr, 1);
 617     Machine();
 618   }
 619 }
 620
 621 module Tile10(){ ////toplevel
 622   sz = [250,250];
 623   c0 = tile01_tr + [0,0];
 624   c = Rectangle_corners(c0, sz);
 625   cnr_posts = Rectangle_corners2posts(c);
 626   cty = cutout_tile11_y;
 627   rcy = cty + rearcurve_avoid_y;
 628   posts = [ cnr_posts[0] + [ 0,                             cty ],
 629             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 630             cnr_posts[1] + [ 0,                             rcy ],
 631             cnr_posts[2],
 632             cnr_posts[3] ];
 633   rcs = [R_EDGE(c,2)];
 634   difference(){
 635     union(){
 636       Rectangle_TileBase(c);
 637       Posts(posts);
 638       RoundEdge(R_EDGE(c,1));
 639       RoundEdge(R_EDGE(c,2));
 640       InterlockEdge(c[3], tile_11_10_cnr);
 641     }
 642     RoundCornerCut(rcs);
 643     Machine();
 644   }
 645   RoundCornerAdd(rcs);
 646 }
 647
 648 module Tile00(){ ////toplevel
 649   sz = [250,170];
 650   c0 = tile01_tr + [0,-sz[1]];
 651   c = Rectangle_corners(c0, sz);
 652   cnr_posts = Rectangle_corners2posts(c);
 653   cty = cutout_tile01_y;
 654   rcy = cty + frontcurve_avoid_y;
 655   posts = [ cnr_posts[0],
 656             cnr_posts[1],
 657             cnr_posts[2] + [ 0,                             -rcy ],
 658             cnr_posts[2] + [ -sz[0] + rearedge_len - cutout_l_end_x, -cty ],
 659             cnr_posts[3] + [ 0,                             -cty ]
 660             ];
 661   rcs = [R_EDGE(c,1)];
 662   difference(){
 663     union(){
 664       Rectangle_TileBase(c);
 665       Posts(posts);
 666       RoundEdge(R_EDGE(c,0));
 667       RoundEdge(R_EDGE(c,1));
 668       InterlockEdge(tile_01_00_cnr, c[0]);
 669     }
 670     RoundCornerCut(rcs);
 671     Machine();
 672   }
 673   RoundCornerAdd(rcs);
 674 }
 675
 676 module Demo(){ ////toplevel
 677   translate(demo_slop*[-2,1]) color("blue") Tile12();
 678   translate(demo_slop*[-2,0]) color("red")  Tile02();
 679   translate(demo_slop*[-2,1]) color("orange") Tile11();
 680   translate(demo_slop*[-2,0]) color("purple") Tile01();
 681   translate(demo_slop*[-3,1]) color("blue")   Tile10();
 682   translate(demo_slop*[-3,0]) color("red")    Tile00();
 683   %Machine();
 684 }
 685
 686 //TestPiece1();
 687 //TestPiece2();
 688 //Demo();
 689
 690 //Machine_Profile();
 691 //Machine_RearProfile();