poster-tube-lid.scad

   1 // -*- C -*-
   2
   3 coarse = false;
   4
   5 main_dia = 71.2 + 0.50 - 2.26;
   6 top_thick_middle = 4;
   7 top_thick_by_oring = 3.0;
   8 top_middle_dr = 11;
   9
  10 main_cnr = 6.0;
  11
  12 min_wall = 3;
  13
  14 rivet_posn = 6.0 + 0.1;
  15 rivet_thick = 1.67;
  16 rivet_width = 4.15 + 1.0;
  17 rivet_tall = 5.51 + 1.49;
  18
  19 over_rivet_wall = 1.0;
  20 side_rivet_gap = 1.5;
  21 inside_rivet_gap = 1.5;
  22
  23 bayo_interf = 0.44;
  24 bayo_behind = 3.5;
  25 bayo_interf_width = 2.0;
  26 bayo_interf_slope = 0.5;
  27
  28 oring_thick = 5.0;
  29 oring_bore = 62.0;
  30
  31 oring_upper_embed_angle = 80;
  32 oring_compress = 0.1; // proportion
  33
  34 oring_rm_beside = 8;
  35 oring_rm_scale = 2.0;
  36 oring_rm_angle = 20;
  37
  38 side_taper = 1.0;
  39
  40 bayo_gap = 6.0;
  41
  42 bayo_entry = bayo_behind/3;
  43
  44 bayo_slice_size = coarse ? 5 : 1;
  45
  46 brace_hole_width = 1.0;
  47 brace_above_below = 1.2;
  48 brace_end_shorter = 0.3;
  49
  50 jig_thick = 1.4;
  51 jig_hole_dia = 3.0;
  52 jig_rim = 5;
  53 jig_mark = 5;
  54
  55 strap_hoop_thick = 6;
  56 strap_hoop_inside = 10;
  57 strap_hoop_strlen = 10;
  58 strap_hoop_elevation = 45;
  59
  60 sm_inner_circum = 218;
  61 sm_main_thick = 2.0;
  62 sm_main_width = 20;
  63
  64 sm_bolt_dia = 3.5 + 0.1;
  65 sm_bolt_shaft = 21.9;
  66 sm_bolt_head_dia = 6.94 + 1.0;
  67 sm_bolt_head_thick = 2.14;
  68 sm_bolt_nut_width = 5.89 + 0.25;
  69 sm_bolt_nut_thick = 3.68;
  70 sm_bolt_tighten_allow = 2.0;
  71
  72 sm_bolt_y_clear = 0.75;
  73 sm_bolt_y_over = 0.5;
  74
  75 sm_closure_cnr = 3.0;
  76
  77 // calculated
  78
  79 TAU = PI*2;
  80
  81 bayo_entry_x = bayo_entry;
  82 bayo_entry_z = bayo_entry;
  83 bayo_inramp_x = bayo_entry;
  84 bayo_inramp_z = bayo_entry;
  85
  86 oring_mid_dia = oring_bore + oring_thick;
  87 oring_outer_dia = oring_mid_dia + oring_thick;
  88
  89 oring_oblate = (1 - oring_compress);
  90
  91 oring_y_rad = oring_thick/2 * oring_oblate;
  92 oring_x_rad = oring_thick/2 / oring_oblate;
  93
  94 by_oring_z = oring_y_rad * (1 + cos(oring_upper_embed_angle));
  95
  96 side_height = rivet_posn + bayo_behind + rivet_thick/2;
  97 side_thick = rivet_tall + over_rivet_wall;
  98
  99 top_z = top_thick_by_oring + oring_y_rad + by_oring_z;
 100
 101 middle_bot_z = top_z - top_thick_middle;
 102
 103 bayo_entry = bayo_behind / 3.0;
 104 bayo_top_z = bayo_behind + bayo_gap;
 105
 106 rivet_entry_width = rivet_width + side_rivet_gap;
 107
 108 jig_mark_rad = jig_mark + main_dia/2 + jig_thick;
 109
 110 handling_dia = oring_bore + oring_thick*2 + min_wall*2;
 111 handling_angle = 45;
 112
 113 sm_inner_rad = (sm_inner_circum + sm_bolt_tighten_allow/2) / TAU;
 114 sm_outer_rad = sm_inner_rad + sm_main_thick;
 115
 116 smc_pos = [ 0, sm_inner_rad, 0 ];
 117
 118 smc_bolt_nut_dia = sm_bolt_nut_width / cos(30);
 119 smc_bolt_nut_eff_thick = sm_bolt_nut_thick + sm_bolt_tighten_allow;
 120
 121 smc_bolt_y = sm_bolt_dia/2 + sm_bolt_y_clear;
 122 smc_max_y = smc_bolt_y + sm_bolt_y_over
 123   + max(sm_bolt_head_dia/2, smc_bolt_nut_dia/2);
 124 smc_cnr_c_x = sm_bolt_shaft/2 - sm_closure_cnr
 125   + sm_bolt_head_thick/2 + smc_bolt_nut_eff_thick/2;
 126
 127 $fs= coarse ? 2.5 : 0.5;
 128 $fa= coarse ? 5 : 1;
 129
 130 // bayonet definition
 131
 132 bayo_a = [ bayo_entry_x, 0 ];
 133 bayo_p = [ 0, bayo_entry_z ];
 134 bayo_n = [ 0, bayo_behind-bayo_inramp_z ];
 135 bayo_m = [ bayo_inramp_x, bayo_behind ];
 136 bayo_l = bayo_m + bayo_interf * [ 1/bayo_interf_slope,  1 ];
 137 bayo_k = bayo_l + [ bayo_interf_width, 0 ];
 138 bayo_j = bayo_k + bayo_interf * [ 1/bayo_interf_slope, -1 ];
 139 bayo_i = bayo_j + [ rivet_width + inside_rivet_gap, 0 ];
 140 bayo_h = [ bayo_i[0], bayo_behind + bayo_gap + bayo_interf ];
 141 bayo_g = [ bayo_m[0] - rivet_width, bayo_h[1] ];
 142
 143 bayo_e = [-bayo_p[0], bayo_p[1]] - [rivet_entry_width,0];
 144 bayo_d = [-bayo_a[0], bayo_a[1]] - [rivet_entry_width,0];
 145 bayo_c = bayo_d + [0,-5];
 146 bayo_b = bayo_a + [0,-5];
 147
 148 bayo_f = [ bayo_e[0], bayo_g[1] + (bayo_e[0] - bayo_g[0]) ];
 149
 150 bayo_polygon = [ bayo_a,
 151                  bayo_b,
 152                  bayo_c,
 153                  bayo_d,
 154                  bayo_e,
 155                  bayo_f,
 156                  bayo_g,
 157                  bayo_h,
 158                  bayo_i,
 159                  bayo_j,
 160                  bayo_k,
 161                  bayo_l,
 162                  bayo_m,
 163                  bayo_n,
 164                  bayo_p ];
 165
 166 echo(bayo_polygon);
 167
 168 module MainProfile(){
 169   main_cnr_pos = [ side_thick, top_z ] - [1,1]*main_cnr;
 170   difference(){
 171     union(){
 172       translate(main_cnr_pos){
 173         intersection(){
 174           difference(){
 175             circle(r = main_cnr);
 176             circle(r = main_cnr * 0.5);
 177           }
 178           square([10,10]);
 179         }
 180       }
 181       polygon([[ -top_middle_dr,        middle_bot_z      ],
 182                [ -top_middle_dr,        top_z             ],
 183                [ main_cnr_pos[0],       top_z             ],
 184                [ side_thick,            main_cnr_pos[1]   ],
 185                [ side_thick,            -side_height      ],
 186                [ side_taper,            -side_height      ],
 187                [ 0,                     -rivet_posn       ],
 188                [ 0,                     by_oring_z        ],
 189                [ -oring_x_rad,          by_oring_z        ],
 190                ],
 191               convexity=10);
 192     }
 193     translate([ oring_mid_dia/2 - main_dia/2, 0 ])
 194       hull(){
 195       translate([ 0, oring_y_rad ])
 196         scale([ 1/oring_oblate, oring_oblate ])
 197         circle(oring_thick/2);
 198       translate([ 0, oring_y_rad*2 - oring_thick/2 ])
 199         circle(oring_thick/2);
 200     }
 201   }
 202 }
 203
 204 module StrapHoopProfile(){
 205   circle(r = strap_hoop_thick/2);
 206 }
 207
 208 module StrapHoop(){ ////toplevel
 209   bigrad = strap_hoop_inside/2 + strap_hoop_thick/2;
 210   extralen = strap_hoop_thick * 5;
 211
 212   intersection(){
 213     rotate([strap_hoop_elevation, 0,0]){
 214       for (x= [ -1, +1 ] * bigrad) {
 215         translate([x, -extralen, 0])
 216           rotate([-90,0,0])
 217           linear_extrude(height= extralen + strap_hoop_strlen + 0.1,
 218                          convexity=10)
 219           StrapHoopProfile();
 220       }
 221       translate([0, strap_hoop_strlen, 0]){
 222         intersection(){
 223           rotate_extrude(convexity=10)
 224             translate([bigrad, 0,0])
 225             StrapHoopProfile();
 226           translate([0,50,0])
 227             cube([100,100,100], center=true);
 228         }
 229       }
 230     }
 231     translate([0, 50, 0])
 232       cube(100, center=true);
 233   }
 234 }
 235
 236 module HandlingProfile(){
 237 //  translate([
 238 }
 239
 240 module RotateProjectSlice(offset, slice_size, nom_rad, real_rad){
 241   // nom_rad > real_rad
 242   rotate([0,0, atan2(offset, nom_rad) ]){
 243     intersection(){
 244       translate([-offset, -10, 0])
 245         rotate([90,0,0])
 246         linear_extrude(height= nom_rad*2)
 247         children(0);
 248       translate([0,0, -25])
 249         cylinder(h=50, r= real_rad);
 250       translate([0,0, -25])
 251         linear_extrude(height= 50)
 252         polygon([ [ 0,0 ],
 253                   [ -slice_size, -real_rad*2 ],
 254                   [ +slice_size, -real_rad*2 ] ]);
 255     }
 256   }
 257 }
 258
 259 module RotateProject(x_min, x_max, slice_size, nom_rad, real_rad){
 260   offs = [ for (i=[ x_min :
 261                     slice_size :
 262                     x_max + slice_size ]) i ];
 263   echo (offs);
 264   for (off=offs)
 265     RotateProjectSlice(off, slice_size, nom_rad, real_rad)
 266     children(0);
 267 }
 268
 269 module BayonetCutout(){
 270   RotateProject(bayo_c[0], bayo_i[0], bayo_slice_size,
 271                 main_dia/2 + side_thick,
 272                 main_dia/2 + rivet_tall)
 273     translate([-0.5 * (bayo_a[0] + bayo_d[0]), 0])
 274     polygon(bayo_polygon, convexity=10);
 275 }
 276
 277 module ProfilesDemo(){ ////toplevel
 278   translate([-10,0]) MainProfile();
 279   translate([+10, -side_height]) polygon(bayo_polygon, convexity=10);
 280 }
 281
 282 module LimitForHandling(){ ////toplevel
 283   hull() for (r=[0,180])
 284     rotate([0,0,r]) {
 285       for (rs=[-1,+1]) {
 286         for (xd=[0,1]) {
 287           rotate([0,0, rs * handling_angle/2]) {
 288             translate([rs * xd * main_dia/2 * tan(handling_angle/2),
 289                        main_dia/2 + side_thick - main_cnr,
 290                        top_z - main_cnr]) {
 291               mirror([0,0,1])
 292                 cylinder(r= main_cnr, h=50);
 293               sphere(main_cnr);
 294             }
 295           }
 296         }
 297       }
 298     }
 299   hull() rotate_extrude(){
 300     translate([ handling_dia/2 - main_cnr, top_z - main_cnr ]) {
 301       circle(r = main_cnr);
 302       mirror([0,1]) square([ main_cnr, 50 ]);
 303     }
 304   }
 305   //cylinder(r= handling_dia/2, h=20);
 306 }
 307
 308 module Cover(){ ////toplevel
 309   render() difference(){
 310     intersection(){
 311       union(){
 312         rotate_extrude(convexity=10)
 313           translate([main_dia/2, 0])
 314           MainProfile();
 315         translate([0,0, middle_bot_z])
 316           cylinder(h= top_thick_middle, r = main_dia/2 - top_middle_dr + 1);
 317       }
 318       LimitForHandling();
 319     }
 320     for (r=[0,180]){
 321       rotate([0,0, r])
 322         translate([0,0, -side_height])
 323         BayonetCutout();
 324       rotate([0,0, r + asin((-oring_rm_beside) / (main_dia/2))])
 325         translate([0,
 326                    oring_mid_dia/2 + oring_thick/4 * oring_rm_scale,
 327                    oring_y_rad * 1.5])
 328         rotate([-oring_rm_angle, 0, 0])
 329         mirror([0,0,1])
 330         cylinder(r = oring_thick/4 * oring_rm_scale, h=20);
 331     }
 332     for (r=[0 : 60 : 179]) {
 333       rotate([0,0, r]) {
 334         height = top_thick_middle - brace_above_below*2;
 335         translate([0,0, middle_bot_z + brace_above_below + height/2 ])
 336         cube(center=true, [ oring_bore - brace_end_shorter,
 337                             brace_hole_width, height ]);
 338       }
 339     }
 340   }
 341 //  translate(strap_hoop_thick * [-0.5, 0, +1])
 342 //    translate([handling_dia/2, 0, -side_height])
 343 //    rotate([0,180,0]) rotate([0,0,90])
 344 //    StrapHoop();
 345 }
 346
 347 module SavingHole(){
 348   translate([0,0, -10])
 349     cylinder(r= main_dia/2 - jig_rim, h=20);
 350 }
 351
 352 module Jig(){ ////toplevel
 353   difference(){
 354     union(){
 355       translate([0,0, -side_height]){
 356         cylinder(r= main_dia/2 + jig_thick, h= side_height + jig_thick);
 357       }
 358       translate([-jig_mark_rad, 0, jig_thick - jig_mark])
 359         cube([jig_mark_rad*2, jig_mark, jig_mark]);
 360     }
 361     translate([0,0, -side_height-1])
 362       cylinder(r= main_dia/2, h= side_height + 1);
 363     SavingHole();
 364     translate([0,0, -rivet_posn])
 365       rotate([90, 0,0])
 366       translate([0,0, -100])
 367       cylinder(r= jig_hole_dia/2, h = 200);
 368   }
 369 }
 370
 371 module CoverTest2(){ ////toplevel
 372   difference(){
 373     Cover();
 374     SavingHole();
 375   }
 376 }
 377
 378 module CoverTest1(){ ////toplevel
 379   difference(){
 380     CoverTest2();
 381     difference(){
 382       for (r= [ 40, 147 ]){
 383         rotate([0,0, r]){
 384           translate([0,0, -10]) {
 385             cube([ main_dia*3, main_dia * .53, 18], center=true);
 386           }
 387         }
 388       }
 389 //      translate([ 50, 0, 0 ])
 390 //      cube([ 100,
 391 //             strap_hoop_inside + strap_hoop_thick*2 + 1,
 392 //             100 ],
 393 //           center=true);
 394     }
 395   }
 396 }
 397
 398 module StrapMountBolt(l_delta){ ///toplevel
 399   // positioned relative to smc_pos
 400   translate([(smc_bolt_nut_eff_thick - sm_bolt_head_thick)/2,
 401              smc_bolt_y,
 402              sm_main_width/2]){
 403     translate([ -sm_bolt_shaft/2-1, 0,0 ]){
 404       rotate([0,90,0]) cylinder(r= sm_bolt_dia/2, h= sm_bolt_shaft+2);
 405     }
 406     translate([ -sm_bolt_shaft/2, 0,0 ])
 407       rotate([0,-90,0])
 408       cylinder($fn=6, r=smc_bolt_nut_dia/2,
 409                h=smc_bolt_nut_eff_thick + l_delta);
 410     translate([ sm_bolt_shaft/2, 0,0 ])
 411       rotate([0,90,0])
 412       cylinder(r=sm_bolt_head_dia/2, h=sm_bolt_head_thick + l_delta);
 413   }
 414 }
 415
 416 module StrapMountProtrusion(half_x, max_y, cnr){
 417   translate(smc_pos){
 418     linear_extrude(height=sm_main_width, convexity=10){
 419       hull(){
 420         for (m = [0,1]) mirror([m,0,0]) {
 421           translate([-(half_x - cnr), max_y - cnr])
 422             circle(r=cnr);
 423           translate([-half_x, -sm_inner_rad])
 424             square([1,1]);
 425         }
 426       }
 427     }
 428   }
 429 }
 430
 431 module StrapMount(){ ////toplevel
 432   difference(){
 433     union(){
 434       cylinder(r=sm_outer_rad, h=sm_main_width);
 435       StrapMountProtrusion(smc_cnr_c_x + sm_closure_cnr,
 436                            smc_max_y,
 437                            sm_closure_cnr);
 438       rotate([0,0,180]){
 439         StrapMountProtrusion(strap_hoop_inside/2 + strap_hoop_thick,
 440                              strap_hoop_thick,
 441                              sm_closure_cnr);
 442         translate(smc_pos +
 443                   [0,0, sm_main_width] +
 444                   strap_hoop_thick * [ 0, 0.5, -1.0 ])
 445           StrapHoop();
 446       }
 447     }
 448     translate([0,0,-1])
 449       cylinder(r=sm_inner_rad, h=sm_main_width+2);
 450     translate(smc_pos)
 451       StrapMountBolt(10);
 452     translate(smc_pos)
 453       cube([ sm_bolt_tighten_allow, 40,100 ], center=true);
 454   }
 455 }
 456
 457 //ProfilesDemo();
 458 //BayonetCutout();
 459 //MainProfile();
 460 //Cover();
 461 //Jig();
 462 //CoverTest();