poster-tube-lid.scad

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4
   5 coarse = false;
   6
   7 main_dia = 71.2 + 0.50 - 2.26;
   8 top_thick_middle = 4;
   9 top_thick_by_oring = 3.0;
  10 top_middle_dr = 11;
  11
  12 main_cnr = 6.0;
  13
  14 min_wall = 3;
  15
  16 rivet_posn = 6.0 + 0.30;
  17 rivet_thick = 1.67;
  18 rivet_width = 4.15 + 1.0;
  19 rivet_tall = 5.51 + 1.49;
  20
  21 over_rivet_wall = 1.0;
  22 side_rivet_gap = 1.5;
  23 inside_rivet_gap = 1.5;
  24
  25 bayo_interf = 0.30;
  26 bayo_behind = 3.5;
  27 bayo_interf_width = 2.0;
  28 bayo_interf_slope = 0.5;
  29
  30 oring_thick = 5.0;
  31 oring_bore = 62.0;
  32
  33 oring_upper_embed_angle = 80;
  34 oring_compress = 0.1; // proportion
  35 oring_compress_more = 0.2;
  36
  37 oring_rm_beside = 8;
  38 oring_rm_scale = 2.0;
  39 oring_rm_angle = 20;
  40
  41 side_taper = 1.0;
  42
  43 bayo_gap = 6.0;
  44
  45 bayo_entry = bayo_behind/3;
  46
  47 bayo_slice_size = coarse ? 5 : 1;
  48
  49 brace_hole_width = 1.0;
  50 brace_above_below = 1.2;
  51 brace_end_shorter = 0.3;
  52
  53 jig_thick = 1.4;
  54 jig_hole_dia = 3.0;
  55 jig_rim = 5;
  56 jig_mark = 5;
  57
  58 strap_hoop_thick = 6;
  59 strap_hoop_inside = 10;
  60 strap_hoop_strlen = 10;
  61 strap_hoop_elevation = 45;
  62
  63 sm_inner_circum = 218 - 1.90 - 1.00 - 0.50;
  64 sm_main_thick = 2.0;
  65 sm_main_width = 20;
  66
  67 sm_bolt_dia = 3.5 + 0.1;
  68 sm_bolt_shaft = 21.9;
  69 sm_bolt_head_dia = 6.94 + 1.0;
  70 sm_bolt_head_thick = 2.14;
  71 sm_bolt_nut_width = 5.89 + 0.25;
  72 sm_bolt_nut_thick = 3.68;
  73 sm_bolt_tighten_allow = 2.0;
  74
  75 sm_bolt_y_clear = 0.75;
  76 sm_bolt_y_over = 0.5;
  77
  78 sm_closure_cnr = 3.0;
  79
  80 catch_stalk_h = 4.5;
  81 catch_stalk_len = 50;
  82 catch_head_th = 3;
  83
  84 catch_pin_slop = 0.25; // each side, and above
  85 catch_pin_slop_x_extra = 0.0; // only on one side
  86 catch_stalk_above_gap = 1.5;
  87 catch_stalk_eff_bend_rad = catch_stalk_len * 0.75;
  88
  89 catch_strap_width = 12;
  90 catch_stalk_base_width = 15;
  91
  92 catch_knob_dia = 6;
  93 catch_knob_above_gap = 5;
  94 catch_knob_height = 5;
  95
  96 catch_stalk_below_gap = 1.0;
  97 catch_stalk_beside_gap = 2.0;
  98
  99 // calculated
 100
 101 TAU = PI*2;
 102
 103 bayo_entry_x = bayo_entry;
 104 bayo_entry_z = bayo_entry;
 105 bayo_inramp_x = bayo_entry;
 106 bayo_inramp_z = bayo_entry;
 107
 108 oring_mid_dia = oring_bore + oring_thick;
 109 oring_outer_dia = oring_mid_dia + oring_thick;
 110
 111 oring_oblate = (1 - oring_compress);
 112
 113 oring_y_rad = oring_thick/2 * oring_oblate;
 114 oring_x_rad = oring_thick/2 / oring_oblate;
 115
 116 by_oring_z = oring_y_rad * (1 + cos(oring_upper_embed_angle));
 117
 118 side_height = rivet_posn + bayo_behind + rivet_thick/2;
 119 side_thick = rivet_tall + over_rivet_wall;
 120
 121 top_z = top_thick_by_oring + oring_y_rad + by_oring_z;
 122
 123 middle_bot_z = top_z - top_thick_middle;
 124
 125 bayo_entry = bayo_behind / 3.0;
 126 bayo_top_z = bayo_behind + bayo_gap;
 127
 128 bayo_nom_rad = main_dia/2 + side_thick;
 129 bayo_real_rad = main_dia/2 + rivet_tall;
 130
 131 rivet_entry_width = rivet_width + side_rivet_gap;
 132
 133 jig_mark_rad = jig_mark + main_dia/2 + jig_thick;
 134
 135 handling_dia = oring_bore + oring_thick*2 + min_wall*2;
 136 handling_angle = 45;
 137
 138 sm_inner_rad = (sm_inner_circum + sm_bolt_tighten_allow/2) / TAU;
 139 sm_outer_rad = sm_inner_rad + sm_main_thick;
 140
 141 smc_pos = [ 0, sm_inner_rad, 0 ];
 142
 143 smc_bolt_nut_dia = sm_bolt_nut_width / cos(30);
 144 smc_bolt_nut_eff_thick = sm_bolt_nut_thick + sm_bolt_tighten_allow;
 145
 146 smc_bolt_y = sm_bolt_dia/2 + sm_bolt_y_clear;
 147 smc_max_y = smc_bolt_y + sm_bolt_y_over
 148   + max(sm_bolt_head_dia/2, smc_bolt_nut_dia/2);
 149 smc_cnr_c_x = sm_bolt_shaft/2 - sm_closure_cnr
 150   + sm_bolt_head_thick/2 + smc_bolt_nut_eff_thick/2;
 151
 152 catch_cr = catch_knob_dia/2 + catch_stalk_beside_gap;
 153 catch_strap_thick = sm_main_thick;
 154
 155 echo("R ", sm_inner_rad, bayo_real_rad, bayo_nom_rad);
 156
 157 $fs= coarse ? 2.5 : 0.5;
 158 $fa= coarse ? 5 : 1;
 159
 160 include <poster-tube-lid-parametric.scad>
 161
 162 // bayonet definition
 163
 164 bayo_a = [ bayo_entry_x, 0 ];
 165 bayo_p = [ 0, bayo_entry_z ];
 166 bayo_n = [ 0, bayo_behind-bayo_inramp_z ];
 167 bayo_m = [ bayo_inramp_x, bayo_behind ];
 168 bayo_l = bayo_m + bayo_interf * [ 1/bayo_interf_slope,  1 ];
 169 bayo_k = bayo_l + [ bayo_interf_width, 0 ];
 170 bayo_j = bayo_k + bayo_interf * [ 1/bayo_interf_slope, -1 ];
 171 bayo_i = bayo_j + [ rivet_width + inside_rivet_gap, 0 ];
 172 bayo_h = [ bayo_i[0], bayo_behind + bayo_gap + bayo_interf ];
 173 bayo_g = [ bayo_m[0] - rivet_width, bayo_h[1] ];
 174
 175 bayo_e = [-bayo_p[0], bayo_p[1]] - [rivet_entry_width,0];
 176 bayo_d = [-bayo_a[0], bayo_a[1]] - [rivet_entry_width,0];
 177 bayo_c = bayo_d + [0,-5];
 178 bayo_b = bayo_a + [0,-5];
 179
 180 bayo_f = [ bayo_e[0], bayo_g[1] + (bayo_e[0] - bayo_g[0]) ];
 181
 182 bayo_polygon = [ bayo_a,
 183                  bayo_b,
 184                  bayo_c,
 185                  bayo_d,
 186                  bayo_e,
 187                  bayo_f,
 188                  bayo_g,
 189                  bayo_h,
 190                  bayo_i,
 191                  bayo_j,
 192                  bayo_k,
 193                  bayo_l,
 194                  bayo_m,
 195                  bayo_n,
 196                  bayo_p ];
 197
 198 echo(bayo_polygon);
 199
 200 // CATCH
 201
 202 cppxC = 0.41 * sm_inner_rad * TAU;
 203
 204 // catch pin
 205
 206 cpp_adj = (bayo_n[0] - bayo_f[0]) * (1 - sm_inner_rad / bayo_nom_rad);
 207 // radius scaling due to nom and actual radius difference in
 208 // bayo entry construction
 209
 210 cppa = bayo_f + [1,-1] * catch_pin_slop + [1,0] * cpp_adj;
 211 cppb = bayo_g + [1,-1] * catch_pin_slop + [1,0] * cpp_adj;
 212 cppd = [ bayo_n[0]
 213          - catch_pin_slop - catch_pin_slop_x_extra,
 214          -catch_stalk_above_gap ];
 215 cppc = [ cppd[0], cppb[1] ];
 216 cpph = cppd + [0,-1] * catch_stalk_h;
 217 cppe = cppd + [0,-1] * (catch_knob_above_gap + catch_knob_dia/2);
 218 cppf = [ cppa[0], cppe[1] ];
 219 cppg = [ cppa[0], cpph[1] ];
 220 cppB = 0.5 * (cppf + cppe);
 221
 222 echo("RR", sm_inner_rad / bayo_nom_rad);
 223
 224 // catch assembly depression below pin
 225
 226 cppy6 = cppB[1] - (catch_knob_dia/2
 227                    + (cppc[1] - cppd[1])
 228                    + catch_stalk_below_gap);
 229 cpp7 = [ cppB[0], cppy6 + catch_cr ];
 230 cpp11 = cpp7 + [1,0] * catch_cr;
 231 cppy9 = cppy6 + catch_strap_width * 1/3;
 232 cpp9 = [ cpp7[0] + catch_cr * 2, cppy9 ];
 233 cpp8 = cpp9 + [0,-1] * catch_cr;
 234 cpp10 = cpp8 + [-1,0] * catch_cr;
 235 cppC = [ cppxC, cpp9[1] ];
 236 cppD = cppC + [0,-1] * catch_strap_width;
 237
 238 // catch assembly stalk and so on
 239
 240 cppF = [ cppg[0] - catch_stalk_eff_bend_rad, cppd[1] ];
 241 cpp4 = [ cppg[0] - catch_stalk_len, cpph[1] ] + [1,-1] * catch_cr;
 242 cpp5 = [ cpp4[0], cppC[1] + catch_cr ];
 243 cpp2 = cpp5 + [-1,0] * (catch_cr * 2 + catch_stalk_base_width);
 244 cpp2r = cpp2 + [1,0] * catch_cr;
 245 cpp2d = cpp2 + [0,-1] * catch_cr;
 246 cpp3 = [ cpp2[0] + catch_cr * 2, cppd[1] - catch_cr ];
 247 cppA = [ -cppxC, cpp9[1] ];
 248 cppE = [ cppA[0], cppD[1] ];
 249
 250 catch_assembly_dy = -cppy9 + catch_strap_width;
 251
 252
 253 module MainProfile(){
 254   main_cnr_pos = [ side_thick, top_z ] - [1,1]*main_cnr;
 255   difference(){
 256     union(){
 257       translate(main_cnr_pos){
 258         intersection(){
 259           difference(){
 260             circle(r = main_cnr);
 261             circle(r = main_cnr * 0.5);
 262           }
 263           square([10,10]);
 264         }
 265       }
 266       polygon([[ -top_middle_dr,        middle_bot_z      ],
 267                [ -top_middle_dr,        top_z             ],
 268                [ main_cnr_pos[0],       top_z             ],
 269                [ side_thick,            main_cnr_pos[1]   ],
 270                [ side_thick,            -side_height      ],
 271                [ side_taper,            -side_height      ],
 272                [ 0,                     -rivet_posn       ],
 273                [ 0,                     by_oring_z        ],
 274                [ -oring_x_rad,          by_oring_z        ],
 275                ],
 276               convexity=10);
 277     }
 278     translate([ oring_mid_dia/2 - main_dia/2, 0 ])
 279       hull(){
 280       translate([ 0, oring_y_rad ])
 281         scale([ 1/oring_oblate * (oring_compress_more+1) , oring_oblate ])
 282         circle(oring_thick/2);
 283       translate([ 0, oring_y_rad*2 - oring_thick/2 ])
 284         circle(oring_thick/2);
 285     }
 286   }
 287 }
 288
 289 module StrapHoopProfile(){
 290   circle(r = strap_hoop_thick/2);
 291 }
 292
 293 module StrapHoop(){ ////toplevel
 294   bigrad = strap_hoop_inside/2 + strap_hoop_thick/2;
 295   extralen = strap_hoop_thick * 5;
 296
 297   intersection(){
 298     rotate([strap_hoop_elevation, 0,0]){
 299       for (x= [ -1, +1 ] * bigrad) {
 300         translate([x, -extralen, 0])
 301           rotate([-90,0,0])
 302           linear_extrude(height= extralen + strap_hoop_strlen + 0.1,
 303                          convexity=10)
 304           StrapHoopProfile();
 305       }
 306       translate([0, strap_hoop_strlen, 0]){
 307         intersection(){
 308           rotate_extrude(convexity=10)
 309             translate([bigrad, 0,0])
 310             StrapHoopProfile();
 311           translate([0,50,0])
 312             cube([100,100,100], center=true);
 313         }
 314       }
 315     }
 316     translate([0, 50, 0])
 317       cube(100, center=true);
 318   }
 319 }
 320
 321 module RotateProjectSlice(offset, slice_size, nom_rad, real_rad){
 322   // nom_rad > real_rad
 323   rotate([0,0, atan2(offset, nom_rad) ]){
 324     intersection(){
 325       translate([-offset, -10, 0])
 326         rotate([90,0,0])
 327         linear_extrude(height= nom_rad*2)
 328         children(0);
 329       translate([0,0, -25])
 330         cylinder(h=50, r= real_rad);
 331       translate([0,0, -25])
 332         linear_extrude(height= 50)
 333         polygon([ [ 0,0 ],
 334                   [ -slice_size, -real_rad*2 ],
 335                   [ +slice_size, -real_rad*2 ] ]);
 336     }
 337   }
 338 }
 339
 340 module RotateProject(x_min, x_max, slice_size, nom_rad, real_rad){
 341   offs = [ for (i=[ x_min :
 342                     slice_size :
 343                     x_max + slice_size ]) i ];
 344   echo (offs);
 345   for (off=offs)
 346     RotateProjectSlice(off, slice_size, nom_rad, real_rad)
 347     children(0);
 348 }
 349
 350 module BayonetCutout(){
 351   RotateProject(bayo_c[0], bayo_i[0], bayo_slice_size,
 352                 bayo_nom_rad,
 353                 bayo_real_rad)
 354     translate([-0.5 * (bayo_a[0] + bayo_d[0]), 0])
 355     polygon(bayo_polygon, convexity=10);
 356 }
 357
 358 module ProfilesDemo(){ ////toplevel
 359   translate([-10,0]) MainProfile();
 360   translate([+10, -side_height]) polygon(bayo_polygon, convexity=10);
 361 }
 362
 363 module LimitForHandling(){ ////toplevel
 364   hull() for (r=[0,180])
 365     rotate([0,0,r]) {
 366       for (rs=[-1,+1]) {
 367         for (xd=[0,1]) {
 368           rotate([0,0, rs * handling_angle/2]) {
 369             translate([rs * xd * main_dia/2 * tan(handling_angle/2),
 370                        main_dia/2 + side_thick - main_cnr,
 371                        top_z - main_cnr]) {
 372               mirror([0,0,1])
 373                 cylinder(r= main_cnr, h=50);
 374               sphere(main_cnr);
 375             }
 376           }
 377         }
 378       }
 379     }
 380   hull() rotate_extrude(){
 381     translate([ handling_dia/2 - main_cnr, top_z - main_cnr ]) {
 382       circle(r = main_cnr);
 383       mirror([0,1]) square([ main_cnr, 50 ]);
 384     }
 385   }
 386   //cylinder(r= handling_dia/2, h=20);
 387 }
 388
 389 module Cover(){ ////toplevel
 390   render() difference(){
 391     intersection(){
 392       union(){
 393         rotate_extrude(convexity=10)
 394           translate([main_dia/2, 0])
 395           MainProfile();
 396         translate([0,0, middle_bot_z])
 397           cylinder(h= top_thick_middle, r = main_dia/2 - top_middle_dr + 1);
 398       }
 399       LimitForHandling();
 400     }
 401     for (r=[0,180]){
 402       rotate([0,0, r])
 403         translate([0,0, -side_height])
 404         BayonetCutout();
 405       rotate([0,0, r + asin((-oring_rm_beside) / (main_dia/2))])
 406         translate([0,
 407                    oring_mid_dia/2 + oring_thick/4 * oring_rm_scale,
 408                    oring_y_rad * 1.5])
 409         rotate([-oring_rm_angle, 0, 0])
 410         mirror([0,0,1])
 411         cylinder(r = oring_thick/4 * oring_rm_scale, h=20);
 412     }
 413     for (r=[0 : 60 : 179]) {
 414       rotate([0,0, r]) {
 415         height = top_thick_middle - brace_above_below*2;
 416         translate([0,0, middle_bot_z + brace_above_below + height/2 ])
 417         cube(center=true, [ oring_bore - brace_end_shorter,
 418                             brace_hole_width, height ]);
 419       }
 420     }
 421   }
 422   for (r=[0,180])
 423     rotate([0,0,r])
 424       translate([-implheadcup_large_dia * .5 - implheadcup_thick/2,
 425                  -implheadcup_large_dia * .0,
 426                  middle_bot_z + 0.1])
 427       ImplHeadCup();
 428 //  translate(strap_hoop_thick * [-0.5, 0, +1])
 429 //    translate([handling_dia/2, 0, -side_height])
 430 //    rotate([0,180,0]) rotate([0,0,90])
 431 //    StrapHoop();
 432 }
 433
 434 module SavingHole(){
 435   translate([0,0, -10])
 436     cylinder(r= main_dia/2 - jig_rim, h=20);
 437 }
 438
 439 module Jig(){ ////toplevel
 440   difference(){
 441     union(){
 442       translate([0,0, -side_height]){
 443         cylinder(r= main_dia/2 + jig_thick, h= side_height + jig_thick);
 444       }
 445       translate([-jig_mark_rad, 0, jig_thick - jig_mark])
 446         cube([jig_mark_rad*2, jig_mark, jig_mark]);
 447     }
 448     translate([0,0, -side_height-1])
 449       cylinder(r= main_dia/2, h= side_height + 1);
 450     SavingHole();
 451     translate([0,0, -rivet_posn])
 452       rotate([90, 0,0])
 453       translate([0,0, -100])
 454       cylinder(r= jig_hole_dia/2, h = 200);
 455   }
 456 }
 457
 458 module CoverTest2(){ ////toplevel
 459   difference(){
 460     Cover();
 461     SavingHole();
 462   }
 463 }
 464
 465 module CoverTest1(){ ////toplevel
 466   difference(){
 467     CoverTest2();
 468     difference(){
 469       for (r= [ 40, 147 ]){
 470         rotate([0,0, r]){
 471           translate([0,0, -10]) {
 472             cube([ main_dia*3, main_dia * .53, 18], center=true);
 473           }
 474         }
 475       }
 476 //      translate([ 50, 0, 0 ])
 477 //      cube([ 100,
 478 //             strap_hoop_inside + strap_hoop_thick*2 + 1,
 479 //             100 ],
 480 //           center=true);
 481     }
 482   }
 483 }
 484
 485 module ImplHeadCupTest(){ ////toplevel
 486   for (r=[0,180])
 487     rotate([0,0,r])
 488       translate([-17,0,0])
 489       ImplHeadCup();
 490 }
 491
 492 module SomeStrap(width){
 493   // children(0) is to add, (1) subtract
 494   difference(){
 495     union(){
 496       cylinder(r=sm_outer_rad, h=width);
 497       StrapMountProtrusion(smc_cnr_c_x + sm_closure_cnr,
 498                            smc_max_y,
 499                            sm_closure_cnr,
 500                            width);
 501       children(0);
 502     }
 503     translate([0,0,-1])
 504       cylinder(r=sm_inner_rad, h=width+2);
 505     translate(smc_pos)
 506       StrapMountBolt(10, width);
 507     translate(smc_pos)
 508       cube([ sm_bolt_tighten_allow, 40,100 ], center=true);
 509     children(1);
 510   }
 511 }
 512
 513 module StrapMountBolt(l_delta, strap_width){ ///toplevel
 514   // positioned relative to smc_pos
 515   translate([(smc_bolt_nut_eff_thick - sm_bolt_head_thick)/2,
 516              smc_bolt_y,
 517              strap_width/2]){
 518     translate([ -sm_bolt_shaft/2-1, 0,0 ]){
 519       rotate([0,90,0]) cylinder(r= sm_bolt_dia/2, h= sm_bolt_shaft+2);
 520     }
 521     translate([ -sm_bolt_shaft/2, 0,0 ])
 522       rotate([0,-90,0])
 523       cylinder($fn=6, r=smc_bolt_nut_dia/2,
 524                h=smc_bolt_nut_eff_thick + l_delta);
 525     translate([ sm_bolt_shaft/2, 0,0 ])
 526       rotate([0,90,0])
 527       cylinder(r=sm_bolt_head_dia/2, h=sm_bolt_head_thick + l_delta);
 528   }
 529 }
 530
 531 module StrapMountProtrusion(half_x, max_y, cnr, width){
 532   translate(smc_pos){
 533     linear_extrude(height=width, convexity=10){
 534       hull(){
 535         for (m = [0,1]) mirror([m,0,0]) {
 536           translate([-(half_x - cnr), max_y - cnr])
 537             circle(r=cnr);
 538           translate([-half_x, -sm_inner_rad])
 539             square([1,1]);
 540         }
 541       }
 542     }
 543   }
 544 }
 545
 546 module StrapMount(){ ////toplevel
 547   SomeStrap(sm_main_width){
 548     rotate([0,0,180]){
 549       StrapMountProtrusion(strap_hoop_inside/2 + strap_hoop_thick,
 550                            strap_hoop_thick,
 551                            sm_closure_cnr);
 552       translate(smc_pos +
 553                 [0,0, sm_main_width] +
 554                 strap_hoop_thick * [ 0, 0.5, -1.0 ])
 555         StrapHoop();
 556     }
 557     union(){ };
 558   }
 559 }
 560
 561 module CatchAssemblyCoreProfile(){
 562   difference(){
 563     union(){
 564       hull(){
 565         translate(cpp3) circle(r= catch_cr);
 566         polygon([ cpp3,
 567                   cpp2r,
 568                   cpp5,
 569                   cpph,
 570                   cppd
 571                   ]);
 572       }
 573       polygon([cppD,
 574                cppC,
 575                cpp9,
 576                cpp10,
 577                cpp11,
 578                cpp4,
 579                cpp2r,
 580                cpp2d,
 581                cppA,
 582                cppE
 583                ]);
 584       translate(cpp8) circle(r= catch_cr);
 585     }
 586     hull(){
 587       translate(cpp4) circle(r= catch_cr);
 588       translate(cpp5) circle(r= catch_cr);
 589       translate(cpp7) circle(r= catch_cr);
 590       polygon([cpp4,
 591                cppg,
 592                cpph,
 593                cpp10,
 594                cpp11,
 595                ]);
 596     }
 597     translate(cpp2) circle(r= catch_cr);
 598   }
 599   // if cpp11 is above cpp10, the subtracted hull above
 600   // can go down too far.  Ensure we do not cut off below cppy6.
 601   polygon([ cppE,
 602             cppD,
 603             cpp9,
 604             [ cpp9[0],            cppy6 ],
 605             [ cpp7[0] - catch_cr, cppy6 ],
 606             cpp2d
 607             ]);
 608 }
 609
 610 module CatchHeadProfile(){
 611   intersection(){
 612     translate(cppF){
 613       difference(){
 614         circle(r = dist2d(cppF, cppd));
 615         //circle(r = dist2d(cppF, cppa));
 616       }
 617     }
 618     polygon([ cppa,
 619               cppg,
 620               cpph,
 621               cppd,
 622               cppc,
 623               cppb ]);
 624   }
 625   polygon([ cppd,
 626             cppg,
 627             cppf,
 628             cppe,
 629             cpph ]);
 630 }
 631
 632
 633 module CatchCore(){ /////toplevel
 634   linear_extrude(height=catch_strap_thick, convexity=10)
 635     CatchAssemblyCoreProfile();
 636
 637   linear_extrude(height=catch_head_th, convexity=10)
 638     CatchHeadProfile();
 639
 640   translate(concat(cppB,[0])) hull(){
 641     translate([0,0, catch_knob_height + catch_head_th - catch_knob_dia/2])
 642       sphere(r = catch_knob_dia/2);
 643     cylinder(r = catch_knob_dia/2, h = 0.1);
 644   }
 645 }
 646
 647 module CatchPreDistort(){ /////toplevel
 648   scale(100 / sm_inner_rad)
 649     rotate([90,0,0])
 650     CatchCore();
 651 }
 652
 653 module CatchAssembly(){ /////toplevel
 654   rotate([0,0, -(cppe[0] + cppB[0] + catch_pin_slop) / sm_inner_rad * 360/TAU])
 655     translate([0,0, catch_assembly_dy])
 656     scale(sm_inner_rad / 100)
 657     import(str("poster-tube-lid,CatchPostDistort-fa",
 658                (coarse ? 20 : 3),
 659                ".stl"),
 660            convexity=20);
 661
 662   SomeStrap(catch_strap_width){
 663     union(){ }
 664     union(){
 665       translate([-200, -200, -200])
 666         cube([400, 200, 400]);
 667     }
 668   }
 669 }
 670
 671 module CatchDemo(){ /////toplevel
 672   color("blue") translate([0,0,
 673                            -catch_assembly_dy
 674              ])
 675     CatchAssembly();
 676   translate([0,0,+side_height
 677              ])
 678     Cover();
 679 }
 680
 681 module CatchDemoS(){ /////toplevel
 682   color("blue") translate([0,0,
 683              -catch_assembly_dy
 684              ])
 685     CatchAssembly();
 686   intersection(){
 687     translate([0,0,+side_height
 688                ])
 689       Cover();
 690     mirror([0,1,0]) translate([-250,33,0]) cube([500,500,500]);
 691   }
 692   color("black")
 693     translate([0,-33,0])
 694     cube([6.15, 2,2], center=true);
 695 }
 696
 697 module CatchPinProfileDemo(){ /////toplevel
 698   echo("G ",
 699        cpp2[0] - cpp1[0],
 700        bayo_n[0] - bayo_e[0]);
 701   color("blue") translate([0,0,
 702                            +1,
 703              ]) {
 704     CatchAssemblyCoreProfile();
 705     CatchHeadProfile();
 706   }
 707   polygon(bayo_polygon, convexity=10);
 708 }
 709
 710 //ProfilesDemo();
 711 //BayonetCutout();
 712 //MainProfile();
 713 //Cover();
 714 //Jig();
 715 //CoverTest();