poster-tube-lid.scad

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4
   5 coarse = false;
   6
   7 main_dia = 71.2 + 0.50 - 2.26;
   8 top_thick_middle = 4;
   9 top_thick_by_oring = 3.0;
  10 top_middle_dr = 11;
  11
  12 main_cnr = 6.0;
  13
  14 min_wall = 3;
  15
  16 rivet_posn = 6.0 + 0.30;
  17 rivet_thick = 1.67;
  18 rivet_width = 4.15 + 1.0;
  19 rivet_tall = 5.51 + 1.49;
  20
  21 over_rivet_wall = 1.0;
  22 side_rivet_gap = 1.5;
  23 inside_rivet_gap = 1.5;
  24
  25 bayo_interf = 0.30;
  26 bayo_behind = 3.5;
  27 bayo_interf_width = 2.0;
  28 bayo_interf_slope = 0.5;
  29
  30 oring_thick = 5.0;
  31 oring_bore = 62.0;
  32
  33 oring_upper_embed_angle = 80;
  34 oring_compress = 0.1; // proportion
  35 oring_compress_more = 0.2;
  36
  37 oring_rm_beside = 8;
  38 oring_rm_scale = 2.0;
  39 oring_rm_angle = 20;
  40
  41 side_taper = 1.0;
  42
  43 bayo_gap = 6.0;
  44
  45 bayo_entry = bayo_behind/3;
  46
  47 bayo_slice_size = coarse ? 5 : 1;
  48
  49 brace_hole_width = 1.0;
  50 brace_above_below = 1.2;
  51 brace_end_shorter = 0.3;
  52
  53 jig_thick = 1.4;
  54 jig_hole_dia = 3.0;
  55 jig_rim = 5;
  56 jig_mark = 5;
  57
  58 strap_hoop_thick = 6;
  59 strap_hoop_inside = 10;
  60 strap_hoop_strlen = 10;
  61 strap_hoop_elevation = 45;
  62
  63 sm_inner_circum = 218 - 1.90 - 1.00 - 0.50;
  64 sm_main_thick = 2.0;
  65 sm_main_width = 20;
  66
  67 sm_bolt_dia = 3.5 + 0.1;
  68 sm_bolt_shaft = 21.9;
  69 sm_bolt_head_dia = 6.94 + 1.0;
  70 sm_bolt_head_thick = 2.14;
  71 sm_bolt_nut_width = 5.89 + 0.25;
  72 sm_bolt_nut_thick = 3.68;
  73 sm_bolt_tighten_allow = 2.0;
  74
  75 sm_bolt_y_clear = 0.75;
  76 sm_bolt_y_over = 0.5;
  77
  78 sm_closure_cnr = 3.0;
  79
  80 catch_stem_h = 3;
  81 catch_stem_len = 50;
  82 catch_stem_th = 3;
  83
  84 catch_pin_slop = 0.25; // each side, and above
  85 catch_stalk_above_gap = 1.5;
  86 catch_stalk_eff_bend_rad = catch_stem_len * 0.75;
  87
  88 catch_stalk_base_width = 15;
  89
  90 catch_knob_dia = 6;
  91 catch_knob_above_gap = 8;
  92 catch_knob_height = 6;
  93
  94 catch_stem_below_gap = 1.0;
  95 catch_stem_beside_gap = 2.0;
  96 catch_pin_gap = 0.5;
  97 catch_hook_slope = 0.15;
  98
  99 // calculated
 100
 101 TAU = PI*2;
 102
 103 bayo_entry_x = bayo_entry;
 104 bayo_entry_z = bayo_entry;
 105 bayo_inramp_x = bayo_entry;
 106 bayo_inramp_z = bayo_entry;
 107
 108 oring_mid_dia = oring_bore + oring_thick;
 109 oring_outer_dia = oring_mid_dia + oring_thick;
 110
 111 oring_oblate = (1 - oring_compress);
 112
 113 oring_y_rad = oring_thick/2 * oring_oblate;
 114 oring_x_rad = oring_thick/2 / oring_oblate;
 115
 116 by_oring_z = oring_y_rad * (1 + cos(oring_upper_embed_angle));
 117
 118 side_height = rivet_posn + bayo_behind + rivet_thick/2;
 119 side_thick = rivet_tall + over_rivet_wall;
 120
 121 top_z = top_thick_by_oring + oring_y_rad + by_oring_z;
 122
 123 middle_bot_z = top_z - top_thick_middle;
 124
 125 bayo_entry = bayo_behind / 3.0;
 126 bayo_top_z = bayo_behind + bayo_gap;
 127
 128 bayo_nom_rad = main_dia/2 + side_thick;
 129 bayo_real_rad = main_dia/2 + rivet_tall;
 130
 131 rivet_entry_width = rivet_width + side_rivet_gap;
 132
 133 jig_mark_rad = jig_mark + main_dia/2 + jig_thick;
 134
 135 handling_dia = oring_bore + oring_thick*2 + min_wall*2;
 136 handling_angle = 45;
 137
 138 sm_inner_rad = (sm_inner_circum + sm_bolt_tighten_allow/2) / TAU;
 139 sm_outer_rad = sm_inner_rad + sm_main_thick;
 140
 141 smc_pos = [ 0, sm_inner_rad, 0 ];
 142
 143 smc_bolt_nut_dia = sm_bolt_nut_width / cos(30);
 144 smc_bolt_nut_eff_thick = sm_bolt_nut_thick + sm_bolt_tighten_allow;
 145
 146 smc_bolt_y = sm_bolt_dia/2 + sm_bolt_y_clear;
 147 smc_max_y = smc_bolt_y + sm_bolt_y_over
 148   + max(sm_bolt_head_dia/2, smc_bolt_nut_dia/2);
 149 smc_cnr_c_x = sm_bolt_shaft/2 - sm_closure_cnr
 150   + sm_bolt_head_thick/2 + smc_bolt_nut_eff_thick/2;
 151
 152 catch_cr = catch_knob_dia/2 + catch_stem_beside_gap;
 153 catch_strap_width = sm_main_width;
 154 catch_strap_thick = sm_main_thick;
 155 catch_stem_end_h = catch_stem_h;
 156 catch_pin_width = (rivet_entry_width * sm_inner_rad / bayo_nom_rad)
 157                    - catch_pin_gap;
 158
 159 echo("R ", sm_inner_rad, bayo_real_rad, bayo_nom_rad);
 160
 161 $fs= coarse ? 2.5 : 0.5;
 162 $fa= coarse ? 5 : 1;
 163
 164 include <poster-tube-lid-parametric.scad>
 165
 166 // bayonet definition
 167
 168 bayo_a = [ bayo_entry_x, 0 ];
 169 bayo_p = [ 0, bayo_entry_z ];
 170 bayo_n = [ 0, bayo_behind-bayo_inramp_z ];
 171 bayo_m = [ bayo_inramp_x, bayo_behind ];
 172 bayo_l = bayo_m + bayo_interf * [ 1/bayo_interf_slope,  1 ];
 173 bayo_k = bayo_l + [ bayo_interf_width, 0 ];
 174 bayo_j = bayo_k + bayo_interf * [ 1/bayo_interf_slope, -1 ];
 175 bayo_i = bayo_j + [ rivet_width + inside_rivet_gap, 0 ];
 176 bayo_h = [ bayo_i[0], bayo_behind + bayo_gap + bayo_interf ];
 177 bayo_g = [ bayo_m[0] - rivet_width, bayo_h[1] ];
 178
 179 bayo_e = [-bayo_p[0], bayo_p[1]] - [rivet_entry_width,0];
 180 bayo_d = [-bayo_a[0], bayo_a[1]] - [rivet_entry_width,0];
 181 bayo_c = bayo_d + [0,-5];
 182 bayo_b = bayo_a + [0,-5];
 183
 184 bayo_f = [ bayo_e[0], bayo_g[1] + (bayo_e[0] - bayo_g[0]) ];
 185
 186 bayo_polygon = [ bayo_a,
 187                  bayo_b,
 188                  bayo_c,
 189                  bayo_d,
 190                  bayo_e,
 191                  bayo_f,
 192                  bayo_g,
 193                  bayo_h,
 194                  bayo_i,
 195                  bayo_j,
 196                  bayo_k,
 197                  bayo_l,
 198                  bayo_m,
 199                  bayo_n,
 200                  bayo_p ];
 201
 202 echo(bayo_polygon);
 203
 204 // CATCH
 205
 206 //cppy6 = -catch_strap_width * 2/3;
 207
 208 cppxC = 0.41 * sm_inner_rad * TAU;
 209
 210 // catch pin
 211
 212 cppa = bayo_f + [1,-1] * catch_pin_slop;
 213 cppb = bayo_g + [1,-1] * catch_pin_slop;
 214 cppd = [ bayo_n[0] - catch_pin_slop, -catch_stalk_above_gap ];
 215 cppc = [ cppd[0], cppb[1] ];
 216 cpph = cppd + [0,-1] * catch_stem_h;
 217 cppe = cppd + [0,-1] * (catch_knob_above_gap + catch_knob_dia/2);
 218 cppf = [ cppa[0], cppe[1] ];
 219 cppg = [ cppa[0], cpph[1] ];
 220 cppB = 0.5 * (cppf + cppe);
 221
 222 // catch assembly depression below pin
 223
 224 cppy6 = cppB[1] - (catch_knob_dia/2
 225                    + (cppc[1] - cppd[1])
 226                    + catch_stem_below_gap);
 227 cpp7 = [ cppB[0], cppy6 + catch_cr ];
 228 cpp11 = cpp7 + [1,0] * catch_cr;
 229 cppy9 = cppy6 + catch_strap_width * 1/3;
 230 cpp9 = [ cpp7[0] + catch_cr * 2, cppy9 ];
 231 cpp8 = cpp9 + [0,-1] * catch_cr;
 232 cpp10 = cpp8 + [-1,0] * catch_cr;
 233 cppC = [ cppxC, cpp9[1] ];
 234 cppD = cppC + [0,-1] * catch_strap_width;
 235
 236 // catch assembly stalk and so on
 237
 238 cppF = [ cppg[0] - catch_stalk_eff_bend_rad, cppd[1] ];
 239 cpp4 = [ cppg[0] - catch_stem_len, cpph[1] ] + [1,-1] * catch_cr;
 240 cpp5 = [ cpp4[0], cppC[1] + catch_cr ];
 241 cpp2 = cpp5 + [-1,0] * (catch_cr * 2 + catch_stalk_base_width);
 242 cpp2r = cpp2 + [1,0] * catch_cr;
 243 cpp2d = cpp2 + [0,-1] * catch_cr;
 244 cpp3 = [ cpp2[0] + catch_cr * 2, cppd[1] - catch_cr ];
 245 cppA = [ -cppxC, cpp9[1] ];
 246 cppE = [ cppA[0], cppD[1] ];
 247
 248 catch_assembly_dy = -cppy9 + catch_strap_width;
 249
 250
 251 module MainProfile(){
 252   main_cnr_pos = [ side_thick, top_z ] - [1,1]*main_cnr;
 253   difference(){
 254     union(){
 255       translate(main_cnr_pos){
 256         intersection(){
 257           difference(){
 258             circle(r = main_cnr);
 259             circle(r = main_cnr * 0.5);
 260           }
 261           square([10,10]);
 262         }
 263       }
 264       polygon([[ -top_middle_dr,        middle_bot_z      ],
 265                [ -top_middle_dr,        top_z             ],
 266                [ main_cnr_pos[0],       top_z             ],
 267                [ side_thick,            main_cnr_pos[1]   ],
 268                [ side_thick,            -side_height      ],
 269                [ side_taper,            -side_height      ],
 270                [ 0,                     -rivet_posn       ],
 271                [ 0,                     by_oring_z        ],
 272                [ -oring_x_rad,          by_oring_z        ],
 273                ],
 274               convexity=10);
 275     }
 276     translate([ oring_mid_dia/2 - main_dia/2, 0 ])
 277       hull(){
 278       translate([ 0, oring_y_rad ])
 279         scale([ 1/oring_oblate * (oring_compress_more+1) , oring_oblate ])
 280         circle(oring_thick/2);
 281       translate([ 0, oring_y_rad*2 - oring_thick/2 ])
 282         circle(oring_thick/2);
 283     }
 284   }
 285 }
 286
 287 module StrapHoopProfile(){
 288   circle(r = strap_hoop_thick/2);
 289 }
 290
 291 module StrapHoop(){ ////toplevel
 292   bigrad = strap_hoop_inside/2 + strap_hoop_thick/2;
 293   extralen = strap_hoop_thick * 5;
 294
 295   intersection(){
 296     rotate([strap_hoop_elevation, 0,0]){
 297       for (x= [ -1, +1 ] * bigrad) {
 298         translate([x, -extralen, 0])
 299           rotate([-90,0,0])
 300           linear_extrude(height= extralen + strap_hoop_strlen + 0.1,
 301                          convexity=10)
 302           StrapHoopProfile();
 303       }
 304       translate([0, strap_hoop_strlen, 0]){
 305         intersection(){
 306           rotate_extrude(convexity=10)
 307             translate([bigrad, 0,0])
 308             StrapHoopProfile();
 309           translate([0,50,0])
 310             cube([100,100,100], center=true);
 311         }
 312       }
 313     }
 314     translate([0, 50, 0])
 315       cube(100, center=true);
 316   }
 317 }
 318
 319 module RotateProjectSlice(offset, slice_size, nom_rad, real_rad){
 320   // nom_rad > real_rad
 321   rotate([0,0, atan2(offset, nom_rad) ]){
 322     intersection(){
 323       translate([-offset, -10, 0])
 324         rotate([90,0,0])
 325         linear_extrude(height= nom_rad*2)
 326         children(0);
 327       translate([0,0, -25])
 328         cylinder(h=50, r= real_rad);
 329       translate([0,0, -25])
 330         linear_extrude(height= 50)
 331         polygon([ [ 0,0 ],
 332                   [ -slice_size, -real_rad*2 ],
 333                   [ +slice_size, -real_rad*2 ] ]);
 334     }
 335   }
 336 }
 337
 338 module RotateProject(x_min, x_max, slice_size, nom_rad, real_rad){
 339   offs = [ for (i=[ x_min :
 340                     slice_size :
 341                     x_max + slice_size ]) i ];
 342   echo (offs);
 343   for (off=offs)
 344     RotateProjectSlice(off, slice_size, nom_rad, real_rad)
 345     children(0);
 346 }
 347
 348 module BayonetCutout(){
 349   RotateProject(bayo_c[0], bayo_i[0], bayo_slice_size,
 350                 bayo_nom_rad,
 351                 bayo_real_rad)
 352     translate([-0.5 * (bayo_a[0] + bayo_d[0]), 0])
 353     polygon(bayo_polygon, convexity=10);
 354 }
 355
 356 module ProfilesDemo(){ ////toplevel
 357   translate([-10,0]) MainProfile();
 358   translate([+10, -side_height]) polygon(bayo_polygon, convexity=10);
 359 }
 360
 361 module LimitForHandling(){ ////toplevel
 362   hull() for (r=[0,180])
 363     rotate([0,0,r]) {
 364       for (rs=[-1,+1]) {
 365         for (xd=[0,1]) {
 366           rotate([0,0, rs * handling_angle/2]) {
 367             translate([rs * xd * main_dia/2 * tan(handling_angle/2),
 368                        main_dia/2 + side_thick - main_cnr,
 369                        top_z - main_cnr]) {
 370               mirror([0,0,1])
 371                 cylinder(r= main_cnr, h=50);
 372               sphere(main_cnr);
 373             }
 374           }
 375         }
 376       }
 377     }
 378   hull() rotate_extrude(){
 379     translate([ handling_dia/2 - main_cnr, top_z - main_cnr ]) {
 380       circle(r = main_cnr);
 381       mirror([0,1]) square([ main_cnr, 50 ]);
 382     }
 383   }
 384   //cylinder(r= handling_dia/2, h=20);
 385 }
 386
 387 module Cover(){ ////toplevel
 388   render() difference(){
 389     intersection(){
 390       union(){
 391         rotate_extrude(convexity=10)
 392           translate([main_dia/2, 0])
 393           MainProfile();
 394         translate([0,0, middle_bot_z])
 395           cylinder(h= top_thick_middle, r = main_dia/2 - top_middle_dr + 1);
 396       }
 397       LimitForHandling();
 398     }
 399     for (r=[0,180]){
 400       rotate([0,0, r])
 401         translate([0,0, -side_height])
 402         BayonetCutout();
 403       rotate([0,0, r + asin((-oring_rm_beside) / (main_dia/2))])
 404         translate([0,
 405                    oring_mid_dia/2 + oring_thick/4 * oring_rm_scale,
 406                    oring_y_rad * 1.5])
 407         rotate([-oring_rm_angle, 0, 0])
 408         mirror([0,0,1])
 409         cylinder(r = oring_thick/4 * oring_rm_scale, h=20);
 410     }
 411     for (r=[0 : 60 : 179]) {
 412       rotate([0,0, r]) {
 413         height = top_thick_middle - brace_above_below*2;
 414         translate([0,0, middle_bot_z + brace_above_below + height/2 ])
 415         cube(center=true, [ oring_bore - brace_end_shorter,
 416                             brace_hole_width, height ]);
 417       }
 418     }
 419   }
 420   for (r=[0,180])
 421     rotate([0,0,r])
 422       translate([-implheadcup_large_dia * .5 - implheadcup_thick/2,
 423                  -implheadcup_large_dia * .0,
 424                  middle_bot_z + 0.1])
 425       ImplHeadCup();
 426 //  translate(strap_hoop_thick * [-0.5, 0, +1])
 427 //    translate([handling_dia/2, 0, -side_height])
 428 //    rotate([0,180,0]) rotate([0,0,90])
 429 //    StrapHoop();
 430 }
 431
 432 module SavingHole(){
 433   translate([0,0, -10])
 434     cylinder(r= main_dia/2 - jig_rim, h=20);
 435 }
 436
 437 module Jig(){ ////toplevel
 438   difference(){
 439     union(){
 440       translate([0,0, -side_height]){
 441         cylinder(r= main_dia/2 + jig_thick, h= side_height + jig_thick);
 442       }
 443       translate([-jig_mark_rad, 0, jig_thick - jig_mark])
 444         cube([jig_mark_rad*2, jig_mark, jig_mark]);
 445     }
 446     translate([0,0, -side_height-1])
 447       cylinder(r= main_dia/2, h= side_height + 1);
 448     SavingHole();
 449     translate([0,0, -rivet_posn])
 450       rotate([90, 0,0])
 451       translate([0,0, -100])
 452       cylinder(r= jig_hole_dia/2, h = 200);
 453   }
 454 }
 455
 456 module CoverTest2(){ ////toplevel
 457   difference(){
 458     Cover();
 459     SavingHole();
 460   }
 461 }
 462
 463 module CoverTest1(){ ////toplevel
 464   difference(){
 465     CoverTest2();
 466     difference(){
 467       for (r= [ 40, 147 ]){
 468         rotate([0,0, r]){
 469           translate([0,0, -10]) {
 470             cube([ main_dia*3, main_dia * .53, 18], center=true);
 471           }
 472         }
 473       }
 474 //      translate([ 50, 0, 0 ])
 475 //      cube([ 100,
 476 //             strap_hoop_inside + strap_hoop_thick*2 + 1,
 477 //             100 ],
 478 //           center=true);
 479     }
 480   }
 481 }
 482
 483 module ImplHeadCupTest(){ ////toplevel
 484   for (r=[0,180])
 485     rotate([0,0,r])
 486       translate([-17,0,0])
 487       ImplHeadCup();
 488 }
 489
 490 module SomeStrap(){
 491   // children(0) is to add, (1) subtract
 492   difference(){
 493     union(){
 494       cylinder(r=sm_outer_rad, h=sm_main_width);
 495       StrapMountProtrusion(smc_cnr_c_x + sm_closure_cnr,
 496                            smc_max_y,
 497                            sm_closure_cnr);
 498       children(0);
 499     }
 500     translate([0,0,-1])
 501       cylinder(r=sm_inner_rad, h=sm_main_width+2);
 502     translate(smc_pos)
 503       StrapMountBolt(10);
 504     translate(smc_pos)
 505       cube([ sm_bolt_tighten_allow, 40,100 ], center=true);
 506     children(1);
 507   }
 508 }
 509
 510 module StrapMountBolt(l_delta){ ///toplevel
 511   // positioned relative to smc_pos
 512   translate([(smc_bolt_nut_eff_thick - sm_bolt_head_thick)/2,
 513              smc_bolt_y,
 514              sm_main_width/2]){
 515     translate([ -sm_bolt_shaft/2-1, 0,0 ]){
 516       rotate([0,90,0]) cylinder(r= sm_bolt_dia/2, h= sm_bolt_shaft+2);
 517     }
 518     translate([ -sm_bolt_shaft/2, 0,0 ])
 519       rotate([0,-90,0])
 520       cylinder($fn=6, r=smc_bolt_nut_dia/2,
 521                h=smc_bolt_nut_eff_thick + l_delta);
 522     translate([ sm_bolt_shaft/2, 0,0 ])
 523       rotate([0,90,0])
 524       cylinder(r=sm_bolt_head_dia/2, h=sm_bolt_head_thick + l_delta);
 525   }
 526 }
 527
 528 module StrapMountProtrusion(half_x, max_y, cnr){
 529   translate(smc_pos){
 530     linear_extrude(height=sm_main_width, convexity=10){
 531       hull(){
 532         for (m = [0,1]) mirror([m,0,0]) {
 533           translate([-(half_x - cnr), max_y - cnr])
 534             circle(r=cnr);
 535           translate([-half_x, -sm_inner_rad])
 536             square([1,1]);
 537         }
 538       }
 539     }
 540   }
 541 }
 542
 543 module StrapMount(){ ////toplevel
 544   SomeStrap(){
 545     rotate([0,0,180]){
 546       StrapMountProtrusion(strap_hoop_inside/2 + strap_hoop_thick,
 547                            strap_hoop_thick,
 548                            sm_closure_cnr);
 549       translate(smc_pos +
 550                 [0,0, sm_main_width] +
 551                 strap_hoop_thick * [ 0, 0.5, -1.0 ])
 552         StrapHoop();
 553     }
 554     union(){ };
 555   }
 556 }
 557
 558 module CatchAssemblyCoreProfile(){
 559   difference(){
 560     union(){
 561       hull(){
 562         translate(cpp3) circle(r= catch_cr);
 563         polygon([ cpp3,
 564                   cpp2r,
 565                   cpp5,
 566                   cpph,
 567                   cppd
 568                   ]);
 569       }
 570       polygon([cppD,
 571                cppC,
 572                cpp9,
 573                cpp10,
 574                cpp11,
 575                cpp4,
 576                cpp2r,
 577                cpp2d,
 578                cppA,
 579                cppE
 580                ]);
 581       translate(cpp8) circle(r= catch_cr);
 582     }
 583     hull(){
 584       translate(cpp4) circle(r= catch_cr);
 585       translate(cpp5) circle(r= catch_cr);
 586       translate(cpp7) circle(r= catch_cr);
 587       polygon([cpp4,
 588                cppg,
 589                cpph,
 590                cpp10,
 591                cpp11,
 592                ]);
 593     }
 594     translate(cpp2) circle(r= catch_cr);
 595   }
 596 }
 597
 598 module CatchHeadProfile(){
 599   intersection(){
 600     translate(cppF){
 601       difference(){
 602         circle(r = dist2d(cppF, cppd));
 603         circle(r = dist2d(cppF, cppa));
 604       }
 605     }
 606     polygon([ cppa,
 607               cppg,
 608               cpph,
 609               cppd,
 610               cppc,
 611               cppb ]);
 612   }
 613   polygon([ cppd,
 614             cppg,
 615             cppf,
 616             cppe,
 617             cpph ]);
 618 }
 619
 620
 621 module CatchCore(){ /////toplevel
 622   linear_extrude(height=catch_strap_thick, convexity=10)
 623     CatchAssemblyCoreProfile();
 624
 625   linear_extrude(height=catch_strap_thick, convexity=10)
 626     CatchHeadProfile();
 627
 628   translate(concat(cppB,[0])) hull(){
 629     translate([0,0, catch_knob_height - catch_knob_dia/2])
 630       sphere(r = catch_knob_dia/2);
 631     cylinder(r = catch_knob_dia/2, h = 0.1);
 632   }
 633 }
 634
 635 module CatchPreDistort(){ /////toplevel
 636   scale(100 / sm_inner_rad)
 637     rotate([90,0,0])
 638     CatchCore();
 639 }
 640
 641 module CatchAssembly(){ /////toplevel
 642   rotate([0,0, -(cppe[0] + cppB[0]) / sm_inner_rad * 360/TAU])
 643     translate([0,0, catch_assembly_dy])
 644     scale(sm_inner_rad / 100)
 645     import(str("poster-tube-lid,CatchPostDistort-fa",
 646                (coarse ? 20 : 3),
 647                ".stl"),
 648            convexity=20);
 649
 650   SomeStrap(){
 651     union(){ }
 652     union(){
 653       translate([-200, -200, -200])
 654         cube([400, 200, 400]);
 655     }
 656   }
 657 }
 658
 659 module CatchDemo(){ /////toplevel
 660   color("blue") translate([0,0,
 661              -catch_strap_width
 662              -cpp0[1]
 663              ])
 664     CatchAssembly();
 665   translate([0,0,+side_height
 666              ])
 667     Cover();
 668 }
 669
 670 module CatchDemoS(){ /////toplevel
 671   color("blue") translate([0,0,
 672              -catch_strap_width
 673              -cpp0[1]
 674              ])
 675     CatchAssembly();
 676   intersection(){
 677     translate([0,0,+side_height
 678                ])
 679       Cover();
 680     mirror([0,1,0]) translate([-250,33,0]) cube([500,500,500]);
 681   }
 682   color("black")
 683     translate([0,-33,0])
 684     cube([6.15, 2,2], center=true);
 685 }
 686
 687 module CatchPinProfileDemo(){ /////toplevel
 688   echo("G ",
 689        cpp2[0] - cpp1[0],
 690        bayo_n[0] - bayo_e[0]);
 691   color("blue") translate([0,0,
 692                            +1,
 693              ]) {
 694     CatchAssemblyCoreProfile();
 695     CatchHeadProfile();
 696   }
 697   polygon(bayo_polygon, convexity=10);
 698 }
 699
 700 //ProfilesDemo();
 701 //BayonetCutout();
 702 //MainProfile();
 703 //Cover();
 704 //Jig();
 705 //CoverTest();