sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 tile_th = 3;
  11 post_dia = 8;
  12
  13 post_shorter = 1;
  14
  15 screw_dia = 2.2;
  16 screw_big_dia = 3.6;
  17 screw_big_len = 4.0;
  18
  19 round_edge_rad = 2.0;
  20
  21 round_cnr_rad = 10;
  22
  23 interlock_dia = 10;
  24 interlock_fine = 0.66;
  25
  26 interlock_fine_slope = 1.0;
  27 interlock_fine_lenslop = 1.0;
  28
  29 demo_slop = 0.1;
  30
  31 // cutout
  32
  33 machine_rear_to_front = 85;
  34
  35 machine_rear_profile = [
  36                         [ -  0,  -0.00 ],
  37                         [ -  2,  -0.10 ],
  38                         [ -  4,  -0.20 ],
  39                         [ -  5,  -0.30 ],
  40                         [ -  6,  -0.40 ],
  41                         [ -  7,  -0.50 ],
  42                         [ -  8,  -0.75 ],
  43                         [ - 10,  -1.50 ],
  44                         [ - 12,  -2.25 ],
  45                         [ - 14,  -3.25 ],
  46                         [ - 16,  -4.25 ],
  47                         [ - 18,  -5.75 ],
  48                         [ - 20,  -8.00 ]
  49                         ];
  50
  51 machine_front_profile =  [
  52                           [  128,  -3.70,  ],
  53                           [  124,  -2.90,  ],
  54                           [  120,  -2.45,  ],
  55                           [  116,  -2.10,  ],
  56                           [  112,  -1.80,  ],
  57                           [  108,  -1.55,  ],
  58                           [  104,  -1.25,  ],
  59                           [  100,  -1.00,  ],
  60                           [   96,  -0.80,  ],
  61                           [   92,  -0.65,  ],
  62                           [   88,  -0.55,  ],
  63                           [   84,  -0.50,  ]
  64                           ];
  65
  66 cutout_l_end_y_front_slop = 0.5;
  67 cutout_l_end_y_rear_slop = 0.5;
  68 cutout_l_end_x_slop = 0.25;
  69
  70 cutout_l_end_x = 22;
  71 cutout_l_end_y = machine_rear_to_front;
  72 cutout_l_end_curve = 1;
  73 cutout_l_end_y_total = cutout_l_end_y
  74   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  75
  76 tile02_tr = [-250, 0];
  77 tile01_tr = [  0, 0];
  78
  79 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  80 cutout_tile11_x = cutout_l_end_x + cutout_l_end_curve;
  81 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  82
  83 // front and rear curves
  84
  85 rearedge_len = 170;
  86
  87 rearcurve_strt_len = 52;
  88
  89 rearcurve_z_slop = 0.75;
  90
  91 rearcurve_avoid_y = 35;
  92
  93 rearcurve_double_inrad = 26.10 + 8.04;
  94
  95 reartablet_z = 2.54;
  96 reartablet_x = 5 + 1;
  97 reartablet_y = 8;
  98
  99 frontcurve_side_skew = 3.5 / 72;
 100 frontcurve_avoid_y = 70;
 101 frontcurve_z_slop = 0.75;
 102
 103 frontcurve_strt_len = 60;
 104 frontcurve_dualcurve_angle = 90 - 65;
 105
 106 // calculated
 107
 108 TEST = false;
 109
 110 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
 111
 112 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
 113
 114 hole_slop = (ply_hole_dia - post_dia)/2;
 115 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
 116
 117 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
 118          tile_hard_edge_hole_dist));
 119
 120 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
 121          tile_hard_edge_hole_dist + round_edge_rad));
 122
 123 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
 124 thehd_tr = thehd;
 125 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 126 thehd_bl = -thehd_tr;
 127 thehd_br = -thehd_tl;
 128
 129 tablet_z_slop = rearcurve_z_slop;
 130
 131 interlock_rad = interlock_dia/2;
 132 interlock_negative_rad = interlock_rad + 0.125;
 133
 134 interlock_sq_adj = 0.2; // arbitrary
 135
 136 first_front = machine_front_profile[len(machine_front_profile)-1];
 137
 138 m4_define(`POST_TCROSSSZ',
 139           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 140
 141 module Post(){
 142   mirror([0,0,1]) {
 143     difference(){
 144       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 145       translate([0,0, tile_th]) {
 146         cylinder(r= screw_big_dia/2, h= screw_big_len);
 147         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
 148       }
 149     }
 150     if (TEST) {
 151       translate([0,0, tile_th/2]) {
 152         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 153         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 154       }
 155     }
 156   }
 157 }
 158
 159 module Posts(posts) {
 160   for (p= posts) {
 161     translate(concat(p, [0]))
 162       Post();
 163   }
 164 }
 165
 166 module TileBase(botleft, topright){
 167   size = topright - botleft;
 168   botleft_post = botleft + thehd_tr;
 169   topright_post = topright + thehd_bl;
 170   difference(){
 171     mirror([0,0,1])
 172       translate(concat(botleft, [0]))
 173       cube(concat(size, [tile_th]));
 174     if (!TEST) {
 175       cidsz = topright_post-botleft_post
 176         + [-post_dia,-post_dia]
 177         + [0, thehd[1]];
 178       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
 179       echo("CID",cidsz,cidszr);
 180       translate( concat(botleft_post, [ -tile_th ])
 181                  + 0.5 * [ post_dia, post_dia, 0 ]
 182                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
 183         Commitid_BestCount_M(cidszr);
 184     }
 185     if (TEST) {
 186       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
 187       cidsz = [ thehd[0], size[1] - 2*crossoff ];
 188       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
 189       translate( concat(botleft + [0, crossoff] + (cidsz-cidszr)/2, [0]) )
 190         Commitid_BestCount(cidszr);
 191       difference(){
 192         mirror([0,0,1]) {
 193           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 194             cube(concat(size - [test_edge,test_edge]*2, [tile_th]));
 195           translate(concat(botleft_post, [-1]))
 196             cube(concat(topright_post-botleft_post, [tile_th+2]));
 197         }
 198         shufflesz = max(test_edge, tile_hard_edge_hole_dist)*2;
 199         minkowski(){
 200           MachineEnvelope();
 201           cube(shufflesz, center=true);
 202         }
 203       }
 204     }
 205   }
 206 }
 207
 208 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 209 m4_define(`INREFFRAME',`
 210   length_vec = ($2) - ($1);
 211   length = dist2d([0,0], length_vec);
 212   length_uvec = length_vec / length;
 213   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 214   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 215         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 216         [ 0,              0,              1,            0, ],
 217         [ 0,              0,              0,            1, ] ];
 218   $3
 219   multmatrix(m)
 220 ')
 221
 222 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 223 m4_dnl    INREFFRAME_EDGE { body; }
 224 m4_define(`INREFFRAME_EDGE',`
 225   translate([0,0, -round_edge_rad])
 226 ')
 227
 228 module RoundEdge(left_cnr, right_cnr) {
 229   INREFFRAME(left_cnr, right_cnr)
 230     INREFFRAME_EDGE {
 231     difference(){
 232       rotate([0,90,0])
 233         cylinder(r= round_edge_rad, h= length, $fn=50);
 234       translate([-1, 0, -20])
 235         cube([length+2, 20, 20]);
 236     }
 237   }
 238 }
 239
 240 m4_define(`ROUNDCORNER_VARS',`
 241   this_cnr = ci[0];
 242   right_cnr = ci[1];
 243   left_cnr = ci[2];
 244   bigr= round_cnr_rad - round_edge_rad
 245 ')
 246
 247 module RoundCorner_selector(ci, adj) {
 248   r = round_cnr_rad - round_edge_rad;
 249   cube(r*2 + adj, center=true);
 250 }
 251
 252 module RoundCornerCut(ci) {
 253   // ci should be [this_cnr, right_cnr, left_cnr]
 254   // where right_cnr is to the right (ie, anticlockwise)
 255   ROUNDCORNER_VARS;
 256   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 257     difference(){
 258       RoundCorner_selector(ci, -0.1);
 259       translate([bigr, bigr, 0])
 260         cylinder(center=true, h=20, r= bigr);
 261     }
 262   }
 263 }
 264
 265 module RoundCornerAdd(ci) {
 266   ROUNDCORNER_VARS;
 267   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 268     intersection(){
 269       RoundCorner_selector(ci, +0.1);
 270       translate([bigr, bigr, 0])
 271         rotate_extrude(convexity=10, $fn=50)
 272         translate([bigr, 0])
 273         difference(){
 274           circle(r= round_edge_rad, $fn=50);
 275           mirror([1,1])
 276             square([20,20]);
 277         }
 278     }
 279   }
 280 }
 281
 282 module InterlockLobePlan(negative) {
 283   r = negative ? interlock_negative_rad : interlock_rad;
 284   ymir = negative ? 0 : 1;
 285
 286   dx = sqrt(3) * r;
 287   $fn= 80;
 288   translate([thehd[0], 0]){
 289     mirror([0,ymir]){
 290       circle(r=r);
 291       difference(){
 292         translate([-dx, -0.1])
 293           square([ dx*2, r/2 + 0.1 ]);
 294         for (xi = [-1, 1]) {
 295           translate([ xi*dx, r ])
 296             circle(r=r);
 297         }
 298       }
 299     }
 300   }
 301 }
 302
 303 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 304   for (lobei = [ 0 : nlobes-1 ]) {
 305     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 306     translate([lobex, 0, 0]) {
 307       InterlockLobePlan(negative);
 308     }
 309   }
 310
 311   if (dosquare) {
 312     iadj = 0;
 313     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 314     mirror([0, negative])
 315       translate([slotshorter, iadj])
 316       square([length - slotshorter*2, interlock_fine + iadj*2]);
 317   }
 318 }
 319
 320 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 321   plusth = negative * 1.0;
 322   protr = interlock_fine + interlock_sq_adj;
 323
 324   z2 = -tile_th/2;
 325   z1 = -tile_th/2 - protr / interlock_fine_slope;
 326   z3 = -tile_th/2 + protr / interlock_fine_slope;
 327
 328   negsign = negative ? -1 : +1;
 329   yprotr = negsign * protr;
 330
 331   INREFFRAME(left_cnr, right_cnr) {
 332     for (vsect = [ // zs0            zs1      ys0,            ys1
 333                   [ -tile_th-plusth, plusth,  0,              0],
 334                   [ z1,              z2,      0, yprotr],
 335                   [ z2,              z3,      yprotr, 0],
 336                   ]) {
 337       zs0 = vsect[0];
 338       zs1 = vsect[1];
 339       zsd = zs1-zs0;
 340       ys0 = vsect[2];
 341       ys1 = vsect[3];
 342       ysd = ys1-ys0;
 343       sl = ysd/zsd;
 344       m = [ [ 1,0,   0,    0 ],
 345             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 346             [ 0,0,   1,  zs0 ],
 347             [ 0,0,   0,    1 ] ];
 348       multmatrix(m)
 349         linear_extrude(height=zsd, convexity=10)
 350         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 351     }
 352   }
 353 }
 354
 355 function TestPiece_holes2corners(holes) =
 356   [ holes[0] + thehd_bl,
 357     holes[1] + thehd_br,
 358     holes[1] + thehd_tr,
 359     holes[0] + thehd_tl ];
 360
 361 module TestPiece1(){ ////toplevel
 362   holes = [ [-100, 0],
 363             [   0, 0]
 364             ];
 365   corners = TestPiece_holes2corners(holes);
 366   rcs = [corners[0], corners[1]];
 367   difference(){
 368     union(){
 369       TileBase(corners[0], corners[2]);
 370       Posts(holes);
 371       RoundEdge(corners[0], corners[1]);
 372       RoundEdge(corners[3], corners[0]);
 373     }
 374     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 375     RoundCornerCut(rcs);
 376   }
 377   RoundCornerAdd(rcs);
 378 }
 379
 380 module TestPiece2(){ ////toplevel
 381   holes = [ [   0, 0],
 382             [  50, 0]
 383             ];
 384   corners = TestPiece_holes2corners(holes);
 385   TileBase(corners[0], corners[2]);
 386   Posts(holes);
 387   RoundEdge(corners[0], corners[1]);
 388   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 389 }
 390
 391 module TestDemo(){ ////toplevel
 392   translate([ -thehd[0], 0 ])
 393     color("blue")
 394     TestPiece1();
 395   translate([ +thehd[0] + demo_slop, 0 ])
 396     TestPiece2();
 397 }
 398
 399 module Machine_Arm(){
 400   ysz = cutout_l_end_y_total;
 401   // assume the round end is arc of a circle
 402   chordlen = dist2d([0,0], [ cutout_l_end_y, cutout_l_end_curve ]);
 403   endrad = cutout_l_end_y / cutout_l_end_curve * chordlen;
 404
 405   translate([0,0,-30]) linear_extrude(height=60) {
 406     translate(tile01_tr + [0, (-cutout_tile01_y + cutout_tile11_y)/2]) {
 407       intersection(){
 408         translate([-50, -ysz/2])
 409           square([400, ysz]);
 410         translate([ endrad - cutout_tile11_x - cutout_l_end_x_slop, 0 ])
 411           circle(r=endrad, $fa=0.01,$fd=5);
 412       }
 413     }
 414   }
 415 }
 416
 417 module Machine_Profile(){
 418   first_rear = machine_rear_profile[0];
 419   below_point = 0.5 * ( first_rear + first_front ) + [ 0, -10 ];
 420   pol = concat( machine_rear_profile,
 421                 [ below_point ],
 422                 machine_front_profile);
 423   skew_angle = atan2( first_front[1] - first_rear[1],
 424                       first_front[0] - first_rear[0] );
 425   //echo(below_point, pol, skew_angle);
 426   hull(){
 427     for (z=[0,-40]) {
 428       translate([0,z]) {
 429         //scale([1,5])
 430         rotate([0,0, -skew_angle ]){
 431           //translate( - first_front )
 432           polygon(pol);
 433         }
 434       }
 435     }
 436   }
 437 }
 438
 439 module Machine_NewRearProfile(){
 440   // figures copied out of xfig edit boxes
 441   // best not to edit the posbox size if poss - just move it
 442   posbox = 10 * ([7.2333,-14.1267] - [-16.2289,40.0289]); // box, Green
 443   sideline = -10 * ([-6.2400,13.5600] - [-2.4467,28.2556]); // line, Blue
 444   scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
 445   scaleline_mm = 12+5+10+5+3;
 446   sh = -[abs(posbox[0]), abs(posbox[1])];
 447   rot = atan2(-sideline[0], sideline[1]);
 448   sc = scaleline_mm / scaleline;
 449   //echo("SH",sh,rot,sc);
 450   scale(sc) rotate(rot) translate(sh){
 451     import("sewing-table-rear-profile.dxf", convexity=10); // spline, Pink3
 452   }
 453 }
 454
 455 module Machine_NewRearCurve(){
 456   slant = atan2(4,210-10);
 457   //echo("SL",slant);
 458   translate([0,0, rearcurve_double_inrad]) rotate([slant,0,0]){
 459     translate([ rearcurve_double_inrad,
 460                 0,
 461                 -rearcurve_double_inrad + 10 ]){
 462       rotate([180,0,0]) rotate([0,0,90]) linear_extrude(height=30){
 463         hull(){
 464           Machine_NewRearProfile();
 465           translate([0,-100]) Machine_NewRearProfile();
 466         }
 467       }
 468     }
 469     rotate([0,90,0]) rotate([90,0,0]) {
 470       intersection(){
 471         rotate_extrude(convexity=10, $fn=64)
 472           rotate(90)
 473           translate([ 0, -rearcurve_double_inrad ])
 474           Machine_NewRearProfile();
 475         translate([0,0,-500])
 476           cube([500,500,1000]);
 477       }
 478     }
 479     translate([1,0,-rearcurve_double_inrad])
 480       rotate([0,-90,0]) rotate([0,0,-90])
 481       linear_extrude(height= rearcurve_strt_len + 1)
 482       Machine_NewRearProfile();
 483   }
 484 }
 485
 486 module Machine_RearProfile(){ ////toplevel
 487   intersection(){
 488     Machine_Profile();
 489     translate([ -200 + machine_rear_to_front/2, -100 ]) {
 490       square([200,200]);
 491     }
 492   }
 493 }
 494
 495 module Machine_FrontProfile(){
 496   intersection(){
 497     Machine_Profile();
 498     translate([ machine_rear_to_front/2, -100 ]) {
 499       square([200,200]);
 500     }
 501   }
 502 }
 503
 504 module Machine_Curves(){ ////toplevel
 505   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 506               cutout_tile11_y,
 507               0 ]){
 508     //%cube([20,20,20]);
 509     translate([ -reartablet_x,
 510                 -1,
 511                 -reartablet_z + tablet_z_slop])
 512       mirror([0,0,1])
 513       cube([ reartablet_x+1,
 514              reartablet_y+1,
 515              20 ]);
 516   }
 517   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 518               cutout_tile11_y,
 519               frontcurve_z_slop ]){
 520     translate([ 0, -first_front[0] , 0 ])
 521       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 522                   [0,  1,   0, 0],
 523                   [0,  0,   1, 0],
 524                   [0,  0,   0, 1]])
 525       translate([ 0, first_front[0] , 0 ])
 526       mirror([1,0,0]){
 527       rotate([0,-90,0])rotate([0,0,-90]){
 528         linear_extrude(height= 200)
 529           Machine_FrontProfile();
 530       }
 531     }
 532     translate([ rearcurve_strt_len,
 533                 0,
 534                 rearcurve_z_slop ]){
 535       Machine_NewRearCurve();
 536     }
 537   }
 538 }
 539
 540 module Machine(){ ////toplevel
 541   Machine_Arm();
 542   Machine_Curves();
 543 }
 544
 545 module MachineEnvelope(){
 546   // used for testing
 547   p_arm_bl = [-cutout_tile11_x, -cutout_tile01_y];
 548   y_arm_t  = cutout_tile11_y;
 549   p_crv_fl = p_arm_bl + [rearedge_len, -frontcurve_avoid_y];
 550   y_crv_b  = y_arm_t + rearcurve_avoid_y;
 551
 552   translate([0,0,-50]) linear_extrude(height= 100){
 553     translate(p_arm_bl) square([400, y_arm_t] - p_arm_bl);
 554     translate(p_crv_fl) square([400, y_crv_b] - p_crv_fl);
 555   }
 556 }
 557
 558 function Rectangle_corners(c0, sz) =
 559   // returns the corners of a rectangle from c0 to c0+sz
 560   // if sz is positive, the corners are anticlockwise starting with c0
 561   [ c0 + [ 0,     0     ],
 562     c0 + [ sz[0], 0     ],
 563     c0 + [ sz[0], sz[1] ],
 564     c0 + [ 0,     sz[1] ] ];
 565
 566 function Rectangle_corners2posts(c) =
 567   [ c[0] + thehd_tr,
 568     c[1] + thehd_tl,
 569     c[2] + thehd_bl,
 570     c[3] + thehd_br ];
 571
 572 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 573
 574 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 575
 576 m4_dnl   R_EDGE(c,ix)
 577 m4_dnl        c is from Rectangle_corners and
 578 m4_dnl        ix is a corner number
 579 m4_dnl    expands to two comma-separated corners:
 580 m4_dnl    that denoted by ix, and the next one anticlockwise
 581 m4_define(`R_EDGE',`$1[$2],$1[(($2)+1)%4]')
 582
 583 module FitTest_general(c0,sz, dobrace=false){
 584   c = Rectangle_corners(c0, sz);
 585   brace = [7,7,9];
 586   difference(){
 587     union(){
 588       Rectangle_TileBase(c);
 589       if (dobrace) {
 590         translate(concat(c0, [-brace[2] + 0.1])){
 591           difference(){
 592             cube(concat(sz,[brace[2]]) - [5,0,0]);
 593             translate(brace + [0,0, -25])
 594               cube(concat(sz, [50]) - brace*2 + [10,0,0]);
 595           }
 596         }
 597       }
 598       RoundEdge(R_EDGE(c,1));
 599     }
 600     Machine();
 601   }
 602 }
 603
 604 module FitTest_Entire(){ ////toplevel
 605   FitTest_general([-40,-80], [275,180], dobrace=true);
 606 }
 607
 608 module FitTest_RearCurve(){ ////toplevel
 609   FitTest_general([110,0], [170,100]);
 610 }
 611
 612 module Tile02(){ ////toplevel
 613   sz = [100,170];
 614   c0 = tile02_tr + -sz;
 615   c = Rectangle_corners(c0, sz);
 616   posts = Rectangle_corners2posts(c);
 617   rcs = [R_EDGE(c,0)];
 618   difference(){
 619     union(){
 620       Rectangle_TileBase(c);
 621       Posts(posts);
 622       RoundEdge(R_EDGE(c,0));
 623       RoundEdge(R_EDGE(c,3));
 624       InterlockEdge(R_EDGE(c,2), 0);
 625     }
 626     InterlockEdge(R_EDGE(c,1), 1);
 627     RoundCornerCut(rcs);
 628   }
 629   RoundCornerAdd(rcs);
 630 }
 631
 632 module Tile12(){ ////toplevel
 633   sz = [100,250];
 634   c0 = tile02_tr + [-sz[0], 0];
 635   c = Rectangle_corners(c0, sz);
 636   posts = Rectangle_corners2posts(c);
 637   rcs = [R_EDGE(c,3)];
 638   difference(){
 639     union(){
 640       Rectangle_TileBase(c);
 641       Posts(posts);
 642       RoundEdge(R_EDGE(c,2));
 643       RoundEdge(R_EDGE(c,3));
 644     }
 645     InterlockEdge(R_EDGE(c,0), 1);
 646     InterlockEdge(R_EDGE(c,1), 1);
 647     RoundCornerCut(rcs);
 648   }
 649   RoundCornerAdd(rcs);
 650 }
 651
 652 tile_01_11_cnr = tile01_tr + [-cutout_tile11_x, 0];
 653 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 654 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 655
 656 module Tile11(){ ////toplevel
 657   sz = [250,250];
 658   c0 = tile01_tr + [-sz[0],0];
 659   c = Rectangle_corners(c0, sz);
 660   cnr_posts = Rectangle_corners2posts(c);
 661   posts = concat(
 662                  Posts_interpolate_one(cnr_posts[0],
 663                                        cnr_posts[1] - [cutout_tile11_x, 0]),
 664                  [ cnr_posts[1] + [0, cutout_tile11_y],
 665                    cnr_posts[2],
 666                    cnr_posts[3]
 667                    ]);
 668   difference(){
 669     union(){
 670       Rectangle_TileBase(c);
 671       Posts(posts);
 672       RoundEdge(R_EDGE(c,2));
 673       InterlockEdge(R_EDGE(c,3));
 674     }
 675     InterlockEdge(c[0], tile_01_11_cnr, 1);
 676     InterlockEdge(tile_11_10_cnr, c[2], 1);
 677     Machine();
 678   }
 679 }
 680
 681 module Tile01(){ ////toplevel
 682   sz = [250,170];
 683   c0 = tile01_tr + -sz;
 684   c = Rectangle_corners(c0, sz);
 685   cnr_posts = Rectangle_corners2posts(c);
 686   posts = concat(
 687                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 688                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 689                  Posts_interpolate_one(cnr_posts[2] - [cutout_tile11_x, 0],
 690                                        cnr_posts[3])
 691                  );
 692   difference(){
 693     union(){
 694       Rectangle_TileBase(c);
 695       Posts(posts);
 696       RoundEdge(R_EDGE(c,0));
 697       InterlockEdge(tile_01_11_cnr, c[3]);
 698       InterlockEdge(R_EDGE(c,3));
 699     }
 700     InterlockEdge(c[1], tile_01_00_cnr, 1);
 701     Machine();
 702   }
 703 }
 704
 705 module Tile10(){ ////toplevel
 706   sz = [250,250];
 707   c0 = tile01_tr + [0,0];
 708   c = Rectangle_corners(c0, sz);
 709   cnr_posts = Rectangle_corners2posts(c);
 710   cty = cutout_tile11_y;
 711   rcy = cty + rearcurve_avoid_y;
 712   posts = [ cnr_posts[0] + [ 0,                             cty ],
 713             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 714             cnr_posts[1] + [ 0,                             rcy ],
 715             cnr_posts[2],
 716             cnr_posts[3] ];
 717   rcs = [R_EDGE(c,2)];
 718   difference(){
 719     union(){
 720       Rectangle_TileBase(c);
 721       Posts(posts);
 722       RoundEdge(R_EDGE(c,1));
 723       RoundEdge(R_EDGE(c,2));
 724       InterlockEdge(c[3], tile_11_10_cnr);
 725     }
 726     RoundCornerCut(rcs);
 727     Machine();
 728   }
 729   RoundCornerAdd(rcs);
 730 }
 731
 732 module Tile00(){ ////toplevel
 733   sz = [250,170];
 734   c0 = tile01_tr + [0,-sz[1]];
 735   c = Rectangle_corners(c0, sz);
 736
 737   // the edge c[1]..c[2] needs a diagonal chunk, from c1bis to c2bis
 738   c2bis = [ -cutout_l_end_x + rearedge_len + frontcurve_strt_len, c[2][1] ];
 739   c1bis = [ c[1][0],
 740             c[2][1] -
 741             (c[2][0] - c2bis[0]) * tan(90 - frontcurve_dualcurve_angle) ];
 742
 743   cnr_posts = Rectangle_corners2posts(c);
 744   cty = cutout_tile01_y;
 745   rcy = cty + frontcurve_avoid_y;
 746   posts = [ cnr_posts[0],
 747             cnr_posts[1],
 748             cnr_posts[2] + [ 0,                             -rcy ],
 749             cnr_posts[2] + [ -sz[0] + rearedge_len - cutout_l_end_x, -cty ],
 750             cnr_posts[3] + [ 0,                             -cty ]
 751             ];
 752   rcs = [R_EDGE(c,1)];
 753   difference(){
 754     union(){
 755       difference(){
 756         union(){
 757           Rectangle_TileBase(c);
 758           Posts(posts);
 759           RoundEdge(R_EDGE(c,0));
 760           RoundEdge(c[1], c1bis);
 761           InterlockEdge(tile_01_00_cnr, c[0]);
 762         }
 763         RoundCornerCut(rcs);
 764         translate([0,0,-20]) linear_extrude(height=40) {
 765           polygon([ c1bis, c1bis + [50,0], c2bis + [50,0], c2bis ]);
 766         }
 767       }
 768       RoundEdge(c1bis, c2bis);
 769     }
 770     Machine();
 771   }
 772   RoundCornerAdd(rcs);
 773   RoundCornerAdd([c1bis,c2bis,c[1]]);
 774 }
 775
 776 module FitTest_FrontCurve(){ ////toplevel
 777   p0 = [110,-80];
 778   sz = [170,80];
 779   intersection() {
 780     Tile00();
 781     translate([0,0,-8]) linear_extrude(height=18) {
 782       translate(p0) square(sz);
 783     }
 784   }
 785 }
 786
 787 module RoundCornerDemo_plat(cnr){
 788   mirror([0,0,1]) linear_extrude(height=1) polygon(cnr);
 789 }
 790
 791 module RoundCornerDemo(){ ////toplevel
 792   cnr = [ [0,0], [15,0], [-10,10] ];
 793   translate([0,25,0]) RoundCornerDemo_plat(cnr);
 794   translate([25,0,0]) RoundCornerAdd(cnr);
 795   translate([-25,0,0]) RoundCornerCut(cnr);
 796   difference(){
 797     RoundCornerDemo_plat(cnr);
 798     RoundCornerCut(cnr);
 799   }
 800   RoundCornerAdd(cnr);
 801 }
 802
 803 module Demo(){ ////toplevel
 804   translate(demo_slop*[-2,1]) color("blue") Tile12();
 805   translate(demo_slop*[-2,0]) color("red")  Tile02();
 806   translate(demo_slop*[-2,1]) color("orange") Tile11();
 807   translate(demo_slop*[-2,0]) color("purple") Tile01();
 808   translate(demo_slop*[-3,1]) color("blue")   Tile10();
 809   translate(demo_slop*[-3,0]) color("red")    Tile00();
 810   %Machine();
 811 }
 812
 813 //TestPiece1();
 814 //TestPiece2();
 815 //Demo();
 816
 817 //Machine_Profile();
 818 //Machine_NewRearProfile();
 819 //Machine_NewRearCurve();
 820 //Machine_Curves();
 821 //Machine();
 822 //FitTest();
 823 //MachineEnvelope();