sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 ply_hole_dia_real = 12;
  11
  12 tile_th = 3;
  13 post_dia = 8;
  14
  15 post_shorter = 1;
  16
  17 screw_dia = 2.2;
  18 screw_big_dia = 3.6;
  19 screw_big_len = 4.0;
  20
  21 round_edge_rad = 2.0;
  22
  23 round_cnr_rad = 10;
  24
  25 interlock_dia = 10;
  26 interlock_fine = 0.66;
  27
  28 interlock_fine_slope = 1.0;
  29 interlock_fine_lenslop = 1.0;
  30
  31 demo_slop = 0.1;
  32
  33 leg_height = 50;
  34
  35 leg_big_dia = 37;
  36 leg_bot_dia = 15;
  37 leg_top_flat_z = 5;
  38
  39 // cutout
  40
  41 machine_rear_to_front = 84 + 0.25 - 1.4;
  42
  43 cutout_l_end_y_front_slop = 0.5;
  44 cutout_l_end_y_rear_slop = 0.5;
  45
  46 cutout_l_end_x = 22;
  47 cutout_l_end_y = machine_rear_to_front;
  48 cutout_l_end_new_x_slop = 1.4 - 1.95;
  49 cutout_l_end_y_total = cutout_l_end_y
  50   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  51
  52 tile02_tr = [-250, 0];
  53 tile01_tr = [  0, 0];
  54
  55 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  56 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  57
  58 // front and rear curves
  59
  60 rearedge_len = 170 + 0.70;
  61 frontedge_len = 170;
  62
  63 rearcurve_strt_len = 52;
  64
  65 rearcurve_z_slop = -0.50;
  66
  67 rearcurve_avoid_y = 35;
  68
  69 rearcurve_double_inrad = 26.10 + 8.04;
  70
  71 reartablet_z = 2.54;
  72 reartablet_x = 5 + 1;
  73 reartablet_y = 8;
  74
  75 frontcurve_side_skew = 3.5 / 72;
  76 frontcurve_avoid_y = 70;
  77 frontcurve_z_slop = 0.75;
  78
  79 frontcurve_strt_len = 50;
  80 frontcurve_dualcurve_angle = 30;
  81
  82 teststrapslots_at = [ [ 110, 70 ], [ 110, -35 ],
  83                       [ 180, 90 ],
  84                       [ 190, -80 ], // do not change index of this one
  85                       [   0, 70 ],  [  0, -35 ],
  86                       ];
  87
  88 teststrap = [ 3, 5 ];
  89 teststrap_peg = [7.5, 3.5];
  90
  91 ply_edge_hole_dist_real = 14;
  92
  93 // calculated
  94
  95 TEST = false;
  96 JIG = false;
  97
  98 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
  99
 100 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
 101
 102 hole_slop = (ply_hole_dia - post_dia)/2;
 103 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
 104
 105 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
 106          tile_hard_edge_hole_dist));
 107
 108 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
 109          tile_hard_edge_hole_dist + round_edge_rad));
 110
 111 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
 112 thehd_tr = thehd;
 113 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 114 thehd_bl = -thehd_tr;
 115 thehd_br = -thehd_tl;
 116
 117 tablet_z_slop = 1.00;
 118
 119 interlock_rad = interlock_dia/2;
 120 interlock_negative_rad = interlock_rad + 0.125;
 121
 122 interlock_sq_adj = 0.2; // arbitrary
 123
 124 m4_define(`POST_TCROSSSZ',
 125           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 126
 127 module Post(){
 128   mirror([0,0,1]) {
 129     if (!JIG) {
 130       difference(){
 131         cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 132         translate([0,0, tile_th]) {
 133           cylinder(r= screw_big_dia/2, h= screw_big_len);
 134           cylinder(r= screw_dia/2, h= ply_th, $fn=20);
 135         }
 136       }
 137     }
 138     if (TEST) {
 139       translate([0,0, tile_th/2]) {
 140         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 141         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 142       }
 143     }
 144     if (JIG) {
 145       translate([0,0, tile_th/2]) {
 146         cube([POST_TCROSSSZ, POST_TCROSSSZ, tile_th], center=true);
 147       }
 148     }
 149   }
 150 }
 151
 152 module PostHole(){
 153   if (JIG) {
 154     translate([0,0,-5])
 155       cylinder(r= post_dia/2 + jig_post_hole_slop, h=10);
 156     translate([0,0, -jig_min_th])
 157       cylinder(r= ply_hole_dia_real/2, h = 5);
 158     for (rot=[0:90:270]) rotate(rot) {
 159         translate([ ply_edge_hole_dist_real, 0, 0 ])
 160           cube([ jig_pencil_rad*2, jig_pencil_slotlen, 20 ], center=true);
 161       }
 162   }
 163 }
 164
 165 module Posts(posts) {
 166   for (p= posts) {
 167     translate(concat(p, [0]))
 168       Post();
 169   }
 170 }
 171 module PostHoles(posts) {
 172   for (p= posts)  {
 173     translate(concat(p, [0]))
 174       PostHole();
 175   }
 176 }
 177
 178 module TileBase(botleft, topright){
 179   size = topright - botleft;
 180   botleft_post = botleft + thehd_tr;
 181   topright_post = topright + thehd_bl;
 182   difference(){
 183     mirror([0,0,1])
 184       translate(concat(botleft, [0]))
 185       cube(concat(size, [tile_th]));
 186     if (!(TEST || JIG)) {
 187       cidsz = topright_post-botleft_post
 188         + [-post_dia,-post_dia]
 189         + [0, thehd[1]];
 190       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
 191       echo("CID",cidsz,cidszr);
 192       translate( concat(botleft_post, [ -tile_th ])
 193                  + 0.5 * [ post_dia, post_dia, 0 ]
 194                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
 195         Commitid_BestCount_M(cidszr);
 196     }
 197     if ((TEST || JIG)) {
 198       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
 199       cidsz = [ thehd[0], size[1] - 2*crossoff ];
 200       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
 201       if (TEST)
 202         translate( concat(botleft + [0, crossoff] + (cidsz-cidszr)/2, [0]) )
 203           Commitid_BestCount(cidszr);
 204       difference(){
 205         mirror([0,0,1]) {
 206           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 207             cube(concat(size - [test_edge,test_edge]*2, [tile_th*2]));
 208           translate(concat(botleft_post, [-1]))
 209             cube(concat(topright_post-botleft_post, [tile_th+2]));
 210         }
 211         shufflesz = max(test_edge, tile_hard_edge_hole_dist)*2;
 212         minkowski(){
 213           MachineEnvelope();
 214           cube(shufflesz, center=true);
 215         }
 216         if (JIG) {
 217           translate([0,0,-20]) linear_extrude(height=20) {
 218             for (diag=[[ +1, botleft                   ],
 219                        [ -1, [topright[0], botleft[1]] ]]) {
 220               translate(diag[1])
 221                 rotate(atan2(size[1], diag[0] * size[0]))
 222                 translate([0, -test_edge/2])
 223                 square([vectorlen2d(size), test_edge]);
 224             }
 225           }
 226         }
 227       }
 228     }
 229   }
 230 }
 231
 232 m4_dnl   R_EDGE(c,ix)
 233 m4_dnl        c is from Rectangle_corners and
 234 m4_dnl        ix is a corner number
 235 m4_dnl    expands to two comma-separated corners:
 236 m4_dnl    that denoted by ix, and the next one anticlockwise
 237 m4_define(`R_EDGE',`$1[$2], $1[(($2)+1)%4]')
 238
 239 m4_dnl   R_CNR(c,ix)
 240 m4_dnl        c is from Rectangle_corners and
 241 m4_dnl        ix is a corner number
 242 m4_dnl    expands to an array of corners as for RoundCorner
 243 m4_define(`R_CNR',`[ $1[$2], $1[(($2)+1)%4], $1[(($2)+3)%4] ]')
 244
 245 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 246 m4_define(`INREFFRAME',`
 247   length_vec = ($2) - ($1);
 248   length = dist2d([0,0], length_vec);
 249   length_uvec = length_vec / length;
 250   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 251   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 252         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 253         [ 0,              0,              1,            0, ],
 254         [ 0,              0,              0,            1, ] ];
 255   $3
 256   multmatrix(m)
 257 ')
 258
 259 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 260 m4_dnl    INREFFRAME_EDGE { body; }
 261 m4_define(`INREFFRAME_EDGE',`
 262   translate([0,0, -round_edge_rad])
 263 ')
 264
 265 module RoundEdge(left_cnr, right_cnr) {
 266   INREFFRAME(left_cnr, right_cnr)
 267     INREFFRAME_EDGE {
 268     difference(){
 269       rotate([0,90,0])
 270         cylinder(r= round_edge_rad, h= length, $fn=50);
 271       translate([-1, 0, -20])
 272         cube([length+2, 20, 20]);
 273     }
 274   }
 275 }
 276
 277 m4_define(`ROUNDCORNER_VARS',`
 278   this_cnr = ci[0];
 279   right_cnr = ci[1];
 280   left_cnr = ci[2];
 281   bigr= round_cnr_rad - round_edge_rad;
 282   l_uvec = unitvector2d(left_cnr - this_cnr);
 283   r_uvec = unitvector2d(right_cnr - this_cnr);
 284   lp1 = left_cnr  + clockwise2d(l_uvec) * bigr;
 285   lp2 = this_cnr  + clockwise2d(l_uvec) * bigr;
 286   lp3 = this_cnr  - clockwise2d(r_uvec) * bigr;
 287   lp4 = right_cnr - clockwise2d(r_uvec) * bigr;
 288   ctr = line_intersection_2d(lp1,lp2,lp3,lp4);
 289   ctr3 = concat(ctr,[0])
 290 ')
 291
 292 module RoundCorner_selector(ci, adj) {
 293   ROUNDCORNER_VARS;
 294   intersection(){
 295     union(){
 296       INREFFRAME(ctr3,concat(lp1,[4])){
 297         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 298           translate([-bigr*2 + adj, -bigr])
 299             square([bigr*2, bigr*3]);
 300         }
 301       }
 302     }
 303     union(){
 304       INREFFRAME(ctr3,concat(lp4,[0])){
 305         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 306           translate([-bigr*2, -bigr*2])
 307             square([bigr*2 + adj, bigr*3]);
 308         }
 309       }
 310     }
 311   }
 312 }
 313
 314 module RoundCornerCut(ci) {
 315   // ci should be [this_cnr, right_cnr, left_cnr]
 316   // where right_cnr is to the right (ie, anticlockwise)
 317   ROUNDCORNER_VARS;
 318   difference(){
 319     RoundCorner_selector(ci, -0.1);
 320     translate(ctr3)
 321       cylinder(center=true, h=20, r= bigr);
 322   }
 323 }
 324
 325 module RoundCornerAdd(ci) {
 326   ROUNDCORNER_VARS;
 327   intersection(){
 328     RoundCorner_selector(ci, +0.1);
 329     INREFFRAME_EDGE {
 330       translate(ctr3){
 331         rotate_extrude(convexity=10, $fn=50)
 332           translate([bigr, 0])
 333           difference(){
 334           circle(r= round_edge_rad, $fn=50);
 335           mirror([1,1])
 336             square([20,20]);
 337         }
 338       }
 339     }
 340   }
 341 }
 342
 343 module InterlockLobePlan(negative) {
 344   r = negative ? interlock_negative_rad : interlock_rad;
 345   ymir = negative ? 0 : 1;
 346
 347   dx = sqrt(3) * r;
 348   $fn= 80;
 349   translate([thehd[0], 0]){
 350     mirror([0,ymir]){
 351       circle(r=r);
 352       difference(){
 353         translate([-dx, -0.1])
 354           square([ dx*2, r/2 + 0.1 ]);
 355         for (xi = [-1, 1]) {
 356           translate([ xi*dx, r ])
 357             circle(r=r);
 358         }
 359       }
 360     }
 361   }
 362 }
 363
 364 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 365   for (lobei = [ 0 : nlobes-1 ]) {
 366     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 367     translate([lobex, 0, 0]) {
 368       InterlockLobePlan(negative);
 369     }
 370   }
 371
 372   if (dosquare) {
 373     iadj = 0;
 374     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 375     mirror([0, negative])
 376       translate([slotshorter, iadj])
 377       square([length - slotshorter*2, interlock_fine + iadj*2]);
 378   }
 379 }
 380
 381 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 382   plusth = negative * 1.0;
 383   protr = interlock_fine + interlock_sq_adj;
 384
 385   z2 = -tile_th/2;
 386   z1 = -tile_th/2 - protr / interlock_fine_slope;
 387   z3 = -tile_th/2 + protr / interlock_fine_slope;
 388
 389   negsign = negative ? -1 : +1;
 390   yprotr = negsign * protr;
 391
 392   INREFFRAME(left_cnr, right_cnr) {
 393     for (vsect = [ // zs0            zs1      ys0,            ys1
 394                   [ -tile_th-plusth, plusth,  0,              0],
 395                   [ z1,              z2,      0, yprotr],
 396                   [ z2,              z3,      yprotr, 0],
 397                   ]) {
 398       zs0 = vsect[0];
 399       zs1 = vsect[1];
 400       zsd = zs1-zs0;
 401       ys0 = vsect[2];
 402       ys1 = vsect[3];
 403       ysd = ys1-ys0;
 404       sl = ysd/zsd;
 405       m = [ [ 1,0,   0,    0 ],
 406             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 407             [ 0,0,   1,  zs0 ],
 408             [ 0,0,   0,    1 ] ];
 409       multmatrix(m)
 410         linear_extrude(height=zsd, convexity=10)
 411         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 412     }
 413   }
 414 }
 415
 416 function TestPiece_holes2corners(holes) =
 417   [ holes[0] + thehd_bl,
 418     holes[1] + thehd_br,
 419     holes[1] + thehd_tr,
 420     holes[0] + thehd_tl ];
 421
 422 module TestPiece1(){ ////toplevel
 423   holes = [ [-100, 0],
 424             [   0, 0]
 425             ];
 426   corners = TestPiece_holes2corners(holes);
 427   rcs = R_CNR(corners,0);
 428   difference(){
 429     union(){
 430       TileBase(corners[0], corners[2]);
 431       Posts(holes);
 432       RoundEdge(corners[0], corners[1]);
 433       RoundEdge(corners[3], corners[0]);
 434     }
 435     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 436     RoundCornerCut(rcs);
 437     PostHoles(holes);
 438   }
 439   RoundCornerAdd(rcs);
 440 }
 441
 442 module TestPiece2(){ ////toplevel
 443   holes = [ [   0, 0],
 444             [  50, 0]
 445             ];
 446   corners = TestPiece_holes2corners(holes);
 447   difference(){
 448     union(){
 449       TileBase(corners[0], corners[2]);
 450       Posts(holes);
 451       RoundEdge(corners[0], corners[1]);
 452       InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 453     }
 454     PostHoles(holes);
 455   }
 456 }
 457
 458 module TestDemo(){ ////toplevel
 459   translate([ -thehd[0], 0 ])
 460     color("blue")
 461     TestPiece1();
 462   translate([ +thehd[0] + demo_slop, 0 ])
 463     TestPiece2();
 464 }
 465
 466 module Machine_NewRearProfile(){
 467   // figures copied out of xfig edit boxes
 468   // best not to edit the posbox size if poss - just move it
 469   posbox = 10 * ([7.2333,-14.1267] - [-16.2289,40.0289]); // box, Green
 470   sideline = -10 * ([-6.2400,13.5600] - [-2.4467,28.2556]); // line, Blue
 471   scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
 472   scaleline_mm = 12+5+10+5+3;
 473   sh = -[abs(posbox[0]), abs(posbox[1])];
 474   rot = atan2(-sideline[0], sideline[1]);
 475   sc = scaleline_mm / scaleline;
 476   //echo("SH",sh,rot,sc);
 477   scale(sc) rotate(rot) translate(sh){
 478     import("sewing-table-rear-profile.dxf", convexity=10); // spline, Pink3
 479   }
 480 }
 481
 482 module Machine_NewFrontProfile(){
 483   // figures copied out of xfig edit boxes
 484   // best not to edit the posbox size if poss - just move it
 485   posbox = 10 * ([11.8022,8.0600] - [4.2044,19.1867]); // box, Green
 486   refline = 10 * ([7.6778,16.7222] - [27.8689,17.6578]); // line, Blue
 487   refline_mm = (11-1)*10;
 488   sh = -[abs(posbox[0]), abs(posbox[1])];
 489   rot = atan2(-refline[0], refline[1]);
 490   sc = refline_mm / vectorlen2d(refline);
 491   //echo("SH",sh,rot,sc);
 492   mirror([1,0]) scale(sc) rotate(rot+90) translate(sh){
 493     import("sewing-table-front-profile.dxf", convexity=10); // spline, Pink3
 494   }
 495 }
 496
 497 module Machine_NewEndProfile(){
 498   // figures copied out of xfig edit boxes
 499   // NB that y coords are reversed - xfig origin is at bottom left
 500   posboxs = 10 * [[4.0400,17.7956], [11.6622,32.5511]]; // box, Pink3
 501   refline = 10 * ([8.4000,22.6000] - [50.3000,22.2000]); // line, Blue
 502   refline_mm = 10 * (11 - 2.5);
 503   sidelines = 10 * [[[9.0889,20.6178], [8.9644,14.6889]],
 504                     [[50.3800,21.9578], [50.1933,14.4933]]]; // lines, Blue3
 505   baseline = 10 * [[8.4000,18.0822], [50.3000,17.6822]]; // line, Green2
 506
 507   rot_adj = -0.38;
 508
 509   posbox = [min(posboxs[0][0],posboxs[1][0]),
 510             max(posboxs[0][1],posboxs[1][1])];
 511
 512   m4_define(`MNEP_ELP',
 513      `line_intersection_2d(baseline[0],baseline[1],
 514                            sidelines[$1][0],sidelines[$1][1])')
 515   endline = [MNEP_ELP(0),MNEP_ELP(1)];
 516
 517   rot = atan2(-refline[1], -refline[0]);
 518   sc = refline_mm / vectorlen2d(refline);
 519   sh = (0.5 * (endline[0] + endline[1])) - posbox;
 520
 521   ellen = sc * dist2d(endline[0],endline[1]);
 522   scy = cutout_l_end_y_total / ellen;
 523
 524   scale([scy,1]) scale(sc) rotate(rot + rot_adj) translate(-[sh[0],-sh[1]]){
 525
 526     mirror([0,1]){
 527   //%translate(1 * (posboxs[0] - posbox)) square(50);
 528   //%translate(1 * (posboxs[1] - posbox)) square(50);
 529 //  %translate(1 * (baseline[0] - posbox)) square([50,10]);
 530
 531 //  %translate(1 * (endline[0] - posbox)) square([50,10]);
 532 //  %translate(1 * (endline[1] - posbox)) square([50,10]);
 533
 534 //  %translate(1 * (sidelines[0][0] - posbox)) square([10,50]);
 535 //  %translate(1 * (sidelines[0][1] - posbox)) square([10,50]);
 536 //  %translate(1 * (sidelines[1][0] - posbox)) square([10,50]);
 537 //  %translate(1 * (sidelines[1][1] - posbox)) square([10,50]);
 538     }
 539
 540     import("sewing-table-end-profile.dxf", convexity=10); // spline, Pink3
 541   }
 542 }
 543
 544 module Machine_NewEndProfileDemo(){ ////toplevel
 545     translate([0,5,0])                             Machine_NewEndProfile();
 546     translate([0,5,1]) color("blue") mirror([1,0]) Machine_NewEndProfile();
 547   mirror([0,1,0]){
 548     translate([0,5, 0])                             Machine_NewEndProfile();
 549     translate([0,5,-1]) color("blue") mirror([1,0]) Machine_NewEndProfile();
 550   }
 551 }
 552
 553 module Machine_NewArm(){
 554   translate([0,0,-30]) linear_extrude(height=60) {
 555     translate(tile01_tr + [ -cutout_l_end_x - cutout_l_end_new_x_slop,
 556                             (-cutout_tile01_y + cutout_tile11_y)/2 ]){
 557       rotate(-90){
 558         hull(){
 559           for (d=[0,400])
 560             translate([0,d]) Machine_NewEndProfile();
 561         }
 562       }
 563     }
 564   }
 565 }
 566
 567 module Machine_NewRearCurve(){
 568   slant = atan2(4,210-10);
 569   //echo("SL",slant);
 570   translate([0,0, rearcurve_double_inrad]) rotate([slant,0,0]){
 571     translate([ rearcurve_double_inrad,
 572                 0,
 573                 -rearcurve_double_inrad + 10 ]){
 574       rotate([180,0,0]) rotate([0,0,90]) linear_extrude(height=30){
 575         hull(){
 576           Machine_NewRearProfile();
 577           translate([0,-100]) Machine_NewRearProfile();
 578         }
 579       }
 580     }
 581     rotate([0,90,0]) rotate([90,0,0]) {
 582       intersection(){
 583         rotate_extrude(convexity=10, $fn=64)
 584           rotate(90)
 585           translate([ 0, -rearcurve_double_inrad ])
 586           Machine_NewRearProfile();
 587         translate([0,0,-500])
 588           cube([500,500,1000]);
 589       }
 590     }
 591     translate([1,0,-rearcurve_double_inrad])
 592       rotate([0,-90,0]) rotate([0,0,-90])
 593       linear_extrude(height= rearcurve_strt_len + 1)
 594       Machine_NewRearProfile();
 595   }
 596 }
 597
 598 module Machine_Curves(){ ////toplevel
 599   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 600               cutout_tile11_y,
 601               0 ]){
 602     //%cube([20,20,20]);
 603     translate([ -reartablet_x,
 604                 -1,
 605                 -reartablet_z + tablet_z_slop])
 606       mirror([0,0,1])
 607       cube([ reartablet_x+1,
 608              reartablet_y+1,
 609              20 ]);
 610   }
 611   translate([ tile01_tr[0] - cutout_l_end_x + frontedge_len,
 612               cutout_tile11_y,
 613               frontcurve_z_slop ]){
 614     translate([0, -machine_rear_to_front, 0])
 615       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 616                   [0,  1,   0, 0],
 617                   [0,  0,   1, 0],
 618                   [0,  0,   0, 1]])
 619       mirror([1,0,0]) rotate([0,-90,0])rotate([0,0,-90])
 620       linear_extrude(height= 200)
 621       Machine_NewFrontProfile();
 622   }
 623   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 624               cutout_tile11_y,
 625               frontcurve_z_slop ]){
 626     translate([ rearcurve_strt_len,
 627                 0,
 628                 rearcurve_z_slop ]){
 629       Machine_NewRearCurve();
 630     }
 631   }
 632 }
 633
 634 module TestStrapSlots(){
 635   pegwidth = teststrap_peg[0];
 636   for (pos = teststrapslots_at) {
 637     echo("TSS",pos);
 638     translate(concat(pos,[0]))
 639       for (mx = [0,1]) mirror([mx,0,0]) {
 640           translate([ pegwidth/2, -teststrap[1]/2, -20 ])
 641             cube(concat(teststrap,[40]));
 642         }
 643   }
 644 }
 645
 646 module TestStrapPeg_any(l){ cube(concat([l],teststrap_peg)); }
 647
 648 module TestStrapPeg_Short(){ ////toplevel
 649   TestStrapPeg_any(35);
 650 }
 651
 652 module TestStrapPeg_Long(){ ////toplevel
 653   TestStrapPeg_any(60);
 654 }
 655
 656 module Machine(){ ////toplevel
 657   Machine_NewArm();
 658   Machine_Curves();
 659   if (TEST)
 660     TestStrapSlots();
 661 }
 662
 663 module MachineEnvelope(){
 664   // used for testing
 665   p_arm_bl = [-cutout_l_end_x, -cutout_tile01_y];
 666   y_arm_t  = cutout_tile11_y;
 667   p_crv_fl = p_arm_bl + [frontedge_len, -frontcurve_avoid_y];
 668   y_crv_b  = y_arm_t + rearcurve_avoid_y;
 669
 670   translate([0,0,-50]) linear_extrude(height= 100){
 671     translate(p_arm_bl) square([400, y_arm_t] - p_arm_bl);
 672     translate(p_crv_fl) square([400, y_crv_b] - p_crv_fl);
 673   }
 674 }
 675
 676 module Leg(){ ////toplevel
 677   difference(){
 678     union(){
 679       hull(){
 680         mirror([0,0,1])
 681           cylinder(r= leg_big_dia/2, height=leg_top_flat_z, $fn=100);
 682         translate([0,0, -leg_height])
 683           cylinder(r= leg_bot_dia/2, height=1, $fn=100);
 684       }
 685     }
 686   }
 687 }
 688
 689 function Rectangle_corners(c0, sz) =
 690   // returns the corners of a rectangle from c0 to c0+sz
 691   // if sz is positive, the corners are anticlockwise starting with c0
 692   [ c0 + [ 0,     0     ],
 693     c0 + [ sz[0], 0     ],
 694     c0 + [ sz[0], sz[1] ],
 695     c0 + [ 0,     sz[1] ] ];
 696
 697 function Rectangle_corners2posts(c) =
 698   [ c[0] + thehd_tr,
 699     c[1] + thehd_tl,
 700     c[2] + thehd_bl,
 701     c[3] + thehd_br ];
 702
 703 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 704
 705 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 706
 707 module Tile02(){ ////toplevel
 708   sz = [100,170];
 709   c0 = tile02_tr + -sz;
 710   c = Rectangle_corners(c0, sz);
 711   posts = Rectangle_corners2posts(c);
 712   rcs = R_CNR(c,0);
 713   difference(){
 714     union(){
 715       Rectangle_TileBase(c);
 716       Posts(posts);
 717       RoundEdge(R_EDGE(c,0));
 718       RoundEdge(R_EDGE(c,3));
 719       InterlockEdge(R_EDGE(c,2), 0);
 720     }
 721     InterlockEdge(R_EDGE(c,1), 1);
 722     RoundCornerCut(rcs);
 723     PostHoles(posts);
 724   }
 725   RoundCornerAdd(rcs);
 726 }
 727
 728 module Tile12(){ ////toplevel
 729   sz = [100,250];
 730   c0 = tile02_tr + [-sz[0], 0];
 731   c = Rectangle_corners(c0, sz);
 732   posts = Rectangle_corners2posts(c);
 733   rcs = R_CNR(c,3);
 734   difference(){
 735     union(){
 736       Rectangle_TileBase(c);
 737       Posts(posts);
 738       RoundEdge(R_EDGE(c,2));
 739       RoundEdge(R_EDGE(c,3));
 740     }
 741     InterlockEdge(R_EDGE(c,0), 1);
 742     InterlockEdge(R_EDGE(c,1), 1);
 743     RoundCornerCut(rcs);
 744     PostHoles(posts);
 745   }
 746   RoundCornerAdd(rcs);
 747 }
 748
 749 tile_01_11_cnr = tile01_tr + [-cutout_l_end_x, 0];
 750 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 751 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 752
 753 module Tile11(){ ////toplevel
 754   sz = [250,250];
 755   c0 = tile01_tr + [-sz[0],0];
 756   c = Rectangle_corners(c0, sz);
 757   cnr_posts = Rectangle_corners2posts(c);
 758   posts = concat(
 759                  Posts_interpolate_one(cnr_posts[0],
 760                                        cnr_posts[1] - [cutout_l_end_x, 0]),
 761                  [ cnr_posts[1] + [0, cutout_tile11_y],
 762                    cnr_posts[2],
 763                    cnr_posts[3]
 764                    ]);
 765   difference(){
 766     union(){
 767       Rectangle_TileBase(c);
 768       Posts(posts);
 769       RoundEdge(R_EDGE(c,2));
 770       InterlockEdge(R_EDGE(c,3));
 771     }
 772     InterlockEdge(c[0], tile_01_11_cnr, 1);
 773     InterlockEdge(tile_11_10_cnr, c[2], 1);
 774     PostHoles(posts);
 775     Machine();
 776   }
 777 }
 778
 779 module Tile01(){ ////toplevel
 780   sz = [250,170];
 781   c0 = tile01_tr + -sz;
 782   c = Rectangle_corners(c0, sz);
 783   cnr_posts = Rectangle_corners2posts(c);
 784   posts = concat(
 785                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 786                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 787                  Posts_interpolate_one(cnr_posts[2] - [cutout_l_end_x, 0],
 788                                        cnr_posts[3])
 789                  );
 790   difference(){
 791     union(){
 792       Rectangle_TileBase(c);
 793       Posts(posts);
 794       RoundEdge(R_EDGE(c,0));
 795       InterlockEdge(tile_01_11_cnr, c[3]);
 796       InterlockEdge(R_EDGE(c,3));
 797     }
 798     PostHoles(posts);
 799     InterlockEdge(c[1], tile_01_00_cnr, 1);
 800     Machine();
 801   }
 802 }
 803
 804 module Tile10(){ ////toplevel
 805   sz = [250,250];
 806   c0 = tile01_tr + [0,0];
 807   c = Rectangle_corners(c0, sz);
 808   cnr_posts = Rectangle_corners2posts(c);
 809   cty = cutout_tile11_y;
 810   rcy = cty + rearcurve_avoid_y;
 811   posts = [ cnr_posts[0] + [ 0,                             cty ],
 812             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 813             cnr_posts[1] + [ 0,                             rcy ],
 814             cnr_posts[2],
 815             cnr_posts[3] ];
 816   rcs = R_CNR(c,2);
 817   difference(){
 818     union(){
 819       Rectangle_TileBase(c);
 820       Posts(posts);
 821       RoundEdge(R_EDGE(c,1));
 822       RoundEdge(R_EDGE(c,2));
 823       InterlockEdge(c[3], tile_11_10_cnr);
 824     }
 825     PostHoles(posts);
 826     RoundCornerCut(rcs);
 827     Machine();
 828   }
 829   RoundCornerAdd(rcs);
 830 }
 831
 832 module Tile00(){ ////toplevel
 833   sz = [250,170];
 834   c0 = tile01_tr + [0,-sz[1]];
 835   c = Rectangle_corners(c0, sz);
 836
 837   // the edge c[1]..c[2] needs a diagonal chunk, from c1bis to c2bis
 838   c2bis = [ -cutout_l_end_x + frontedge_len + frontcurve_strt_len, c[2][1] ];
 839   c1bis = [ c[1][0],
 840             c[2][1] -
 841             (c[2][0] - c2bis[0]) * tan(90 - frontcurve_dualcurve_angle) ];
 842
 843   cnr_posts = Rectangle_corners2posts(c);
 844   cty = cutout_tile01_y;
 845   rcy = cty + frontcurve_avoid_y;
 846   posts = [ cnr_posts[0],
 847             cnr_posts[1],
 848             0.5 * (cnr_posts[0] + cnr_posts[1]),
 849             cnr_posts[2] + [ 0,                             -rcy ],
 850             cnr_posts[2] + [ -sz[0] + frontedge_len - cutout_l_end_x, -cty ],
 851             cnr_posts[3] + [ 0,                             -cty ]
 852             ];
 853   rcs = R_CNR(c,1);
 854   rc2 = [c1bis,c2bis,c[1]];
 855   difference(){
 856     union(){
 857       difference(){
 858         union(){
 859           Rectangle_TileBase(c);
 860           Posts(posts);
 861           RoundEdge(R_EDGE(c,0));
 862           RoundEdge(c[1], c1bis);
 863           InterlockEdge(tile_01_00_cnr, c[0]);
 864         }
 865         RoundCornerCut(rcs);
 866         translate([0,0,-20]) linear_extrude(height=40) {
 867           polygon([ c1bis, c1bis + [50,0], c2bis + [50,0], c2bis ]);
 868         }
 869       }
 870       RoundEdge(c1bis, c2bis);
 871     }
 872     Machine();
 873     PostHoles(posts);
 874     RoundCornerCut(rc2);
 875   }
 876   RoundCornerAdd(rcs);
 877   RoundCornerAdd(rc2);
 878 }
 879
 880 module FitTest_general(c0,sz, dobrace=false, bracexx=0){
 881   c = Rectangle_corners(c0, sz);
 882   brace = [7,7,9];
 883   bsz = sz + [bracexx,0,0];
 884   difference(){
 885     union(){
 886       Rectangle_TileBase(c);
 887       if (dobrace) {
 888         translate(concat(c0, [-brace[2] + 0.1])){
 889           difference(){
 890             cube(concat(bsz, [brace[2]]) - [5,0,0]);
 891             translate(brace + [0,0, -25])
 892               cube(concat(bsz, [50]) - brace*2 + [10,0,0]);
 893           }
 894         }
 895       }
 896       RoundEdge(R_EDGE(c,1));
 897     }
 898     Machine();
 899   }
 900 }
 901
 902 module FitTest_PairLink(cut=false){ ////toplevel
 903   cy0=-55; cy1=85; cx=132;
 904   bar = [10,10];
 905   legrad = 12;
 906   footrad_min = 1; footrad_max = 4; footrad_depth = 5;
 907   strap = [3,5];
 908   adj_neg_slop = 1.0;
 909   bar_z_slop = 1.75;
 910
 911   // calculated
 912   straphole_x_max = legrad/sqrt(2) + footrad_max;
 913   dz = cut ? adj_neg_slop : 0;
 914
 915   translate([cx - bar[0]/2, cy0, dz + bar_z_slop])
 916     cube([bar[0], cy1-cy0, bar[1] - bar_z_slop]);
 917
 918   for (endy=[cy0,cy1]) {
 919     $fn=32;
 920     translate([cx,endy,dz]){
 921       // feet
 922       for (rot=[45:90:315]) rotate(rot) {
 923         translate([legrad,0,0]){
 924           hull(){
 925             cylinder(r= footrad_max, h=1);
 926             translate([0,0,-footrad_depth])
 927               cylinder(r= footrad_min, h=1);
 928           }
 929           if (cut)
 930             translate([0,0,-10])
 931             cylinder(r= footrad_min +
 932                      adj_neg_slop * (footrad_max-footrad_min)/footrad_depth,
 933                      h=20);
 934         }
 935       }
 936       // legs
 937       for (rot=[45,135]) rotate(rot) {
 938         hull(){
 939           for (s=[-1,+1]){
 940             translate([s*legrad,0,0])
 941               cylinder(r= footrad_max, h=bar[1]);
 942           }
 943         }
 944       }
 945       // strap holes
 946       if (cut) {
 947         for (rot=[0,180]) rotate(rot) {
 948             translate([ straphole_x_max - strap[0]/2, 0,0 ])
 949               cube(concat(strap,[20]), center=true);
 950           }
 951       }
 952     }
 953   }
 954 }
 955
 956 module FitTest_RearCurve(){ ////toplevel
 957   difference(){
 958     FitTest_general([100,0], [180,100]);
 959     FitTest_PairLink(true);
 960     TestStrapSlots();
 961   }
 962 }
 963
 964 module FitTest_FrontCurve(){ ////toplevel
 965   p0 = [100,-80];
 966   sz = [180,80];
 967   difference(){
 968     intersection() {
 969       Tile00();
 970       translate([0,0,-8]) linear_extrude(height=18) {
 971         translate(p0) square(sz);
 972         translate(teststrapslots_at[3])
 973           scale(2* [ teststrap_peg[0], teststrap[1] ])
 974           circle(r=1, $fn=20);
 975       }
 976     }
 977     FitTest_PairLink(true);
 978     TestStrapSlots();
 979   }
 980 }
 981
 982 module FitTest_Entire(){ ////toplevel
 983   p0 = [-33,-80];
 984   szrear = [263,180];
 985   szfront = [243,szrear[1]];
 986   difference(){
 987     FitTest_general(p0, szrear, dobrace=true, bracexx=0);
 988     FitTest_PairLink(true);
 989     translate(concat(p0,[0]) + [szfront[0],-10,-40])
 990       cube([100, -p0[1], 80]);
 991     TestStrapSlots();
 992   }
 993   intersection(){
 994     FitTest_RearCurve();
 995     translate(concat(p0,[-20])) cube(concat(szrear,[40]));
 996   }
 997   FitTest_FrontCurve();
 998 }
 999
1000 module FitTest_EntireDemo(){ ////toplevel
1001   FitTest_Entire();
1002   //%Tile00();
1003 }
1004
1005 module FitTest_EndEnd(){ ////toplevel
1006   p0 = [-30,-32];
1007   sz = [156,81] - p0;
1008   sz2 = [136,68] - p0;
1009   difference(){
1010     FitTest_general(p0, sz);
1011     translate([ p0[0] -1, p0[1]+sz2[1], -10])
1012       cube([ sz2[0] +1, 50, 20 ]);
1013   }
1014 }
1015
1016 module FitTest_PairDemo(){ ////toplevel
1017   sh=[-90,-15,0];
1018   translate(sh){
1019     FitTest_PairLink();
1020     %FitTest_FrontCurve();
1021     %FitTest_RearCurve();
1022   }
1023   rotate([0,0,180]){
1024     translate(sh){
1025       difference(){
1026         union(){
1027           FitTest_FrontCurve();
1028           FitTest_RearCurve();
1029         }
1030         #FitTest_PairLink(true);
1031       }
1032     }
1033   }
1034 }
1035
1036 module RoundCornerDemo_plat(cnr){
1037   mirror([0,0,1]) linear_extrude(height=1) polygon(cnr);
1038 }
1039
1040 module RoundCornerDemo(){ ////toplevel
1041   cnr = [ [-2,-3], [13,-3], [-12,9] ];
1042   translate([0,25,0]) RoundCornerDemo_plat(cnr);
1043   translate([25,0,0]) RoundCornerAdd(cnr);
1044   translate([-25,0,0]) RoundCornerCut(cnr);
1045   translate([0,-25,0]) RoundCorner_selector(cnr, 0);
1046   difference(){
1047     RoundCornerDemo_plat(cnr);
1048     RoundCornerCut(cnr);
1049   }
1050   RoundCornerAdd(cnr);
1051 }
1052
1053 module Demo(){ ////toplevel
1054   translate(demo_slop*[-2,1]) color("blue") Tile12();
1055   translate(demo_slop*[-2,0]) color("red")  Tile02();
1056   translate(demo_slop*[-2,1]) color("orange") Tile11();
1057   translate(demo_slop*[-2,0]) color("purple") Tile01();
1058   translate(demo_slop*[-3,1]) color("blue")   Tile10();
1059   translate(demo_slop*[-3,0]) color("red")    Tile00();
1060   %Machine();
1061   // Can also do this, to print reference sheet:
1062   //  load this into openscad
1063   //  select Ctrl-4 view, view all, scale appropriately
1064   //  import sewing-table,Demo-flat.png
1065   //  pngtopnm <sewing-table,Demo-flat.png | ppmbrighten -s -50 -v +100 >t.pnm
1066   //  lpr t.pnm
1067 }
1068
1069 //TestPiece1();
1070 //TestPiece2();
1071 //Demo();
1072
1073 //Machine_NewRearProfile();
1074 //Machine_NewRearCurve();
1075 //Machine_NewFrontProfile();
1076 //Machine_NewEndProfile();
1077 //Machine_NewEndProfileDemo();
1078 //Machine_Curves();
1079 //Machine();
1080 //FitTest();
1081 //MachineEnvelope();