sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 tile_th = 3;
  11 post_dia = 8;
  12
  13 post_shorter = 1;
  14
  15 screw_dia = 2.2;
  16 screw_big_dia = 3.6;
  17 screw_big_len = 4.0;
  18
  19 round_edge_rad = 2.0;
  20
  21 round_cnr_rad = 10;
  22
  23 interlock_dia = 10;
  24 interlock_fine = 0.66;
  25
  26 interlock_fine_slope = 1.0;
  27 interlock_fine_lenslop = 1.0;
  28
  29 demo_slop = 0.1;
  30
  31 // cutout
  32
  33 machine_rear_to_front = 85;
  34
  35 machine_rear_profile = [
  36                         [ -  0,  -0.00 ],
  37                         [ -  2,  -0.10 ],
  38                         [ -  4,  -0.20 ],
  39                         [ -  5,  -0.30 ],
  40                         [ -  6,  -0.40 ],
  41                         [ -  7,  -0.50 ],
  42                         [ -  8,  -0.75 ],
  43                         [ - 10,  -1.50 ],
  44                         [ - 12,  -2.25 ],
  45                         [ - 14,  -3.25 ],
  46                         [ - 16,  -4.25 ],
  47                         [ - 18,  -5.75 ],
  48                         [ - 20,  -8.00 ]
  49                         ];
  50
  51 machine_front_profile =  [
  52                           [  128,  -3.70,  ],
  53                           [  124,  -2.90,  ],
  54                           [  120,  -2.45,  ],
  55                           [  116,  -2.10,  ],
  56                           [  112,  -1.80,  ],
  57                           [  108,  -1.55,  ],
  58                           [  104,  -1.25,  ],
  59                           [  100,  -1.00,  ],
  60                           [   96,  -0.80,  ],
  61                           [   92,  -0.65,  ],
  62                           [   88,  -0.55,  ],
  63                           [   84,  -0.50,  ]
  64                           ];
  65
  66 cutout_l_end_y_front_slop = 0.5;
  67 cutout_l_end_y_rear_slop = 0.5;
  68 cutout_l_end_x_slop = 0.25;
  69
  70 cutout_l_end_x = 22;
  71 cutout_l_end_y = machine_rear_to_front;
  72 cutout_l_end_curve = 1;
  73 cutout_l_end_y_total = cutout_l_end_y
  74   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  75
  76 tile02_tr = [-250, 0];
  77 tile01_tr = [  0, 0];
  78
  79 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  80 cutout_tile11_x = cutout_l_end_x + cutout_l_end_curve;
  81 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  82
  83 // front and rear curves
  84
  85 rearedge_len = 170;
  86
  87 rearcurve_strt_len = 52;
  88
  89 rearcurve_z_slop = 0.75;
  90
  91 rearcurve_avoid_y = 35;
  92
  93 rearcurve_double_inrad = 26.10 + 8.04;
  94
  95 reartablet_z = 2.54;
  96 reartablet_x = 5 + 1;
  97 reartablet_y = 5;
  98
  99 frontcurve_side_skew = 3.5 / 72;
 100 frontcurve_avoid_y = 70;
 101 frontcurve_z_slop = 0.75;
 102
 103 // calculated
 104
 105 TEST = false;
 106
 107 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
 108
 109 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
 110
 111 hole_slop = (ply_hole_dia - post_dia)/2;
 112 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
 113
 114 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
 115          tile_hard_edge_hole_dist));
 116
 117 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
 118          tile_hard_edge_hole_dist + round_edge_rad));
 119
 120 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
 121 thehd_tr = thehd;
 122 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 123 thehd_bl = -thehd_tr;
 124 thehd_br = -thehd_tl;
 125
 126 interlock_rad = interlock_dia/2;
 127 interlock_negative_rad = interlock_rad + 0.125;
 128
 129 interlock_sq_adj = 0.2; // arbitrary
 130
 131 first_front = machine_front_profile[len(machine_front_profile)-1];
 132
 133 m4_define(`POST_TCROSSSZ',
 134           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 135
 136 module Post(){
 137   mirror([0,0,1]) {
 138     difference(){
 139       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 140       translate([0,0, tile_th]) {
 141         cylinder(r= screw_big_dia/2, h= screw_big_len);
 142         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
 143       }
 144     }
 145     if (TEST) {
 146       translate([0,0, tile_th/2]) {
 147         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 148         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 149       }
 150     }
 151   }
 152 }
 153
 154 module Posts(posts) {
 155   for (p= posts) {
 156     translate(concat(p, [0]))
 157       Post();
 158   }
 159 }
 160
 161 module TileBase(botleft, topright){
 162   size = topright - botleft;
 163   botleft_post = botleft + thehd_tr;
 164   topright_post = topright + thehd_bl;
 165   difference(){
 166     mirror([0,0,1])
 167       translate(concat(botleft, [0]))
 168       cube(concat(size, [tile_th]));
 169     if (!TEST) {
 170       translate( concat(botleft_post, [ -tile_th ])
 171                  + 0.5 * [ post_dia, post_dia, 0 ] )
 172         Commitid_BestCount_M( topright_post-botleft_post
 173                               + [-post_dia,-post_dia]
 174                               + [0, thehd[1]]);
 175     }
 176     if (TEST) {
 177       translate( concat(botleft + [thehd[0], 0], [0]) )
 178         Commitid_BestCount([ size[0] - thehd[0]*2, thehd[1] ]);
 179       difference(){
 180         mirror([0,0,1]) {
 181           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 182             cube(concat(size - [test_edge,test_edge]*2, [tile_th]));
 183           translate(concat(botleft_post, [-1]))
 184             cube(concat(topright_post-botleft_post, [tile_th+2]));
 185         }
 186         minkowski(){
 187           Machine();
 188           cube(max(test_edge, tile_hard_edge_hole_dist)*2, center=true);
 189         }
 190       }
 191     }
 192   }
 193 }
 194
 195 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 196 m4_define(`INREFFRAME',`
 197   length_vec = ($2) - ($1);
 198   length = dist2d([0,0], length_vec);
 199   length_uvec = length_vec / length;
 200   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 201   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 202         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 203         [ 0,              0,              1,            0, ],
 204         [ 0,              0,              0,            1, ] ];
 205   $3
 206   multmatrix(m)
 207 ')
 208
 209 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 210 m4_dnl    INREFFRAME_EDGE { body; }
 211 m4_define(`INREFFRAME_EDGE',`
 212   translate([0,0, -round_edge_rad])
 213 ')
 214
 215 module RoundEdge(left_cnr, right_cnr) {
 216   INREFFRAME(left_cnr, right_cnr)
 217     INREFFRAME_EDGE {
 218     difference(){
 219       rotate([0,90,0])
 220         cylinder(r= round_edge_rad, h= length, $fn=50);
 221       translate([-1, 0, -20])
 222         cube([length+2, 20, 20]);
 223     }
 224   }
 225 }
 226
 227 module RoundCornerCut(ci) {
 228   // ci should be [this_cnr, right_cnr]
 229   // where right_cnr is to the right (ie, anticlockwise)
 230   this_cnr = ci[0];
 231   right_cnr = ci[1];
 232   offr= round_cnr_rad - round_edge_rad;
 233   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 234     difference(){
 235       cube(offr*2 - 0.1, center=true);
 236       translate([offr, offr, 0])
 237         cylinder(center=true, h=20, r= offr);
 238     }
 239   }
 240 }
 241
 242 module RoundCornerAdd(ci) {
 243   this_cnr = ci[0];
 244   right_cnr = ci[1];
 245   bigr = round_cnr_rad - round_edge_rad;
 246   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 247     intersection(){
 248       cube(bigr*2 + 0.1, center=true);
 249       translate([bigr, bigr, 0])
 250         rotate_extrude(convexity=10, $fn=50)
 251         translate([bigr, 0])
 252         difference(){
 253           circle(r= round_edge_rad, $fn=50);
 254           mirror([1,1])
 255             square([20,20]);
 256         }
 257     }
 258   }
 259 }
 260
 261 module InterlockLobePlan(negative) {
 262   r = negative ? interlock_negative_rad : interlock_rad;
 263   ymir = negative ? 0 : 1;
 264
 265   dx = sqrt(3) * r;
 266   $fn= 80;
 267   translate([thehd[0], 0]){
 268     mirror([0,ymir]){
 269       circle(r=r);
 270       difference(){
 271         translate([-dx, -0.1])
 272           square([ dx*2, r/2 + 0.1 ]);
 273         for (xi = [-1, 1]) {
 274           translate([ xi*dx, r ])
 275             circle(r=r);
 276         }
 277       }
 278     }
 279   }
 280 }
 281
 282 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 283   for (lobei = [ 0 : nlobes-1 ]) {
 284     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 285     translate([lobex, 0, 0]) {
 286       InterlockLobePlan(negative);
 287     }
 288   }
 289
 290   if (dosquare) {
 291     iadj = 0;
 292     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 293     mirror([0, negative])
 294       translate([slotshorter, iadj])
 295       square([length - slotshorter*2, interlock_fine + iadj*2]);
 296   }
 297 }
 298
 299 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 300   plusth = negative * 1.0;
 301   protr = interlock_fine + interlock_sq_adj;
 302
 303   z2 = -tile_th/2;
 304   z1 = -tile_th/2 - protr / interlock_fine_slope;
 305   z3 = -tile_th/2 + protr / interlock_fine_slope;
 306
 307   negsign = negative ? -1 : +1;
 308   yprotr = negsign * protr;
 309
 310   INREFFRAME(left_cnr, right_cnr) {
 311     for (vsect = [ // zs0            zs1      ys0,            ys1
 312                   [ -tile_th-plusth, plusth,  0,              0],
 313                   [ z1,              z2,      0, yprotr],
 314                   [ z2,              z3,      yprotr, 0],
 315                   ]) {
 316       zs0 = vsect[0];
 317       zs1 = vsect[1];
 318       zsd = zs1-zs0;
 319       ys0 = vsect[2];
 320       ys1 = vsect[3];
 321       ysd = ys1-ys0;
 322       sl = ysd/zsd;
 323       m = [ [ 1,0,   0,    0 ],
 324             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 325             [ 0,0,   1,  zs0 ],
 326             [ 0,0,   0,    1 ] ];
 327       multmatrix(m)
 328         linear_extrude(height=zsd, convexity=10)
 329         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 330     }
 331   }
 332 }
 333
 334 function TestPiece_holes2corners(holes) =
 335   [ holes[0] + thehd_bl,
 336     holes[1] + thehd_br,
 337     holes[1] + thehd_tr,
 338     holes[0] + thehd_tl ];
 339
 340 module TestPiece1(){ ////toplevel
 341   holes = [ [-100, 0],
 342             [   0, 0]
 343             ];
 344   corners = TestPiece_holes2corners(holes);
 345   rcs = [corners[0], corners[1]];
 346   difference(){
 347     union(){
 348       TileBase(corners[0], corners[2]);
 349       Posts(holes);
 350       RoundEdge(corners[0], corners[1]);
 351       RoundEdge(corners[3], corners[0]);
 352     }
 353     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 354     RoundCornerCut(rcs);
 355   }
 356   RoundCornerAdd(rcs);
 357 }
 358
 359 module TestPiece2(){ ////toplevel
 360   holes = [ [   0, 0],
 361             [  50, 0]
 362             ];
 363   corners = TestPiece_holes2corners(holes);
 364   TileBase(corners[0], corners[2]);
 365   Posts(holes);
 366   RoundEdge(corners[0], corners[1]);
 367   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 368 }
 369
 370 module TestDemo(){ ////toplevel
 371   translate([ -thehd[0], 0 ])
 372     color("blue")
 373     TestPiece1();
 374   translate([ +thehd[0] + demo_slop, 0 ])
 375     TestPiece2();
 376 }
 377
 378 module Machine_Arm(){
 379   ysz = cutout_l_end_y_total;
 380   // assume the round end is arc of a circle
 381   chordlen = dist2d([0,0], [ cutout_l_end_y, cutout_l_end_curve ]);
 382   endrad = cutout_l_end_y / cutout_l_end_curve * chordlen;
 383
 384   translate([0,0,-30]) linear_extrude(height=60) {
 385     translate(tile01_tr + [0, (-cutout_tile01_y + cutout_tile11_y)/2]) {
 386       intersection(){
 387         translate([-100, -ysz/2])
 388           square([400, ysz]);
 389         translate([ endrad - cutout_tile11_x - cutout_l_end_x_slop, 0 ])
 390           circle(r=endrad, $fa=0.01,$fd=5);
 391       }
 392     }
 393   }
 394 }
 395
 396 module Machine_Profile(){
 397   first_rear = machine_rear_profile[0];
 398   below_point = 0.5 * ( first_rear + first_front ) + [ 0, -10 ];
 399   pol = concat( machine_rear_profile,
 400                 [ below_point ],
 401                 machine_front_profile);
 402   skew_angle = atan2( first_front[1] - first_rear[1],
 403                       first_front[0] - first_rear[0] );
 404   echo(below_point, pol, skew_angle);
 405   hull(){
 406     for (z=[0,-40]) {
 407       translate([0,z]) {
 408         //scale([1,5])
 409         rotate([0,0, -skew_angle ]){
 410           //translate( - first_front )
 411           polygon(pol);
 412         }
 413       }
 414     }
 415   }
 416 }
 417
 418 module Machine_RearProfile(){
 419   intersection(){
 420     Machine_Profile();
 421     translate([ -200 + machine_rear_to_front/2, -100 ]) {
 422       square([200,200]);
 423     }
 424   }
 425 }
 426
 427 module Machine_FrontProfile(){
 428   intersection(){
 429     Machine_Profile();
 430     translate([ machine_rear_to_front/2, -100 ]) {
 431       square([200,200]);
 432     }
 433   }
 434 }
 435
 436 module Machine_Curves(){ ////toplevel
 437   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 438               cutout_tile11_y,
 439               0 ]){
 440     //%cube([20,20,20]);
 441     translate([ -reartablet_x,
 442                 -1,
 443                 -reartablet_z])
 444       mirror([0,0,1])
 445       cube([ reartablet_x+1,
 446              reartablet_y+1,
 447              20 ]);
 448   }
 449   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 450               cutout_tile11_y,
 451               frontcurve_z_slop ]){
 452     translate([ 0, -first_front[0] , 0 ])
 453       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 454                   [0,  1,   0, 0],
 455                   [0,  0,   1, 0],
 456                   [0,  0,   0, 1]])
 457       translate([ 0, first_front[0] , 0 ])
 458       mirror([1,0,0]){
 459       rotate([0,-90,0])rotate([0,0,-90]){
 460         linear_extrude(height= 200)
 461           Machine_FrontProfile();
 462       }
 463     }
 464     translate([ rearcurve_strt_len,
 465                 0,
 466                 rearcurve_z_slop ]){
 467       translate([ 1,
 468                   0,
 469                   0
 470                   ]){
 471         rotate([0,-90,0])rotate([0,0,-90]){
 472           linear_extrude(height= rearcurve_strt_len + 1)
 473           Machine_RearProfile();
 474         }
 475       }
 476       translate([ 0,
 477                   0,
 478                   rearcurve_double_inrad ]) {
 479         intersection(){
 480           rotate([90,0,0]){
 481             rotate_extrude(convexity=10, $fn=32) {
 482               rotate([0,0,90]) translate([ 0,
 483                           -rearcurve_double_inrad ]) {
 484                 Machine_RearProfile();
 485               }
 486             }
 487           }
 488           mirror([0,0,1])
 489             translate([0,-75,0]) cube([150,150,150]);
 490         }
 491       }
 492     }
 493   }
 494 }
 495
 496 module Machine(){ ////toplevel
 497   Machine_Arm();
 498   Machine_Curves();
 499 }
 500
 501 function Rectangle_corners(c0, sz) =
 502   // returns the corners of a rectangle from c0 to c0+sz
 503   // if sz is positive, the corners are anticlockwise starting with c0
 504   [ c0 + [ 0,     0     ],
 505     c0 + [ sz[0], 0     ],
 506     c0 + [ sz[0], sz[1] ],
 507     c0 + [ 0,     sz[1] ] ];
 508
 509 function Rectangle_corners2posts(c) =
 510   [ c[0] + thehd_tr,
 511     c[1] + thehd_tl,
 512     c[2] + thehd_bl,
 513     c[3] + thehd_br ];
 514
 515 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 516
 517 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 518
 519 m4_dnl   R_EDGE(c,ix)
 520 m4_dnl        c is from Rectangle_corners and
 521 m4_dnl        ix is a corner number
 522 m4_dnl    expands to two comma-separated corners:
 523 m4_dnl    that denoted by ix, and the next one anticlockwise
 524 m4_define(`R_EDGE',`$1[$2],$1[(($2)+1)%4]')
 525
 526 module Tile02(){ ////toplevel
 527   sz = [100,170];
 528   c0 = tile02_tr + -sz;
 529   c = Rectangle_corners(c0, sz);
 530   posts = Rectangle_corners2posts(c);
 531   rcs = [R_EDGE(c,0)];
 532   difference(){
 533     union(){
 534       Rectangle_TileBase(c);
 535       Posts(posts);
 536       RoundEdge(R_EDGE(c,0));
 537       RoundEdge(R_EDGE(c,3));
 538       InterlockEdge(R_EDGE(c,2), 0);
 539     }
 540     InterlockEdge(R_EDGE(c,1), 1);
 541     RoundCornerCut(rcs);
 542   }
 543   RoundCornerAdd(rcs);
 544 }
 545
 546 module Tile12(){ ////toplevel
 547   sz = [100,250];
 548   c0 = tile02_tr + [-sz[0], 0];
 549   c = Rectangle_corners(c0, sz);
 550   posts = Rectangle_corners2posts(c);
 551   rcs = [R_EDGE(c,3)];
 552   difference(){
 553     union(){
 554       Rectangle_TileBase(c);
 555       Posts(posts);
 556       RoundEdge(R_EDGE(c,2));
 557       RoundEdge(R_EDGE(c,3));
 558     }
 559     InterlockEdge(R_EDGE(c,0), 1);
 560     InterlockEdge(R_EDGE(c,1), 1);
 561     RoundCornerCut(rcs);
 562   }
 563   RoundCornerAdd(rcs);
 564 }
 565
 566 tile_01_11_cnr = tile01_tr + [-cutout_tile11_x, 0];
 567 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 568 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 569
 570 module Tile11(){ ////toplevel
 571   sz = [250,250];
 572   c0 = tile01_tr + [-sz[0],0];
 573   c = Rectangle_corners(c0, sz);
 574   cnr_posts = Rectangle_corners2posts(c);
 575   posts = concat(
 576                  Posts_interpolate_one(cnr_posts[0],
 577                                        cnr_posts[1] - [cutout_tile11_x, 0]),
 578                  [ cnr_posts[1] + [0, cutout_tile11_y],
 579                    cnr_posts[2],
 580                    cnr_posts[3]
 581                    ]);
 582   difference(){
 583     union(){
 584       Rectangle_TileBase(c);
 585       Posts(posts);
 586       RoundEdge(R_EDGE(c,2));
 587       InterlockEdge(R_EDGE(c,3));
 588     }
 589     InterlockEdge(c[0], tile_01_11_cnr, 1);
 590     InterlockEdge(tile_11_10_cnr, c[2], 1);
 591     Machine();
 592   }
 593 }
 594
 595 module Tile01(){ ////toplevel
 596   sz = [250,170];
 597   c0 = tile01_tr + -sz;
 598   c = Rectangle_corners(c0, sz);
 599   cnr_posts = Rectangle_corners2posts(c);
 600   posts = concat(
 601                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 602                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 603                  Posts_interpolate_one(cnr_posts[2] - [cutout_tile11_x, 0],
 604                                        cnr_posts[3])
 605                  );
 606   difference(){
 607     union(){
 608       Rectangle_TileBase(c);
 609       Posts(posts);
 610       RoundEdge(R_EDGE(c,0));
 611       InterlockEdge(tile_01_11_cnr, c[3]);
 612       InterlockEdge(R_EDGE(c,3));
 613     }
 614     InterlockEdge(c[1], tile_01_00_cnr, 1);
 615     Machine();
 616   }
 617 }
 618
 619 module Tile10(){ ////toplevel
 620   sz = [250,250];
 621   c0 = tile01_tr + [0,0];
 622   c = Rectangle_corners(c0, sz);
 623   cnr_posts = Rectangle_corners2posts(c);
 624   cty = cutout_tile11_y;
 625   rcy = cty + rearcurve_avoid_y;
 626   posts = [ cnr_posts[0] + [ 0,                             cty ],
 627             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 628             cnr_posts[1] + [ 0,                             rcy ],
 629             cnr_posts[2],
 630             cnr_posts[3] ];
 631   rcs = [R_EDGE(c,2)];
 632   difference(){
 633     union(){
 634       Rectangle_TileBase(c);
 635       Posts(posts);
 636       RoundEdge(R_EDGE(c,1));
 637       RoundEdge(R_EDGE(c,2));
 638       InterlockEdge(c[3], tile_11_10_cnr);
 639     }
 640     RoundCornerCut(rcs);
 641     Machine();
 642   }
 643   RoundCornerAdd(rcs);
 644 }
 645
 646 module Tile00(){ ////toplevel
 647   sz = [250,170];
 648   c0 = tile01_tr + [0,-sz[1]];
 649   c = Rectangle_corners(c0, sz);
 650   cnr_posts = Rectangle_corners2posts(c);
 651   cty = cutout_tile01_y;
 652   rcy = cty + frontcurve_avoid_y;
 653   posts = [ cnr_posts[0],
 654             cnr_posts[1],
 655             cnr_posts[2] + [ 0,                             -rcy ],
 656             cnr_posts[2] + [ -sz[0] + rearedge_len - cutout_l_end_x, -cty ],
 657             cnr_posts[3] + [ 0,                             -cty ]
 658             ];
 659   rcs = [R_EDGE(c,1)];
 660   difference(){
 661     union(){
 662       Rectangle_TileBase(c);
 663       Posts(posts);
 664       RoundEdge(R_EDGE(c,0));
 665       RoundEdge(R_EDGE(c,1));
 666       InterlockEdge(tile_01_00_cnr, c[0]);
 667     }
 668     RoundCornerCut(rcs);
 669     Machine();
 670   }
 671   RoundCornerAdd(rcs);
 672 }
 673
 674 module Demo(){ ////toplevel
 675   translate(demo_slop*[-2,1]) color("blue") Tile12();
 676   translate(demo_slop*[-2,0]) color("red")  Tile02();
 677   translate(demo_slop*[-2,1]) color("orange") Tile11();
 678   translate(demo_slop*[-2,0]) color("purple") Tile01();
 679   translate(demo_slop*[-3,1]) color("blue")   Tile10();
 680   translate(demo_slop*[-3,0]) color("red")    Tile00();
 681   %Machine();
 682 }
 683
 684 //TestPiece1();
 685 //TestPiece2();
 686 //Demo();
 687
 688 //Machine_Profile();
 689 //Machine_RearProfile();