sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 tile_th = 3;
  11 post_dia = 8;
  12
  13 post_shorter = 1;
  14
  15 screw_dia = 2.2;
  16 screw_big_dia = 3.6;
  17 screw_big_len = 4.0;
  18
  19 round_edge_rad = 2.0;
  20
  21 round_cnr_rad = 10;
  22
  23 interlock_dia = 10;
  24 interlock_fine = 0.66;
  25
  26 interlock_fine_slope = 1.0;
  27 interlock_fine_lenslop = 1.0;
  28
  29 demo_slop = 0.1;
  30
  31 // cutout
  32
  33 machine_rear_to_front = 85;
  34
  35 machine_rear_profile = [
  36                         [ -  0,  -0.00 ],
  37                         [ -  2,  -0.10 ],
  38                         [ -  4,  -0.20 ],
  39                         [ -  5,  -0.30 ],
  40                         [ -  6,  -0.40 ],
  41                         [ -  7,  -0.50 ],
  42                         [ -  8,  -0.75 ],
  43                         [ - 10,  -1.50 ],
  44                         [ - 12,  -2.25 ],
  45                         [ - 14,  -3.25 ],
  46                         [ - 16,  -4.25 ],
  47                         [ - 18,  -5.75 ],
  48                         [ - 20,  -8.00 ]
  49                         ];
  50
  51 machine_front_profile =  [
  52                           [  128,  -3.70,  ],
  53                           [  124,  -2.90,  ],
  54                           [  120,  -2.45,  ],
  55                           [  116,  -2.10,  ],
  56                           [  112,  -1.80,  ],
  57                           [  108,  -1.55,  ],
  58                           [  104,  -1.25,  ],
  59                           [  100,  -1.00,  ],
  60                           [   96,  -0.80,  ],
  61                           [   92,  -0.65,  ],
  62                           [   88,  -0.55,  ],
  63                           [   84,  -0.50,  ]
  64                           ];
  65
  66 cutout_l_end_y_front_slop = 0.5;
  67 cutout_l_end_y_rear_slop = 0.5;
  68 cutout_l_end_x_slop = 0.25;
  69
  70 cutout_l_end_x = 22;
  71 cutout_l_end_y = machine_rear_to_front;
  72 cutout_l_end_curve = 1;
  73 cutout_l_end_y_total = cutout_l_end_y
  74   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  75
  76 tile02_tr = [-250, 0];
  77 tile01_tr = [  0, 0];
  78
  79 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  80 cutout_tile11_x = cutout_l_end_x + cutout_l_end_curve;
  81 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  82
  83 // front and rear curves
  84
  85 rearedge_len = 170;
  86
  87 rearcurve_strt_len = 52;
  88
  89 rearcurve_z_slop = 0.75;
  90
  91 rearcurve_avoid_y = 35;
  92
  93 rearcurve_double_inrad = 26.10 + 8.04;
  94
  95 reartablet_z = 2.54;
  96 reartablet_x = 5 + 1;
  97 reartablet_y = 5;
  98
  99 frontcurve_side_skew = 3.5 / 72;
 100 frontcurve_avoid_y = 70;
 101 frontcurve_z_slop = 0.75;
 102
 103 // calculated
 104
 105 TEST = false;
 106
 107 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
 108
 109 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
 110
 111 hole_slop = (ply_hole_dia - post_dia)/2;
 112 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
 113
 114 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
 115          tile_hard_edge_hole_dist));
 116
 117 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
 118          tile_hard_edge_hole_dist + round_edge_rad));
 119
 120 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
 121 thehd_tr = thehd;
 122 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 123 thehd_bl = -thehd_tr;
 124 thehd_br = -thehd_tl;
 125
 126 interlock_rad = interlock_dia/2;
 127 interlock_negative_rad = interlock_rad + 0.125;
 128
 129 interlock_sq_adj = 0.2; // arbitrary
 130
 131 first_front = machine_front_profile[len(machine_front_profile)-1];
 132
 133 m4_define(`POST_TCROSSSZ',
 134           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 135
 136 module Post(){
 137   mirror([0,0,1]) {
 138     difference(){
 139       cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 140       translate([0,0, tile_th]) {
 141         cylinder(r= screw_big_dia/2, h= screw_big_len);
 142         cylinder(r= screw_dia/2, h= ply_th, $fn=20);
 143       }
 144     }
 145     if (TEST) {
 146       translate([0,0, tile_th/2]) {
 147         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 148         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 149       }
 150     }
 151   }
 152 }
 153
 154 module Posts(posts) {
 155   for (p= posts) {
 156     translate(concat(p, [0]))
 157       Post();
 158   }
 159 }
 160
 161 module TileBase(botleft, topright){
 162   size = topright - botleft;
 163   botleft_post = botleft + thehd_tr;
 164   topright_post = topright + thehd_bl;
 165   difference(){
 166     mirror([0,0,1])
 167       translate(concat(botleft, [0]))
 168       cube(concat(size, [tile_th]));
 169     if (!TEST) {
 170       cidsz = topright_post-botleft_post
 171         + [-post_dia,-post_dia]
 172         + [0, thehd[1]];
 173       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
 174       echo("CID",cidsz,cidszr);
 175       translate( concat(botleft_post, [ -tile_th ])
 176                  + 0.5 * [ post_dia, post_dia, 0 ]
 177                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
 178         Commitid_BestCount_M(cidszr);
 179     }
 180     if (TEST) {
 181       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
 182       cidsz = [ thehd[0], size[1] - 2*crossoff ];
 183       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
 184       translate( concat(botleft + [0, crossoff] + (cidsz-cidszr)/2, [0]) )
 185         Commitid_BestCount(cidszr);
 186       difference(){
 187         mirror([0,0,1]) {
 188           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 189             cube(concat(size - [test_edge,test_edge]*2, [tile_th]));
 190           translate(concat(botleft_post, [-1]))
 191             cube(concat(topright_post-botleft_post, [tile_th+2]));
 192         }
 193         minkowski(){
 194           Machine();
 195           cube(max(test_edge, tile_hard_edge_hole_dist)*2, center=true);
 196         }
 197       }
 198     }
 199   }
 200 }
 201
 202 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 203 m4_define(`INREFFRAME',`
 204   length_vec = ($2) - ($1);
 205   length = dist2d([0,0], length_vec);
 206   length_uvec = length_vec / length;
 207   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 208   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 209         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 210         [ 0,              0,              1,            0, ],
 211         [ 0,              0,              0,            1, ] ];
 212   $3
 213   multmatrix(m)
 214 ')
 215
 216 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 217 m4_dnl    INREFFRAME_EDGE { body; }
 218 m4_define(`INREFFRAME_EDGE',`
 219   translate([0,0, -round_edge_rad])
 220 ')
 221
 222 module RoundEdge(left_cnr, right_cnr) {
 223   INREFFRAME(left_cnr, right_cnr)
 224     INREFFRAME_EDGE {
 225     difference(){
 226       rotate([0,90,0])
 227         cylinder(r= round_edge_rad, h= length, $fn=50);
 228       translate([-1, 0, -20])
 229         cube([length+2, 20, 20]);
 230     }
 231   }
 232 }
 233
 234 module RoundCornerCut(ci) {
 235   // ci should be [this_cnr, right_cnr]
 236   // where right_cnr is to the right (ie, anticlockwise)
 237   this_cnr = ci[0];
 238   right_cnr = ci[1];
 239   offr= round_cnr_rad - round_edge_rad;
 240   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 241     difference(){
 242       cube(offr*2 - 0.1, center=true);
 243       translate([offr, offr, 0])
 244         cylinder(center=true, h=20, r= offr);
 245     }
 246   }
 247 }
 248
 249 module RoundCornerAdd(ci) {
 250   this_cnr = ci[0];
 251   right_cnr = ci[1];
 252   bigr = round_cnr_rad - round_edge_rad;
 253   INREFFRAME(this_cnr, right_cnr) INREFFRAME_EDGE {
 254     intersection(){
 255       cube(bigr*2 + 0.1, center=true);
 256       translate([bigr, bigr, 0])
 257         rotate_extrude(convexity=10, $fn=50)
 258         translate([bigr, 0])
 259         difference(){
 260           circle(r= round_edge_rad, $fn=50);
 261           mirror([1,1])
 262             square([20,20]);
 263         }
 264     }
 265   }
 266 }
 267
 268 module InterlockLobePlan(negative) {
 269   r = negative ? interlock_negative_rad : interlock_rad;
 270   ymir = negative ? 0 : 1;
 271
 272   dx = sqrt(3) * r;
 273   $fn= 80;
 274   translate([thehd[0], 0]){
 275     mirror([0,ymir]){
 276       circle(r=r);
 277       difference(){
 278         translate([-dx, -0.1])
 279           square([ dx*2, r/2 + 0.1 ]);
 280         for (xi = [-1, 1]) {
 281           translate([ xi*dx, r ])
 282             circle(r=r);
 283         }
 284       }
 285     }
 286   }
 287 }
 288
 289 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 290   for (lobei = [ 0 : nlobes-1 ]) {
 291     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 292     translate([lobex, 0, 0]) {
 293       InterlockLobePlan(negative);
 294     }
 295   }
 296
 297   if (dosquare) {
 298     iadj = 0;
 299     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 300     mirror([0, negative])
 301       translate([slotshorter, iadj])
 302       square([length - slotshorter*2, interlock_fine + iadj*2]);
 303   }
 304 }
 305
 306 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 307   plusth = negative * 1.0;
 308   protr = interlock_fine + interlock_sq_adj;
 309
 310   z2 = -tile_th/2;
 311   z1 = -tile_th/2 - protr / interlock_fine_slope;
 312   z3 = -tile_th/2 + protr / interlock_fine_slope;
 313
 314   negsign = negative ? -1 : +1;
 315   yprotr = negsign * protr;
 316
 317   INREFFRAME(left_cnr, right_cnr) {
 318     for (vsect = [ // zs0            zs1      ys0,            ys1
 319                   [ -tile_th-plusth, plusth,  0,              0],
 320                   [ z1,              z2,      0, yprotr],
 321                   [ z2,              z3,      yprotr, 0],
 322                   ]) {
 323       zs0 = vsect[0];
 324       zs1 = vsect[1];
 325       zsd = zs1-zs0;
 326       ys0 = vsect[2];
 327       ys1 = vsect[3];
 328       ysd = ys1-ys0;
 329       sl = ysd/zsd;
 330       m = [ [ 1,0,   0,    0 ],
 331             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 332             [ 0,0,   1,  zs0 ],
 333             [ 0,0,   0,    1 ] ];
 334       multmatrix(m)
 335         linear_extrude(height=zsd, convexity=10)
 336         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 337     }
 338   }
 339 }
 340
 341 function TestPiece_holes2corners(holes) =
 342   [ holes[0] + thehd_bl,
 343     holes[1] + thehd_br,
 344     holes[1] + thehd_tr,
 345     holes[0] + thehd_tl ];
 346
 347 module TestPiece1(){ ////toplevel
 348   holes = [ [-100, 0],
 349             [   0, 0]
 350             ];
 351   corners = TestPiece_holes2corners(holes);
 352   rcs = [corners[0], corners[1]];
 353   difference(){
 354     union(){
 355       TileBase(corners[0], corners[2]);
 356       Posts(holes);
 357       RoundEdge(corners[0], corners[1]);
 358       RoundEdge(corners[3], corners[0]);
 359     }
 360     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 361     RoundCornerCut(rcs);
 362   }
 363   RoundCornerAdd(rcs);
 364 }
 365
 366 module TestPiece2(){ ////toplevel
 367   holes = [ [   0, 0],
 368             [  50, 0]
 369             ];
 370   corners = TestPiece_holes2corners(holes);
 371   TileBase(corners[0], corners[2]);
 372   Posts(holes);
 373   RoundEdge(corners[0], corners[1]);
 374   InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 375 }
 376
 377 module TestDemo(){ ////toplevel
 378   translate([ -thehd[0], 0 ])
 379     color("blue")
 380     TestPiece1();
 381   translate([ +thehd[0] + demo_slop, 0 ])
 382     TestPiece2();
 383 }
 384
 385 module Machine_Arm(){
 386   ysz = cutout_l_end_y_total;
 387   // assume the round end is arc of a circle
 388   chordlen = dist2d([0,0], [ cutout_l_end_y, cutout_l_end_curve ]);
 389   endrad = cutout_l_end_y / cutout_l_end_curve * chordlen;
 390
 391   translate([0,0,-30]) linear_extrude(height=60) {
 392     translate(tile01_tr + [0, (-cutout_tile01_y + cutout_tile11_y)/2]) {
 393       intersection(){
 394         translate([-100, -ysz/2])
 395           square([400, ysz]);
 396         translate([ endrad - cutout_tile11_x - cutout_l_end_x_slop, 0 ])
 397           circle(r=endrad, $fa=0.01,$fd=5);
 398       }
 399     }
 400   }
 401 }
 402
 403 module Machine_Profile(){
 404   first_rear = machine_rear_profile[0];
 405   below_point = 0.5 * ( first_rear + first_front ) + [ 0, -10 ];
 406   pol = concat( machine_rear_profile,
 407                 [ below_point ],
 408                 machine_front_profile);
 409   skew_angle = atan2( first_front[1] - first_rear[1],
 410                       first_front[0] - first_rear[0] );
 411   echo(below_point, pol, skew_angle);
 412   hull(){
 413     for (z=[0,-40]) {
 414       translate([0,z]) {
 415         //scale([1,5])
 416         rotate([0,0, -skew_angle ]){
 417           //translate( - first_front )
 418           polygon(pol);
 419         }
 420       }
 421     }
 422   }
 423 }
 424
 425 module Machine_NewRearProfile(){ ////toplevel
 426   import("sewing-table-rear-profile.dxf", convexity=10);
 427 }
 428
 429 module Machine_RearProfile(){ ////toplevel
 430   intersection(){
 431     Machine_Profile();
 432     translate([ -200 + machine_rear_to_front/2, -100 ]) {
 433       square([200,200]);
 434     }
 435   }
 436 }
 437
 438 module Machine_FrontProfile(){
 439   intersection(){
 440     Machine_Profile();
 441     translate([ machine_rear_to_front/2, -100 ]) {
 442       square([200,200]);
 443     }
 444   }
 445 }
 446
 447 module Machine_Curves(){ ////toplevel
 448   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 449               cutout_tile11_y,
 450               0 ]){
 451     //%cube([20,20,20]);
 452     translate([ -reartablet_x,
 453                 -1,
 454                 -reartablet_z])
 455       mirror([0,0,1])
 456       cube([ reartablet_x+1,
 457              reartablet_y+1,
 458              20 ]);
 459   }
 460   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 461               cutout_tile11_y,
 462               frontcurve_z_slop ]){
 463     translate([ 0, -first_front[0] , 0 ])
 464       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 465                   [0,  1,   0, 0],
 466                   [0,  0,   1, 0],
 467                   [0,  0,   0, 1]])
 468       translate([ 0, first_front[0] , 0 ])
 469       mirror([1,0,0]){
 470       rotate([0,-90,0])rotate([0,0,-90]){
 471         linear_extrude(height= 200)
 472           Machine_FrontProfile();
 473       }
 474     }
 475     translate([ rearcurve_strt_len,
 476                 0,
 477                 rearcurve_z_slop ]){
 478       translate([ 1,
 479                   0,
 480                   0
 481                   ]){
 482         rotate([0,-90,0])rotate([0,0,-90]){
 483           linear_extrude(height= rearcurve_strt_len + 1)
 484           Machine_RearProfile();
 485         }
 486       }
 487       translate([ 0,
 488                   0,
 489                   rearcurve_double_inrad ]) {
 490         intersection(){
 491           rotate([90,0,0]){
 492             rotate_extrude(convexity=10, $fn=32) {
 493               rotate([0,0,90]) translate([ 0,
 494                           -rearcurve_double_inrad ]) {
 495                 Machine_RearProfile();
 496               }
 497             }
 498           }
 499           mirror([0,0,1])
 500             translate([0,-75,0]) cube([150,150,150]);
 501         }
 502       }
 503     }
 504   }
 505 }
 506
 507 module Machine(){ ////toplevel
 508   Machine_Arm();
 509   Machine_Curves();
 510 }
 511
 512 function Rectangle_corners(c0, sz) =
 513   // returns the corners of a rectangle from c0 to c0+sz
 514   // if sz is positive, the corners are anticlockwise starting with c0
 515   [ c0 + [ 0,     0     ],
 516     c0 + [ sz[0], 0     ],
 517     c0 + [ sz[0], sz[1] ],
 518     c0 + [ 0,     sz[1] ] ];
 519
 520 function Rectangle_corners2posts(c) =
 521   [ c[0] + thehd_tr,
 522     c[1] + thehd_tl,
 523     c[2] + thehd_bl,
 524     c[3] + thehd_br ];
 525
 526 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 527
 528 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 529
 530 m4_dnl   R_EDGE(c,ix)
 531 m4_dnl        c is from Rectangle_corners and
 532 m4_dnl        ix is a corner number
 533 m4_dnl    expands to two comma-separated corners:
 534 m4_dnl    that denoted by ix, and the next one anticlockwise
 535 m4_define(`R_EDGE',`$1[$2],$1[(($2)+1)%4]')
 536
 537 module FitTest(){ ////toplevel
 538   sz = [280,180];
 539   c0 = [-50,-80];
 540   c = Rectangle_corners(c0, sz);
 541   brace = [7,7,9];
 542   difference(){
 543     union(){
 544       Rectangle_TileBase(c);
 545       translate(concat(c0, [-brace[2] + 0.1])){
 546         difference(){
 547           cube(concat(sz,[brace[2]]) - [5,0,0]);
 548           translate(brace + [0,0, -25])
 549             cube(concat(sz, [50]) - brace*2 + [10,0,0]);
 550         }
 551       }
 552       RoundEdge(R_EDGE(c,1));
 553     }
 554     Machine();
 555   }
 556 }
 557
 558 module Tile02(){ ////toplevel
 559   sz = [100,170];
 560   c0 = tile02_tr + -sz;
 561   c = Rectangle_corners(c0, sz);
 562   posts = Rectangle_corners2posts(c);
 563   rcs = [R_EDGE(c,0)];
 564   difference(){
 565     union(){
 566       Rectangle_TileBase(c);
 567       Posts(posts);
 568       RoundEdge(R_EDGE(c,0));
 569       RoundEdge(R_EDGE(c,3));
 570       InterlockEdge(R_EDGE(c,2), 0);
 571     }
 572     InterlockEdge(R_EDGE(c,1), 1);
 573     RoundCornerCut(rcs);
 574   }
 575   RoundCornerAdd(rcs);
 576 }
 577
 578 module Tile12(){ ////toplevel
 579   sz = [100,250];
 580   c0 = tile02_tr + [-sz[0], 0];
 581   c = Rectangle_corners(c0, sz);
 582   posts = Rectangle_corners2posts(c);
 583   rcs = [R_EDGE(c,3)];
 584   difference(){
 585     union(){
 586       Rectangle_TileBase(c);
 587       Posts(posts);
 588       RoundEdge(R_EDGE(c,2));
 589       RoundEdge(R_EDGE(c,3));
 590     }
 591     InterlockEdge(R_EDGE(c,0), 1);
 592     InterlockEdge(R_EDGE(c,1), 1);
 593     RoundCornerCut(rcs);
 594   }
 595   RoundCornerAdd(rcs);
 596 }
 597
 598 tile_01_11_cnr = tile01_tr + [-cutout_tile11_x, 0];
 599 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 600 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 601
 602 module Tile11(){ ////toplevel
 603   sz = [250,250];
 604   c0 = tile01_tr + [-sz[0],0];
 605   c = Rectangle_corners(c0, sz);
 606   cnr_posts = Rectangle_corners2posts(c);
 607   posts = concat(
 608                  Posts_interpolate_one(cnr_posts[0],
 609                                        cnr_posts[1] - [cutout_tile11_x, 0]),
 610                  [ cnr_posts[1] + [0, cutout_tile11_y],
 611                    cnr_posts[2],
 612                    cnr_posts[3]
 613                    ]);
 614   difference(){
 615     union(){
 616       Rectangle_TileBase(c);
 617       Posts(posts);
 618       RoundEdge(R_EDGE(c,2));
 619       InterlockEdge(R_EDGE(c,3));
 620     }
 621     InterlockEdge(c[0], tile_01_11_cnr, 1);
 622     InterlockEdge(tile_11_10_cnr, c[2], 1);
 623     Machine();
 624   }
 625 }
 626
 627 module Tile01(){ ////toplevel
 628   sz = [250,170];
 629   c0 = tile01_tr + -sz;
 630   c = Rectangle_corners(c0, sz);
 631   cnr_posts = Rectangle_corners2posts(c);
 632   posts = concat(
 633                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 634                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 635                  Posts_interpolate_one(cnr_posts[2] - [cutout_tile11_x, 0],
 636                                        cnr_posts[3])
 637                  );
 638   difference(){
 639     union(){
 640       Rectangle_TileBase(c);
 641       Posts(posts);
 642       RoundEdge(R_EDGE(c,0));
 643       InterlockEdge(tile_01_11_cnr, c[3]);
 644       InterlockEdge(R_EDGE(c,3));
 645     }
 646     InterlockEdge(c[1], tile_01_00_cnr, 1);
 647     Machine();
 648   }
 649 }
 650
 651 module Tile10(){ ////toplevel
 652   sz = [250,250];
 653   c0 = tile01_tr + [0,0];
 654   c = Rectangle_corners(c0, sz);
 655   cnr_posts = Rectangle_corners2posts(c);
 656   cty = cutout_tile11_y;
 657   rcy = cty + rearcurve_avoid_y;
 658   posts = [ cnr_posts[0] + [ 0,                             cty ],
 659             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 660             cnr_posts[1] + [ 0,                             rcy ],
 661             cnr_posts[2],
 662             cnr_posts[3] ];
 663   rcs = [R_EDGE(c,2)];
 664   difference(){
 665     union(){
 666       Rectangle_TileBase(c);
 667       Posts(posts);
 668       RoundEdge(R_EDGE(c,1));
 669       RoundEdge(R_EDGE(c,2));
 670       InterlockEdge(c[3], tile_11_10_cnr);
 671     }
 672     RoundCornerCut(rcs);
 673     Machine();
 674   }
 675   RoundCornerAdd(rcs);
 676 }
 677
 678 module Tile00(){ ////toplevel
 679   sz = [250,170];
 680   c0 = tile01_tr + [0,-sz[1]];
 681   c = Rectangle_corners(c0, sz);
 682   cnr_posts = Rectangle_corners2posts(c);
 683   cty = cutout_tile01_y;
 684   rcy = cty + frontcurve_avoid_y;
 685   posts = [ cnr_posts[0],
 686             cnr_posts[1],
 687             cnr_posts[2] + [ 0,                             -rcy ],
 688             cnr_posts[2] + [ -sz[0] + rearedge_len - cutout_l_end_x, -cty ],
 689             cnr_posts[3] + [ 0,                             -cty ]
 690             ];
 691   rcs = [R_EDGE(c,1)];
 692   difference(){
 693     union(){
 694       Rectangle_TileBase(c);
 695       Posts(posts);
 696       RoundEdge(R_EDGE(c,0));
 697       RoundEdge(R_EDGE(c,1));
 698       InterlockEdge(tile_01_00_cnr, c[0]);
 699     }
 700     RoundCornerCut(rcs);
 701     Machine();
 702   }
 703   RoundCornerAdd(rcs);
 704 }
 705
 706 module Demo(){ ////toplevel
 707   translate(demo_slop*[-2,1]) color("blue") Tile12();
 708   translate(demo_slop*[-2,0]) color("red")  Tile02();
 709   translate(demo_slop*[-2,1]) color("orange") Tile11();
 710   translate(demo_slop*[-2,0]) color("purple") Tile01();
 711   translate(demo_slop*[-3,1]) color("blue")   Tile10();
 712   translate(demo_slop*[-3,0]) color("red")    Tile00();
 713   %Machine();
 714 }
 715
 716 //TestPiece1();
 717 //TestPiece2();
 718 //Demo();
 719
 720 //Machine_Profile();
 721 //Machine_RearProfile();