sewing-table.scad.m4

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4 include <commitid.scad>
   5
   6 ply_th = 18;
   7 ply_hole_dia = 15;
   8 ply_edge_min = 10;
   9
  10 ply_hole_dia_real = 12;
  11
  12 tile_th = 3;
  13 post_dia = 8;
  14
  15 post_shorter = 1;
  16
  17 screw_dia = 2.2;
  18 screw_big_dia = 3.6;
  19 screw_big_len = 4.0;
  20
  21 round_edge_rad = 2.0;
  22
  23 round_cnr_rad = 10;
  24
  25 interlock_dia = 10;
  26 interlock_fine = 0.66;
  27
  28 interlock_fine_slope = 1.0;
  29 interlock_fine_lenslop = 1.0;
  30
  31 demo_slop = 0.1;
  32
  33 leg_height = 50;
  34
  35 leg_hole_dia = 5 + 0.75;
  36 leg_big_dia = 37;
  37 leg_bot_dia = 15;
  38 leg_top_flat_z = 5;
  39
  40 leg_fin_top_w = 5;
  41 leg_fin_bot_w = 5;
  42 leg_fin_bot_rad = 30;
  43 leg_fin_bot_flat_z = 5;
  44
  45 leg_n_fins = 4;
  46
  47 // cutout
  48
  49 machine_rear_to_front = 84 + 0.25 - 1.4;
  50
  51 cutout_l_end_y_front_slop = 0.5;
  52 cutout_l_end_y_rear_slop = 0.5;
  53
  54 cutout_l_end_x = 22;
  55 cutout_l_end_y = machine_rear_to_front;
  56 cutout_l_end_new_x_slop = 1.4 - 1.95;
  57 cutout_l_end_y_total = cutout_l_end_y
  58   + cutout_l_end_y_front_slop + cutout_l_end_y_rear_slop;
  59
  60 tile02_tr = [-250, 0];
  61 tile01_tr = [  0, 0];
  62
  63 cutout_tile01_y = 170 - 147 + cutout_l_end_y_front_slop;
  64 cutout_tile11_y = cutout_l_end_y_total - cutout_tile01_y;
  65
  66 // front and rear curves
  67
  68 rearedge_len = 170 + 0.70;
  69 frontedge_len = 170;
  70
  71 rearcurve_strt_len = 52;
  72
  73 rearcurve_z_slop = -0.50;
  74
  75 rearcurve_avoid_y = 35;
  76
  77 rearcurve_double_inrad = 26.10 + 8.04;
  78
  79 reartablet_z = 2.54;
  80 reartablet_x = 5 + 1;
  81 reartablet_y = 8;
  82
  83 frontcurve_side_skew = 3.5 / 72;
  84 frontcurve_avoid_y = 70;
  85 frontcurve_z_slop = 0.75;
  86
  87 frontcurve_strt_len = 50;
  88 frontcurve_dualcurve_angle = 30;
  89
  90 teststrapslots_at = [ [ 110, 70 ], [ 110, -35 ],
  91                       [ 180, 90 ],
  92                       [ 190, -80 ], // do not change index of this one
  93                       [   0, 70 ],  [  0, -35 ],
  94                       ];
  95
  96 teststrap = [ 3, 5 ];
  97 teststrap_peg = [7.5, 3.5];
  98
  99 ply_edge_hole_dist_real = 14;
 100
 101 // calculated
 102
 103 TEST = false;
 104 JIG = false;
 105
 106 ply_edge_hole_dist = ply_edge_min + ply_hole_dia/2;
 107
 108 echo(str("HOLES IN PLY ctr dist from PLY edge = ", ply_edge_hole_dist));
 109
 110 hole_slop = (ply_hole_dia - post_dia)/2;
 111 tile_hard_edge_hole_dist = ply_edge_hole_dist + hole_slop;
 112
 113 echo(str("HOLES IN PLY ctr dist from TILE HARD edge = ",
 114          tile_hard_edge_hole_dist));
 115
 116 echo(str("HOLES IN PLY ctr dist from TILE ROUND edge = ",
 117          tile_hard_edge_hole_dist + round_edge_rad));
 118
 119 thehd = [ tile_hard_edge_hole_dist, tile_hard_edge_hole_dist ];
 120 thehd_tr = thehd;
 121 thehd_tl = [ -thehd_tr[0], thehd_tr[1] ];
 122 thehd_bl = -thehd_tr;
 123 thehd_br = -thehd_tl;
 124
 125 tablet_z_slop = 1.00;
 126
 127 interlock_rad = interlock_dia/2;
 128 interlock_negative_rad = interlock_rad + 0.125;
 129
 130 interlock_sq_adj = 0.2; // arbitrary
 131
 132 leg_fin_top_rad = sqrt( pow(leg_big_dia/2,2) -
 133                         pow(leg_fin_top_w/2,2) );
 134
 135 m4_define(`POST_TCROSSSZ',
 136           `2*( tile_hard_edge_hole_dist - test_edge + 1 )')
 137
 138 module Post(){
 139   mirror([0,0,1]) {
 140     if (!JIG) {
 141       difference(){
 142         cylinder(r= post_dia/2, h= tile_th + ply_th - post_shorter);
 143         translate([0,0, tile_th]) {
 144           cylinder(r= screw_big_dia/2, h= screw_big_len);
 145           cylinder(r= screw_dia/2, h= ply_th, $fn=20);
 146         }
 147       }
 148     }
 149     if (TEST) {
 150       translate([0,0, tile_th/2]) {
 151         cube([post_dia,      POST_TCROSSSZ, tile_th], center=true);
 152         cube([POST_TCROSSSZ, post_dia,      tile_th], center=true);
 153       }
 154     }
 155     if (JIG) {
 156       translate([0,0, tile_th/2]) {
 157         cube([POST_TCROSSSZ, POST_TCROSSSZ, tile_th], center=true);
 158       }
 159     }
 160   }
 161 }
 162
 163 module PostHole(){
 164   if (JIG) {
 165     translate([0,0,-5])
 166       cylinder(r= post_dia/2 + jig_post_hole_slop, h=10);
 167     translate([0,0, -jig_min_th])
 168       cylinder(r= ply_hole_dia_real/2, h = 5);
 169     for (rot=[0:90:270]) rotate(rot) {
 170         translate([ ply_edge_hole_dist_real, 0, 0 ])
 171           cube([ jig_pencil_rad*2, jig_pencil_slotlen, 20 ], center=true);
 172       }
 173   }
 174 }
 175
 176 module Posts(posts) {
 177   for (p= posts) {
 178     translate(concat(p, [0]))
 179       Post();
 180   }
 181 }
 182 module PostHoles(posts) {
 183   for (p= posts)  {
 184     translate(concat(p, [0]))
 185       PostHole();
 186   }
 187 }
 188
 189 module TileBase(botleft, topright){
 190   size = topright - botleft;
 191   botleft_post = botleft + thehd_tr;
 192   topright_post = topright + thehd_bl;
 193   difference(){
 194     mirror([0,0,1])
 195       translate(concat(botleft, [0]))
 196       cube(concat(size, [tile_th]));
 197     if (!(TEST || JIG)) {
 198       cidsz = topright_post-botleft_post
 199         + [-post_dia,-post_dia]
 200         + [0, thehd[1]];
 201       cidszr = [ min(cidsz[0],50), min(cidsz[1],50) ];
 202       echo("CID",cidsz,cidszr);
 203       translate( concat(botleft_post, [ -tile_th ])
 204                  + 0.5 * [ post_dia, post_dia, 0 ]
 205                  + 0.5 * concat( cidsz - cidszr, [ 0 ]) )
 206         Commitid_BestCount_M(cidszr);
 207     }
 208     if ((TEST || JIG)) {
 209       crossoff = tile_hard_edge_hole_dist + POST_TCROSSSZ/2;
 210       cidsz = [ thehd[0], size[1] - 2*crossoff ];
 211       cidszr = [ cidsz[0], min(cidsz[1], 50) ];
 212       if (TEST)
 213         translate( concat(botleft + [0, crossoff] + (cidsz-cidszr)/2, [0]) )
 214           Commitid_BestCount(cidszr);
 215       difference(){
 216         mirror([0,0,1]) {
 217           translate(concat(botleft + [test_edge,test_edge], [test_tile_th]))
 218             cube(concat(size - [test_edge,test_edge]*2, [tile_th*2]));
 219           translate(concat(botleft_post, [-1]))
 220             cube(concat(topright_post-botleft_post, [tile_th+2]));
 221         }
 222         shufflesz = max(test_edge, tile_hard_edge_hole_dist)*2;
 223         minkowski(){
 224           MachineEnvelope();
 225           cube(shufflesz, center=true);
 226         }
 227         if (JIG) {
 228           translate([0,0,-20]) linear_extrude(height=20) {
 229             for (diag=[[ +1, botleft                   ],
 230                        [ -1, [topright[0], botleft[1]] ]]) {
 231               translate(diag[1])
 232                 rotate(atan2(size[1], diag[0] * size[0]))
 233                 translate([0, -test_edge/2])
 234                 square([vectorlen2d(size), test_edge]);
 235             }
 236           }
 237         }
 238       }
 239     }
 240   }
 241 }
 242
 243 m4_dnl   R_EDGE(c,ix)
 244 m4_dnl        c is from Rectangle_corners and
 245 m4_dnl        ix is a corner number
 246 m4_dnl    expands to two comma-separated corners:
 247 m4_dnl    that denoted by ix, and the next one anticlockwise
 248 m4_define(`R_EDGE',`$1[$2], $1[(($2)+1)%4]')
 249
 250 m4_dnl   R_CNR(c,ix)
 251 m4_dnl        c is from Rectangle_corners and
 252 m4_dnl        ix is a corner number
 253 m4_dnl    expands to an array of corners as for RoundCorner
 254 m4_define(`R_CNR',`[ $1[$2], $1[(($2)+1)%4], $1[(($2)+3)%4] ]')
 255
 256 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars) { body; }
 257 m4_define(`INREFFRAME',`
 258   length_vec = ($2) - ($1);
 259   length = dist2d([0,0], length_vec);
 260   length_uvec = length_vec / length;
 261   ortho_uvec = [ -length_uvec[1], length_uvec[0] ];
 262   m = [ [ length_uvec[0],  ortho_uvec[0], 0, ($1)[0], ],
 263         [ length_uvec[1],  ortho_uvec[1], 0, ($1)[1], ],
 264         [ 0,              0,              1,            0, ],
 265         [ 0,              0,              0,            1, ] ];
 266   $3
 267   multmatrix(m)
 268 ')
 269
 270 m4_dnl  INREFFRAME(left_cnr, right_cnr, morevars)
 271 m4_dnl    INREFFRAME_EDGE { body; }
 272 m4_define(`INREFFRAME_EDGE',`
 273   translate([0,0, -round_edge_rad])
 274 ')
 275
 276 module RoundEdge(left_cnr, right_cnr) {
 277   INREFFRAME(left_cnr, right_cnr)
 278     INREFFRAME_EDGE {
 279     difference(){
 280       rotate([0,90,0])
 281         cylinder(r= round_edge_rad, h= length, $fn=50);
 282       translate([-1, 0, -20])
 283         cube([length+2, 20, 20]);
 284     }
 285   }
 286 }
 287
 288 m4_define(`ROUNDCORNER_VARS',`
 289   this_cnr = ci[0];
 290   right_cnr = ci[1];
 291   left_cnr = ci[2];
 292   bigr= round_cnr_rad - round_edge_rad;
 293   l_uvec = unitvector2d(left_cnr - this_cnr);
 294   r_uvec = unitvector2d(right_cnr - this_cnr);
 295   lp1 = left_cnr  + clockwise2d(l_uvec) * bigr;
 296   lp2 = this_cnr  + clockwise2d(l_uvec) * bigr;
 297   lp3 = this_cnr  - clockwise2d(r_uvec) * bigr;
 298   lp4 = right_cnr - clockwise2d(r_uvec) * bigr;
 299   ctr = line_intersection_2d(lp1,lp2,lp3,lp4);
 300   ctr3 = concat(ctr,[0])
 301 ')
 302
 303 module RoundCorner_selector(ci, adj) {
 304   ROUNDCORNER_VARS;
 305   intersection(){
 306     union(){
 307       INREFFRAME(ctr3,concat(lp1,[4])){
 308         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 309           translate([-bigr*2 + adj, -bigr])
 310             square([bigr*2, bigr*3]);
 311         }
 312       }
 313     }
 314     union(){
 315       INREFFRAME(ctr3,concat(lp4,[0])){
 316         translate([0,0,-bigr]) linear_extrude(height=bigr*2) {
 317           translate([-bigr*2, -bigr*2])
 318             square([bigr*2 + adj, bigr*3]);
 319         }
 320       }
 321     }
 322   }
 323 }
 324
 325 module RoundCornerCut(ci) {
 326   // ci should be [this_cnr, right_cnr, left_cnr]
 327   // where right_cnr is to the right (ie, anticlockwise)
 328   ROUNDCORNER_VARS;
 329   difference(){
 330     RoundCorner_selector(ci, -0.1);
 331     translate(ctr3)
 332       cylinder(center=true, h=20, r= bigr);
 333   }
 334 }
 335
 336 module RoundCornerAdd(ci) {
 337   ROUNDCORNER_VARS;
 338   intersection(){
 339     RoundCorner_selector(ci, +0.1);
 340     INREFFRAME_EDGE {
 341       translate(ctr3){
 342         rotate_extrude(convexity=10, $fn=50)
 343           translate([bigr, 0])
 344           difference(){
 345           circle(r= round_edge_rad, $fn=50);
 346           mirror([1,1])
 347             square([20,20]);
 348         }
 349       }
 350     }
 351   }
 352 }
 353
 354 module InterlockLobePlan(negative) {
 355   r = negative ? interlock_negative_rad : interlock_rad;
 356   ymir = negative ? 0 : 1;
 357
 358   dx = sqrt(3) * r;
 359   $fn= 80;
 360   translate([thehd[0], 0]){
 361     mirror([0,ymir]){
 362       circle(r=r);
 363       difference(){
 364         translate([-dx, -0.1])
 365           square([ dx*2, r/2 + 0.1 ]);
 366         for (xi = [-1, 1]) {
 367           translate([ xi*dx, r ])
 368             circle(r=r);
 369         }
 370       }
 371     }
 372   }
 373 }
 374
 375 module InterlockEdgePlan(negative, nlobes, length, dosquare=true) {
 376   for (lobei = [ 0 : nlobes-1 ]) {
 377     lobex = (length - thehd[0]*2) * (lobei ? lobei / (nlobes-1) : 0);
 378     translate([lobex, 0, 0]) {
 379       InterlockLobePlan(negative);
 380     }
 381   }
 382
 383   if (dosquare) {
 384     iadj = 0;
 385     slotshorter = negative ? -0.1 : interlock_fine_lenslop;
 386     mirror([0, negative])
 387       translate([slotshorter, iadj])
 388       square([length - slotshorter*2, interlock_fine + iadj*2]);
 389   }
 390 }
 391
 392 module InterlockEdge(left_cnr, right_cnr, negative=0, nlobes=2) {
 393   plusth = negative * 1.0;
 394   protr = interlock_fine + interlock_sq_adj;
 395
 396   z2 = -tile_th/2;
 397   z1 = -tile_th/2 - protr / interlock_fine_slope;
 398   z3 = -tile_th/2 + protr / interlock_fine_slope;
 399
 400   negsign = negative ? -1 : +1;
 401   yprotr = negsign * protr;
 402
 403   INREFFRAME(left_cnr, right_cnr) {
 404     for (vsect = [ // zs0            zs1      ys0,            ys1
 405                   [ -tile_th-plusth, plusth,  0,              0],
 406                   [ z1,              z2,      0, yprotr],
 407                   [ z2,              z3,      yprotr, 0],
 408                   ]) {
 409       zs0 = vsect[0];
 410       zs1 = vsect[1];
 411       zsd = zs1-zs0;
 412       ys0 = vsect[2];
 413       ys1 = vsect[3];
 414       ysd = ys1-ys0;
 415       sl = ysd/zsd;
 416       m = [ [ 1,0,   0,    0 ],
 417             [ 0,1, -sl, -ys0 + negsign*interlock_sq_adj ],
 418             [ 0,0,   1,  zs0 ],
 419             [ 0,0,   0,    1 ] ];
 420       multmatrix(m)
 421         linear_extrude(height=zsd, convexity=10)
 422         InterlockEdgePlan(negative, nlobes, length, !!ysd);
 423     }
 424   }
 425 }
 426
 427 function TestPiece_holes2corners(holes) =
 428   [ holes[0] + thehd_bl,
 429     holes[1] + thehd_br,
 430     holes[1] + thehd_tr,
 431     holes[0] + thehd_tl ];
 432
 433 module TestPiece1(){ ////toplevel
 434   holes = [ [-100, 0],
 435             [   0, 0]
 436             ];
 437   corners = TestPiece_holes2corners(holes);
 438   rcs = R_CNR(corners,0);
 439   difference(){
 440     union(){
 441       TileBase(corners[0], corners[2]);
 442       Posts(holes);
 443       RoundEdge(corners[0], corners[1]);
 444       RoundEdge(corners[3], corners[0]);
 445     }
 446     InterlockEdge(corners[1], corners[2], 1, nlobes=1);
 447     RoundCornerCut(rcs);
 448     PostHoles(holes);
 449   }
 450   RoundCornerAdd(rcs);
 451 }
 452
 453 module TestPiece2(){ ////toplevel
 454   holes = [ [   0, 0],
 455             [  50, 0]
 456             ];
 457   corners = TestPiece_holes2corners(holes);
 458   difference(){
 459     union(){
 460       TileBase(corners[0], corners[2]);
 461       Posts(holes);
 462       RoundEdge(corners[0], corners[1]);
 463       InterlockEdge(corners[3], corners[0], 0, nlobes=1);
 464     }
 465     PostHoles(holes);
 466   }
 467 }
 468
 469 module TestDemo(){ ////toplevel
 470   translate([ -thehd[0], 0 ])
 471     color("blue")
 472     TestPiece1();
 473   translate([ +thehd[0] + demo_slop, 0 ])
 474     TestPiece2();
 475 }
 476
 477 module Machine_NewRearProfile(){
 478   // figures copied out of xfig edit boxes
 479   // best not to edit the posbox size if poss - just move it
 480   posbox = 10 * ([7.2333,-14.1267] - [-16.2289,40.0289]); // box, Green
 481   sideline = -10 * ([-6.2400,13.5600] - [-2.4467,28.2556]); // line, Blue
 482   scaleline = 10 * dist2d([-1.1911,-20.4800], [-11.2600,4.0578]); // Green2
 483   scaleline_mm = 12+5+10+5+3;
 484   sh = -[abs(posbox[0]), abs(posbox[1])];
 485   rot = atan2(-sideline[0], sideline[1]);
 486   sc = scaleline_mm / scaleline;
 487   //echo("SH",sh,rot,sc);
 488   scale(sc) rotate(rot) translate(sh){
 489     import("sewing-table-rear-profile.dxf", convexity=10); // spline, Pink3
 490   }
 491 }
 492
 493 module Machine_NewFrontProfile(){
 494   // figures copied out of xfig edit boxes
 495   // best not to edit the posbox size if poss - just move it
 496   posbox = 10 * ([11.8022,8.0600] - [4.2044,19.1867]); // box, Green
 497   refline = 10 * ([7.6778,16.7222] - [27.8689,17.6578]); // line, Blue
 498   refline_mm = (11-1)*10;
 499   sh = -[abs(posbox[0]), abs(posbox[1])];
 500   rot = atan2(-refline[0], refline[1]);
 501   sc = refline_mm / vectorlen2d(refline);
 502   //echo("SH",sh,rot,sc);
 503   mirror([1,0]) scale(sc) rotate(rot+90) translate(sh){
 504     import("sewing-table-front-profile.dxf", convexity=10); // spline, Pink3
 505   }
 506 }
 507
 508 module Machine_NewEndProfile(){
 509   // figures copied out of xfig edit boxes
 510   // NB that y coords are reversed - xfig origin is at bottom left
 511   posboxs = 10 * [[4.0400,17.7956], [11.6622,32.5511]]; // box, Pink3
 512   refline = 10 * ([8.4000,22.6000] - [50.3000,22.2000]); // line, Blue
 513   refline_mm = 10 * (11 - 2.5);
 514   sidelines = 10 * [[[9.0889,20.6178], [8.9644,14.6889]],
 515                     [[50.3800,21.9578], [50.1933,14.4933]]]; // lines, Blue3
 516   baseline = 10 * [[8.4000,18.0822], [50.3000,17.6822]]; // line, Green2
 517
 518   rot_adj = -0.38;
 519
 520   posbox = [min(posboxs[0][0],posboxs[1][0]),
 521             max(posboxs[0][1],posboxs[1][1])];
 522
 523   m4_define(`MNEP_ELP',
 524      `line_intersection_2d(baseline[0],baseline[1],
 525                            sidelines[$1][0],sidelines[$1][1])')
 526   endline = [MNEP_ELP(0),MNEP_ELP(1)];
 527
 528   rot = atan2(-refline[1], -refline[0]);
 529   sc = refline_mm / vectorlen2d(refline);
 530   sh = (0.5 * (endline[0] + endline[1])) - posbox;
 531
 532   ellen = sc * dist2d(endline[0],endline[1]);
 533   scy = cutout_l_end_y_total / ellen;
 534
 535   scale([scy,1]) scale(sc) rotate(rot + rot_adj) translate(-[sh[0],-sh[1]]){
 536
 537     mirror([0,1]){
 538   //%translate(1 * (posboxs[0] - posbox)) square(50);
 539   //%translate(1 * (posboxs[1] - posbox)) square(50);
 540 //  %translate(1 * (baseline[0] - posbox)) square([50,10]);
 541
 542 //  %translate(1 * (endline[0] - posbox)) square([50,10]);
 543 //  %translate(1 * (endline[1] - posbox)) square([50,10]);
 544
 545 //  %translate(1 * (sidelines[0][0] - posbox)) square([10,50]);
 546 //  %translate(1 * (sidelines[0][1] - posbox)) square([10,50]);
 547 //  %translate(1 * (sidelines[1][0] - posbox)) square([10,50]);
 548 //  %translate(1 * (sidelines[1][1] - posbox)) square([10,50]);
 549     }
 550
 551     import("sewing-table-end-profile.dxf", convexity=10); // spline, Pink3
 552   }
 553 }
 554
 555 module Machine_NewEndProfileDemo(){ ////toplevel
 556     translate([0,5,0])                             Machine_NewEndProfile();
 557     translate([0,5,1]) color("blue") mirror([1,0]) Machine_NewEndProfile();
 558   mirror([0,1,0]){
 559     translate([0,5, 0])                             Machine_NewEndProfile();
 560     translate([0,5,-1]) color("blue") mirror([1,0]) Machine_NewEndProfile();
 561   }
 562 }
 563
 564 module Machine_NewArm(){
 565   translate([0,0,-30]) linear_extrude(height=60) {
 566     translate(tile01_tr + [ -cutout_l_end_x - cutout_l_end_new_x_slop,
 567                             (-cutout_tile01_y + cutout_tile11_y)/2 ]){
 568       rotate(-90){
 569         hull(){
 570           for (d=[0,400])
 571             translate([0,d]) Machine_NewEndProfile();
 572         }
 573       }
 574     }
 575   }
 576 }
 577
 578 module Machine_NewRearCurve(){
 579   slant = atan2(4,210-10);
 580   //echo("SL",slant);
 581   translate([0,0, rearcurve_double_inrad]) rotate([slant,0,0]){
 582     translate([ rearcurve_double_inrad,
 583                 0,
 584                 -rearcurve_double_inrad + 10 ]){
 585       rotate([180,0,0]) rotate([0,0,90]) linear_extrude(height=30){
 586         hull(){
 587           Machine_NewRearProfile();
 588           translate([0,-100]) Machine_NewRearProfile();
 589         }
 590       }
 591     }
 592     rotate([0,90,0]) rotate([90,0,0]) {
 593       intersection(){
 594         rotate_extrude(convexity=10, $fn=64)
 595           rotate(90)
 596           translate([ 0, -rearcurve_double_inrad ])
 597           Machine_NewRearProfile();
 598         translate([0,0,-500])
 599           cube([500,500,1000]);
 600       }
 601     }
 602     translate([1,0,-rearcurve_double_inrad])
 603       rotate([0,-90,0]) rotate([0,0,-90])
 604       linear_extrude(height= rearcurve_strt_len + 1)
 605       Machine_NewRearProfile();
 606   }
 607 }
 608
 609 module Machine_Curves(){ ////toplevel
 610   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 611               cutout_tile11_y,
 612               0 ]){
 613     //%cube([20,20,20]);
 614     translate([ -reartablet_x,
 615                 -1,
 616                 -reartablet_z + tablet_z_slop])
 617       mirror([0,0,1])
 618       cube([ reartablet_x+1,
 619              reartablet_y+1,
 620              20 ]);
 621   }
 622   translate([ tile01_tr[0] - cutout_l_end_x + frontedge_len,
 623               cutout_tile11_y,
 624               frontcurve_z_slop ]){
 625     translate([0, -machine_rear_to_front, 0])
 626       multmatrix([[1, -frontcurve_side_skew, 0, 0],
 627                   [0,  1,   0, 0],
 628                   [0,  0,   1, 0],
 629                   [0,  0,   0, 1]])
 630       mirror([1,0,0]) rotate([0,-90,0])rotate([0,0,-90])
 631       linear_extrude(height= 200)
 632       Machine_NewFrontProfile();
 633   }
 634   translate([ tile01_tr[0] - cutout_l_end_x + rearedge_len,
 635               cutout_tile11_y,
 636               frontcurve_z_slop ]){
 637     translate([ rearcurve_strt_len,
 638                 0,
 639                 rearcurve_z_slop ]){
 640       Machine_NewRearCurve();
 641     }
 642   }
 643 }
 644
 645 module TestStrapSlots(){
 646   pegwidth = teststrap_peg[0];
 647   for (pos = teststrapslots_at) {
 648     echo("TSS",pos);
 649     translate(concat(pos,[0]))
 650       for (mx = [0,1]) mirror([mx,0,0]) {
 651           translate([ pegwidth/2, -teststrap[1]/2, -20 ])
 652             cube(concat(teststrap,[40]));
 653         }
 654   }
 655 }
 656
 657 module TestStrapPeg_any(l){ cube(concat([l],teststrap_peg)); }
 658
 659 module TestStrapPeg_Short(){ ////toplevel
 660   TestStrapPeg_any(35);
 661 }
 662
 663 module TestStrapPeg_Long(){ ////toplevel
 664   TestStrapPeg_any(60);
 665 }
 666
 667 module Machine(){ ////toplevel
 668   Machine_NewArm();
 669   Machine_Curves();
 670   if (TEST)
 671     TestStrapSlots();
 672 }
 673
 674 module MachineEnvelope(){
 675   // used for testing
 676   p_arm_bl = [-cutout_l_end_x, -cutout_tile01_y];
 677   y_arm_t  = cutout_tile11_y;
 678   p_crv_fl = p_arm_bl + [frontedge_len, -frontcurve_avoid_y];
 679   y_crv_b  = y_arm_t + rearcurve_avoid_y;
 680
 681   translate([0,0,-50]) linear_extrude(height= 100){
 682     translate(p_arm_bl) square([400, y_arm_t] - p_arm_bl);
 683     translate(p_crv_fl) square([400, y_crv_b] - p_crv_fl);
 684   }
 685 }
 686
 687 module Leg(){ ////toplevel
 688   difference(){
 689     union(){
 690       hull(){
 691         mirror([0,0,1])
 692           cylinder(r= leg_big_dia/2, height=leg_top_flat_z, $fn=100);
 693         translate([0,0, -leg_height])
 694           cylinder(r= leg_bot_dia/2, height=1, $fn=100);
 695       }
 696       for (rot=[0: 360/leg_n_fins : 359]) rotate(rot) {
 697           hull(){
 698             mirror([0,0,1]) translate([0, -leg_fin_top_w/2, 0])
 699               cube([ leg_fin_top_rad - 0.1,
 700                      leg_fin_top_w,
 701                      1 ])
 702               ;
 703             translate([0, -leg_fin_bot_w/2, -leg_height])
 704               cube([ leg_fin_bot_rad,
 705                      leg_fin_bot_w,
 706                      leg_fin_bot_flat_z ]);
 707           }
 708         }
 709     }
 710     mirror([0,0,1]) translate([0,0,-1])
 711       cylinder(r= leg_hole_dia/2, h=leg_height+2, $fn=30);
 712   }
 713 }
 714
 715 function Rectangle_corners(c0, sz) =
 716   // returns the corners of a rectangle from c0 to c0+sz
 717   // if sz is positive, the corners are anticlockwise starting with c0
 718   [ c0 + [ 0,     0     ],
 719     c0 + [ sz[0], 0     ],
 720     c0 + [ sz[0], sz[1] ],
 721     c0 + [ 0,     sz[1] ] ];
 722
 723 function Rectangle_corners2posts(c) =
 724   [ c[0] + thehd_tr,
 725     c[1] + thehd_tl,
 726     c[2] + thehd_bl,
 727     c[3] + thehd_br ];
 728
 729 module Rectangle_TileBase(c) { TileBase(c[0], c[2]); }
 730
 731 function Posts_interpolate_one(c0,c1) = [c0, (c0+c1)/2, c1];
 732
 733 module Tile02(){ ////toplevel
 734   sz = [100,170];
 735   c0 = tile02_tr + -sz;
 736   c = Rectangle_corners(c0, sz);
 737   posts = Rectangle_corners2posts(c);
 738   rcs = R_CNR(c,0);
 739   difference(){
 740     union(){
 741       Rectangle_TileBase(c);
 742       Posts(posts);
 743       RoundEdge(R_EDGE(c,0));
 744       RoundEdge(R_EDGE(c,3));
 745       InterlockEdge(R_EDGE(c,2), 0);
 746     }
 747     InterlockEdge(R_EDGE(c,1), 1);
 748     RoundCornerCut(rcs);
 749     PostHoles(posts);
 750   }
 751   RoundCornerAdd(rcs);
 752 }
 753
 754 module Tile12(){ ////toplevel
 755   sz = [100,250];
 756   c0 = tile02_tr + [-sz[0], 0];
 757   c = Rectangle_corners(c0, sz);
 758   posts = Rectangle_corners2posts(c);
 759   rcs = R_CNR(c,3);
 760   difference(){
 761     union(){
 762       Rectangle_TileBase(c);
 763       Posts(posts);
 764       RoundEdge(R_EDGE(c,2));
 765       RoundEdge(R_EDGE(c,3));
 766     }
 767     InterlockEdge(R_EDGE(c,0), 1);
 768     InterlockEdge(R_EDGE(c,1), 1);
 769     RoundCornerCut(rcs);
 770     PostHoles(posts);
 771   }
 772   RoundCornerAdd(rcs);
 773 }
 774
 775 tile_01_11_cnr = tile01_tr + [-cutout_l_end_x, 0];
 776 tile_11_10_cnr = tile01_tr + [0, cutout_tile11_y];
 777 tile_01_00_cnr = tile01_tr - [0, cutout_tile01_y];
 778
 779 module Tile11(){ ////toplevel
 780   sz = [250,250];
 781   c0 = tile01_tr + [-sz[0],0];
 782   c = Rectangle_corners(c0, sz);
 783   cnr_posts = Rectangle_corners2posts(c);
 784   posts = concat(
 785                  Posts_interpolate_one(cnr_posts[0],
 786                                        cnr_posts[1] - [cutout_l_end_x, 0]),
 787                  [ cnr_posts[1] + [0, cutout_tile11_y],
 788                    cnr_posts[2],
 789                    cnr_posts[3]
 790                    ]);
 791   difference(){
 792     union(){
 793       Rectangle_TileBase(c);
 794       Posts(posts);
 795       RoundEdge(R_EDGE(c,2));
 796       InterlockEdge(R_EDGE(c,3));
 797     }
 798     InterlockEdge(c[0], tile_01_11_cnr, 1);
 799     InterlockEdge(tile_11_10_cnr, c[2], 1);
 800     PostHoles(posts);
 801     Machine();
 802   }
 803 }
 804
 805 module Tile01(){ ////toplevel
 806   sz = [250,170];
 807   c0 = tile01_tr + -sz;
 808   c = Rectangle_corners(c0, sz);
 809   cnr_posts = Rectangle_corners2posts(c);
 810   posts = concat(
 811                  Posts_interpolate_one(R_EDGE(cnr_posts,0)),
 812                  [ cnr_posts[2] + [0, -cutout_tile01_y] ],
 813                  Posts_interpolate_one(cnr_posts[2] - [cutout_l_end_x, 0],
 814                                        cnr_posts[3])
 815                  );
 816   difference(){
 817     union(){
 818       Rectangle_TileBase(c);
 819       Posts(posts);
 820       RoundEdge(R_EDGE(c,0));
 821       InterlockEdge(tile_01_11_cnr, c[3]);
 822       InterlockEdge(R_EDGE(c,3));
 823     }
 824     PostHoles(posts);
 825     InterlockEdge(c[1], tile_01_00_cnr, 1);
 826     Machine();
 827   }
 828 }
 829
 830 module Tile10(){ ////toplevel
 831   sz = [250,250];
 832   c0 = tile01_tr + [0,0];
 833   c = Rectangle_corners(c0, sz);
 834   cnr_posts = Rectangle_corners2posts(c);
 835   cty = cutout_tile11_y;
 836   rcy = cty + rearcurve_avoid_y;
 837   posts = [ cnr_posts[0] + [ 0,                             cty ],
 838             cnr_posts[1] + [ -sz[0] + rearedge_len - cutout_l_end_x, cty ],
 839             cnr_posts[1] + [ 0,                             rcy ],
 840             cnr_posts[2],
 841             cnr_posts[3] ];
 842   rcs = R_CNR(c,2);
 843   difference(){
 844     union(){
 845       Rectangle_TileBase(c);
 846       Posts(posts);
 847       RoundEdge(R_EDGE(c,1));
 848       RoundEdge(R_EDGE(c,2));
 849       InterlockEdge(c[3], tile_11_10_cnr);
 850     }
 851     PostHoles(posts);
 852     RoundCornerCut(rcs);
 853     Machine();
 854   }
 855   RoundCornerAdd(rcs);
 856 }
 857
 858 module Tile00(){ ////toplevel
 859   sz = [250,170];
 860   c0 = tile01_tr + [0,-sz[1]];
 861   c = Rectangle_corners(c0, sz);
 862
 863   // the edge c[1]..c[2] needs a diagonal chunk, from c1bis to c2bis
 864   c2bis = [ -cutout_l_end_x + frontedge_len + frontcurve_strt_len, c[2][1] ];
 865   c1bis = [ c[1][0],
 866             c[2][1] -
 867             (c[2][0] - c2bis[0]) * tan(90 - frontcurve_dualcurve_angle) ];
 868
 869   cnr_posts = Rectangle_corners2posts(c);
 870   cty = cutout_tile01_y;
 871   rcy = cty + frontcurve_avoid_y;
 872   posts = [ cnr_posts[0],
 873             cnr_posts[1],
 874             0.5 * (cnr_posts[0] + cnr_posts[1]),
 875             cnr_posts[2] + [ 0,                             -rcy ],
 876             cnr_posts[2] + [ -sz[0] + frontedge_len - cutout_l_end_x, -cty ],
 877             cnr_posts[3] + [ 0,                             -cty ]
 878             ];
 879   rcs = R_CNR(c,1);
 880   rc2 = [c1bis,c2bis,c[1]];
 881   difference(){
 882     union(){
 883       difference(){
 884         union(){
 885           Rectangle_TileBase(c);
 886           Posts(posts);
 887           RoundEdge(R_EDGE(c,0));
 888           RoundEdge(c[1], c1bis);
 889           InterlockEdge(tile_01_00_cnr, c[0]);
 890         }
 891         RoundCornerCut(rcs);
 892         translate([0,0,-20]) linear_extrude(height=40) {
 893           polygon([ c1bis, c1bis + [50,0], c2bis + [50,0], c2bis ]);
 894         }
 895       }
 896       RoundEdge(c1bis, c2bis);
 897     }
 898     Machine();
 899     PostHoles(posts);
 900     RoundCornerCut(rc2);
 901   }
 902   RoundCornerAdd(rcs);
 903   RoundCornerAdd(rc2);
 904 }
 905
 906 module FitTest_general(c0,sz, dobrace=false, bracexx=0){
 907   c = Rectangle_corners(c0, sz);
 908   brace = [7,7,9];
 909   bsz = sz + [bracexx,0,0];
 910   difference(){
 911     union(){
 912       Rectangle_TileBase(c);
 913       if (dobrace) {
 914         translate(concat(c0, [-brace[2] + 0.1])){
 915           difference(){
 916             cube(concat(bsz, [brace[2]]) - [5,0,0]);
 917             translate(brace + [0,0, -25])
 918               cube(concat(bsz, [50]) - brace*2 + [10,0,0]);
 919           }
 920         }
 921       }
 922       RoundEdge(R_EDGE(c,1));
 923     }
 924     Machine();
 925   }
 926 }
 927
 928 module FitTest_PairLink(cut=false){ ////toplevel
 929   cy0=-55; cy1=85; cx=132;
 930   bar = [10,10];
 931   legrad = 12;
 932   footrad_min = 1; footrad_max = 4; footrad_depth = 5;
 933   strap = [3,5];
 934   adj_neg_slop = 1.0;
 935   bar_z_slop = 1.75;
 936
 937   // calculated
 938   straphole_x_max = legrad/sqrt(2) + footrad_max;
 939   dz = cut ? adj_neg_slop : 0;
 940
 941   translate([cx - bar[0]/2, cy0, dz + bar_z_slop])
 942     cube([bar[0], cy1-cy0, bar[1] - bar_z_slop]);
 943
 944   for (endy=[cy0,cy1]) {
 945     $fn=32;
 946     translate([cx,endy,dz]){
 947       // feet
 948       for (rot=[45:90:315]) rotate(rot) {
 949         translate([legrad,0,0]){
 950           hull(){
 951             cylinder(r= footrad_max, h=1);
 952             translate([0,0,-footrad_depth])
 953               cylinder(r= footrad_min, h=1);
 954           }
 955           if (cut)
 956             translate([0,0,-10])
 957             cylinder(r= footrad_min +
 958                      adj_neg_slop * (footrad_max-footrad_min)/footrad_depth,
 959                      h=20);
 960         }
 961       }
 962       // legs
 963       for (rot=[45,135]) rotate(rot) {
 964         hull(){
 965           for (s=[-1,+1]){
 966             translate([s*legrad,0,0])
 967               cylinder(r= footrad_max, h=bar[1]);
 968           }
 969         }
 970       }
 971       // strap holes
 972       if (cut) {
 973         for (rot=[0,180]) rotate(rot) {
 974             translate([ straphole_x_max - strap[0]/2, 0,0 ])
 975               cube(concat(strap,[20]), center=true);
 976           }
 977       }
 978     }
 979   }
 980 }
 981
 982 module FitTest_RearCurve(){ ////toplevel
 983   difference(){
 984     FitTest_general([100,0], [180,100]);
 985     FitTest_PairLink(true);
 986     TestStrapSlots();
 987   }
 988 }
 989
 990 module FitTest_FrontCurve(){ ////toplevel
 991   p0 = [100,-80];
 992   sz = [180,80];
 993   difference(){
 994     intersection() {
 995       Tile00();
 996       translate([0,0,-8]) linear_extrude(height=18) {
 997         translate(p0) square(sz);
 998         translate(teststrapslots_at[3])
 999           scale(2* [ teststrap_peg[0], teststrap[1] ])
1000           circle(r=1, $fn=20);
1001       }
1002     }
1003     FitTest_PairLink(true);
1004     TestStrapSlots();
1005   }
1006 }
1007
1008 module FitTest_Entire(){ ////toplevel
1009   p0 = [-33,-80];
1010   szrear = [263,180];
1011   szfront = [243,szrear[1]];
1012   difference(){
1013     FitTest_general(p0, szrear, dobrace=true, bracexx=0);
1014     FitTest_PairLink(true);
1015     translate(concat(p0,[0]) + [szfront[0],-10,-40])
1016       cube([100, -p0[1], 80]);
1017     TestStrapSlots();
1018   }
1019   intersection(){
1020     FitTest_RearCurve();
1021     translate(concat(p0,[-20])) cube(concat(szrear,[40]));
1022   }
1023   FitTest_FrontCurve();
1024 }
1025
1026 module FitTest_EntireDemo(){ ////toplevel
1027   FitTest_Entire();
1028   //%Tile00();
1029 }
1030
1031 module FitTest_EndEnd(){ ////toplevel
1032   p0 = [-30,-32];
1033   sz = [156,81] - p0;
1034   sz2 = [136,68] - p0;
1035   difference(){
1036     FitTest_general(p0, sz);
1037     translate([ p0[0] -1, p0[1]+sz2[1], -10])
1038       cube([ sz2[0] +1, 50, 20 ]);
1039   }
1040 }
1041
1042 module FitTest_PairDemo(){ ////toplevel
1043   sh=[-90,-15,0];
1044   translate(sh){
1045     FitTest_PairLink();
1046     %FitTest_FrontCurve();
1047     %FitTest_RearCurve();
1048   }
1049   rotate([0,0,180]){
1050     translate(sh){
1051       difference(){
1052         union(){
1053           FitTest_FrontCurve();
1054           FitTest_RearCurve();
1055         }
1056         #FitTest_PairLink(true);
1057       }
1058     }
1059   }
1060 }
1061
1062 module RoundCornerDemo_plat(cnr){
1063   mirror([0,0,1]) linear_extrude(height=1) polygon(cnr);
1064 }
1065
1066 module RoundCornerDemo(){ ////toplevel
1067   cnr = [ [-2,-3], [13,-3], [-12,9] ];
1068   translate([0,25,0]) RoundCornerDemo_plat(cnr);
1069   translate([25,0,0]) RoundCornerAdd(cnr);
1070   translate([-25,0,0]) RoundCornerCut(cnr);
1071   translate([0,-25,0]) RoundCorner_selector(cnr, 0);
1072   difference(){
1073     RoundCornerDemo_plat(cnr);
1074     RoundCornerCut(cnr);
1075   }
1076   RoundCornerAdd(cnr);
1077 }
1078
1079 module Demo(){ ////toplevel
1080   translate(demo_slop*[-2,1]) color("blue") Tile12();
1081   translate(demo_slop*[-2,0]) color("red")  Tile02();
1082   translate(demo_slop*[-2,1]) color("orange") Tile11();
1083   translate(demo_slop*[-2,0]) color("purple") Tile01();
1084   translate(demo_slop*[-3,1]) color("blue")   Tile10();
1085   translate(demo_slop*[-3,0]) color("red")    Tile00();
1086   %Machine();
1087   // Can also do this, to print reference sheet:
1088   //  load this into openscad
1089   //  select Ctrl-4 view, view all, scale appropriately
1090   //  import sewing-table,Demo-flat.png
1091   //  pngtopnm <sewing-table,Demo-flat.png | ppmbrighten -s -50 -v +100 >t.pnm
1092   //  lpr t.pnm
1093 }
1094
1095 //TestPiece1();
1096 //TestPiece2();
1097 //Demo();
1098
1099 //Machine_NewRearProfile();
1100 //Machine_NewRearCurve();
1101 //Machine_NewFrontProfile();
1102 //Machine_NewEndProfile();
1103 //Machine_NewEndProfileDemo();
1104 //Machine_Curves();
1105 //Machine();
1106 //FitTest();
1107 //MachineEnvelope();