sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 tile_th = 3;
  11 post_dia = 8;
  12
  13 post_shorter = 1;
  14
  15 screw_dia = 2.2;
  16 screw_big_dia = 3.6;
  17 screw_big_len = 4.0;
  18
  19 round_edge_rad = 2.0;
  20
  21 round_cnr_rad = 10;
  22
  23 interlock_dia = 10;
  24 interlock_fine = 0.66;
  25
  26 interlock_fine_slope = 1.0;
  27 interlock_fine_lenslop = 1.0;
  28
  29 demo_slop = 0.1;
  30
  31 // cutout
  32
  33 machine_rear_to_front = 84 + 0.25 - 1.4;
  34
  35 cutout_l_end_y_front_slop = 0.5;
  36 cutout_l_end_y_rear_slop = 0.5;
  37 cutout_l_end_x_slop = 0.25;
  38
  39 cutout_l_end_x = 22;
  40 cutout_l_end_y = machine_rear_to_front;
  41 cutout_l_end_curve = 1;
  42 cutout_l_end_y_total = cutout_l_end_y
  43   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  44
  45 tile02_tr = [-250, 0];
  46 tile01_tr = [  0, 0];
  47
  48 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  49 cutout_tile11_x = cutout_l_end_x + cutout_l_end_curve;
  50 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  51
  52 // front and rear curves
  53
  54 rearedge_len = 170;
  55
  56 rearcurve_strt_len = 52;
  57
  58 rearcurve_z_slop = -0.50;
  59
  60 rearcurve_avoid_y = 35;
  61
  62 rearcurve_double_inrad = 26.10 + 8.04;
  63
  64 reartablet_z = 2.54;
  65 reartablet_x = 5 + 1;
  66 reartablet_y = 8;
  67
  68 frontcurve_side_skew = 3.5 / 72;
  69 frontcurve_avoid_y = 70;
  70 frontcurve_z_slop = 0.75;
  71
  72 frontcurve_strt_len = 50;
  73 frontcurve_dualcurve_angle = 30;
  74
  75 teststrapslots_at = [ [ 110, 70 ],
  76                       [ 180, 90 ],
  77                       [ 110, -35 ],
  78                       [ 190, -80 ],
  79                       ];
  80
  81 // calculated
  82
  83 TEST = false;
  84
  85 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
  86
  87 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
  88
  89 hole_slop = (ply_hole_dia - post_dia)/2;
  90 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
  91
  92 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
  93          tile_hard_edge_hole_dist));
  94
  95 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
  96          tile_hard_edge_hole_dist + round_edge_rad));
  97
  98 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
  99 thehd_tr = thehd;
 100 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 101 thehd_bl = -thehd_tr;
 102 thehd_br = -thehd_tl;
 103
 104 tablet_z_slop = rearcurve_z_slop;
 105
 106 interlock_rad = interlock_dia/2;
 107 interlock_negative_rad = interlock_rad + 0.125;
 108
 109 interlock_sq_adj = 0.2; // arbitrary
 110
 111 m4_define(`POST_TCROSSSZ',
 112           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 113
 114 module Post(){
 115   mirror([0,0,1]) {
 116     difference(){
 117       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 118       translate([0,0, tile_th]) {
 119         cylinder(r= screw_big_dia/2, h= screw_big_len);
 120         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
 121       }
 122     }
 123     if (TEST) {
 124       translate([0,0, tile_th/2]) {
 125         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 126         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 127       }
 128     }
 129   }
 130 }
 131
 132 module Posts(posts) {
 133   for (p= posts) {
 134     translate(concat(p, [0]))
 135       Post();
 136   }
 137 }
 138
 139 module TileBase(botleft, topright){
 140   size = topright - botleft;
 141   botleft_post = botleft + thehd_tr;
 142   topright_post = topright + thehd_bl;
 143   difference(){
 144     mirror([0,0,1])
 145       translate(concat(botleft, [0]))
 146       cube(concat(size, [tile_th]));
 147     if (!TEST) {
 148       cidsz = topright_post-botleft_post
 149         + [-post_dia,-post_dia]
 150         + [0, thehd[1]];
 151       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
 152       echo("CID",cidsz,cidszr);
 153       translate( concat(botleft_post, [ -tile_th ])
 154                  + 0.5 * [ post_dia, post_dia, 0 ]
 155                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
 156         Commitid_BestCount_M(cidszr);
 157     }
 158     if (TEST) {
 159       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
 160       cidsz = [ thehd[0], size[1] - 2*crossoff ];
 161       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
 162       translate( concat(botleft + [0, crossoff] + (cidsz-cidszr)/2, [0]) )
 163         Commitid_BestCount(cidszr);
 164       difference(){
 165         mirror([0,0,1]) {
 166           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 167             cube(concat(size - [test_edge,test_edge]*2, [tile_th]));
 168           translate(concat(botleft_post, [-1]))
 169             cube(concat(topright_post-botleft_post, [tile_th+2]));
 170         }
 171         shufflesz = max(test_edge, tile_hard_edge_hole_dist)*2;
 172         minkowski(){
 173           MachineEnvelope();
 174           cube(shufflesz, center=true);
 175         }
 176       }
 177     }
 178   }
 179 }
 180
 181 m4_dnl   R_EDGE(c,ix)
 182 m4_dnl        c is from Rectangle_corners and
 183 m4_dnl        ix is a corner number
 184 m4_dnl    expands to two comma-separated corners:
 185 m4_dnl    that denoted by ix, and the next one anticlockwise
 186 m4_define(`R_EDGE',`$1[$2], $1[(($2)+1)%4]')
 187
 188 m4_dnl   R_CNR(c,ix)
 189 m4_dnl        c is from Rectangle_corners and
 190 m4_dnl        ix is a corner number
 191 m4_dnl    expands to an array of corners as for RoundCorner
 192 m4_define(`R_CNR',`[ $1[$2], $1[(($2)+1)%4], $1[(($2)+3)%4] ]')
 193
 194 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 195 m4_define(`INREFFRAME',`
 196   length_vec = ($2) - ($1);
 197   length = dist2d([0,0], length_vec);
 198   length_uvec = length_vec / length;
 199   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 200   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 201         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 202         [ 0,              0,              1,            0, ],
 203         [ 0,              0,              0,            1, ] ];
 204   $3
 205   multmatrix(m)
 206 ')
 207
 208 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 209 m4_dnl    INREFFRAME_EDGE { body; }
 210 m4_define(`INREFFRAME_EDGE',`
 211   translate([0,0, -round_edge_rad])
 212 ')
 213
 214 module RoundEdge(left_cnr, right_cnr) {
 215   INREFFRAME(left_cnr, right_cnr)
 216     INREFFRAME_EDGE {
 217     difference(){
 218       rotate([0,90,0])
 219         cylinder(r= round_edge_rad, h= length, $fn=50);
 220       translate([-1, 0, -20])
 221         cube([length+2, 20, 20]);
 222     }
 223   }
 224 }
 225
 226 m4_define(`ROUNDCORNER_VARS',`
 227   this_cnr = ci[0];
 228   right_cnr = ci[1];
 229   left_cnr = ci[2];
 230   bigr= round_cnr_rad - round_edge_rad;
 231   l_uvec = unitvector2d(left_cnr - this_cnr);
 232   r_uvec = unitvector2d(right_cnr - this_cnr);
 233   lp1 = left_cnr  + clockwise2d(l_uvec) * bigr;
 234   lp2 = this_cnr  + clockwise2d(l_uvec) * bigr;
 235   lp3 = this_cnr  - clockwise2d(r_uvec) * bigr;
 236   lp4 = right_cnr - clockwise2d(r_uvec) * bigr;
 237   ctr = line_intersection_2d(lp1,lp2,lp3,lp4);
 238   ctr3 = concat(ctr,[0])
 239 ')
 240
 241 module RoundCorner_selector(ci, adj) {
 242   ROUNDCORNER_VARS;
 243   intersection(){
 244     union(){
 245       INREFFRAME(ctr3,concat(lp1,[4])){
 246         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 247           translate([-bigr*2 + adj, -bigr])
 248             square([bigr*2, bigr*3]);
 249         }
 250       }
 251     }
 252     union(){
 253       INREFFRAME(ctr3,concat(lp4,[0])){
 254         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 255           translate([-bigr*2, -bigr*2])
 256             square([bigr*2 + adj, bigr*3]);
 257         }
 258       }
 259     }
 260   }
 261 }
 262
 263 module RoundCornerCut(ci) {
 264   // ci should be [this_cnr, right_cnr, left_cnr]
 265   // where right_cnr is to the right (ie, anticlockwise)
 266   ROUNDCORNER_VARS;
 267   difference(){
 268     RoundCorner_selector(ci, -0.1);
 269     translate(ctr3)
 270       cylinder(center=true, h=20, r= bigr);
 271   }
 272 }
 273
 274 module RoundCornerAdd(ci) {
 275   ROUNDCORNER_VARS;
 276   intersection(){
 277     RoundCorner_selector(ci, +0.1);
 278     INREFFRAME_EDGE {
 279       translate(ctr3){
 280         rotate_extrude(convexity=10, $fn=50)
 281           translate([bigr, 0])
 282           difference(){
 283           circle(r= round_edge_rad, $fn=50);
 284           mirror([1,1])
 285             square([20,20]);
 286         }
 287       }
 288     }
 289   }
 290 }
 291
 292 module InterlockLobePlan(negative) {
 293   r = negative ? interlock_negative_rad : interlock_rad;
 294   ymir = negative ? 0 : 1;
 295
 296   dx = sqrt(3) * r;
 297   $fn= 80;
 298   translate([thehd[0], 0]){
 299     mirror([0,ymir]){
 300       circle(r=r);
 301       difference(){
 302         translate([-dx, -0.1])
 303           square([ dx*2, r/2 + 0.1 ]);
 304         for (xi = [-1, 1]) {
 305           translate([ xi*dx, r ])
 306             circle(r=r);
 307         }
 308       }
 309     }
 310   }
 311 }
 312
 313 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 314   for (lobei = [ 0 : nlobes-1 ]) {
 315     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 316     translate([lobex, 0, 0]) {
 317       InterlockLobePlan(negative);
 318     }
 319   }
 320
 321   if (dosquare) {
 322     iadj = 0;
 323     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 324     mirror([0, negative])
 325       translate([slotshorter, iadj])
 326       square([length - slotshorter*2, interlock_fine + iadj*2]);
 327   }
 328 }
 329
 330 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 331   plusth = negative * 1.0;
 332   protr = interlock_fine + interlock_sq_adj;
 333
 334   z2 = -tile_th/2;
 335   z1 = -tile_th/2 - protr / interlock_fine_slope;
 336   z3 = -tile_th/2 + protr / interlock_fine_slope;
 337
 338   negsign = negative ? -1 : +1;
 339   yprotr = negsign * protr;
 340
 341   INREFFRAME(left_cnr, right_cnr) {
 342     for (vsect = [ // zs0            zs1      ys0,            ys1
 343                   [ -tile_th-plusth, plusth,  0,              0],
 344                   [ z1,              z2,      0, yprotr],
 345                   [ z2,              z3,      yprotr, 0],
 346                   ]) {
 347       zs0 = vsect[0];
 348       zs1 = vsect[1];
 349       zsd = zs1-zs0;
 350       ys0 = vsect[2];
 351       ys1 = vsect[3];
 352       ysd = ys1-ys0;
 353       sl = ysd/zsd;
 354       m = [ [ 1,0,   0,    0 ],
 355             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 356             [ 0,0,   1,  zs0 ],
 357             [ 0,0,   0,    1 ] ];
 358       multmatrix(m)
 359         linear_extrude(height=zsd, convexity=10)
 360         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 361     }
 362   }
 363 }
 364
 365 function TestPiece_holes2corners(holes) =
 366   [ holes[0] + thehd_bl,
 367     holes[1] + thehd_br,
 368     holes[1] + thehd_tr,
 369     holes[0] + thehd_tl ];
 370
 371 module TestPiece1(){ ////toplevel
 372   holes = [ [-100, 0],
 373             [   0, 0]
 374             ];
 375   corners = TestPiece_holes2corners(holes);
 376   rcs = R_CNR(corners,0);
 377   difference(){
 378     union(){
 379       TileBase(corners[0], corners[2]);
 380       Posts(holes);
 381       RoundEdge(corners[0], corners[1]);
 382       RoundEdge(corners[3], corners[0]);
 383     }
 384     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 385     RoundCornerCut(rcs);
 386   }
 387   RoundCornerAdd(rcs);
 388 }
 389
 390 module TestPiece2(){ ////toplevel
 391   holes = [ [   0, 0],
 392             [  50, 0]
 393             ];
 394   corners = TestPiece_holes2corners(holes);
 395   TileBase(corners[0], corners[2]);
 396   Posts(holes);
 397   RoundEdge(corners[0], corners[1]);
 398   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 399 }
 400
 401 module TestDemo(){ ////toplevel
 402   translate([ -thehd[0], 0 ])
 403     color("blue")
 404     TestPiece1();
 405   translate([ +thehd[0] + demo_slop, 0 ])
 406     TestPiece2();
 407 }
 408
 409 module Machine_Arm(){
 410   ysz = cutout_l_end_y_total;
 411   // assume the round end is arc of a circle
 412   chordlen = dist2d([0,0], [ cutout_l_end_y, cutout_l_end_curve ]);
 413   endrad = cutout_l_end_y / cutout_l_end_curve * chordlen;
 414
 415   translate([0,0,-30]) linear_extrude(height=60) {
 416     translate(tile01_tr + [0, (-cutout_tile01_y + cutout_tile11_y)/2]) {
 417       intersection(){
 418         translate([-50, -ysz/2])
 419           square([400, ysz]);
 420         translate([ endrad - cutout_tile11_x - cutout_l_end_x_slop, 0 ])
 421           circle(r=endrad, $fa=0.01,$fd=5);
 422       }
 423     }
 424   }
 425 }
 426
 427 module Machine_NewRearProfile(){
 428   // figures copied out of xfig edit boxes
 429   // best not to edit the posbox size if poss - just move it
 430   posbox = 10 * ([7.2333,-14.1267] - [-16.2289,40.0289]); // box, Green
 431   sideline = -10 * ([-6.2400,13.5600] - [-2.4467,28.2556]); // line, Blue
 432   scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
 433   scaleline_mm = 12+5+10+5+3;
 434   sh = -[abs(posbox[0]), abs(posbox[1])];
 435   rot = atan2(-sideline[0], sideline[1]);
 436   sc = scaleline_mm / scaleline;
 437   //echo("SH",sh,rot,sc);
 438   scale(sc) rotate(rot) translate(sh){
 439     import("sewing-table-rear-profile.dxf", convexity=10); // spline, Pink3
 440   }
 441 }
 442
 443 module Machine_NewFrontProfile(){
 444   // figures copied out of xfig edit boxes
 445   // best not to edit the posbox size if poss - just move it
 446   posbox = 10 * ([11.8022,8.0600] - [4.2044,19.1867]); // box, Green
 447   refline = 10 * ([7.6778,16.7222] - [27.8689,17.6578]); // line, Blue
 448   refline_mm = (11-1)*10;
 449   sh = -[abs(posbox[0]), abs(posbox[1])];
 450   rot = atan2(-refline[0], refline[1]);
 451   sc = refline_mm / vectorlen2d(refline);
 452   //echo("SH",sh,rot,sc);
 453   mirror([1,0]) scale(sc) rotate(rot+90) translate(sh){
 454     import("sewing-table-front-profile.dxf", convexity=10); // spline, Pink3
 455   }
 456 }
 457
 458 module Machine_NewRearCurve(){
 459   slant = atan2(4,210-10);
 460   //echo("SL",slant);
 461   translate([0,0, rearcurve_double_inrad]) rotate([slant,0,0]){
 462     translate([ rearcurve_double_inrad,
 463                 0,
 464                 -rearcurve_double_inrad + 10 ]){
 465       rotate([180,0,0]) rotate([0,0,90]) linear_extrude(height=30){
 466         hull(){
 467           Machine_NewRearProfile();
 468           translate([0,-100]) Machine_NewRearProfile();
 469         }
 470       }
 471     }
 472     rotate([0,90,0]) rotate([90,0,0]) {
 473       intersection(){
 474         rotate_extrude(convexity=10, $fn=64)
 475           rotate(90)
 476           translate([ 0, -rearcurve_double_inrad ])
 477           Machine_NewRearProfile();
 478         translate([0,0,-500])
 479           cube([500,500,1000]);
 480       }
 481     }
 482     translate([1,0,-rearcurve_double_inrad])
 483       rotate([0,-90,0]) rotate([0,0,-90])
 484       linear_extrude(height= rearcurve_strt_len + 1)
 485       Machine_NewRearProfile();
 486   }
 487 }
 488
 489 module Machine_Curves(){ ////toplevel
 490   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 491               cutout_tile11_y,
 492               0 ]){
 493     //%cube([20,20,20]);
 494     translate([ -reartablet_x,
 495                 -1,
 496                 -reartablet_z + tablet_z_slop])
 497       mirror([0,0,1])
 498       cube([ reartablet_x+1,
 499              reartablet_y+1,
 500              20 ]);
 501   }
 502   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 503               cutout_tile11_y,
 504               frontcurve_z_slop ]){
 505     translate([0, -machine_rear_to_front, 0])
 506       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 507                   [0,  1,   0, 0],
 508                   [0,  0,   1, 0],
 509                   [0,  0,   0, 1]])
 510       mirror([1,0,0]) rotate([0,-90,0])rotate([0,0,-90])
 511       linear_extrude(height= 200)
 512       Machine_NewFrontProfile();
 513
 514     translate([ rearcurve_strt_len,
 515                 0,
 516                 rearcurve_z_slop ]){
 517       Machine_NewRearCurve();
 518     }
 519   }
 520 }
 521
 522 module TestStrapSlots(){
 523   pegwidth = 7.5;
 524   strap = [ 3, 5 ];
 525   for (pos = teststrapslots_at) {
 526     echo("TSS",pos);
 527     translate(concat(pos,[0]))
 528       for (mx = [0,1]) mirror([mx,0,0]) {
 529           translate([ pegwidth/2, -strap[1]/2, -20 ])
 530             #cube(concat(strap,[40]));
 531         }
 532   }
 533 }
 534
 535 module Machine(){ ////toplevel
 536   Machine_Arm();
 537   Machine_Curves();
 538   if (TEST)
 539     TestStrapSlots();
 540 }
 541
 542 module MachineEnvelope(){
 543   // used for testing
 544   p_arm_bl = [-cutout_tile11_x, -cutout_tile01_y];
 545   y_arm_t  = cutout_tile11_y;
 546   p_crv_fl = p_arm_bl + [rearedge_len, -frontcurve_avoid_y];
 547   y_crv_b  = y_arm_t + rearcurve_avoid_y;
 548
 549   translate([0,0,-50]) linear_extrude(height= 100){
 550     translate(p_arm_bl) square([400, y_arm_t] - p_arm_bl);
 551     translate(p_crv_fl) square([400, y_crv_b] - p_crv_fl);
 552   }
 553 }
 554
 555 function Rectangle_corners(c0, sz) =
 556   // returns the corners of a rectangle from c0 to c0+sz
 557   // if sz is positive, the corners are anticlockwise starting with c0
 558   [ c0 + [ 0,     0     ],
 559     c0 + [ sz[0], 0     ],
 560     c0 + [ sz[0], sz[1] ],
 561     c0 + [ 0,     sz[1] ] ];
 562
 563 function Rectangle_corners2posts(c) =
 564   [ c[0] + thehd_tr,
 565     c[1] + thehd_tl,
 566     c[2] + thehd_bl,
 567     c[3] + thehd_br ];
 568
 569 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 570
 571 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 572
 573 module Tile02(){ ////toplevel
 574   sz = [100,170];
 575   c0 = tile02_tr + -sz;
 576   c = Rectangle_corners(c0, sz);
 577   posts = Rectangle_corners2posts(c);
 578   rcs = R_CNR(c,0);
 579   difference(){
 580     union(){
 581       Rectangle_TileBase(c);
 582       Posts(posts);
 583       RoundEdge(R_EDGE(c,0));
 584       RoundEdge(R_EDGE(c,3));
 585       InterlockEdge(R_EDGE(c,2), 0);
 586     }
 587     InterlockEdge(R_EDGE(c,1), 1);
 588     RoundCornerCut(rcs);
 589   }
 590   RoundCornerAdd(rcs);
 591 }
 592
 593 module Tile12(){ ////toplevel
 594   sz = [100,250];
 595   c0 = tile02_tr + [-sz[0], 0];
 596   c = Rectangle_corners(c0, sz);
 597   posts = Rectangle_corners2posts(c);
 598   rcs = R_CNR(c,3);
 599   difference(){
 600     union(){
 601       Rectangle_TileBase(c);
 602       Posts(posts);
 603       RoundEdge(R_EDGE(c,2));
 604       RoundEdge(R_EDGE(c,3));
 605     }
 606     InterlockEdge(R_EDGE(c,0), 1);
 607     InterlockEdge(R_EDGE(c,1), 1);
 608     RoundCornerCut(rcs);
 609   }
 610   RoundCornerAdd(rcs);
 611 }
 612
 613 tile_01_11_cnr = tile01_tr + [-cutout_tile11_x, 0];
 614 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 615 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 616
 617 module Tile11(){ ////toplevel
 618   sz = [250,250];
 619   c0 = tile01_tr + [-sz[0],0];
 620   c = Rectangle_corners(c0, sz);
 621   cnr_posts = Rectangle_corners2posts(c);
 622   posts = concat(
 623                  Posts_interpolate_one(cnr_posts[0],
 624                                        cnr_posts[1] - [cutout_tile11_x, 0]),
 625                  [ cnr_posts[1] + [0, cutout_tile11_y],
 626                    cnr_posts[2],
 627                    cnr_posts[3]
 628                    ]);
 629   difference(){
 630     union(){
 631       Rectangle_TileBase(c);
 632       Posts(posts);
 633       RoundEdge(R_EDGE(c,2));
 634       InterlockEdge(R_EDGE(c,3));
 635     }
 636     InterlockEdge(c[0], tile_01_11_cnr, 1);
 637     InterlockEdge(tile_11_10_cnr, c[2], 1);
 638     Machine();
 639   }
 640 }
 641
 642 module Tile01(){ ////toplevel
 643   sz = [250,170];
 644   c0 = tile01_tr + -sz;
 645   c = Rectangle_corners(c0, sz);
 646   cnr_posts = Rectangle_corners2posts(c);
 647   posts = concat(
 648                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 649                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 650                  Posts_interpolate_one(cnr_posts[2] - [cutout_tile11_x, 0],
 651                                        cnr_posts[3])
 652                  );
 653   difference(){
 654     union(){
 655       Rectangle_TileBase(c);
 656       Posts(posts);
 657       RoundEdge(R_EDGE(c,0));
 658       InterlockEdge(tile_01_11_cnr, c[3]);
 659       InterlockEdge(R_EDGE(c,3));
 660     }
 661     InterlockEdge(c[1], tile_01_00_cnr, 1);
 662     Machine();
 663   }
 664 }
 665
 666 module Tile10(){ ////toplevel
 667   sz = [250,250];
 668   c0 = tile01_tr + [0,0];
 669   c = Rectangle_corners(c0, sz);
 670   cnr_posts = Rectangle_corners2posts(c);
 671   cty = cutout_tile11_y;
 672   rcy = cty + rearcurve_avoid_y;
 673   posts = [ cnr_posts[0] + [ 0,                             cty ],
 674             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 675             cnr_posts[1] + [ 0,                             rcy ],
 676             cnr_posts[2],
 677             cnr_posts[3] ];
 678   rcs = R_CNR(c,2);
 679   difference(){
 680     union(){
 681       Rectangle_TileBase(c);
 682       Posts(posts);
 683       RoundEdge(R_EDGE(c,1));
 684       RoundEdge(R_EDGE(c,2));
 685       InterlockEdge(c[3], tile_11_10_cnr);
 686     }
 687     RoundCornerCut(rcs);
 688     Machine();
 689   }
 690   RoundCornerAdd(rcs);
 691 }
 692
 693 module Tile00(){ ////toplevel
 694   sz = [250,170];
 695   c0 = tile01_tr + [0,-sz[1]];
 696   c = Rectangle_corners(c0, sz);
 697
 698   // the edge c[1]..c[2] needs a diagonal chunk, from c1bis to c2bis
 699   c2bis = [ -cutout_l_end_x + rearedge_len + frontcurve_strt_len, c[2][1] ];
 700   c1bis = [ c[1][0],
 701             c[2][1] -
 702             (c[2][0] - c2bis[0]) * tan(90 - frontcurve_dualcurve_angle) ];
 703
 704   cnr_posts = Rectangle_corners2posts(c);
 705   cty = cutout_tile01_y;
 706   rcy = cty + frontcurve_avoid_y;
 707   posts = [ cnr_posts[0],
 708             cnr_posts[1],
 709             cnr_posts[2] + [ 0,                             -rcy ],
 710             cnr_posts[2] + [ -sz[0] + rearedge_len - cutout_l_end_x, -cty ],
 711             cnr_posts[3] + [ 0,                             -cty ]
 712             ];
 713   rcs = R_CNR(c,1);
 714   rc2 = [c1bis,c2bis,c[1]];
 715   difference(){
 716     union(){
 717       difference(){
 718         union(){
 719           Rectangle_TileBase(c);
 720           Posts(posts);
 721           RoundEdge(R_EDGE(c,0));
 722           RoundEdge(c[1], c1bis);
 723           InterlockEdge(tile_01_00_cnr, c[0]);
 724         }
 725         RoundCornerCut(rcs);
 726         translate([0,0,-20]) linear_extrude(height=40) {
 727           polygon([ c1bis, c1bis + [50,0], c2bis + [50,0], c2bis ]);
 728         }
 729       }
 730       RoundEdge(c1bis, c2bis);
 731     }
 732     Machine();
 733     RoundCornerCut(rc2);
 734   }
 735   RoundCornerAdd(rcs);
 736   RoundCornerAdd(rc2);
 737 }
 738
 739 module FitTest_general(c0,sz, dobrace=false, bracexx=0){
 740   c = Rectangle_corners(c0, sz);
 741   brace = [7,7,9];
 742   bsz = sz + [bracexx,0,0];
 743   difference(){
 744     union(){
 745       Rectangle_TileBase(c);
 746       if (dobrace) {
 747         translate(concat(c0, [-brace[2] + 0.1])){
 748           difference(){
 749             cube(concat(bsz, [brace[2]]) - [5,0,0]);
 750             translate(brace + [0,0, -25])
 751               cube(concat(bsz, [50]) - brace*2 + [10,0,0]);
 752           }
 753         }
 754       }
 755       RoundEdge(R_EDGE(c,1));
 756     }
 757     Machine();
 758   }
 759 }
 760
 761 module FitTest_PairLink(cut=false){ ////toplevel
 762   cy0=-55; cy1=85; cx=132;
 763   bar = [10,10];
 764   legrad = 12;
 765   footrad_min = 1; footrad_max = 4; footrad_depth = 5;
 766   strap = [3,5];
 767   adj_neg_slop = 1.0;
 768   bar_z_slop = 1.75;
 769
 770   // calculated
 771   straphole_x_max = legrad/sqrt(2) + footrad_max;
 772   dz = cut ? adj_neg_slop : 0;
 773
 774   translate([cx - bar[0]/2, cy0, dz + bar_z_slop])
 775     cube([bar[0], cy1-cy0, bar[1] - bar_z_slop]);
 776
 777   for (endy=[cy0,cy1]) {
 778     $fn=32;
 779     translate([cx,endy,dz]){
 780       // feet
 781       for (rot=[45:90:315]) rotate(rot) {
 782         translate([legrad,0,0]){
 783           hull(){
 784             cylinder(r= footrad_max, h=1);
 785             translate([0,0,-footrad_depth])
 786               cylinder(r= footrad_min, h=1);
 787           }
 788           translate([0,0,-10])
 789             cylinder(r= footrad_min +
 790                      adj_neg_slop * (footrad_max-footrad_min)/footrad_depth,
 791                      h=20);
 792         }
 793       }
 794       // legs
 795       for (rot=[45,135]) rotate(rot) {
 796         hull(){
 797           for (s=[-1,+1]){
 798             translate([s*legrad,0,0])
 799               cylinder(r= footrad_max, h=bar[1]);
 800           }
 801         }
 802       }
 803       // strap holes
 804       if (cut) {
 805         for (rot=[0,180]) rotate(rot) {
 806             translate([ straphole_x_max - strap[0]/2, 0,0 ])
 807               cube(concat(strap,[20]), center=true);
 808           }
 809       }
 810     }
 811   }
 812 }
 813
 814 module FitTest_RearCurve(){ ////toplevel
 815   difference(){
 816     FitTest_general([100,0], [180,100]);
 817     FitTest_PairLink(true);
 818     TestStrapSlots();
 819   }
 820 }
 821
 822 module FitTest_FrontCurve(){ ////toplevel
 823   p0 = [100,-80];
 824   sz = [180,80];
 825   difference(){
 826     intersection() {
 827       Tile00();
 828       translate([0,0,-8]) linear_extrude(height=18) {
 829         translate(p0) square(sz);
 830       }
 831     }
 832     FitTest_PairLink(true);
 833   }
 834 }
 835
 836 module FitTest_Entire(){ ////toplevel
 837   p0 = [-40,-80];
 838   szrear = [270,180];
 839   szfront = [250,szrear[1]];
 840   difference(){
 841     FitTest_general(p0, szrear, dobrace=true, bracexx=0);
 842     FitTest_PairLink(true);
 843     translate(concat(p0,[0]) + [szfront[0],-10,-40])
 844       cube([100, -p0[1], 80]);
 845   }
 846   intersection(){
 847     FitTest_RearCurve();
 848     translate(concat(p0,[-20])) cube(concat(szrear,[40]));
 849   }
 850   FitTest_FrontCurve();
 851 }
 852
 853 module FitTest_EntireDemo(){ ////toplevel
 854   FitTest_Entire();
 855   //%Tile00();
 856 }
 857
 858 module FitTest_PairDemo(){ ////toplevel
 859   sh=[-90,-15,0];
 860   translate(sh){
 861     FitTest_PairLink();
 862     %FitTest_FrontCurve();
 863     %FitTest_RearCurve();
 864   }
 865   rotate([0,0,180]){
 866     translate(sh){
 867       difference(){
 868         union(){
 869           FitTest_FrontCurve();
 870           FitTest_RearCurve();
 871         }
 872         #FitTest_PairLink(true);
 873       }
 874     }
 875   }
 876 }
 877
 878 module RoundCornerDemo_plat(cnr){
 879   mirror([0,0,1]) linear_extrude(height=1) polygon(cnr);
 880 }
 881
 882 module RoundCornerDemo(){ ////toplevel
 883   cnr = [ [-2,-3], [13,-3], [-12,9] ];
 884   translate([0,25,0]) RoundCornerDemo_plat(cnr);
 885   translate([25,0,0]) RoundCornerAdd(cnr);
 886   translate([-25,0,0]) RoundCornerCut(cnr);
 887   translate([0,-25,0]) RoundCorner_selector(cnr, 0);
 888   difference(){
 889     RoundCornerDemo_plat(cnr);
 890     RoundCornerCut(cnr);
 891   }
 892   RoundCornerAdd(cnr);
 893 }
 894
 895 module Demo(){ ////toplevel
 896   translate(demo_slop*[-2,1]) color("blue") Tile12();
 897   translate(demo_slop*[-2,0]) color("red")  Tile02();
 898   translate(demo_slop*[-2,1]) color("orange") Tile11();
 899   translate(demo_slop*[-2,0]) color("purple") Tile01();
 900   translate(demo_slop*[-3,1]) color("blue")   Tile10();
 901   translate(demo_slop*[-3,0]) color("red")    Tile00();
 902   %Machine();
 903 }
 904
 905 //TestPiece1();
 906 //TestPiece2();
 907 //Demo();
 908
 909 //Machine_NewRearProfile();
 910 //Machine_NewRearCurve();
 911 //Machine_NewFrontProfile();
 912 //Machine_Curves();
 913 //Machine();
 914 //FitTest();
 915 //MachineEnvelope();