poster-tube-lid.scad

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4
   5 coarse = false;
   6
   7 main_dia = 71.2 + 0.50 - 2.26;
   8 top_thick_middle = 4;
   9 top_thick_by_oring = 3.0;
  10 top_middle_dr = 11;
  11
  12 main_cnr = 6.0;
  13
  14 min_wall = 3;
  15
  16 rivet_posn = 6.0 + 0.30;
  17 rivet_thick = 1.67;
  18 rivet_width = 4.15 + 1.0;
  19 rivet_tall = 5.51 + 1.49;
  20
  21 over_rivet_wall = 1.0;
  22 side_rivet_gap = 1.5;
  23 inside_rivet_gap = 1.5;
  24
  25 bayo_interf = 0.30;
  26 bayo_behind = 3.5;
  27 bayo_interf_width = 2.0;
  28 bayo_interf_slope = 0.5;
  29
  30 oring_thick = 5.0;
  31 oring_bore = 62.0;
  32
  33 oring_upper_embed_angle = 80;
  34 oring_compress = 0.1; // proportion
  35 oring_compress_more = 0.2;
  36
  37 oring_rm_beside = 8;
  38 oring_rm_scale = 2.0;
  39 oring_rm_angle = 20;
  40
  41 side_taper = 1.0;
  42
  43 bayo_gap = 6.0;
  44
  45 bayo_entry = bayo_behind/3;
  46
  47 bayo_slice_size = coarse ? 5 : 1;
  48
  49 brace_hole_width = 1.0;
  50 brace_above_below = 1.2;
  51 brace_end_shorter = 0.3;
  52
  53 jig_thick = 1.4;
  54 jig_hole_dia = 3.0;
  55 jig_rim = 5;
  56 jig_mark = 5;
  57
  58 strap_hoop_thick = 6;
  59 strap_hoop_inside = 10;
  60 strap_hoop_strlen = 10;
  61 strap_hoop_elevation = 45;
  62
  63 sm_inner_circum = 218 - 1.90 - 1.00 - 0.50;
  64 sm_main_thick = 2.0;
  65 sm_main_width = 20;
  66
  67 sm_bolt_dia = 3.5 + 0.1;
  68 sm_bolt_shaft = 21.9;
  69 sm_bolt_head_dia = 6.94 + 1.0;
  70 sm_bolt_head_thick = 2.14;
  71 sm_bolt_nut_width = 5.89 + 0.25;
  72 sm_bolt_nut_thick = 3.68;
  73 sm_bolt_tighten_allow = 2.0;
  74
  75 sm_bolt_y_clear = 0.75;
  76 sm_bolt_y_over = 0.5;
  77
  78 sm_closure_cnr = 3.0;
  79
  80 catch_stem_h = 3;
  81 catch_stem_len = 50;
  82 catch_stem_th = 3;
  83
  84 catch_pin_slop = 0.25; // each side, and above
  85 catch_stalk_above_gap = 1.5;
  86 catch_stalk_eff_bend_rad = catch_stem_len * 0.75;
  87
  88 catch_stalk_base_width = 15;
  89
  90 catch_knob_dia = 6;
  91 catch_knob_above_gap = 8;
  92 catch_knob_height = 6;
  93
  94 catch_stem_below_gap = 1.0;
  95 catch_stem_beside_gap = 2.0;
  96 catch_pin_gap = 0.5;
  97 catch_hook_slope = 0.15;
  98
  99 // calculated
 100
 101 TAU = PI*2;
 102
 103 bayo_entry_x = bayo_entry;
 104 bayo_entry_z = bayo_entry;
 105 bayo_inramp_x = bayo_entry;
 106 bayo_inramp_z = bayo_entry;
 107
 108 oring_mid_dia = oring_bore + oring_thick;
 109 oring_outer_dia = oring_mid_dia + oring_thick;
 110
 111 oring_oblate = (1 - oring_compress);
 112
 113 oring_y_rad = oring_thick/2 * oring_oblate;
 114 oring_x_rad = oring_thick/2 / oring_oblate;
 115
 116 by_oring_z = oring_y_rad * (1 + cos(oring_upper_embed_angle));
 117
 118 side_height = rivet_posn + bayo_behind + rivet_thick/2;
 119 side_thick = rivet_tall + over_rivet_wall;
 120
 121 top_z = top_thick_by_oring + oring_y_rad + by_oring_z;
 122
 123 middle_bot_z = top_z - top_thick_middle;
 124
 125 bayo_entry = bayo_behind / 3.0;
 126 bayo_top_z = bayo_behind + bayo_gap;
 127
 128 bayo_nom_rad = main_dia/2 + side_thick;
 129 bayo_real_rad = main_dia/2 + rivet_tall;
 130
 131 rivet_entry_width = rivet_width + side_rivet_gap;
 132
 133 jig_mark_rad = jig_mark + main_dia/2 + jig_thick;
 134
 135 handling_dia = oring_bore + oring_thick*2 + min_wall*2;
 136 handling_angle = 45;
 137
 138 sm_inner_rad = (sm_inner_circum + sm_bolt_tighten_allow/2) / TAU;
 139 sm_outer_rad = sm_inner_rad + sm_main_thick;
 140
 141 smc_pos = [ 0, sm_inner_rad, 0 ];
 142
 143 smc_bolt_nut_dia = sm_bolt_nut_width / cos(30);
 144 smc_bolt_nut_eff_thick = sm_bolt_nut_thick + sm_bolt_tighten_allow;
 145
 146 smc_bolt_y = sm_bolt_dia/2 + sm_bolt_y_clear;
 147 smc_max_y = smc_bolt_y + sm_bolt_y_over
 148   + max(sm_bolt_head_dia/2, smc_bolt_nut_dia/2);
 149 smc_cnr_c_x = sm_bolt_shaft/2 - sm_closure_cnr
 150   + sm_bolt_head_thick/2 + smc_bolt_nut_eff_thick/2;
 151
 152 catch_cr = catch_knob_dia/2 + catch_stem_beside_gap;
 153 catch_strap_width = sm_main_width;
 154 catch_strap_thick = sm_main_thick;
 155 catch_stem_end_h = catch_stem_h;
 156 catch_pin_width = (rivet_entry_width * sm_inner_rad / bayo_nom_rad)
 157                    - catch_pin_gap;
 158
 159 echo("R ", sm_inner_rad, bayo_real_rad, bayo_nom_rad);
 160
 161 $fs= coarse ? 2.5 : 0.5;
 162 $fa= coarse ? 5 : 1;
 163
 164 include <poster-tube-lid-parametric.scad>
 165
 166 // bayonet definition
 167
 168 bayo_a = [ bayo_entry_x, 0 ];
 169 bayo_p = [ 0, bayo_entry_z ];
 170 bayo_n = [ 0, bayo_behind-bayo_inramp_z ];
 171 bayo_m = [ bayo_inramp_x, bayo_behind ];
 172 bayo_l = bayo_m + bayo_interf * [ 1/bayo_interf_slope,  1 ];
 173 bayo_k = bayo_l + [ bayo_interf_width, 0 ];
 174 bayo_j = bayo_k + bayo_interf * [ 1/bayo_interf_slope, -1 ];
 175 bayo_i = bayo_j + [ rivet_width + inside_rivet_gap, 0 ];
 176 bayo_h = [ bayo_i[0], bayo_behind + bayo_gap + bayo_interf ];
 177 bayo_g = [ bayo_m[0] - rivet_width, bayo_h[1] ];
 178
 179 bayo_e = [-bayo_p[0], bayo_p[1]] - [rivet_entry_width,0];
 180 bayo_d = [-bayo_a[0], bayo_a[1]] - [rivet_entry_width,0];
 181 bayo_c = bayo_d + [0,-5];
 182 bayo_b = bayo_a + [0,-5];
 183
 184 bayo_f = [ bayo_e[0], bayo_g[1] + (bayo_e[0] - bayo_g[0]) ];
 185
 186 bayo_polygon = [ bayo_a,
 187                  bayo_b,
 188                  bayo_c,
 189                  bayo_d,
 190                  bayo_e,
 191                  bayo_f,
 192                  bayo_g,
 193                  bayo_h,
 194                  bayo_i,
 195                  bayo_j,
 196                  bayo_k,
 197                  bayo_l,
 198                  bayo_m,
 199                  bayo_n,
 200                  bayo_p ];
 201
 202 echo(bayo_polygon);
 203
 204 // CATCH
 205
 206 //cppy6 = -catch_strap_width * 2/3;
 207
 208 cppxC = 0.41 * sm_inner_rad * TAU;
 209
 210 // catch pin
 211
 212 cppa = bayo_f + [1,-1] * catch_pin_slop;
 213 cppb = bayo_g + [1,-1] * catch_pin_slop;
 214 cppd = [ bayo_n[0] - catch_pin_slop, -catch_stalk_above_gap ];
 215 cppc = [ cppd[0], cppb[1] ];
 216 cpph = cppd + [0,-1] * catch_stem_h;
 217 cppe = cppd + [0,-1] * (catch_knob_above_gap + catch_knob_dia/2);
 218 cppf = [ cppa[0], cppe[1] ];
 219 cppg = [ cppa[0], cpph[1] ];
 220 cppB = 0.5 * (cppf + cppe);
 221
 222 // catch assembly depression below pin
 223
 224 cppy6 = cppB[1] - (catch_knob_dia/2
 225                    + (cppc[1] - cppd[1])
 226                    + catch_stem_below_gap);
 227 cpp7 = [ cppB[0], cppy6 + catch_cr ];
 228 cpp11 = cpp7 + [1,0] * catch_cr;
 229 cppy9 = cppy6 + catch_strap_width * 1/3;
 230 cpp9 = [ cpp7[0] + catch_cr * 2, cppy9 ];
 231 cpp8 = cpp9 + [0,-1] * catch_cr;
 232 cpp10 = cpp8 + [-1,0] * catch_cr;
 233 cppC = [ cppxC, cpp9[1] ];
 234 cppD = cppC + [0,-1] * catch_strap_width;
 235
 236 // catch assembly stalk and so on
 237
 238 cppF = [ cppg[0] - catch_stalk_eff_bend_rad, cppd[1] ];
 239 cpp4 = [ cppg[0] - catch_stem_len, cpph[1] ] + [1,-1] * catch_cr;
 240 cpp5 = [ cpp4[0], cppC[1] + catch_cr ];
 241 cpp2 = cpp5 + [-1,0] * (catch_cr * 2 + catch_stalk_base_width);
 242 cpp2r = cpp2 + [1,0] * catch_cr;
 243 cpp2d = cpp2 + [0,-1] * catch_cr;
 244 cpp3 = [ cpp2[0] + catch_cr * 2, cppd[1] - catch_cr ];
 245 cppA = [ -cppxC, cpp9[1] ];
 246 cppE = [ cppA[0], cppD[1] ];
 247
 248
 249 module MainProfile(){
 250   main_cnr_pos = [ side_thick, top_z ] - [1,1]*main_cnr;
 251   difference(){
 252     union(){
 253       translate(main_cnr_pos){
 254         intersection(){
 255           difference(){
 256             circle(r = main_cnr);
 257             circle(r = main_cnr * 0.5);
 258           }
 259           square([10,10]);
 260         }
 261       }
 262       polygon([[ -top_middle_dr,        middle_bot_z      ],
 263                [ -top_middle_dr,        top_z             ],
 264                [ main_cnr_pos[0],       top_z             ],
 265                [ side_thick,            main_cnr_pos[1]   ],
 266                [ side_thick,            -side_height      ],
 267                [ side_taper,            -side_height      ],
 268                [ 0,                     -rivet_posn       ],
 269                [ 0,                     by_oring_z        ],
 270                [ -oring_x_rad,          by_oring_z        ],
 271                ],
 272               convexity=10);
 273     }
 274     translate([ oring_mid_dia/2 - main_dia/2, 0 ])
 275       hull(){
 276       translate([ 0, oring_y_rad ])
 277         scale([ 1/oring_oblate * (oring_compress_more+1) , oring_oblate ])
 278         circle(oring_thick/2);
 279       translate([ 0, oring_y_rad*2 - oring_thick/2 ])
 280         circle(oring_thick/2);
 281     }
 282   }
 283 }
 284
 285 module StrapHoopProfile(){
 286   circle(r = strap_hoop_thick/2);
 287 }
 288
 289 module StrapHoop(){ ////toplevel
 290   bigrad = strap_hoop_inside/2 + strap_hoop_thick/2;
 291   extralen = strap_hoop_thick * 5;
 292
 293   intersection(){
 294     rotate([strap_hoop_elevation, 0,0]){
 295       for (x= [ -1, +1 ] * bigrad) {
 296         translate([x, -extralen, 0])
 297           rotate([-90,0,0])
 298           linear_extrude(height= extralen + strap_hoop_strlen + 0.1,
 299                          convexity=10)
 300           StrapHoopProfile();
 301       }
 302       translate([0, strap_hoop_strlen, 0]){
 303         intersection(){
 304           rotate_extrude(convexity=10)
 305             translate([bigrad, 0,0])
 306             StrapHoopProfile();
 307           translate([0,50,0])
 308             cube([100,100,100], center=true);
 309         }
 310       }
 311     }
 312     translate([0, 50, 0])
 313       cube(100, center=true);
 314   }
 315 }
 316
 317 module RotateProjectSlice(offset, slice_size, nom_rad, real_rad){
 318   // nom_rad > real_rad
 319   rotate([0,0, atan2(offset, nom_rad) ]){
 320     intersection(){
 321       translate([-offset, -10, 0])
 322         rotate([90,0,0])
 323         linear_extrude(height= nom_rad*2)
 324         children(0);
 325       translate([0,0, -25])
 326         cylinder(h=50, r= real_rad);
 327       translate([0,0, -25])
 328         linear_extrude(height= 50)
 329         polygon([ [ 0,0 ],
 330                   [ -slice_size, -real_rad*2 ],
 331                   [ +slice_size, -real_rad*2 ] ]);
 332     }
 333   }
 334 }
 335
 336 module RotateProject(x_min, x_max, slice_size, nom_rad, real_rad){
 337   offs = [ for (i=[ x_min :
 338                     slice_size :
 339                     x_max + slice_size ]) i ];
 340   echo (offs);
 341   for (off=offs)
 342     RotateProjectSlice(off, slice_size, nom_rad, real_rad)
 343     children(0);
 344 }
 345
 346 module BayonetCutout(){
 347   RotateProject(bayo_c[0], bayo_i[0], bayo_slice_size,
 348                 bayo_nom_rad,
 349                 bayo_real_rad)
 350     translate([-0.5 * (bayo_a[0] + bayo_d[0]), 0])
 351     polygon(bayo_polygon, convexity=10);
 352 }
 353
 354 module ProfilesDemo(){ ////toplevel
 355   translate([-10,0]) MainProfile();
 356   translate([+10, -side_height]) polygon(bayo_polygon, convexity=10);
 357 }
 358
 359 module LimitForHandling(){ ////toplevel
 360   hull() for (r=[0,180])
 361     rotate([0,0,r]) {
 362       for (rs=[-1,+1]) {
 363         for (xd=[0,1]) {
 364           rotate([0,0, rs * handling_angle/2]) {
 365             translate([rs * xd * main_dia/2 * tan(handling_angle/2),
 366                        main_dia/2 + side_thick - main_cnr,
 367                        top_z - main_cnr]) {
 368               mirror([0,0,1])
 369                 cylinder(r= main_cnr, h=50);
 370               sphere(main_cnr);
 371             }
 372           }
 373         }
 374       }
 375     }
 376   hull() rotate_extrude(){
 377     translate([ handling_dia/2 - main_cnr, top_z - main_cnr ]) {
 378       circle(r = main_cnr);
 379       mirror([0,1]) square([ main_cnr, 50 ]);
 380     }
 381   }
 382   //cylinder(r= handling_dia/2, h=20);
 383 }
 384
 385 module Cover(){ ////toplevel
 386   render() difference(){
 387     intersection(){
 388       union(){
 389         rotate_extrude(convexity=10)
 390           translate([main_dia/2, 0])
 391           MainProfile();
 392         translate([0,0, middle_bot_z])
 393           cylinder(h= top_thick_middle, r = main_dia/2 - top_middle_dr + 1);
 394       }
 395       LimitForHandling();
 396     }
 397     for (r=[0,180]){
 398       rotate([0,0, r])
 399         translate([0,0, -side_height])
 400         BayonetCutout();
 401       rotate([0,0, r + asin((-oring_rm_beside) / (main_dia/2))])
 402         translate([0,
 403                    oring_mid_dia/2 + oring_thick/4 * oring_rm_scale,
 404                    oring_y_rad * 1.5])
 405         rotate([-oring_rm_angle, 0, 0])
 406         mirror([0,0,1])
 407         cylinder(r = oring_thick/4 * oring_rm_scale, h=20);
 408     }
 409     for (r=[0 : 60 : 179]) {
 410       rotate([0,0, r]) {
 411         height = top_thick_middle - brace_above_below*2;
 412         translate([0,0, middle_bot_z + brace_above_below + height/2 ])
 413         cube(center=true, [ oring_bore - brace_end_shorter,
 414                             brace_hole_width, height ]);
 415       }
 416     }
 417   }
 418   for (r=[0,180])
 419     rotate([0,0,r])
 420       translate([-implheadcup_large_dia * .5 - implheadcup_thick/2,
 421                  -implheadcup_large_dia * .0,
 422                  middle_bot_z + 0.1])
 423       ImplHeadCup();
 424 //  translate(strap_hoop_thick * [-0.5, 0, +1])
 425 //    translate([handling_dia/2, 0, -side_height])
 426 //    rotate([0,180,0]) rotate([0,0,90])
 427 //    StrapHoop();
 428 }
 429
 430 module SavingHole(){
 431   translate([0,0, -10])
 432     cylinder(r= main_dia/2 - jig_rim, h=20);
 433 }
 434
 435 module Jig(){ ////toplevel
 436   difference(){
 437     union(){
 438       translate([0,0, -side_height]){
 439         cylinder(r= main_dia/2 + jig_thick, h= side_height + jig_thick);
 440       }
 441       translate([-jig_mark_rad, 0, jig_thick - jig_mark])
 442         cube([jig_mark_rad*2, jig_mark, jig_mark]);
 443     }
 444     translate([0,0, -side_height-1])
 445       cylinder(r= main_dia/2, h= side_height + 1);
 446     SavingHole();
 447     translate([0,0, -rivet_posn])
 448       rotate([90, 0,0])
 449       translate([0,0, -100])
 450       cylinder(r= jig_hole_dia/2, h = 200);
 451   }
 452 }
 453
 454 module CoverTest2(){ ////toplevel
 455   difference(){
 456     Cover();
 457     SavingHole();
 458   }
 459 }
 460
 461 module CoverTest1(){ ////toplevel
 462   difference(){
 463     CoverTest2();
 464     difference(){
 465       for (r= [ 40, 147 ]){
 466         rotate([0,0, r]){
 467           translate([0,0, -10]) {
 468             cube([ main_dia*3, main_dia * .53, 18], center=true);
 469           }
 470         }
 471       }
 472 //      translate([ 50, 0, 0 ])
 473 //      cube([ 100,
 474 //             strap_hoop_inside + strap_hoop_thick*2 + 1,
 475 //             100 ],
 476 //           center=true);
 477     }
 478   }
 479 }
 480
 481 module ImplHeadCupTest(){ ////toplevel
 482   for (r=[0,180])
 483     rotate([0,0,r])
 484       translate([-17,0,0])
 485       ImplHeadCup();
 486 }
 487
 488 module SomeStrap(){
 489   // children(0) is to add, (1) subtract
 490   difference(){
 491     union(){
 492       cylinder(r=sm_outer_rad, h=sm_main_width);
 493       StrapMountProtrusion(smc_cnr_c_x + sm_closure_cnr,
 494                            smc_max_y,
 495                            sm_closure_cnr);
 496       children(0);
 497     }
 498     translate([0,0,-1])
 499       cylinder(r=sm_inner_rad, h=sm_main_width+2);
 500     translate(smc_pos)
 501       StrapMountBolt(10);
 502     translate(smc_pos)
 503       cube([ sm_bolt_tighten_allow, 40,100 ], center=true);
 504     children(1);
 505   }
 506 }
 507
 508 module StrapMountBolt(l_delta){ ///toplevel
 509   // positioned relative to smc_pos
 510   translate([(smc_bolt_nut_eff_thick - sm_bolt_head_thick)/2,
 511              smc_bolt_y,
 512              sm_main_width/2]){
 513     translate([ -sm_bolt_shaft/2-1, 0,0 ]){
 514       rotate([0,90,0]) cylinder(r= sm_bolt_dia/2, h= sm_bolt_shaft+2);
 515     }
 516     translate([ -sm_bolt_shaft/2, 0,0 ])
 517       rotate([0,-90,0])
 518       cylinder($fn=6, r=smc_bolt_nut_dia/2,
 519                h=smc_bolt_nut_eff_thick + l_delta);
 520     translate([ sm_bolt_shaft/2, 0,0 ])
 521       rotate([0,90,0])
 522       cylinder(r=sm_bolt_head_dia/2, h=sm_bolt_head_thick + l_delta);
 523   }
 524 }
 525
 526 module StrapMountProtrusion(half_x, max_y, cnr){
 527   translate(smc_pos){
 528     linear_extrude(height=sm_main_width, convexity=10){
 529       hull(){
 530         for (m = [0,1]) mirror([m,0,0]) {
 531           translate([-(half_x - cnr), max_y - cnr])
 532             circle(r=cnr);
 533           translate([-half_x, -sm_inner_rad])
 534             square([1,1]);
 535         }
 536       }
 537     }
 538   }
 539 }
 540
 541 module StrapMount(){ ////toplevel
 542   SomeStrap(){
 543     rotate([0,0,180]){
 544       StrapMountProtrusion(strap_hoop_inside/2 + strap_hoop_thick,
 545                            strap_hoop_thick,
 546                            sm_closure_cnr);
 547       translate(smc_pos +
 548                 [0,0, sm_main_width] +
 549                 strap_hoop_thick * [ 0, 0.5, -1.0 ])
 550         StrapHoop();
 551     }
 552     union(){ };
 553   }
 554 }
 555
 556 module CatchAssemblyCoreProfile(){
 557   difference(){
 558     union(){
 559       hull(){
 560         translate(cpp3) circle(r= catch_cr);
 561         polygon([ cpp3,
 562                   cpp2r,
 563                   cpp5,
 564                   cpph,
 565                   cppd
 566                   ]);
 567       }
 568       polygon([cppD,
 569                cppC,
 570                cpp9,
 571                cpp10,
 572                cpp11,
 573                cpp4,
 574                cpp2r,
 575                cpp2d,
 576                cppA,
 577                cppE
 578                ]);
 579       translate(cpp8) circle(r= catch_cr);
 580     }
 581     hull(){
 582       translate(cpp4) circle(r= catch_cr);
 583       translate(cpp5) circle(r= catch_cr);
 584       translate(cpp7) circle(r= catch_cr);
 585       polygon([cpp4,
 586                cppg,
 587                cpph,
 588                cpp10,
 589                cpp11,
 590                ]);
 591     }
 592   }
 593 }
 594
 595 module CatchHeadProfile(){
 596   intersection(){
 597     translate(cppF){
 598       difference(){
 599         circle(r = dist2d(cppF, cppd));
 600         circle(r = dist2d(cppF, cppa));
 601       }
 602     }
 603     polygon([ cppa,
 604               cppg,
 605               cpph,
 606               cppd,
 607               cppc,
 608               cppb ]);
 609   }
 610   polygon([ cppd,
 611             cppg,
 612             cppf,
 613             cppe,
 614             cpph ]);
 615 }
 616
 617
 618 module CatchCore(){ /////toplevel
 619   linear_extrude(height=catch_strap_thick, convexity=10)
 620     CatchAssemblyCoreProfile();
 621
 622   linear_extrude(height=catch_strap_thick, convexity=10)
 623     CatchHeadProfile();
 624
 625   translate(concat(cppB,[0])) hull(){
 626     translate([0,0, catch_knob_height - catch_knob_dia/2])
 627       sphere(r = catch_knob_dia/2);
 628     cylinder(r = catch_knob_dia/2, h = 0.1);
 629   }
 630 }
 631
 632 module CatchPreDistort(){ /////toplevel
 633   scale(100 / sm_inner_rad)
 634     rotate([90,0,0])
 635     CatchCore();
 636 }
 637
 638 module CatchAssembly(){ /////toplevel
 639   rotate([0,0, -0.5 * (cpp1[0] + cpp2[0]) / sm_inner_rad * 360/TAU])
 640     translate([0,0, catch_strap_width])
 641     scale(sm_inner_rad / 100)
 642     import(str("poster-tube-lid,CatchPostDistort-fa",
 643                (coarse ? 20 : 3),
 644                ".stl"),
 645            convexity=20);
 646
 647   SomeStrap(){
 648     union(){ }
 649     union(){
 650       translate([-200, -200, -200])
 651         cube([400, 200, 400]);
 652     }
 653   }
 654 }
 655
 656 module CatchDemo(){ /////toplevel
 657   color("blue") translate([0,0,
 658              -catch_strap_width
 659              -cpp0[1]
 660              ])
 661     CatchAssembly();
 662   translate([0,0,+side_height
 663              ])
 664     Cover();
 665 }
 666
 667 module CatchDemoS(){ /////toplevel
 668   color("blue") translate([0,0,
 669              -catch_strap_width
 670              -cpp0[1]
 671              ])
 672     CatchAssembly();
 673   intersection(){
 674     translate([0,0,+side_height
 675                ])
 676       Cover();
 677     mirror([0,1,0]) translate([-250,33,0]) cube([500,500,500]);
 678   }
 679   color("black")
 680     translate([0,-33,0])
 681     cube([6.15, 2,2], center=true);
 682 }
 683
 684 module CatchPinProfileDemo(){ /////toplevel
 685   echo("G ",
 686        cpp2[0] - cpp1[0],
 687        bayo_n[0] - bayo_e[0]);
 688   color("blue") translate([0,0,
 689                            +1,
 690              ]) {
 691     CatchAssemblyCoreProfile();
 692     CatchHeadProfile();
 693   }
 694   polygon(bayo_polygon, convexity=10);
 695 }
 696
 697 //ProfilesDemo();
 698 //BayonetCutout();
 699 //MainProfile();
 700 //Cover();
 701 //Jig();
 702 //CoverTest();