poster-tube-lid.scad

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4
   5 coarse = false;
   6
   7 main_dia = 71.2 + 0.50 - 2.26;
   8 top_thick_middle = 4;
   9 top_thick_by_oring = 3.0;
  10 top_middle_dr = 11;
  11
  12 main_cnr = 6.0;
  13
  14 min_wall = 3;
  15
  16 rivet_posn = 6.0 + 0.30;
  17 rivet_thick = 1.67;
  18 rivet_width = 4.15 + 1.0;
  19 rivet_tall = 5.51 + 1.49;
  20
  21 over_rivet_wall = 1.0;
  22 side_rivet_gap = 1.5;
  23 inside_rivet_gap = 1.5;
  24
  25 bayo_interf = 0.30;
  26 bayo_behind = 3.5;
  27 bayo_interf_width = 2.0;
  28 bayo_interf_slope = 0.5;
  29
  30 oring_thick = 5.0;
  31 oring_bore = 62.0;
  32
  33 oring_upper_embed_angle = 80;
  34 oring_compress = 0.1; // proportion
  35 oring_compress_more = 0.2;
  36
  37 oring_rm_beside = 8;
  38 oring_rm_scale = 2.0;
  39 oring_rm_angle = 20;
  40
  41 side_taper = 1.0;
  42
  43 bayo_gap = 6.0;
  44
  45 bayo_entry = bayo_behind/3;
  46
  47 bayo_slice_size = coarse ? 5 : 1;
  48
  49 brace_hole_width = 1.0;
  50 brace_above_below = 1.2;
  51 brace_end_shorter = 0.3;
  52
  53 jig_thick = 1.4;
  54 jig_hole_dia = 3.0;
  55 jig_rim = 5;
  56 jig_mark = 5;
  57
  58 strap_hoop_thick = 6;
  59 strap_hoop_inside = 10;
  60 strap_hoop_strlen = 10;
  61 strap_hoop_elevation = 45;
  62
  63 sm_inner_circum = 218 - 1.90 - 1.00 - 0.50;
  64 sm_main_thick = 2.0;
  65 sm_main_width = 20;
  66
  67 sm_bolt_dia = 3.5 + 0.1;
  68 sm_bolt_shaft = 21.9;
  69 sm_bolt_head_dia = 6.94 + 1.0;
  70 sm_bolt_head_thick = 2.14;
  71 sm_bolt_nut_width = 5.89 + 0.25;
  72 sm_bolt_nut_thick = 3.68;
  73 sm_bolt_tighten_allow = 2.0;
  74
  75 sm_bolt_y_clear = 0.75;
  76 sm_bolt_y_over = 0.5;
  77
  78 sm_closure_cnr = 3.0;
  79
  80 catch_stalk_h = 3;
  81 catch_stalk_len = 50;
  82 catch_stalk_th = 3;
  83
  84 catch_pin_slop = 0.25; // each side, and above
  85 catch_pin_slop_x_extra = 0.0; // only on one side
  86 catch_stalk_above_gap = 1.5;
  87 catch_stalk_eff_bend_rad = catch_stalk_len * 0.75;
  88
  89 catch_stalk_base_width = 15;
  90
  91 catch_knob_dia = 6;
  92 catch_knob_above_gap = 8;
  93 catch_knob_height = 6;
  94
  95 catch_stalk_below_gap = 1.0;
  96 catch_stalk_beside_gap = 2.0;
  97 catch_pin_gap = 0.5;
  98 catch_hook_slope = 0.15;
  99
 100 // calculated
 101
 102 TAU = PI*2;
 103
 104 bayo_entry_x = bayo_entry;
 105 bayo_entry_z = bayo_entry;
 106 bayo_inramp_x = bayo_entry;
 107 bayo_inramp_z = bayo_entry;
 108
 109 oring_mid_dia = oring_bore + oring_thick;
 110 oring_outer_dia = oring_mid_dia + oring_thick;
 111
 112 oring_oblate = (1 - oring_compress);
 113
 114 oring_y_rad = oring_thick/2 * oring_oblate;
 115 oring_x_rad = oring_thick/2 / oring_oblate;
 116
 117 by_oring_z = oring_y_rad * (1 + cos(oring_upper_embed_angle));
 118
 119 side_height = rivet_posn + bayo_behind + rivet_thick/2;
 120 side_thick = rivet_tall + over_rivet_wall;
 121
 122 top_z = top_thick_by_oring + oring_y_rad + by_oring_z;
 123
 124 middle_bot_z = top_z - top_thick_middle;
 125
 126 bayo_entry = bayo_behind / 3.0;
 127 bayo_top_z = bayo_behind + bayo_gap;
 128
 129 bayo_nom_rad = main_dia/2 + side_thick;
 130 bayo_real_rad = main_dia/2 + rivet_tall;
 131
 132 rivet_entry_width = rivet_width + side_rivet_gap;
 133
 134 jig_mark_rad = jig_mark + main_dia/2 + jig_thick;
 135
 136 handling_dia = oring_bore + oring_thick*2 + min_wall*2;
 137 handling_angle = 45;
 138
 139 sm_inner_rad = (sm_inner_circum + sm_bolt_tighten_allow/2) / TAU;
 140 sm_outer_rad = sm_inner_rad + sm_main_thick;
 141
 142 smc_pos = [ 0, sm_inner_rad, 0 ];
 143
 144 smc_bolt_nut_dia = sm_bolt_nut_width / cos(30);
 145 smc_bolt_nut_eff_thick = sm_bolt_nut_thick + sm_bolt_tighten_allow;
 146
 147 smc_bolt_y = sm_bolt_dia/2 + sm_bolt_y_clear;
 148 smc_max_y = smc_bolt_y + sm_bolt_y_over
 149   + max(sm_bolt_head_dia/2, smc_bolt_nut_dia/2);
 150 smc_cnr_c_x = sm_bolt_shaft/2 - sm_closure_cnr
 151   + sm_bolt_head_thick/2 + smc_bolt_nut_eff_thick/2;
 152
 153 catch_cr = catch_knob_dia/2 + catch_stalk_beside_gap;
 154 catch_strap_width = sm_main_width;
 155 catch_strap_thick = sm_main_thick;
 156 catch_stalk_end_h = catch_stalk_h;
 157 catch_pin_width = (rivet_entry_width * sm_inner_rad / bayo_nom_rad)
 158                    - catch_pin_gap;
 159
 160 echo("R ", sm_inner_rad, bayo_real_rad, bayo_nom_rad);
 161
 162 $fs= coarse ? 2.5 : 0.5;
 163 $fa= coarse ? 5 : 1;
 164
 165 include <poster-tube-lid-parametric.scad>
 166
 167 // bayonet definition
 168
 169 bayo_a = [ bayo_entry_x, 0 ];
 170 bayo_p = [ 0, bayo_entry_z ];
 171 bayo_n = [ 0, bayo_behind-bayo_inramp_z ];
 172 bayo_m = [ bayo_inramp_x, bayo_behind ];
 173 bayo_l = bayo_m + bayo_interf * [ 1/bayo_interf_slope,  1 ];
 174 bayo_k = bayo_l + [ bayo_interf_width, 0 ];
 175 bayo_j = bayo_k + bayo_interf * [ 1/bayo_interf_slope, -1 ];
 176 bayo_i = bayo_j + [ rivet_width + inside_rivet_gap, 0 ];
 177 bayo_h = [ bayo_i[0], bayo_behind + bayo_gap + bayo_interf ];
 178 bayo_g = [ bayo_m[0] - rivet_width, bayo_h[1] ];
 179
 180 bayo_e = [-bayo_p[0], bayo_p[1]] - [rivet_entry_width,0];
 181 bayo_d = [-bayo_a[0], bayo_a[1]] - [rivet_entry_width,0];
 182 bayo_c = bayo_d + [0,-5];
 183 bayo_b = bayo_a + [0,-5];
 184
 185 bayo_f = [ bayo_e[0], bayo_g[1] + (bayo_e[0] - bayo_g[0]) ];
 186
 187 bayo_polygon = [ bayo_a,
 188                  bayo_b,
 189                  bayo_c,
 190                  bayo_d,
 191                  bayo_e,
 192                  bayo_f,
 193                  bayo_g,
 194                  bayo_h,
 195                  bayo_i,
 196                  bayo_j,
 197                  bayo_k,
 198                  bayo_l,
 199                  bayo_m,
 200                  bayo_n,
 201                  bayo_p ];
 202
 203 echo(bayo_polygon);
 204
 205 // CATCH
 206
 207 //cppy6 = -catch_strap_width * 2/3;
 208
 209 cppxC = 0.41 * sm_inner_rad * TAU;
 210
 211 // catch pin
 212
 213 cpp_adj = (bayo_n[0] - bayo_f[0]) * (1 - sm_inner_rad / bayo_nom_rad);
 214 // radius scaling due to nom and actual radius difference in
 215 // bayo entry construction
 216
 217 cppa = bayo_f + [1,-1] * catch_pin_slop + [1,0] * cpp_adj;
 218 cppb = bayo_g + [1,-1] * catch_pin_slop + [1,0] * cpp_adj;
 219 cppd = [ bayo_n[0]
 220          - catch_pin_slop - catch_pin_slop_x_extra,
 221          -catch_stalk_above_gap ];
 222 cppc = [ cppd[0], cppb[1] ];
 223 cpph = cppd + [0,-1] * catch_stalk_h;
 224 cppe = cppd + [0,-1] * (catch_knob_above_gap + catch_knob_dia/2);
 225 cppf = [ cppa[0], cppe[1] ];
 226 cppg = [ cppa[0], cpph[1] ];
 227 cppB = 0.5 * (cppf + cppe);
 228
 229 echo("RR", sm_inner_rad / bayo_nom_rad);
 230
 231 // catch assembly depression below pin
 232
 233 cppy6 = cppB[1] - (catch_knob_dia/2
 234                    + (cppc[1] - cppd[1])
 235                    + catch_stalk_below_gap);
 236 cpp7 = [ cppB[0], cppy6 + catch_cr ];
 237 cpp11 = cpp7 + [1,0] * catch_cr;
 238 cppy9 = cppy6 + catch_strap_width * 1/3;
 239 cpp9 = [ cpp7[0] + catch_cr * 2, cppy9 ];
 240 cpp8 = cpp9 + [0,-1] * catch_cr;
 241 cpp10 = cpp8 + [-1,0] * catch_cr;
 242 cppC = [ cppxC, cpp9[1] ];
 243 cppD = cppC + [0,-1] * catch_strap_width;
 244
 245 // catch assembly stalk and so on
 246
 247 cppF = [ cppg[0] - catch_stalk_eff_bend_rad, cppd[1] ];
 248 cpp4 = [ cppg[0] - catch_stalk_len, cpph[1] ] + [1,-1] * catch_cr;
 249 cpp5 = [ cpp4[0], cppC[1] + catch_cr ];
 250 cpp2 = cpp5 + [-1,0] * (catch_cr * 2 + catch_stalk_base_width);
 251 cpp2r = cpp2 + [1,0] * catch_cr;
 252 cpp2d = cpp2 + [0,-1] * catch_cr;
 253 cpp3 = [ cpp2[0] + catch_cr * 2, cppd[1] - catch_cr ];
 254 cppA = [ -cppxC, cpp9[1] ];
 255 cppE = [ cppA[0], cppD[1] ];
 256
 257 catch_assembly_dy = -cppy9 + catch_strap_width;
 258
 259
 260 module MainProfile(){
 261   main_cnr_pos = [ side_thick, top_z ] - [1,1]*main_cnr;
 262   difference(){
 263     union(){
 264       translate(main_cnr_pos){
 265         intersection(){
 266           difference(){
 267             circle(r = main_cnr);
 268             circle(r = main_cnr * 0.5);
 269           }
 270           square([10,10]);
 271         }
 272       }
 273       polygon([[ -top_middle_dr,        middle_bot_z      ],
 274                [ -top_middle_dr,        top_z             ],
 275                [ main_cnr_pos[0],       top_z             ],
 276                [ side_thick,            main_cnr_pos[1]   ],
 277                [ side_thick,            -side_height      ],
 278                [ side_taper,            -side_height      ],
 279                [ 0,                     -rivet_posn       ],
 280                [ 0,                     by_oring_z        ],
 281                [ -oring_x_rad,          by_oring_z        ],
 282                ],
 283               convexity=10);
 284     }
 285     translate([ oring_mid_dia/2 - main_dia/2, 0 ])
 286       hull(){
 287       translate([ 0, oring_y_rad ])
 288         scale([ 1/oring_oblate * (oring_compress_more+1) , oring_oblate ])
 289         circle(oring_thick/2);
 290       translate([ 0, oring_y_rad*2 - oring_thick/2 ])
 291         circle(oring_thick/2);
 292     }
 293   }
 294 }
 295
 296 module StrapHoopProfile(){
 297   circle(r = strap_hoop_thick/2);
 298 }
 299
 300 module StrapHoop(){ ////toplevel
 301   bigrad = strap_hoop_inside/2 + strap_hoop_thick/2;
 302   extralen = strap_hoop_thick * 5;
 303
 304   intersection(){
 305     rotate([strap_hoop_elevation, 0,0]){
 306       for (x= [ -1, +1 ] * bigrad) {
 307         translate([x, -extralen, 0])
 308           rotate([-90,0,0])
 309           linear_extrude(height= extralen + strap_hoop_strlen + 0.1,
 310                          convexity=10)
 311           StrapHoopProfile();
 312       }
 313       translate([0, strap_hoop_strlen, 0]){
 314         intersection(){
 315           rotate_extrude(convexity=10)
 316             translate([bigrad, 0,0])
 317             StrapHoopProfile();
 318           translate([0,50,0])
 319             cube([100,100,100], center=true);
 320         }
 321       }
 322     }
 323     translate([0, 50, 0])
 324       cube(100, center=true);
 325   }
 326 }
 327
 328 module RotateProjectSlice(offset, slice_size, nom_rad, real_rad){
 329   // nom_rad > real_rad
 330   rotate([0,0, atan2(offset, nom_rad) ]){
 331     intersection(){
 332       translate([-offset, -10, 0])
 333         rotate([90,0,0])
 334         linear_extrude(height= nom_rad*2)
 335         children(0);
 336       translate([0,0, -25])
 337         cylinder(h=50, r= real_rad);
 338       translate([0,0, -25])
 339         linear_extrude(height= 50)
 340         polygon([ [ 0,0 ],
 341                   [ -slice_size, -real_rad*2 ],
 342                   [ +slice_size, -real_rad*2 ] ]);
 343     }
 344   }
 345 }
 346
 347 module RotateProject(x_min, x_max, slice_size, nom_rad, real_rad){
 348   offs = [ for (i=[ x_min :
 349                     slice_size :
 350                     x_max + slice_size ]) i ];
 351   echo (offs);
 352   for (off=offs)
 353     RotateProjectSlice(off, slice_size, nom_rad, real_rad)
 354     children(0);
 355 }
 356
 357 module BayonetCutout(){
 358   RotateProject(bayo_c[0], bayo_i[0], bayo_slice_size,
 359                 bayo_nom_rad,
 360                 bayo_real_rad)
 361     translate([-0.5 * (bayo_a[0] + bayo_d[0]), 0])
 362     polygon(bayo_polygon, convexity=10);
 363 }
 364
 365 module ProfilesDemo(){ ////toplevel
 366   translate([-10,0]) MainProfile();
 367   translate([+10, -side_height]) polygon(bayo_polygon, convexity=10);
 368 }
 369
 370 module LimitForHandling(){ ////toplevel
 371   hull() for (r=[0,180])
 372     rotate([0,0,r]) {
 373       for (rs=[-1,+1]) {
 374         for (xd=[0,1]) {
 375           rotate([0,0, rs * handling_angle/2]) {
 376             translate([rs * xd * main_dia/2 * tan(handling_angle/2),
 377                        main_dia/2 + side_thick - main_cnr,
 378                        top_z - main_cnr]) {
 379               mirror([0,0,1])
 380                 cylinder(r= main_cnr, h=50);
 381               sphere(main_cnr);
 382             }
 383           }
 384         }
 385       }
 386     }
 387   hull() rotate_extrude(){
 388     translate([ handling_dia/2 - main_cnr, top_z - main_cnr ]) {
 389       circle(r = main_cnr);
 390       mirror([0,1]) square([ main_cnr, 50 ]);
 391     }
 392   }
 393   //cylinder(r= handling_dia/2, h=20);
 394 }
 395
 396 module Cover(){ ////toplevel
 397   render() difference(){
 398     intersection(){
 399       union(){
 400         rotate_extrude(convexity=10)
 401           translate([main_dia/2, 0])
 402           MainProfile();
 403         translate([0,0, middle_bot_z])
 404           cylinder(h= top_thick_middle, r = main_dia/2 - top_middle_dr + 1);
 405       }
 406       LimitForHandling();
 407     }
 408     for (r=[0,180]){
 409       rotate([0,0, r])
 410         translate([0,0, -side_height])
 411         BayonetCutout();
 412       rotate([0,0, r + asin((-oring_rm_beside) / (main_dia/2))])
 413         translate([0,
 414                    oring_mid_dia/2 + oring_thick/4 * oring_rm_scale,
 415                    oring_y_rad * 1.5])
 416         rotate([-oring_rm_angle, 0, 0])
 417         mirror([0,0,1])
 418         cylinder(r = oring_thick/4 * oring_rm_scale, h=20);
 419     }
 420     for (r=[0 : 60 : 179]) {
 421       rotate([0,0, r]) {
 422         height = top_thick_middle - brace_above_below*2;
 423         translate([0,0, middle_bot_z + brace_above_below + height/2 ])
 424         cube(center=true, [ oring_bore - brace_end_shorter,
 425                             brace_hole_width, height ]);
 426       }
 427     }
 428   }
 429   for (r=[0,180])
 430     rotate([0,0,r])
 431       translate([-implheadcup_large_dia * .5 - implheadcup_thick/2,
 432                  -implheadcup_large_dia * .0,
 433                  middle_bot_z + 0.1])
 434       ImplHeadCup();
 435 //  translate(strap_hoop_thick * [-0.5, 0, +1])
 436 //    translate([handling_dia/2, 0, -side_height])
 437 //    rotate([0,180,0]) rotate([0,0,90])
 438 //    StrapHoop();
 439 }
 440
 441 module SavingHole(){
 442   translate([0,0, -10])
 443     cylinder(r= main_dia/2 - jig_rim, h=20);
 444 }
 445
 446 module Jig(){ ////toplevel
 447   difference(){
 448     union(){
 449       translate([0,0, -side_height]){
 450         cylinder(r= main_dia/2 + jig_thick, h= side_height + jig_thick);
 451       }
 452       translate([-jig_mark_rad, 0, jig_thick - jig_mark])
 453         cube([jig_mark_rad*2, jig_mark, jig_mark]);
 454     }
 455     translate([0,0, -side_height-1])
 456       cylinder(r= main_dia/2, h= side_height + 1);
 457     SavingHole();
 458     translate([0,0, -rivet_posn])
 459       rotate([90, 0,0])
 460       translate([0,0, -100])
 461       cylinder(r= jig_hole_dia/2, h = 200);
 462   }
 463 }
 464
 465 module CoverTest2(){ ////toplevel
 466   difference(){
 467     Cover();
 468     SavingHole();
 469   }
 470 }
 471
 472 module CoverTest1(){ ////toplevel
 473   difference(){
 474     CoverTest2();
 475     difference(){
 476       for (r= [ 40, 147 ]){
 477         rotate([0,0, r]){
 478           translate([0,0, -10]) {
 479             cube([ main_dia*3, main_dia * .53, 18], center=true);
 480           }
 481         }
 482       }
 483 //      translate([ 50, 0, 0 ])
 484 //      cube([ 100,
 485 //             strap_hoop_inside + strap_hoop_thick*2 + 1,
 486 //             100 ],
 487 //           center=true);
 488     }
 489   }
 490 }
 491
 492 module ImplHeadCupTest(){ ////toplevel
 493   for (r=[0,180])
 494     rotate([0,0,r])
 495       translate([-17,0,0])
 496       ImplHeadCup();
 497 }
 498
 499 module SomeStrap(){
 500   // children(0) is to add, (1) subtract
 501   difference(){
 502     union(){
 503       cylinder(r=sm_outer_rad, h=sm_main_width);
 504       StrapMountProtrusion(smc_cnr_c_x + sm_closure_cnr,
 505                            smc_max_y,
 506                            sm_closure_cnr);
 507       children(0);
 508     }
 509     translate([0,0,-1])
 510       cylinder(r=sm_inner_rad, h=sm_main_width+2);
 511     translate(smc_pos)
 512       StrapMountBolt(10);
 513     translate(smc_pos)
 514       cube([ sm_bolt_tighten_allow, 40,100 ], center=true);
 515     children(1);
 516   }
 517 }
 518
 519 module StrapMountBolt(l_delta){ ///toplevel
 520   // positioned relative to smc_pos
 521   translate([(smc_bolt_nut_eff_thick - sm_bolt_head_thick)/2,
 522              smc_bolt_y,
 523              sm_main_width/2]){
 524     translate([ -sm_bolt_shaft/2-1, 0,0 ]){
 525       rotate([0,90,0]) cylinder(r= sm_bolt_dia/2, h= sm_bolt_shaft+2);
 526     }
 527     translate([ -sm_bolt_shaft/2, 0,0 ])
 528       rotate([0,-90,0])
 529       cylinder($fn=6, r=smc_bolt_nut_dia/2,
 530                h=smc_bolt_nut_eff_thick + l_delta);
 531     translate([ sm_bolt_shaft/2, 0,0 ])
 532       rotate([0,90,0])
 533       cylinder(r=sm_bolt_head_dia/2, h=sm_bolt_head_thick + l_delta);
 534   }
 535 }
 536
 537 module StrapMountProtrusion(half_x, max_y, cnr){
 538   translate(smc_pos){
 539     linear_extrude(height=sm_main_width, convexity=10){
 540       hull(){
 541         for (m = [0,1]) mirror([m,0,0]) {
 542           translate([-(half_x - cnr), max_y - cnr])
 543             circle(r=cnr);
 544           translate([-half_x, -sm_inner_rad])
 545             square([1,1]);
 546         }
 547       }
 548     }
 549   }
 550 }
 551
 552 module StrapMount(){ ////toplevel
 553   SomeStrap(){
 554     rotate([0,0,180]){
 555       StrapMountProtrusion(strap_hoop_inside/2 + strap_hoop_thick,
 556                            strap_hoop_thick,
 557                            sm_closure_cnr);
 558       translate(smc_pos +
 559                 [0,0, sm_main_width] +
 560                 strap_hoop_thick * [ 0, 0.5, -1.0 ])
 561         StrapHoop();
 562     }
 563     union(){ };
 564   }
 565 }
 566
 567 module CatchAssemblyCoreProfile(){
 568   difference(){
 569     union(){
 570       hull(){
 571         translate(cpp3) circle(r= catch_cr);
 572         polygon([ cpp3,
 573                   cpp2r,
 574                   cpp5,
 575                   cpph,
 576                   cppd
 577                   ]);
 578       }
 579       polygon([cppD,
 580                cppC,
 581                cpp9,
 582                cpp10,
 583                cpp11,
 584                cpp4,
 585                cpp2r,
 586                cpp2d,
 587                cppA,
 588                cppE
 589                ]);
 590       translate(cpp8) circle(r= catch_cr);
 591     }
 592     hull(){
 593       translate(cpp4) circle(r= catch_cr);
 594       translate(cpp5) circle(r= catch_cr);
 595       translate(cpp7) circle(r= catch_cr);
 596       polygon([cpp4,
 597                cppg,
 598                cpph,
 599                cpp10,
 600                cpp11,
 601                ]);
 602     }
 603     translate(cpp2) circle(r= catch_cr);
 604   }
 605 }
 606
 607 module CatchHeadProfile(){
 608   intersection(){
 609     translate(cppF){
 610       difference(){
 611         circle(r = dist2d(cppF, cppd));
 612         //circle(r = dist2d(cppF, cppa));
 613       }
 614     }
 615     polygon([ cppa,
 616               cppg,
 617               cpph,
 618               cppd,
 619               cppc,
 620               cppb ]);
 621   }
 622   polygon([ cppd,
 623             cppg,
 624             cppf,
 625             cppe,
 626             cpph ]);
 627 }
 628
 629
 630 module CatchCore(){ /////toplevel
 631   linear_extrude(height=catch_strap_thick, convexity=10)
 632     CatchAssemblyCoreProfile();
 633
 634   linear_extrude(height=catch_strap_thick, convexity=10)
 635     CatchHeadProfile();
 636
 637   translate(concat(cppB,[0])) hull(){
 638     translate([0,0, catch_knob_height - catch_knob_dia/2])
 639       sphere(r = catch_knob_dia/2);
 640     cylinder(r = catch_knob_dia/2, h = 0.1);
 641   }
 642 }
 643
 644 module CatchPreDistort(){ /////toplevel
 645   scale(100 / sm_inner_rad)
 646     rotate([90,0,0])
 647     CatchCore();
 648 }
 649
 650 module CatchAssembly(){ /////toplevel
 651   rotate([0,0, -(cppe[0] + cppB[0] + catch_pin_slop) / sm_inner_rad * 360/TAU])
 652     translate([0,0, catch_assembly_dy])
 653     scale(sm_inner_rad / 100)
 654     import(str("poster-tube-lid,CatchPostDistort-fa",
 655                (coarse ? 20 : 3),
 656                ".stl"),
 657            convexity=20);
 658
 659   SomeStrap(){
 660     union(){ }
 661     union(){
 662       translate([-200, -200, -200])
 663         cube([400, 200, 400]);
 664     }
 665   }
 666 }
 667
 668 module CatchDemo(){ /////toplevel
 669   color("blue") translate([0,0,
 670                            -catch_assembly_dy
 671              ])
 672     CatchAssembly();
 673   translate([0,0,+side_height
 674              ])
 675     Cover();
 676 }
 677
 678 module CatchDemoS(){ /////toplevel
 679   color("blue") translate([0,0,
 680              -catch_assembly_dy
 681              ])
 682     CatchAssembly();
 683   intersection(){
 684     translate([0,0,+side_height
 685                ])
 686       Cover();
 687     mirror([0,1,0]) translate([-250,33,0]) cube([500,500,500]);
 688   }
 689   color("black")
 690     translate([0,-33,0])
 691     cube([6.15, 2,2], center=true);
 692 }
 693
 694 module CatchPinProfileDemo(){ /////toplevel
 695   echo("G ",
 696        cpp2[0] - cpp1[0],
 697        bayo_n[0] - bayo_e[0]);
 698   color("blue") translate([0,0,
 699                            +1,
 700              ]) {
 701     CatchAssemblyCoreProfile();
 702     CatchHeadProfile();
 703   }
 704   polygon(bayo_polygon, convexity=10);
 705 }
 706
 707 //ProfilesDemo();
 708 //BayonetCutout();
 709 //MainProfile();
 710 //Cover();
 711 //Jig();
 712 //CoverTest();