sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 tile_th = 3;
  11 post_dia = 8;
  12
  13 post_shorter = 1;
  14
  15 screw_dia = 2.2;
  16 screw_big_dia = 3.6;
  17 screw_big_len = 4.0;
  18
  19 round_edge_rad = 2.0;
  20
  21 round_cnr_rad = 10;
  22
  23 interlock_dia = 10;
  24 interlock_fine = 0.66;
  25
  26 interlock_fine_slope = 1.0;
  27 interlock_fine_lenslop = 1.0;
  28
  29 demo_slop = 0.1;
  30
  31 // cutout
  32
  33 machine_rear_to_front = 85;
  34
  35 machine_rear_profile = [
  36                         [ -  0,  -0.00 ],
  37                         [ -  2,  -0.10 ],
  38                         [ -  4,  -0.20 ],
  39                         [ -  5,  -0.30 ],
  40                         [ -  6,  -0.40 ],
  41                         [ -  7,  -0.50 ],
  42                         [ -  8,  -0.75 ],
  43                         [ - 10,  -1.50 ],
  44                         [ - 12,  -2.25 ],
  45                         [ - 14,  -3.25 ],
  46                         [ - 16,  -4.25 ],
  47                         [ - 18,  -5.75 ],
  48                         [ - 20,  -8.00 ]
  49                         ];
  50
  51 machine_front_profile =  [
  52                           [  128,  -3.70,  ],
  53                           [  124,  -2.90,  ],
  54                           [  120,  -2.45,  ],
  55                           [  116,  -2.10,  ],
  56                           [  112,  -1.80,  ],
  57                           [  108,  -1.55,  ],
  58                           [  104,  -1.25,  ],
  59                           [  100,  -1.00,  ],
  60                           [   96,  -0.80,  ],
  61                           [   92,  -0.65,  ],
  62                           [   88,  -0.55,  ],
  63                           [   84,  -0.50,  ]
  64                           ];
  65
  66 cutout_l_end_y_front_slop = 0.5;
  67 cutout_l_end_y_rear_slop = 0.5;
  68 cutout_l_end_x_slop = 0.25;
  69
  70 cutout_l_end_x = 22;
  71 cutout_l_end_y = machine_rear_to_front;
  72 cutout_l_end_curve = 1;
  73 cutout_l_end_y_total = cutout_l_end_y
  74   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  75
  76 tile02_tr = [-250, 0];
  77 tile01_tr = [  0, 0];
  78
  79 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  80 cutout_tile11_x = cutout_l_end_x + cutout_l_end_curve;
  81 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  82
  83 // front and rear curves
  84
  85 rearedge_len = 170;
  86
  87 rearcurve_strt_len = 52;
  88
  89 rearcurve_z_slop = 0.75;
  90
  91 rearcurve_avoid_y = 35;
  92
  93 rearcurve_double_inrad = 26.10 + 8.04;
  94
  95 reartablet_z = 2.54;
  96 reartablet_x = 5 + 1;
  97 reartablet_y = 8;
  98
  99 frontcurve_side_skew = 3.5 / 72;
 100 frontcurve_avoid_y = 70;
 101 frontcurve_z_slop = 0.75;
 102
 103 // calculated
 104
 105 TEST = false;
 106
 107 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
 108
 109 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
 110
 111 hole_slop = (ply_hole_dia - post_dia)/2;
 112 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
 113
 114 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
 115          tile_hard_edge_hole_dist));
 116
 117 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
 118          tile_hard_edge_hole_dist + round_edge_rad));
 119
 120 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
 121 thehd_tr = thehd;
 122 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 123 thehd_bl = -thehd_tr;
 124 thehd_br = -thehd_tl;
 125
 126 tablet_z_slop = rearcurve_z_slop;
 127
 128 interlock_rad = interlock_dia/2;
 129 interlock_negative_rad = interlock_rad + 0.125;
 130
 131 interlock_sq_adj = 0.2; // arbitrary
 132
 133 first_front = machine_front_profile[len(machine_front_profile)-1];
 134
 135 m4_define(`POST_TCROSSSZ',
 136           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 137
 138 module Post(){
 139   mirror([0,0,1]) {
 140     difference(){
 141       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 142       translate([0,0, tile_th]) {
 143         cylinder(r= screw_big_dia/2, h= screw_big_len);
 144         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
 145       }
 146     }
 147     if (TEST) {
 148       translate([0,0, tile_th/2]) {
 149         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 150         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 151       }
 152     }
 153   }
 154 }
 155
 156 module Posts(posts) {
 157   for (p= posts) {
 158     translate(concat(p, [0]))
 159       Post();
 160   }
 161 }
 162
 163 module TileBase(botleft, topright){
 164   size = topright - botleft;
 165   botleft_post = botleft + thehd_tr;
 166   topright_post = topright + thehd_bl;
 167   difference(){
 168     mirror([0,0,1])
 169       translate(concat(botleft, [0]))
 170       cube(concat(size, [tile_th]));
 171     if (!TEST) {
 172       cidsz = topright_post-botleft_post
 173         + [-post_dia,-post_dia]
 174         + [0, thehd[1]];
 175       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
 176       echo("CID",cidsz,cidszr);
 177       translate( concat(botleft_post, [ -tile_th ])
 178                  + 0.5 * [ post_dia, post_dia, 0 ]
 179                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
 180         Commitid_BestCount_M(cidszr);
 181     }
 182     if (TEST) {
 183       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
 184       cidsz = [ thehd[0], size[1] - 2*crossoff ];
 185       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
 186       translate( concat(botleft + [0, crossoff] + (cidsz-cidszr)/2, [0]) )
 187         Commitid_BestCount(cidszr);
 188       difference(){
 189         mirror([0,0,1]) {
 190           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 191             cube(concat(size - [test_edge,test_edge]*2, [tile_th]));
 192           translate(concat(botleft_post, [-1]))
 193             cube(concat(topright_post-botleft_post, [tile_th+2]));
 194         }
 195         minkowski(){
 196           Machine();
 197           cube(max(test_edge, tile_hard_edge_hole_dist)*2, center=true);
 198         }
 199       }
 200     }
 201   }
 202 }
 203
 204 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 205 m4_define(`INREFFRAME',`
 206   length_vec = ($2) - ($1);
 207   length = dist2d([0,0], length_vec);
 208   length_uvec = length_vec / length;
 209   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 210   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 211         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 212         [ 0,              0,              1,            0, ],
 213         [ 0,              0,              0,            1, ] ];
 214   $3
 215   multmatrix(m)
 216 ')
 217
 218 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 219 m4_dnl    INREFFRAME_EDGE { body; }
 220 m4_define(`INREFFRAME_EDGE',`
 221   translate([0,0, -round_edge_rad])
 222 ')
 223
 224 module RoundEdge(left_cnr, right_cnr) {
 225   INREFFRAME(left_cnr, right_cnr)
 226     INREFFRAME_EDGE {
 227     difference(){
 228       rotate([0,90,0])
 229         cylinder(r= round_edge_rad, h= length, $fn=50);
 230       translate([-1, 0, -20])
 231         cube([length+2, 20, 20]);
 232     }
 233   }
 234 }
 235
 236 module RoundCornerCut(ci) {
 237   // ci should be [this_cnr, right_cnr]
 238   // where right_cnr is to the right (ie, anticlockwise)
 239   this_cnr = ci[0];
 240   right_cnr = ci[1];
 241   offr= round_cnr_rad - round_edge_rad;
 242   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 243     difference(){
 244       cube(offr*2 - 0.1, center=true);
 245       translate([offr, offr, 0])
 246         cylinder(center=true, h=20, r= offr);
 247     }
 248   }
 249 }
 250
 251 module RoundCornerAdd(ci) {
 252   this_cnr = ci[0];
 253   right_cnr = ci[1];
 254   bigr = round_cnr_rad - round_edge_rad;
 255   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 256     intersection(){
 257       cube(bigr*2 + 0.1, center=true);
 258       translate([bigr, bigr, 0])
 259         rotate_extrude(convexity=10, $fn=50)
 260         translate([bigr, 0])
 261         difference(){
 262           circle(r= round_edge_rad, $fn=50);
 263           mirror([1,1])
 264             square([20,20]);
 265         }
 266     }
 267   }
 268 }
 269
 270 module InterlockLobePlan(negative) {
 271   r = negative ? interlock_negative_rad : interlock_rad;
 272   ymir = negative ? 0 : 1;
 273
 274   dx = sqrt(3) * r;
 275   $fn= 80;
 276   translate([thehd[0], 0]){
 277     mirror([0,ymir]){
 278       circle(r=r);
 279       difference(){
 280         translate([-dx, -0.1])
 281           square([ dx*2, r/2 + 0.1 ]);
 282         for (xi = [-1, 1]) {
 283           translate([ xi*dx, r ])
 284             circle(r=r);
 285         }
 286       }
 287     }
 288   }
 289 }
 290
 291 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 292   for (lobei = [ 0 : nlobes-1 ]) {
 293     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 294     translate([lobex, 0, 0]) {
 295       InterlockLobePlan(negative);
 296     }
 297   }
 298
 299   if (dosquare) {
 300     iadj = 0;
 301     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 302     mirror([0, negative])
 303       translate([slotshorter, iadj])
 304       square([length - slotshorter*2, interlock_fine + iadj*2]);
 305   }
 306 }
 307
 308 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 309   plusth = negative * 1.0;
 310   protr = interlock_fine + interlock_sq_adj;
 311
 312   z2 = -tile_th/2;
 313   z1 = -tile_th/2 - protr / interlock_fine_slope;
 314   z3 = -tile_th/2 + protr / interlock_fine_slope;
 315
 316   negsign = negative ? -1 : +1;
 317   yprotr = negsign * protr;
 318
 319   INREFFRAME(left_cnr, right_cnr) {
 320     for (vsect = [ // zs0            zs1      ys0,            ys1
 321                   [ -tile_th-plusth, plusth,  0,              0],
 322                   [ z1,              z2,      0, yprotr],
 323                   [ z2,              z3,      yprotr, 0],
 324                   ]) {
 325       zs0 = vsect[0];
 326       zs1 = vsect[1];
 327       zsd = zs1-zs0;
 328       ys0 = vsect[2];
 329       ys1 = vsect[3];
 330       ysd = ys1-ys0;
 331       sl = ysd/zsd;
 332       m = [ [ 1,0,   0,    0 ],
 333             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 334             [ 0,0,   1,  zs0 ],
 335             [ 0,0,   0,    1 ] ];
 336       multmatrix(m)
 337         linear_extrude(height=zsd, convexity=10)
 338         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 339     }
 340   }
 341 }
 342
 343 function TestPiece_holes2corners(holes) =
 344   [ holes[0] + thehd_bl,
 345     holes[1] + thehd_br,
 346     holes[1] + thehd_tr,
 347     holes[0] + thehd_tl ];
 348
 349 module TestPiece1(){ ////toplevel
 350   holes = [ [-100, 0],
 351             [   0, 0]
 352             ];
 353   corners = TestPiece_holes2corners(holes);
 354   rcs = [corners[0], corners[1]];
 355   difference(){
 356     union(){
 357       TileBase(corners[0], corners[2]);
 358       Posts(holes);
 359       RoundEdge(corners[0], corners[1]);
 360       RoundEdge(corners[3], corners[0]);
 361     }
 362     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 363     RoundCornerCut(rcs);
 364   }
 365   RoundCornerAdd(rcs);
 366 }
 367
 368 module TestPiece2(){ ////toplevel
 369   holes = [ [   0, 0],
 370             [  50, 0]
 371             ];
 372   corners = TestPiece_holes2corners(holes);
 373   TileBase(corners[0], corners[2]);
 374   Posts(holes);
 375   RoundEdge(corners[0], corners[1]);
 376   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 377 }
 378
 379 module TestDemo(){ ////toplevel
 380   translate([ -thehd[0], 0 ])
 381     color("blue")
 382     TestPiece1();
 383   translate([ +thehd[0] + demo_slop, 0 ])
 384     TestPiece2();
 385 }
 386
 387 module Machine_Arm(){
 388   ysz = cutout_l_end_y_total;
 389   // assume the round end is arc of a circle
 390   chordlen = dist2d([0,0], [ cutout_l_end_y, cutout_l_end_curve ]);
 391   endrad = cutout_l_end_y / cutout_l_end_curve * chordlen;
 392
 393   translate([0,0,-30]) linear_extrude(height=60) {
 394     translate(tile01_tr + [0, (-cutout_tile01_y + cutout_tile11_y)/2]) {
 395       intersection(){
 396         translate([-50, -ysz/2])
 397           square([400, ysz]);
 398         translate([ endrad - cutout_tile11_x - cutout_l_end_x_slop, 0 ])
 399           circle(r=endrad, $fa=0.01,$fd=5);
 400       }
 401     }
 402   }
 403 }
 404
 405 module Machine_Profile(){
 406   first_rear = machine_rear_profile[0];
 407   below_point = 0.5 * ( first_rear + first_front ) + [ 0, -10 ];
 408   pol = concat( machine_rear_profile,
 409                 [ below_point ],
 410                 machine_front_profile);
 411   skew_angle = atan2( first_front[1] - first_rear[1],
 412                       first_front[0] - first_rear[0] );
 413   echo(below_point, pol, skew_angle);
 414   hull(){
 415     for (z=[0,-40]) {
 416       translate([0,z]) {
 417         //scale([1,5])
 418         rotate([0,0, -skew_angle ]){
 419           //translate( - first_front )
 420           polygon(pol);
 421         }
 422       }
 423     }
 424   }
 425 }
 426
 427 module Machine_NewRearProfile(){
 428   // figures copied out of xfig edit boxes
 429   // best not to edit the posbox size if poss - just move it
 430   posbox = 10 * ([7.2333,-14.1267] - [-16.2289,40.0289]); // box, Green
 431   sideline = -10 * ([-6.2400,13.5600] - [-2.4467,28.2556]); // line, Blue
 432   scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
 433   scaleline_mm = 12+5+10+5+3;
 434   sh = -[abs(posbox[0]), abs(posbox[1])];
 435   rot = atan2(-sideline[0], sideline[1]);
 436   sc = scaleline_mm / scaleline;
 437   echo("SH",sh,rot,sc);
 438   scale(sc) rotate(rot) translate(sh){
 439     import("sewing-table-rear-profile.dxf", convexity=10); // spline, Pink3
 440   }
 441 }
 442
 443 module Machine_NewRearCurve(){
 444   slant = atan2(4,210-10);
 445   echo("SL",slant);
 446   translate([0,0, rearcurve_double_inrad]) rotate([slant,0,0]){
 447     translate([ rearcurve_double_inrad,
 448                 0,
 449                 -rearcurve_double_inrad + 10 ]){
 450       rotate([180,0,0]) rotate([0,0,90]) linear_extrude(height=30){
 451         hull(){
 452           Machine_NewRearProfile();
 453           translate([0,-100]) Machine_NewRearProfile();
 454         }
 455       }
 456     }
 457     rotate([0,90,0]) rotate([90,0,0]) {
 458       intersection(){
 459         rotate_extrude(convexity=10, $fn=64)
 460           rotate(90)
 461           translate([ 0, -rearcurve_double_inrad ])
 462           Machine_NewRearProfile();
 463         translate([0,0,-500])
 464           cube([500,500,1000]);
 465       }
 466     }
 467     translate([1,0,-rearcurve_double_inrad])
 468       rotate([0,-90,0]) rotate([0,0,-90])
 469       linear_extrude(height= rearcurve_strt_len + 1)
 470       Machine_NewRearProfile();
 471   }
 472 }
 473
 474 module Machine_RearProfile(){ ////toplevel
 475   intersection(){
 476     Machine_Profile();
 477     translate([ -200 + machine_rear_to_front/2, -100 ]) {
 478       square([200,200]);
 479     }
 480   }
 481 }
 482
 483 module Machine_FrontProfile(){
 484   intersection(){
 485     Machine_Profile();
 486     translate([ machine_rear_to_front/2, -100 ]) {
 487       square([200,200]);
 488     }
 489   }
 490 }
 491
 492 module Machine_Curves(){ ////toplevel
 493   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 494               cutout_tile11_y,
 495               0 ]){
 496     //%cube([20,20,20]);
 497     translate([ -reartablet_x,
 498                 -1,
 499                 -reartablet_z + tablet_z_slop])
 500       mirror([0,0,1])
 501       cube([ reartablet_x+1,
 502              reartablet_y+1,
 503              20 ]);
 504   }
 505   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 506               cutout_tile11_y,
 507               frontcurve_z_slop ]){
 508     translate([ 0, -first_front[0] , 0 ])
 509       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 510                   [0,  1,   0, 0],
 511                   [0,  0,   1, 0],
 512                   [0,  0,   0, 1]])
 513       translate([ 0, first_front[0] , 0 ])
 514       mirror([1,0,0]){
 515       rotate([0,-90,0])rotate([0,0,-90]){
 516         linear_extrude(height= 200)
 517           Machine_FrontProfile();
 518       }
 519     }
 520     translate([ rearcurve_strt_len,
 521                 0,
 522                 rearcurve_z_slop ]){
 523       Machine_NewRearCurve();
 524     }
 525   }
 526 }
 527
 528 module Machine(){ ////toplevel
 529   Machine_Arm();
 530   Machine_Curves();
 531 }
 532
 533 function Rectangle_corners(c0, sz) =
 534   // returns the corners of a rectangle from c0 to c0+sz
 535   // if sz is positive, the corners are anticlockwise starting with c0
 536   [ c0 + [ 0,     0     ],
 537     c0 + [ sz[0], 0     ],
 538     c0 + [ sz[0], sz[1] ],
 539     c0 + [ 0,     sz[1] ] ];
 540
 541 function Rectangle_corners2posts(c) =
 542   [ c[0] + thehd_tr,
 543     c[1] + thehd_tl,
 544     c[2] + thehd_bl,
 545     c[3] + thehd_br ];
 546
 547 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 548
 549 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 550
 551 m4_dnl   R_EDGE(c,ix)
 552 m4_dnl        c is from Rectangle_corners and
 553 m4_dnl        ix is a corner number
 554 m4_dnl    expands to two comma-separated corners:
 555 m4_dnl    that denoted by ix, and the next one anticlockwise
 556 m4_define(`R_EDGE',`$1[$2],$1[(($2)+1)%4]')
 557
 558 module FitTest_general(c0,sz, dobrace=false){
 559   c = Rectangle_corners(c0, sz);
 560   brace = [7,7,9];
 561   difference(){
 562     union(){
 563       Rectangle_TileBase(c);
 564       if (dobrace) {
 565         translate(concat(c0, [-brace[2] + 0.1])){
 566           difference(){
 567             cube(concat(sz,[brace[2]]) - [5,0,0]);
 568             translate(brace + [0,0, -25])
 569               cube(concat(sz, [50]) - brace*2 + [10,0,0]);
 570           }
 571         }
 572       }
 573       RoundEdge(R_EDGE(c,1));
 574     }
 575     Machine();
 576   }
 577 }
 578
 579 module FitTest_Entire(){ ////toplevel
 580   FitTest_general([-40,-80], [275,180], dobrace=true);
 581 }
 582
 583 module FitTest_RearCurve(){ ////toplevel
 584   FitTest_general([110,0], [170,100]);
 585 }
 586
 587 module FitTest_FrontCurve(){ ////toplevel
 588   FitTest_general([110,-80], [170,80]);
 589 }
 590
 591 module Tile02(){ ////toplevel
 592   sz = [100,170];
 593   c0 = tile02_tr + -sz;
 594   c = Rectangle_corners(c0, sz);
 595   posts = Rectangle_corners2posts(c);
 596   rcs = [R_EDGE(c,0)];
 597   difference(){
 598     union(){
 599       Rectangle_TileBase(c);
 600       Posts(posts);
 601       RoundEdge(R_EDGE(c,0));
 602       RoundEdge(R_EDGE(c,3));
 603       InterlockEdge(R_EDGE(c,2), 0);
 604     }
 605     InterlockEdge(R_EDGE(c,1), 1);
 606     RoundCornerCut(rcs);
 607   }
 608   RoundCornerAdd(rcs);
 609 }
 610
 611 module Tile12(){ ////toplevel
 612   sz = [100,250];
 613   c0 = tile02_tr + [-sz[0], 0];
 614   c = Rectangle_corners(c0, sz);
 615   posts = Rectangle_corners2posts(c);
 616   rcs = [R_EDGE(c,3)];
 617   difference(){
 618     union(){
 619       Rectangle_TileBase(c);
 620       Posts(posts);
 621       RoundEdge(R_EDGE(c,2));
 622       RoundEdge(R_EDGE(c,3));
 623     }
 624     InterlockEdge(R_EDGE(c,0), 1);
 625     InterlockEdge(R_EDGE(c,1), 1);
 626     RoundCornerCut(rcs);
 627   }
 628   RoundCornerAdd(rcs);
 629 }
 630
 631 tile_01_11_cnr = tile01_tr + [-cutout_tile11_x, 0];
 632 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 633 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 634
 635 module Tile11(){ ////toplevel
 636   sz = [250,250];
 637   c0 = tile01_tr + [-sz[0],0];
 638   c = Rectangle_corners(c0, sz);
 639   cnr_posts = Rectangle_corners2posts(c);
 640   posts = concat(
 641                  Posts_interpolate_one(cnr_posts[0],
 642                                        cnr_posts[1] - [cutout_tile11_x, 0]),
 643                  [ cnr_posts[1] + [0, cutout_tile11_y],
 644                    cnr_posts[2],
 645                    cnr_posts[3]
 646                    ]);
 647   difference(){
 648     union(){
 649       Rectangle_TileBase(c);
 650       Posts(posts);
 651       RoundEdge(R_EDGE(c,2));
 652       InterlockEdge(R_EDGE(c,3));
 653     }
 654     InterlockEdge(c[0], tile_01_11_cnr, 1);
 655     InterlockEdge(tile_11_10_cnr, c[2], 1);
 656     Machine();
 657   }
 658 }
 659
 660 module Tile01(){ ////toplevel
 661   sz = [250,170];
 662   c0 = tile01_tr + -sz;
 663   c = Rectangle_corners(c0, sz);
 664   cnr_posts = Rectangle_corners2posts(c);
 665   posts = concat(
 666                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 667                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 668                  Posts_interpolate_one(cnr_posts[2] - [cutout_tile11_x, 0],
 669                                        cnr_posts[3])
 670                  );
 671   difference(){
 672     union(){
 673       Rectangle_TileBase(c);
 674       Posts(posts);
 675       RoundEdge(R_EDGE(c,0));
 676       InterlockEdge(tile_01_11_cnr, c[3]);
 677       InterlockEdge(R_EDGE(c,3));
 678     }
 679     InterlockEdge(c[1], tile_01_00_cnr, 1);
 680     Machine();
 681   }
 682 }
 683
 684 module Tile10(){ ////toplevel
 685   sz = [250,250];
 686   c0 = tile01_tr + [0,0];
 687   c = Rectangle_corners(c0, sz);
 688   cnr_posts = Rectangle_corners2posts(c);
 689   cty = cutout_tile11_y;
 690   rcy = cty + rearcurve_avoid_y;
 691   posts = [ cnr_posts[0] + [ 0,                             cty ],
 692             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 693             cnr_posts[1] + [ 0,                             rcy ],
 694             cnr_posts[2],
 695             cnr_posts[3] ];
 696   rcs = [R_EDGE(c,2)];
 697   difference(){
 698     union(){
 699       Rectangle_TileBase(c);
 700       Posts(posts);
 701       RoundEdge(R_EDGE(c,1));
 702       RoundEdge(R_EDGE(c,2));
 703       InterlockEdge(c[3], tile_11_10_cnr);
 704     }
 705     RoundCornerCut(rcs);
 706     Machine();
 707   }
 708   RoundCornerAdd(rcs);
 709 }
 710
 711 module Tile00(){ ////toplevel
 712   sz = [250,170];
 713   c0 = tile01_tr + [0,-sz[1]];
 714   c = Rectangle_corners(c0, sz);
 715   cnr_posts = Rectangle_corners2posts(c);
 716   cty = cutout_tile01_y;
 717   rcy = cty + frontcurve_avoid_y;
 718   posts = [ cnr_posts[0],
 719             cnr_posts[1],
 720             cnr_posts[2] + [ 0,                             -rcy ],
 721             cnr_posts[2] + [ -sz[0] + rearedge_len - cutout_l_end_x, -cty ],
 722             cnr_posts[3] + [ 0,                             -cty ]
 723             ];
 724   rcs = [R_EDGE(c,1)];
 725   difference(){
 726     union(){
 727       Rectangle_TileBase(c);
 728       Posts(posts);
 729       RoundEdge(R_EDGE(c,0));
 730       RoundEdge(R_EDGE(c,1));
 731       InterlockEdge(tile_01_00_cnr, c[0]);
 732     }
 733     RoundCornerCut(rcs);
 734     Machine();
 735   }
 736   RoundCornerAdd(rcs);
 737 }
 738
 739 module Demo(){ ////toplevel
 740   translate(demo_slop*[-2,1]) color("blue") Tile12();
 741   translate(demo_slop*[-2,0]) color("red")  Tile02();
 742   translate(demo_slop*[-2,1]) color("orange") Tile11();
 743   translate(demo_slop*[-2,0]) color("purple") Tile01();
 744   translate(demo_slop*[-3,1]) color("blue")   Tile10();
 745   translate(demo_slop*[-3,0]) color("red")    Tile00();
 746   %Machine();
 747 }
 748
 749 //TestPiece1();
 750 //TestPiece2();
 751 //Demo();
 752
 753 //Machine_Profile();
 754 //Machine_NewRearProfile();
 755 //Machine_NewRearCurve();
 756 //Machine_Curves();
 757 //Machine();
 758 //FitTest();