poster-tube-lid.scad

   1 // -*- C -*-
   2
   3 main_dia = 71.2 + 0.50 - 2.26;
   4 top_thick = 4;
   5
   6 main_cnr = 4.0;
   7
   8 rivet_posn = 6.0;
   9 rivet_thick = 1.67;
  10 rivet_width = 4.15 + 1.0;
  11 rivet_tall = 5.51 + 0.49;
  12
  13 over_rivet_wall = 0.5;
  14 side_rivet_gap = 1.5;
  15
  16 bayo_interf = 0.75;
  17 bayo_behind = 3.5;
  18 bayo_interf_width = 2.0;
  19 bayo_interf_slope = 0.75;
  20
  21 oring_thick = 5.0;
  22 oring_bore = 62.0;
  23
  24 oring_upper_embed_angle = 45;
  25 oring_compress = 0.1; // proportion
  26
  27 side_taper = 1.0;
  28
  29 bayo_above_gap = 1.0;
  30
  31 bayo_entry = bayo_behind/3;
  32
  33 bayo_slice_size = 1;
  34
  35 brace_hole_width = 1.0;
  36 brace_above_below = 1.2;
  37
  38 jig_thick = 1.4;
  39 jig_hole_dia = 3.0;
  40 jig_rim = 5;
  41 jig_mark = 5;
  42
  43 // calculated
  44
  45 bayo_entry_x = bayo_entry;
  46 bayo_entry_z = bayo_entry;
  47 bayo_inramp_x = bayo_entry;
  48 bayo_inramp_z = bayo_entry;
  49
  50 oring_mid_dia = oring_bore + oring_thick;
  51 oring_outer_dia = oring_mid_dia + oring_thick;
  52
  53 oring_oblate = (1 - oring_compress);
  54
  55 oring_y_rad = oring_thick/2 * oring_oblate;
  56 oring_x_rad = oring_thick/2 / oring_oblate;
  57
  58 seal_thick = oring_y_rad * (1 + cos(oring_upper_embed_angle));
  59
  60 side_height = rivet_posn + bayo_behind + rivet_thick/2;
  61 side_thick = rivet_tall + over_rivet_wall;
  62
  63 top_z = top_thick + seal_thick;
  64
  65 bayo_entry = bayo_behind / 3.0;
  66 bayo_top_z = bayo_behind + rivet_thick + bayo_above_gap;
  67 bayo_entry_ramp = bayo_entry + bayo_interf;
  68
  69 rivet_entry_width = rivet_width + side_rivet_gap;
  70
  71 jig_mark_rad = jig_mark + main_dia/2 + jig_thick;
  72
  73 $fs=0.5;
  74 $fa=1;
  75
  76 // bayonet definition
  77
  78 bayo_a = [ bayo_entry_x, 0 ];
  79 bayo_p = [ 0, bayo_entry_z ];
  80 bayo_n = [ 0, bayo_behind-bayo_inramp_z ];
  81 bayo_m = [ bayo_inramp_x, bayo_behind ];
  82 bayo_l = bayo_m + bayo_interf * [ 1/bayo_interf_slope,  1 ];
  83 bayo_k = bayo_l + [ bayo_interf_width, 0 ];
  84 bayo_j = bayo_k + bayo_interf * [ 1/bayo_interf_slope, -1 ];
  85 bayo_i = bayo_j + [ rivet_width, 0 ];
  86 bayo_h = [ bayo_i[0], bayo_behind + rivet_thick + bayo_above_gap ];
  87 bayo_g = [ bayo_m[0] - rivet_width, bayo_h[1] ];
  88
  89 bayo_e = [-bayo_p[0], bayo_p[1]] - [rivet_entry_width,0];
  90 bayo_d = [-bayo_a[0], bayo_a[1]] - [rivet_entry_width,0];
  91 bayo_c = bayo_d + [0,-5];
  92 bayo_b = bayo_a + [0,-5];
  93
  94 bayo_f = [ bayo_e[0], bayo_g[1] + (bayo_e[0] - bayo_g[0]) ];
  95
  96 bayo_polygon = [ bayo_a,
  97                  bayo_b,
  98                  bayo_c,
  99                  bayo_d,
 100                  bayo_e,
 101                  bayo_f,
 102                  bayo_g,
 103                  bayo_h,
 104                  bayo_i,
 105                  bayo_j,
 106                  bayo_k,
 107                  bayo_l,
 108                  bayo_m,
 109                  bayo_n,
 110                  bayo_p ];
 111
 112 echo(bayo_polygon);
 113
 114 module MainProfile(){
 115   main_cnr_pos = [ side_thick, top_z ] - [1,1]*main_cnr;
 116   difference(){
 117     union(){
 118       translate(main_cnr_pos){
 119         intersection(){
 120           difference(){
 121             circle(r = main_cnr);
 122             circle(r = main_cnr * 0.5);
 123           }
 124           square([10,10]);
 125         }
 126       }
 127       polygon([[ -11,                   seal_thick        ],
 128                [ -11,                   top_z             ],
 129                [ main_cnr_pos[0],       top_z             ],
 130                [ side_thick,            main_cnr_pos[1]   ],
 131                [ side_thick,            -side_height      ],
 132                [ side_taper,            -side_height      ],
 133                [ 0,                     -rivet_posn       ],
 134                [ 0,                     seal_thick        ],
 135                ],
 136               convexity=10);
 137     }
 138     %translate([ oring_mid_dia/2 - main_dia/2,
 139                  oring_y_rad ])
 140        scale([ 1/oring_oblate, oring_oblate ])
 141        circle(oring_thick/2);
 142   }
 143 }
 144
 145 module RotateProjectSlice(offset, slice_size, nom_rad, real_rad){
 146   // nom_rad > real_rad
 147   rotate([0,0, atan2(offset, nom_rad) ]){
 148     intersection(){
 149       translate([-offset, -10, 0])
 150         rotate([90,0,0])
 151         linear_extrude(height= nom_rad*2)
 152         children(0);
 153       translate([0,0, -25])
 154         cylinder(h=50, r= real_rad);
 155       translate([0,0, -25])
 156         linear_extrude(height= 50)
 157         polygon([ [ 0,0 ],
 158                   [ -slice_size, -real_rad*2 ],
 159                   [ +slice_size, -real_rad*2 ] ]);
 160     }
 161   }
 162 }
 163
 164 module RotateProject(x_min, x_max, slice_size, nom_rad, real_rad){
 165   offs = [ for (i=[ x_min :
 166                     slice_size :
 167                     x_max + slice_size ]) i ];
 168   echo (offs);
 169   for (off=offs)
 170     RotateProjectSlice(off, slice_size, nom_rad, real_rad)
 171     children(0);
 172 }
 173
 174 module BayonetCutout(){
 175   RotateProject(bayo_c[0], bayo_i[0], bayo_slice_size,
 176                 main_dia/2 + side_thick,
 177                 main_dia/2 + rivet_tall)
 178     polygon(bayo_polygon, convexity=10);
 179 }
 180
 181 module ProfilesDemo(){ ////toplevel
 182   translate([-20,0]) MainProfile();
 183   polygon(bayo_polygon, convexity=10);
 184 }
 185
 186 module Cover(){ ////toplevel
 187   render() difference(){
 188     union(){
 189       rotate_extrude(convexity=10)
 190         translate([main_dia/2, 0])
 191         MainProfile();
 192       translate([0,0, seal_thick])
 193         cylinder(h= top_thick, r = main_dia/2 - 10);
 194     }
 195     for (r=[0,180])
 196       rotate([0,0, r])
 197         translate([0,0, -side_height])
 198         BayonetCutout();
 199     for (r=[0 : 60 : 179]) {
 200       rotate([0,0, r]) {
 201         height = top_thick - brace_above_below*2;
 202         translate([0,0, seal_thick + brace_above_below + height/2 ])
 203         cube(center=true, [ main_dia, brace_hole_width, height ]);
 204       }
 205     }
 206   }
 207 }
 208
 209 module SavingHole(){
 210   translate([0,0, -10])
 211     cylinder(r= main_dia/2 - jig_rim, h=20);
 212 }
 213
 214 module Jig(){ ////toplevel
 215   difference(){
 216     union(){
 217       translate([0,0, -side_height]){
 218         cylinder(r= main_dia/2 + jig_thick, h= side_height + jig_thick);
 219       }
 220       translate([-jig_mark_rad, 0, jig_thick - jig_mark])
 221         cube([jig_mark_rad*2, jig_mark, jig_mark]);
 222     }
 223     translate([0,0, -side_height-1])
 224       cylinder(r= main_dia/2, h= side_height + 1);
 225     SavingHole();
 226     translate([0,0, -rivet_posn])
 227       rotate([90, 0,0])
 228       translate([0,0, -100])
 229       cylinder(r= jig_hole_dia/2, h = 200);
 230   }
 231 }
 232
 233 module CoverTest2(){ ////toplevel
 234   difference(){
 235     Cover();
 236     SavingHole();
 237   }
 238 }
 239
 240 module CoverTest1(){ ////toplevel
 241   difference(){
 242     CoverTest2();
 243     translate([0,0, -10])
 244       cube([ main_dia*3, main_dia * .85, 20], center=true);
 245   }
 246 }
 247
 248 //ProfilesDemo();
 249 //BayonetCutout();
 250 //MainProfile();
 251 //Cover();
 252 //Jig();
 253 //CoverTest();