sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 tile_th = 3;
  11 post_dia = 8;
  12
  13 post_shorter = 1;
  14
  15 screw_dia = 2.2;
  16 screw_big_dia = 3.6;
  17 screw_big_len = 4.0;
  18
  19 round_edge_rad = 2.0;
  20
  21 round_cnr_rad = 10;
  22
  23 interlock_dia = 10;
  24 interlock_fine = 0.66;
  25
  26 interlock_fine_slope = 1.0;
  27 interlock_fine_lenslop = 1.0;
  28
  29 demo_slop = 0.1;
  30
  31 // cutout
  32
  33 machine_rear_to_front = 85;
  34
  35 machine_rear_profile = [
  36                         [ -  0,  -0.00 ],
  37                         [ -  2,  -0.10 ],
  38                         [ -  4,  -0.20 ],
  39                         [ -  5,  -0.30 ],
  40                         [ -  6,  -0.40 ],
  41                         [ -  7,  -0.50 ],
  42                         [ -  8,  -0.75 ],
  43                         [ - 10,  -1.50 ],
  44                         [ - 12,  -2.25 ],
  45                         [ - 14,  -3.25 ],
  46                         [ - 16,  -4.25 ],
  47                         [ - 18,  -5.75 ],
  48                         [ - 20,  -8.00 ]
  49                         ];
  50
  51 machine_front_profile =  [
  52                           [  128,  -3.70,  ],
  53                           [  124,  -2.90,  ],
  54                           [  120,  -2.45,  ],
  55                           [  116,  -2.10,  ],
  56                           [  112,  -1.80,  ],
  57                           [  108,  -1.55,  ],
  58                           [  104,  -1.25,  ],
  59                           [  100,  -1.00,  ],
  60                           [   96,  -0.80,  ],
  61                           [   92,  -0.65,  ],
  62                           [   88,  -0.55,  ],
  63                           [   84,  -0.50,  ]
  64                           ];
  65
  66 cutout_l_end_y_front_slop = 0.5;
  67 cutout_l_end_y_rear_slop = 0.5;
  68 cutout_l_end_x_slop = 0.25;
  69
  70 cutout_l_end_x = 22;
  71 cutout_l_end_y = machine_rear_to_front;
  72 cutout_l_end_curve = 1;
  73 cutout_l_end_y_total = cutout_l_end_y
  74   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  75
  76 tile02_tr = [-250, 0];
  77 tile01_tr = [  0, 0];
  78
  79 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  80 cutout_tile11_x = cutout_l_end_x + cutout_l_end_curve;
  81 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  82
  83 // front and rear curves
  84
  85 rearedge_len = 170;
  86
  87 rearcurve_strt_len = 52;
  88
  89 rearcurve_z_slop = 0.75;
  90
  91 rearcurve_avoid_y = 35;
  92
  93 rearcurve_double_inrad = 26.10 + 8.04;
  94
  95 reartablet_z = 2.54;
  96 reartablet_x = 5 + 1;
  97 reartablet_y = 8;
  98
  99 frontcurve_side_skew = 3.5 / 72;
 100 frontcurve_avoid_y = 70;
 101 frontcurve_z_slop = 0.75;
 102
 103 frontcurve_strt_len = 60;
 104 frontcurve_dualcurve_angle = 90 - 65;
 105
 106 // calculated
 107
 108 TEST = false;
 109
 110 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
 111
 112 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
 113
 114 hole_slop = (ply_hole_dia - post_dia)/2;
 115 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
 116
 117 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
 118          tile_hard_edge_hole_dist));
 119
 120 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
 121          tile_hard_edge_hole_dist + round_edge_rad));
 122
 123 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
 124 thehd_tr = thehd;
 125 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 126 thehd_bl = -thehd_tr;
 127 thehd_br = -thehd_tl;
 128
 129 tablet_z_slop = rearcurve_z_slop;
 130
 131 interlock_rad = interlock_dia/2;
 132 interlock_negative_rad = interlock_rad + 0.125;
 133
 134 interlock_sq_adj = 0.2; // arbitrary
 135
 136 first_front = machine_front_profile[len(machine_front_profile)-1];
 137
 138 m4_define(`POST_TCROSSSZ',
 139           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 140
 141 module Post(){
 142   mirror([0,0,1]) {
 143     difference(){
 144       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 145       translate([0,0, tile_th]) {
 146         cylinder(r= screw_big_dia/2, h= screw_big_len);
 147         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
 148       }
 149     }
 150     if (TEST) {
 151       translate([0,0, tile_th/2]) {
 152         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 153         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 154       }
 155     }
 156   }
 157 }
 158
 159 module Posts(posts) {
 160   for (p= posts) {
 161     translate(concat(p, [0]))
 162       Post();
 163   }
 164 }
 165
 166 module TileBase(botleft, topright){
 167   size = topright - botleft;
 168   botleft_post = botleft + thehd_tr;
 169   topright_post = topright + thehd_bl;
 170   difference(){
 171     mirror([0,0,1])
 172       translate(concat(botleft, [0]))
 173       cube(concat(size, [tile_th]));
 174     if (!TEST) {
 175       cidsz = topright_post-botleft_post
 176         + [-post_dia,-post_dia]
 177         + [0, thehd[1]];
 178       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
 179       echo("CID",cidsz,cidszr);
 180       translate( concat(botleft_post, [ -tile_th ])
 181                  + 0.5 * [ post_dia, post_dia, 0 ]
 182                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
 183         Commitid_BestCount_M(cidszr);
 184     }
 185     if (TEST) {
 186       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
 187       cidsz = [ thehd[0], size[1] - 2*crossoff ];
 188       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
 189       translate( concat(botleft + [0, crossoff] + (cidsz-cidszr)/2, [0]) )
 190         Commitid_BestCount(cidszr);
 191       difference(){
 192         mirror([0,0,1]) {
 193           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 194             cube(concat(size - [test_edge,test_edge]*2, [tile_th]));
 195           translate(concat(botleft_post, [-1]))
 196             cube(concat(topright_post-botleft_post, [tile_th+2]));
 197         }
 198         shufflesz = max(test_edge, tile_hard_edge_hole_dist)*2;
 199         minkowski(){
 200           MachineEnvelope();
 201           cube(shufflesz, center=true);
 202         }
 203       }
 204     }
 205   }
 206 }
 207
 208 m4_dnl   R_EDGE(c,ix)
 209 m4_dnl        c is from Rectangle_corners and
 210 m4_dnl        ix is a corner number
 211 m4_dnl    expands to two comma-separated corners:
 212 m4_dnl    that denoted by ix, and the next one anticlockwise
 213 m4_define(`R_EDGE',`$1[$2], $1[(($2)+1)%4]')
 214
 215 m4_dnl   R_CNR(c,ix)
 216 m4_dnl        c is from Rectangle_corners and
 217 m4_dnl        ix is a corner number
 218 m4_dnl    expands to an array of corners as for RoundCorner
 219 m4_define(`R_CNR',`[ $1[$2], $1[(($2)+1)%4], $1[(($2)+3)%4] ]')
 220
 221 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 222 m4_define(`INREFFRAME',`
 223   length_vec = ($2) - ($1);
 224   length = dist2d([0,0], length_vec);
 225   length_uvec = length_vec / length;
 226   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 227   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 228         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 229         [ 0,              0,              1,            0, ],
 230         [ 0,              0,              0,            1, ] ];
 231   $3
 232   multmatrix(m)
 233 ')
 234
 235 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 236 m4_dnl    INREFFRAME_EDGE { body; }
 237 m4_define(`INREFFRAME_EDGE',`
 238   translate([0,0, -round_edge_rad])
 239 ')
 240
 241 module RoundEdge(left_cnr, right_cnr) {
 242   INREFFRAME(left_cnr, right_cnr)
 243     INREFFRAME_EDGE {
 244     difference(){
 245       rotate([0,90,0])
 246         cylinder(r= round_edge_rad, h= length, $fn=50);
 247       translate([-1, 0, -20])
 248         cube([length+2, 20, 20]);
 249     }
 250   }
 251 }
 252
 253 m4_define(`ROUNDCORNER_VARS',`
 254   this_cnr = ci[0];
 255   right_cnr = ci[1];
 256   left_cnr = ci[2];
 257   bigr= round_cnr_rad - round_edge_rad;
 258   l_uvec = unitvector2d(left_cnr - this_cnr);
 259   r_uvec = unitvector2d(right_cnr - this_cnr);
 260   lp1 = left_cnr  + clockwise2d(l_uvec) * bigr;
 261   lp2 = this_cnr  + clockwise2d(l_uvec) * bigr;
 262   lp3 = this_cnr  - clockwise2d(r_uvec) * bigr;
 263   lp4 = right_cnr - clockwise2d(r_uvec) * bigr;
 264   ctr = line_intersection_2d(lp1,lp2,lp3,lp4);
 265   ctr3 = concat(ctr,[0])
 266 ')
 267
 268 module RoundCorner_selector(ci, adj) {
 269   ROUNDCORNER_VARS;
 270   echo("RCS",l_uvec,ctr);
 271   %union(){
 272     INREFFRAME(this_cnr, right_cnr) {
 273       cube(bigr*2 + adj, center=true);
 274     }
 275   }
 276   intersection(){
 277     union(){
 278       INREFFRAME(ctr3,concat(lp1,[4])){
 279         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 280           translate([-bigr*2 + adj, -bigr])
 281             square([bigr*2, bigr*3]);
 282         }
 283       }
 284     }
 285     union(){
 286       INREFFRAME(ctr3,concat(lp4,[0])){
 287         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 288           translate([-bigr*2, -bigr*2])
 289             square([bigr*2 + adj, bigr*3]);
 290         }
 291       }
 292     }
 293   }
 294 }
 295
 296 module RoundCornerCut(ci) {
 297   // ci should be [this_cnr, right_cnr, left_cnr]
 298   // where right_cnr is to the right (ie, anticlockwise)
 299   ROUNDCORNER_VARS;
 300   difference(){
 301     RoundCorner_selector(ci, -0.1);
 302     translate(ctr3)
 303       cylinder(center=true, h=20, r= bigr);
 304   }
 305 }
 306
 307 module RoundCornerAdd(ci) {
 308   ROUNDCORNER_VARS;
 309   intersection(){
 310     RoundCorner_selector(ci, +0.1);
 311     INREFFRAME_EDGE {
 312       translate(ctr3){
 313         rotate_extrude(convexity=10, $fn=50)
 314           translate([bigr, 0])
 315           difference(){
 316           circle(r= round_edge_rad, $fn=50);
 317           mirror([1,1])
 318             square([20,20]);
 319         }
 320       }
 321     }
 322   }
 323 }
 324
 325 module InterlockLobePlan(negative) {
 326   r = negative ? interlock_negative_rad : interlock_rad;
 327   ymir = negative ? 0 : 1;
 328
 329   dx = sqrt(3) * r;
 330   $fn= 80;
 331   translate([thehd[0], 0]){
 332     mirror([0,ymir]){
 333       circle(r=r);
 334       difference(){
 335         translate([-dx, -0.1])
 336           square([ dx*2, r/2 + 0.1 ]);
 337         for (xi = [-1, 1]) {
 338           translate([ xi*dx, r ])
 339             circle(r=r);
 340         }
 341       }
 342     }
 343   }
 344 }
 345
 346 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 347   for (lobei = [ 0 : nlobes-1 ]) {
 348     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 349     translate([lobex, 0, 0]) {
 350       InterlockLobePlan(negative);
 351     }
 352   }
 353
 354   if (dosquare) {
 355     iadj = 0;
 356     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 357     mirror([0, negative])
 358       translate([slotshorter, iadj])
 359       square([length - slotshorter*2, interlock_fine + iadj*2]);
 360   }
 361 }
 362
 363 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 364   plusth = negative * 1.0;
 365   protr = interlock_fine + interlock_sq_adj;
 366
 367   z2 = -tile_th/2;
 368   z1 = -tile_th/2 - protr / interlock_fine_slope;
 369   z3 = -tile_th/2 + protr / interlock_fine_slope;
 370
 371   negsign = negative ? -1 : +1;
 372   yprotr = negsign * protr;
 373
 374   INREFFRAME(left_cnr, right_cnr) {
 375     for (vsect = [ // zs0            zs1      ys0,            ys1
 376                   [ -tile_th-plusth, plusth,  0,              0],
 377                   [ z1,              z2,      0, yprotr],
 378                   [ z2,              z3,      yprotr, 0],
 379                   ]) {
 380       zs0 = vsect[0];
 381       zs1 = vsect[1];
 382       zsd = zs1-zs0;
 383       ys0 = vsect[2];
 384       ys1 = vsect[3];
 385       ysd = ys1-ys0;
 386       sl = ysd/zsd;
 387       m = [ [ 1,0,   0,    0 ],
 388             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 389             [ 0,0,   1,  zs0 ],
 390             [ 0,0,   0,    1 ] ];
 391       multmatrix(m)
 392         linear_extrude(height=zsd, convexity=10)
 393         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 394     }
 395   }
 396 }
 397
 398 function TestPiece_holes2corners(holes) =
 399   [ holes[0] + thehd_bl,
 400     holes[1] + thehd_br,
 401     holes[1] + thehd_tr,
 402     holes[0] + thehd_tl ];
 403
 404 module TestPiece1(){ ////toplevel
 405   holes = [ [-100, 0],
 406             [   0, 0]
 407             ];
 408   corners = TestPiece_holes2corners(holes);
 409   rcs = R_CNR(corners,0);
 410   difference(){
 411     union(){
 412       TileBase(corners[0], corners[2]);
 413       Posts(holes);
 414       RoundEdge(corners[0], corners[1]);
 415       RoundEdge(corners[3], corners[0]);
 416     }
 417     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 418     RoundCornerCut(rcs);
 419   }
 420   RoundCornerAdd(rcs);
 421 }
 422
 423 module TestPiece2(){ ////toplevel
 424   holes = [ [   0, 0],
 425             [  50, 0]
 426             ];
 427   corners = TestPiece_holes2corners(holes);
 428   TileBase(corners[0], corners[2]);
 429   Posts(holes);
 430   RoundEdge(corners[0], corners[1]);
 431   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 432 }
 433
 434 module TestDemo(){ ////toplevel
 435   translate([ -thehd[0], 0 ])
 436     color("blue")
 437     TestPiece1();
 438   translate([ +thehd[0] + demo_slop, 0 ])
 439     TestPiece2();
 440 }
 441
 442 module Machine_Arm(){
 443   ysz = cutout_l_end_y_total;
 444   // assume the round end is arc of a circle
 445   chordlen = dist2d([0,0], [ cutout_l_end_y, cutout_l_end_curve ]);
 446   endrad = cutout_l_end_y / cutout_l_end_curve * chordlen;
 447
 448   translate([0,0,-30]) linear_extrude(height=60) {
 449     translate(tile01_tr + [0, (-cutout_tile01_y + cutout_tile11_y)/2]) {
 450       intersection(){
 451         translate([-50, -ysz/2])
 452           square([400, ysz]);
 453         translate([ endrad - cutout_tile11_x - cutout_l_end_x_slop, 0 ])
 454           circle(r=endrad, $fa=0.01,$fd=5);
 455       }
 456     }
 457   }
 458 }
 459
 460 module Machine_Profile(){
 461   first_rear = machine_rear_profile[0];
 462   below_point = 0.5 * ( first_rear + first_front ) + [ 0, -10 ];
 463   pol = concat( machine_rear_profile,
 464                 [ below_point ],
 465                 machine_front_profile);
 466   skew_angle = atan2( first_front[1] - first_rear[1],
 467                       first_front[0] - first_rear[0] );
 468   //echo(below_point, pol, skew_angle);
 469   hull(){
 470     for (z=[0,-40]) {
 471       translate([0,z]) {
 472         //scale([1,5])
 473         rotate([0,0, -skew_angle ]){
 474           //translate( - first_front )
 475           polygon(pol);
 476         }
 477       }
 478     }
 479   }
 480 }
 481
 482 module Machine_NewRearProfile(){
 483   // figures copied out of xfig edit boxes
 484   // best not to edit the posbox size if poss - just move it
 485   posbox = 10 * ([7.2333,-14.1267] - [-16.2289,40.0289]); // box, Green
 486   sideline = -10 * ([-6.2400,13.5600] - [-2.4467,28.2556]); // line, Blue
 487   scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
 488   scaleline_mm = 12+5+10+5+3;
 489   sh = -[abs(posbox[0]), abs(posbox[1])];
 490   rot = atan2(-sideline[0], sideline[1]);
 491   sc = scaleline_mm / scaleline;
 492   //echo("SH",sh,rot,sc);
 493   scale(sc) rotate(rot) translate(sh){
 494     import("sewing-table-rear-profile.dxf", convexity=10); // spline, Pink3
 495   }
 496 }
 497
 498 module Machine_NewRearCurve(){
 499   slant = atan2(4,210-10);
 500   //echo("SL",slant);
 501   translate([0,0, rearcurve_double_inrad]) rotate([slant,0,0]){
 502     translate([ rearcurve_double_inrad,
 503                 0,
 504                 -rearcurve_double_inrad + 10 ]){
 505       rotate([180,0,0]) rotate([0,0,90]) linear_extrude(height=30){
 506         hull(){
 507           Machine_NewRearProfile();
 508           translate([0,-100]) Machine_NewRearProfile();
 509         }
 510       }
 511     }
 512     rotate([0,90,0]) rotate([90,0,0]) {
 513       intersection(){
 514         rotate_extrude(convexity=10, $fn=64)
 515           rotate(90)
 516           translate([ 0, -rearcurve_double_inrad ])
 517           Machine_NewRearProfile();
 518         translate([0,0,-500])
 519           cube([500,500,1000]);
 520       }
 521     }
 522     translate([1,0,-rearcurve_double_inrad])
 523       rotate([0,-90,0]) rotate([0,0,-90])
 524       linear_extrude(height= rearcurve_strt_len + 1)
 525       Machine_NewRearProfile();
 526   }
 527 }
 528
 529 module Machine_RearProfile(){ ////toplevel
 530   intersection(){
 531     Machine_Profile();
 532     translate([ -200 + machine_rear_to_front/2, -100 ]) {
 533       square([200,200]);
 534     }
 535   }
 536 }
 537
 538 module Machine_FrontProfile(){
 539   intersection(){
 540     Machine_Profile();
 541     translate([ machine_rear_to_front/2, -100 ]) {
 542       square([200,200]);
 543     }
 544   }
 545 }
 546
 547 module Machine_Curves(){ ////toplevel
 548   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 549               cutout_tile11_y,
 550               0 ]){
 551     //%cube([20,20,20]);
 552     translate([ -reartablet_x,
 553                 -1,
 554                 -reartablet_z + tablet_z_slop])
 555       mirror([0,0,1])
 556       cube([ reartablet_x+1,
 557              reartablet_y+1,
 558              20 ]);
 559   }
 560   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 561               cutout_tile11_y,
 562               frontcurve_z_slop ]){
 563     translate([ 0, -first_front[0] , 0 ])
 564       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 565                   [0,  1,   0, 0],
 566                   [0,  0,   1, 0],
 567                   [0,  0,   0, 1]])
 568       translate([ 0, first_front[0] , 0 ])
 569       mirror([1,0,0]){
 570       rotate([0,-90,0])rotate([0,0,-90]){
 571         linear_extrude(height= 200)
 572           Machine_FrontProfile();
 573       }
 574     }
 575     translate([ rearcurve_strt_len,
 576                 0,
 577                 rearcurve_z_slop ]){
 578       Machine_NewRearCurve();
 579     }
 580   }
 581 }
 582
 583 module Machine(){ ////toplevel
 584   Machine_Arm();
 585   Machine_Curves();
 586 }
 587
 588 module MachineEnvelope(){
 589   // used for testing
 590   p_arm_bl = [-cutout_tile11_x, -cutout_tile01_y];
 591   y_arm_t  = cutout_tile11_y;
 592   p_crv_fl = p_arm_bl + [rearedge_len, -frontcurve_avoid_y];
 593   y_crv_b  = y_arm_t + rearcurve_avoid_y;
 594
 595   translate([0,0,-50]) linear_extrude(height= 100){
 596     translate(p_arm_bl) square([400, y_arm_t] - p_arm_bl);
 597     translate(p_crv_fl) square([400, y_crv_b] - p_crv_fl);
 598   }
 599 }
 600
 601 function Rectangle_corners(c0, sz) =
 602   // returns the corners of a rectangle from c0 to c0+sz
 603   // if sz is positive, the corners are anticlockwise starting with c0
 604   [ c0 + [ 0,     0     ],
 605     c0 + [ sz[0], 0     ],
 606     c0 + [ sz[0], sz[1] ],
 607     c0 + [ 0,     sz[1] ] ];
 608
 609 function Rectangle_corners2posts(c) =
 610   [ c[0] + thehd_tr,
 611     c[1] + thehd_tl,
 612     c[2] + thehd_bl,
 613     c[3] + thehd_br ];
 614
 615 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 616
 617 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 618
 619 module FitTest_general(c0,sz, dobrace=false){
 620   c = Rectangle_corners(c0, sz);
 621   brace = [7,7,9];
 622   difference(){
 623     union(){
 624       Rectangle_TileBase(c);
 625       if (dobrace) {
 626         translate(concat(c0, [-brace[2] + 0.1])){
 627           difference(){
 628             cube(concat(sz,[brace[2]]) - [5,0,0]);
 629             translate(brace + [0,0, -25])
 630               cube(concat(sz, [50]) - brace*2 + [10,0,0]);
 631           }
 632         }
 633       }
 634       RoundEdge(R_EDGE(c,1));
 635     }
 636     Machine();
 637   }
 638 }
 639
 640 module FitTest_Entire(){ ////toplevel
 641   FitTest_general([-40,-80], [275,180], dobrace=true);
 642 }
 643
 644 module FitTest_RearCurve(){ ////toplevel
 645   FitTest_general([110,0], [170,100]);
 646 }
 647
 648 module Tile02(){ ////toplevel
 649   sz = [100,170];
 650   c0 = tile02_tr + -sz;
 651   c = Rectangle_corners(c0, sz);
 652   posts = Rectangle_corners2posts(c);
 653   rcs = R_CNR(c,0);
 654   difference(){
 655     union(){
 656       Rectangle_TileBase(c);
 657       Posts(posts);
 658       RoundEdge(R_EDGE(c,0));
 659       RoundEdge(R_EDGE(c,3));
 660       InterlockEdge(R_EDGE(c,2), 0);
 661     }
 662     InterlockEdge(R_EDGE(c,1), 1);
 663     RoundCornerCut(rcs);
 664   }
 665   RoundCornerAdd(rcs);
 666 }
 667
 668 module Tile12(){ ////toplevel
 669   sz = [100,250];
 670   c0 = tile02_tr + [-sz[0], 0];
 671   c = Rectangle_corners(c0, sz);
 672   posts = Rectangle_corners2posts(c);
 673   rcs = R_CNR(c,3);
 674   difference(){
 675     union(){
 676       Rectangle_TileBase(c);
 677       Posts(posts);
 678       RoundEdge(R_EDGE(c,2));
 679       RoundEdge(R_EDGE(c,3));
 680     }
 681     InterlockEdge(R_EDGE(c,0), 1);
 682     InterlockEdge(R_EDGE(c,1), 1);
 683     RoundCornerCut(rcs);
 684   }
 685   RoundCornerAdd(rcs);
 686 }
 687
 688 tile_01_11_cnr = tile01_tr + [-cutout_tile11_x, 0];
 689 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 690 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 691
 692 module Tile11(){ ////toplevel
 693   sz = [250,250];
 694   c0 = tile01_tr + [-sz[0],0];
 695   c = Rectangle_corners(c0, sz);
 696   cnr_posts = Rectangle_corners2posts(c);
 697   posts = concat(
 698                  Posts_interpolate_one(cnr_posts[0],
 699                                        cnr_posts[1] - [cutout_tile11_x, 0]),
 700                  [ cnr_posts[1] + [0, cutout_tile11_y],
 701                    cnr_posts[2],
 702                    cnr_posts[3]
 703                    ]);
 704   difference(){
 705     union(){
 706       Rectangle_TileBase(c);
 707       Posts(posts);
 708       RoundEdge(R_EDGE(c,2));
 709       InterlockEdge(R_EDGE(c,3));
 710     }
 711     InterlockEdge(c[0], tile_01_11_cnr, 1);
 712     InterlockEdge(tile_11_10_cnr, c[2], 1);
 713     Machine();
 714   }
 715 }
 716
 717 module Tile01(){ ////toplevel
 718   sz = [250,170];
 719   c0 = tile01_tr + -sz;
 720   c = Rectangle_corners(c0, sz);
 721   cnr_posts = Rectangle_corners2posts(c);
 722   posts = concat(
 723                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 724                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 725                  Posts_interpolate_one(cnr_posts[2] - [cutout_tile11_x, 0],
 726                                        cnr_posts[3])
 727                  );
 728   difference(){
 729     union(){
 730       Rectangle_TileBase(c);
 731       Posts(posts);
 732       RoundEdge(R_EDGE(c,0));
 733       InterlockEdge(tile_01_11_cnr, c[3]);
 734       InterlockEdge(R_EDGE(c,3));
 735     }
 736     InterlockEdge(c[1], tile_01_00_cnr, 1);
 737     Machine();
 738   }
 739 }
 740
 741 module Tile10(){ ////toplevel
 742   sz = [250,250];
 743   c0 = tile01_tr + [0,0];
 744   c = Rectangle_corners(c0, sz);
 745   cnr_posts = Rectangle_corners2posts(c);
 746   cty = cutout_tile11_y;
 747   rcy = cty + rearcurve_avoid_y;
 748   posts = [ cnr_posts[0] + [ 0,                             cty ],
 749             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 750             cnr_posts[1] + [ 0,                             rcy ],
 751             cnr_posts[2],
 752             cnr_posts[3] ];
 753   rcs = R_CNR(c,2);
 754   difference(){
 755     union(){
 756       Rectangle_TileBase(c);
 757       Posts(posts);
 758       RoundEdge(R_EDGE(c,1));
 759       RoundEdge(R_EDGE(c,2));
 760       InterlockEdge(c[3], tile_11_10_cnr);
 761     }
 762     RoundCornerCut(rcs);
 763     Machine();
 764   }
 765   RoundCornerAdd(rcs);
 766 }
 767
 768 module Tile00(){ ////toplevel
 769   sz = [250,170];
 770   c0 = tile01_tr + [0,-sz[1]];
 771   c = Rectangle_corners(c0, sz);
 772
 773   // the edge c[1]..c[2] needs a diagonal chunk, from c1bis to c2bis
 774   c2bis = [ -cutout_l_end_x + rearedge_len + frontcurve_strt_len, c[2][1] ];
 775   c1bis = [ c[1][0],
 776             c[2][1] -
 777             (c[2][0] - c2bis[0]) * tan(90 - frontcurve_dualcurve_angle) ];
 778
 779   cnr_posts = Rectangle_corners2posts(c);
 780   cty = cutout_tile01_y;
 781   rcy = cty + frontcurve_avoid_y;
 782   posts = [ cnr_posts[0],
 783             cnr_posts[1],
 784             cnr_posts[2] + [ 0,                             -rcy ],
 785             cnr_posts[2] + [ -sz[0] + rearedge_len - cutout_l_end_x, -cty ],
 786             cnr_posts[3] + [ 0,                             -cty ]
 787             ];
 788   rcs = R_CNR(c,1);
 789   difference(){
 790     union(){
 791       difference(){
 792         union(){
 793           Rectangle_TileBase(c);
 794           Posts(posts);
 795           RoundEdge(R_EDGE(c,0));
 796           RoundEdge(c[1], c1bis);
 797           InterlockEdge(tile_01_00_cnr, c[0]);
 798         }
 799         RoundCornerCut(rcs);
 800         translate([0,0,-20]) linear_extrude(height=40) {
 801           polygon([ c1bis, c1bis + [50,0], c2bis + [50,0], c2bis ]);
 802         }
 803       }
 804       RoundEdge(c1bis, c2bis);
 805     }
 806     Machine();
 807   }
 808   RoundCornerAdd(rcs);
 809   RoundCornerAdd([c1bis,c2bis,c[1]]);
 810 }
 811
 812 module FitTest_FrontCurve(){ ////toplevel
 813   p0 = [110,-80];
 814   sz = [170,80];
 815   intersection() {
 816     Tile00();
 817     translate([0,0,-8]) linear_extrude(height=18) {
 818       translate(p0) square(sz);
 819     }
 820   }
 821 }
 822
 823 module RoundCornerDemo_plat(cnr){
 824   mirror([0,0,1]) linear_extrude(height=1) polygon(cnr);
 825 }
 826
 827 module RoundCornerDemo(){ ////toplevel
 828   cnr = [ [-2,-3], [13,-3], [-12,9] ];
 829   translate([0,25,0]) RoundCornerDemo_plat(cnr);
 830   translate([25,0,0]) RoundCornerAdd(cnr);
 831   translate([-25,0,0]) RoundCornerCut(cnr);
 832   translate([0,-25,0]) RoundCorner_selector(cnr, 0);
 833   difference(){
 834     RoundCornerDemo_plat(cnr);
 835     RoundCornerCut(cnr);
 836   }
 837   RoundCornerAdd(cnr);
 838 }
 839
 840 module Demo(){ ////toplevel
 841   translate(demo_slop*[-2,1]) color("blue") Tile12();
 842   translate(demo_slop*[-2,0]) color("red")  Tile02();
 843   translate(demo_slop*[-2,1]) color("orange") Tile11();
 844   translate(demo_slop*[-2,0]) color("purple") Tile01();
 845   translate(demo_slop*[-3,1]) color("blue")   Tile10();
 846   translate(demo_slop*[-3,0]) color("red")    Tile00();
 847   %Machine();
 848 }
 849
 850 //TestPiece1();
 851 //TestPiece2();
 852 //Demo();
 853
 854 //Machine_Profile();
 855 //Machine_NewRearProfile();
 856 //Machine_NewRearCurve();
 857 //Machine_Curves();
 858 //Machine();
 859 //FitTest();
 860 //MachineEnvelope();